lib/XML/Feed/Atom.pm

   1 # $Id: Atom.pm 1958 2006-08-14 05:31:27Z btrott $
   2
   3 package XML::Feed::Atom;
   4 use strict;
   5
   6 use base qw( XML::Feed );
   7 use XML::Atom::Feed;
   8 use XML::Atom::Util qw( iso2dt );
   9 use List::Util qw( first );
  10 use DateTime::Format::W3CDTF;
  11
  12 use XML::Atom::Entry;
  13 XML::Atom::Entry->mk_elem_accessors(qw( lat long ), ['http://www.w3.org/2003/01/geo/wgs84_pos#']);
  14
  15 sub init_empty {
  16     my ($feed, %args) = @_;
  17     $args{'Version'} ||= '1.0';
  18
  19     $feed->{atom} = XML::Atom::Feed->new(%args);
  20     $feed;
  21 }
  22
  23 sub init_string {
  24     my $feed = shift;
  25     my($str) = @_;
  26     if ($str) {
  27         $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
  28             or return $feed->error(XML::Atom::Feed->errstr);
  29     }
  30     $feed;
  31 }
  32
  33 sub format { 'Atom' }
  34
  35 sub title { shift->{atom}->title(@_) }
  36 sub link {
  37     my $feed = shift;
  38     if (@_) {
  39         $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
  40                                   type => 'text/html', });
  41     } else {
  42         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $feed->{atom}->link;
  43         $l ? $l->href : undef;
  44     }
  45 }
  46
  47 sub self_link {
  48     my $feed = shift;
  49     if (@_) {
  50         my $uri = shift;
  51         $feed->{atom}->add_link({type => "application/atom+xml", rel => "self", href => $uri});
  52         return $uri;
  53     }
  54     else
  55     {
  56         my $l =
  57             first
  58             { !defined $_->rel || $_->rel eq 'self' }
  59             $feed->{atom}->link;
  60             ;
  61
  62         return $l ? $l->href : undef;
  63     }
  64 }
  65
  66 sub description { shift->{atom}->tagline(@_) }
  67 sub copyright   { shift->{atom}->copyright(@_) }
  68 sub language    { shift->{atom}->language(@_) }
  69 sub generator   { shift->{atom}->generator(@_) }
  70 sub id          { shift->{atom}->id(@_) }
  71 sub updated     { shift->{atom}->updated(@_) }
  72 sub add_link    { shift->{atom}->add_link(@_) }
  73
  74 sub author {
  75     my $feed = shift;
  76     if (@_ && $_[0]) {
  77         my $person = XML::Atom::Person->new(Version => 1.0);
  78         $person->name($_[0]);
  79         $feed->{atom}->author($person);
  80     } else {
  81         $feed->{atom}->author ? $feed->{atom}->author->name : undef;
  82     }
  83 }
  84
  85 sub modified {
  86     my $feed = shift;
  87     if (@_) {
  88         $feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
  89     } else {
  90         return iso2dt($feed->{atom}->modified) if $feed->{atom}->modified;
  91         return iso2dt($feed->{atom}->updated)  if $feed->{atom}->updated;
  92         return undef;
  93     }
  94 }
  95
  96 sub entries {
  97     my @entries;
  98     for my $entry ($_[0]->{atom}->entries) {
  99         push @entries, XML::Feed::Entry::Atom->wrap($entry);
 100     }
 101
 102     @entries;
 103 }
 104
 105 sub add_entry {
 106     my $feed = shift;
 107     my($entry) = @_;
 108     $feed->{atom}->add_entry($entry->unwrap);
 109 }
 110
 111 sub as_xml { $_[0]->{atom}->as_xml }
 112
 113 package XML::Feed::Entry::Atom;
 114 use strict;
 115
 116 use base qw( XML::Feed::Entry );
 117 use XML::Atom::Util qw( iso2dt );
 118 use XML::Feed::Content;
 119 use XML::Atom::Entry;
 120 use List::Util qw( first );
 121
 122 sub init_empty {
 123     my $entry = shift;
 124     $entry->{entry} = XML::Atom::Entry->new(Version => 1.0);
 125     1;
 126 }
 127
 128 sub title { shift->{entry}->title(@_) }
 129 sub source { shift->{entry}->source(@_) }
 130 sub updated { shift->{entry}->updated(@_) }
 131
 132 sub link {
 133     my $entry = shift;
 134     if (@_) {
 135         $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
 136                                     type => 'text/html', });
 137     } else {
 138         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $entry->{entry}->link;
 139         $l ? $l->href : undef;
 140     }
 141 }
 142
 143 sub summary {
 144     my $entry = shift;
 145     if (@_) {
 146                 my %param;
 147                 if (ref($_[0]) eq 'XML::Feed::Content') {
 148                         %param = (Body => $_[0]->body);
 149                 } else {
 150                          %param = (Body => $_[0]);
 151                 }
 152                 $entry->{entry}->summary(XML::Atom::Content->new(%param, Version => 1.0));
 153     } else {
 154                 my $s = $entry->{entry}->summary;
 155         # map Atom types to MIME types
 156         my $type = ($s && ref($s) eq 'XML::Feed::Content') ? $s->type : undef;
 157         if ($type) {
 158             $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
 159             $type = 'text/plain' if $type eq 'text';
 160         }
 161                 my $body = $s;
 162                 if (defined $s && ref($s) eq 'XML::Feed::Content') {
 163                         $body = $s->body;
 164                 }
 165         XML::Feed::Content->wrap({ type => $type,
 166                                    body => $body });
 167     }
 168 }
 169
 170 my %types = (
 171         'text/xhtml' => 'xhtml',
 172         'text/html'  => 'html',
 173         'text/plain' => 'text',
 174 );
 175
 176 sub content {
 177     my $entry = shift;
 178     if (@_) {
 179         my %param;
 180         if (ref($_[0]) eq 'XML::Feed::Content') {
 181                         if (defined $_[0]->type && defined $types{$_[0]->type}) {
 182                     %param = (Body => $_[0]->body, Type => $types{$_[0]->type});
 183                         } else {
 184                     %param = (Body => $_[0]->body);
 185                         }
 186         } else {
 187             %param = (Body => $_[0]);
 188         }
 189         $entry->{entry}->content(XML::Atom::Content->new(%param, Version => 1.0));
 190     } else {
 191         my $c = $entry->{entry}->content;
 192
 193         # map Atom types to MIME types
 194         my $type = $c ? $c->type : undef;
 195         if ($type) {
 196             $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
 197             $type = 'text/plain' if $type eq 'text';
 198         }
 199
 200         XML::Feed::Content->wrap({ type => $type,
 201                                    body => $c ? $c->body : undef });
 202     }
 203 }
 204
 205 sub category {
 206     my $entry = shift;
 207     my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
 208     if (@_) {
 209         $entry->{entry}->add_category({ term => $_[0] });
 210     } else {
 211         my $category = $entry->{entry}->category;
 212         my @return = $category ? ($category->label || $category->term) : $entry->{entry}->getlist($ns, 'subject');
 213         return wantarray? @return : $return[0];
 214     }
 215 }
 216
 217 sub author {
 218     my $entry = shift;
 219     if (@_ && $_[0]) {
 220         my $person = XML::Atom::Person->new(Version => 1.0);
 221         $person->name($_[0]);
 222         $entry->{entry}->author($person);
 223     } else {
 224         $entry->{entry}->author ? $entry->{entry}->author->name : undef;
 225     }
 226 }
 227
 228 sub id { shift->{entry}->id(@_) }
 229
 230 sub issued {
 231     my $entry = shift;
 232     if (@_) {
 233         $entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 234     } else {
 235         $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
 236     }
 237 }
 238
 239 sub modified {
 240     my $entry = shift;
 241     if (@_) {
 242         $entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 243     } else {
 244         return iso2dt($entry->{entry}->modified) if $entry->{entry}->modified;
 245         return iso2dt($entry->{entry}->updated)  if $entry->{entry}->updated;
 246         return undef;
 247     }
 248 }
 249
 250 sub lat {
 251     my $entry = shift;
 252     if (@_) {
 253    $entry->{entry}->lat($_[0]) if $_[0];
 254     } else {
 255    $entry->{entry}->lat;
 256     }
 257 }
 258
 259 sub long {
 260     my $entry = shift;
 261     if (@_) {
 262    $entry->{entry}->long($_[0]) if $_[0];
 263     } else {
 264    $entry->{entry}->long;
 265     }
 266 }
 267
 268 1;