lib/XML/Feed/Atom.pm

   1 # $Id: Atom.pm 1924 2006-03-03 17:34:15Z btrott $
   2
   3 package XML::Feed::Atom;
   4 use strict;
   5
   6 use base qw( XML::Feed );
   7 use XML::Atom::Feed;
   8 use XML::Atom::Util qw( iso2dt );
   9 use List::Util qw( first );
  10 use DateTime::Format::W3CDTF;
  11
  12 sub init_empty {
  13     my $feed = shift;
  14     $feed->{atom} = XML::Atom::Feed->new;
  15     $feed;
  16 }
  17
  18 sub init_string {
  19     my $feed = shift;
  20     my($str) = @_;
  21     if ($str) {
  22         $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
  23             or return $feed->error(XML::Atom::Feed->errstr);
  24     }
  25     $feed;
  26 }
  27
  28 sub format { 'Atom' }
  29
  30 sub title { shift->{atom}->title(@_) }
  31 sub link {
  32     my $feed = shift;
  33     if (@_) {
  34         $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
  35                                   type => 'text/html', });
  36     } else {
  37         my $l = first { $_->rel eq 'alternate' } $feed->{atom}->link;
  38         $l ? $l->href : undef;
  39     }
  40 }
  41 sub description { shift->{atom}->tagline(@_) }
  42 sub copyright   { shift->{atom}->copyright(@_) }
  43 sub language    { shift->{atom}->language(@_) }
  44 sub generator   { shift->{atom}->generator(@_) }
  45
  46 sub author {
  47     my $feed = shift;
  48     if (@_ && $_[0]) {
  49         my $person = XML::Atom::Person->new;
  50         $person->name($_[0]);
  51         $feed->{atom}->author($person);
  52     } else {
  53         $feed->{atom}->author ? $feed->{atom}->author->name : undef;
  54     }
  55 }
  56
  57 sub modified {
  58     my $feed = shift;
  59     if (@_) {
  60         $feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
  61     } else {
  62         iso2dt($feed->{atom}->modified);
  63     }
  64 }
  65
  66 sub entries {
  67     my @entries;
  68     for my $entry ($_[0]->{atom}->entries) {
  69         push @entries, XML::Feed::Entry::Atom->wrap($entry);
  70     }
  71     @entries;
  72 }
  73
  74 sub add_entry {
  75     my $feed = shift;
  76     my($entry) = @_;
  77     $feed->{atom}->add_entry($entry->unwrap);
  78 }
  79
  80 sub as_xml { $_[0]->{atom}->as_xml }
  81
  82 package XML::Feed::Entry::Atom;
  83 use strict;
  84
  85 use base qw( XML::Feed::Entry );
  86 use XML::Atom::Util qw( iso2dt );
  87 use XML::Feed::Content;
  88 use XML::Atom::Entry;
  89 use List::Util qw( first );
  90
  91 sub init_empty {
  92     my $entry = shift;
  93     $entry->{entry} = XML::Atom::Entry->new;
  94     1;
  95 }
  96
  97 sub title { shift->{entry}->title(@_) }
  98 sub link {
  99     my $entry = shift;
 100     if (@_) {
 101         $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
 102                                     type => 'text/html', });
 103     } else {
 104         my $l = first { $_->rel eq 'alternate' } $entry->{entry}->link;
 105         $l ? $l->href : undef;
 106     }
 107 }
 108
 109 sub summary {
 110     my $entry = shift;
 111     if (@_) {
 112         $entry->{entry}->summary(ref($_[0]) eq 'XML::Feed::Content' ?
 113             $_[0]->body : $_[0]);
 114     } else {
 115         XML::Feed::Content->wrap({ type => 'text/html',
 116                                    body => $entry->{entry}->summary });
 117     }
 118 }
 119
 120 sub content {
 121     my $entry = shift;
 122     if (@_) {
 123         my %param;
 124         if (ref($_[0]) eq 'XML::Feed::Content') {
 125             %param = (Body => $_[0]->body, Type => $_[0]->type || 'text/html');
 126         } else {
 127             %param = (Body => $_[0], Type => 'text/html');
 128         }
 129         $entry->{entry}->content(XML::Atom::Content->new(%param));
 130     } else {
 131         my $c = $entry->{entry}->content;
 132         XML::Feed::Content->wrap({ type => $c ? $c->type : undef,
 133                                    body => $c ? $c->body : undef });
 134     }
 135 }
 136
 137 sub category {
 138     my $entry = shift;
 139     my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
 140     if (@_) {
 141         $entry->{entry}->set($ns, 'subject', $_[0]);
 142     } else {
 143         $entry->{entry}->get($ns, 'subject');
 144     }
 145 }
 146
 147 sub author {
 148     my $entry = shift;
 149     if (@_ && $_[0]) {
 150         my $person = XML::Atom::Person->new;
 151         $person->name($_[0]);
 152         $entry->{entry}->author($person);
 153     } else {
 154         $entry->{entry}->author ? $entry->{entry}->author->name : undef;
 155     }
 156 }
 157
 158 sub id { shift->{entry}->id(@_) }
 159
 160 sub issued {
 161     my $entry = shift;
 162     if (@_) {
 163         $entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 164     } else {
 165         $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
 166     }
 167 }
 168
 169 sub modified {
 170     my $entry = shift;
 171     if (@_) {
 172         $entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 173     } else {
 174         $entry->{entry}->modified ? iso2dt($entry->{entry}->modified) : undef;
 175     }
 176 }
 177
 178 1;