lib/XML/Feed/Atom.pm

   1 # $Id: Atom.pm 1958 2006-08-14 05:31:27Z btrott $
   2
   3 package XML::Feed::Atom;
   4 use strict;
   5
   6 use base qw( XML::Feed );
   7 use XML::Atom::Feed;
   8 use XML::Atom::Util qw( iso2dt );
   9 use List::Util qw( first );
  10 use DateTime::Format::W3CDTF;
  11
  12 sub init_empty {
  13     my ($feed, %args) = @_;
  14     $args{'Version'} ||= '1.0';
  15
  16     $feed->{atom} = XML::Atom::Feed->new(%args);
  17     $feed;
  18 }
  19
  20 sub init_string {
  21     my $feed = shift;
  22     my($str) = @_;
  23     if ($str) {
  24         $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
  25             or return $feed->error(XML::Atom::Feed->errstr);
  26     }
  27     $feed;
  28 }
  29
  30 sub format { 'Atom' }
  31
  32 sub title { shift->{atom}->title(@_) }
  33 sub link {
  34     my $feed = shift;
  35     if (@_) {
  36         $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
  37                                   type => 'text/html', });
  38     } else {
  39         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $feed->{atom}->link;
  40         $l ? $l->href : undef;
  41     }
  42 }
  43 sub description { shift->{atom}->tagline(@_) }
  44 sub copyright   { shift->{atom}->copyright(@_) }
  45 sub language    { shift->{atom}->language(@_) }
  46 sub generator   { shift->{atom}->generator(@_) }
  47 sub id          { shift->{atom}->id(@_) }
  48 sub updated     { shift->{atom}->updated(@_) }
  49 sub add_link    { shift->{atom}->add_link(@_) }
  50
  51 sub author {
  52     my $feed = shift;
  53     if (@_ && $_[0]) {
  54         my $person = XML::Atom::Person->new(Version => 1.0);
  55         $person->name($_[0]);
  56         $feed->{atom}->author($person);
  57     } else {
  58         $feed->{atom}->author ? $feed->{atom}->author->name : undef;
  59     }
  60 }
  61
  62 sub modified {
  63     my $feed = shift;
  64     if (@_) {
  65         $feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
  66     } else {
  67         return iso2dt($feed->{atom}->modified) if $feed->{atom}->modified;
  68         return iso2dt($feed->{atom}->updated)  if $feed->{atom}->updated;
  69         return undef;
  70     }
  71 }
  72
  73 sub entries {
  74     my @entries;
  75     for my $entry ($_[0]->{atom}->entries) {
  76         push @entries, XML::Feed::Entry::Atom->wrap($entry);
  77     }
  78
  79     @entries;
  80 }
  81
  82 sub add_entry {
  83     my $feed = shift;
  84     my($entry) = @_;
  85     $feed->{atom}->add_entry($entry->unwrap);
  86 }
  87
  88 sub as_xml { $_[0]->{atom}->as_xml }
  89
  90 package XML::Feed::Entry::Atom;
  91 use strict;
  92
  93 use base qw( XML::Feed::Entry );
  94 use XML::Atom::Util qw( iso2dt );
  95 use XML::Feed::Content;
  96 use XML::Atom::Entry;
  97 use List::Util qw( first );
  98
  99 sub init_empty {
 100     my $entry = shift;
 101     $entry->{entry} = XML::Atom::Entry->new(Version => 1.0);
 102     1;
 103 }
 104
 105 sub title { shift->{entry}->title(@_) }
 106 sub source { shift->{entry}->source(@_) }
 107 sub updated { shift->{entry}->updated(@_) }
 108
 109 sub link {
 110     my $entry = shift;
 111     if (@_) {
 112         $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
 113                                     type => 'text/html', });
 114     } else {
 115         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $entry->{entry}->link;
 116         $l ? $l->href : undef;
 117     }
 118 }
 119
 120 sub summary {
 121     my $entry = shift;
 122     if (@_) {
 123                 my %param;
 124                 if (ref($_[0]) eq 'XML::Feed::Content') {
 125                         %param = (Body => $_[0]->body);
 126                 } else {
 127                          %param = (Body => $_[0]);
 128                 }
 129                 $entry->{entry}->summary(XML::Atom::Content->new(%param, Version => 1.0));
 130     } else {
 131                 my $s = $entry->{entry}->summary;
 132         # map Atom types to MIME types
 133         my $type = ($s && ref($s) eq 'XML::Feed::Content') ? $s->type : undef;
 134         if ($type) {
 135             $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
 136             $type = 'text/plain' if $type eq 'text';
 137         }
 138                 my $body = $s;
 139                 if (defined $s && ref($s) eq 'XML::Feed::Content') {
 140                         $body = $s->body;
 141                 }
 142         XML::Feed::Content->wrap({ type => $type,
 143                                    body => $body });
 144     }
 145 }
 146
 147 my %types = (
 148         'text/xhtml' => 'xhtml',
 149         'text/html'  => 'html',
 150         'text/plain' => 'text',
 151 );
 152
 153 sub content {
 154     my $entry = shift;
 155     if (@_) {
 156         my %param;
 157         if (ref($_[0]) eq 'XML::Feed::Content') {
 158                         if (defined $_[0]->type && defined $types{$_[0]->type}) {
 159                     %param = (Body => $_[0]->body, Type => $types{$_[0]->type});
 160                         } else {
 161                     %param = (Body => $_[0]->body);
 162                         }
 163         } else {
 164             %param = (Body => $_[0]);
 165         }
 166         $entry->{entry}->content(XML::Atom::Content->new(%param, Version => 1.0));
 167     } else {
 168         my $c = $entry->{entry}->content;
 169
 170         # map Atom types to MIME types
 171         my $type = $c ? $c->type : undef;
 172         if ($type) {
 173             $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
 174             $type = 'text/plain' if $type eq 'text';
 175         }
 176
 177         XML::Feed::Content->wrap({ type => $type,
 178                                    body => $c ? $c->body : undef });
 179     }
 180 }
 181
 182 sub category {
 183     my $entry = shift;
 184     my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
 185     if (@_) {
 186         $entry->{entry}->add_category({ term => $_[0] });
 187     } else {
 188         my $category = $entry->{entry}->category;
 189         my @return = $category ? ($category->label || $category->term) : $entry->{entry}->getlist($ns, 'subject');
 190         return wantarray? @return : $return[0];
 191     }
 192 }
 193
 194 sub author {
 195     my $entry = shift;
 196     if (@_ && $_[0]) {
 197         my $person = XML::Atom::Person->new(Version => 1.0);
 198         $person->name($_[0]);
 199         $entry->{entry}->author($person);
 200     } else {
 201         $entry->{entry}->author ? $entry->{entry}->author->name : undef;
 202     }
 203 }
 204
 205 sub id { shift->{entry}->id(@_) }
 206
 207 sub issued {
 208     my $entry = shift;
 209     if (@_) {
 210         $entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 211     } else {
 212         $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
 213     }
 214 }
 215
 216 sub modified {
 217     my $entry = shift;
 218     if (@_) {
 219         $entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 220     } else {
 221         return iso2dt($entry->{entry}->modified) if $entry->{entry}->modified;
 222         return iso2dt($entry->{entry}->updated)  if $entry->{entry}->updated;
 223         return undef;
 224     }
 225 }
 226
 227 1;