lib/XML/Feed/Atom.pm

   1 # $Id: Atom.pm 1865 2005-08-09 20:15:31Z btrott $
   2
   3 package XML::Feed::Atom;
   4 use strict;
   5
   6 use base qw( XML::Feed );
   7 use XML::Atom::Feed;
   8 use XML::Atom::Util qw( iso2dt );
   9 use List::Util qw( first );
  10
  11 sub init_empty {
  12     my $feed = shift;
  13     $feed->{atom} = XML::Atom::Feed->new;
  14     $feed;
  15 }
  16
  17 sub init_string {
  18     my $feed = shift;
  19     my($str) = @_;
  20     if ($str) {
  21         $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
  22             or return $feed->error(XML::Atom::Feed->errstr);
  23     }
  24     $feed;
  25 }
  26
  27 sub format { 'Atom' }
  28
  29 sub title { shift->{atom}->title(@_) }
  30 sub link {
  31     my $feed = shift;
  32     if (@_) {
  33         $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
  34                                   type => 'text/html', });
  35     } else {
  36         my $l = first { $_->rel eq 'alternate' } $feed->{atom}->link;
  37         $l ? $l->href : undef;
  38     }
  39 }
  40 sub description { shift->{atom}->tagline(@_) }
  41 sub copyright   { shift->{atom}->copyright(@_) }
  42 sub language    { shift->{atom}->language(@_) }
  43 sub generator   { shift->{atom}->generator(@_) }
  44
  45 sub author {
  46     my $feed = shift;
  47     if (@_ && $_[0]) {
  48         my $person = XML::Atom::Person->new;
  49         $person->name($_[0]);
  50         $feed->{atom}->author($person);
  51     } else {
  52         $feed->{atom}->author ? $feed->{atom}->author->name : undef;
  53     }
  54 }
  55
  56 sub modified {
  57     my $feed = shift;
  58     if (@_) {
  59         $feed->{atom}->modified($_[0]->iso8601 . 'Z');
  60     } else {
  61         iso2dt($feed->{atom}->modified);
  62     }
  63 }
  64
  65 sub entries {
  66     my @entries;
  67     for my $entry ($_[0]->{atom}->entries) {
  68         push @entries, XML::Feed::Entry::Atom->wrap($entry);
  69     }
  70     @entries;
  71 }
  72
  73 sub add_entry {
  74     my $feed = shift;
  75     my($entry) = @_;
  76     $feed->{atom}->add_entry($entry->unwrap);
  77 }
  78
  79 sub as_xml { $_[0]->{atom}->as_xml }
  80
  81 package XML::Feed::Entry::Atom;
  82 use strict;
  83
  84 use base qw( XML::Feed::Entry );
  85 use XML::Atom::Util qw( iso2dt );
  86 use XML::Feed::Content;
  87 use XML::Atom::Entry;
  88 use List::Util qw( first );
  89
  90 sub init_empty {
  91     my $entry = shift;
  92     $entry->{entry} = XML::Atom::Entry->new;
  93     1;
  94 }
  95
  96 sub title { shift->{entry}->title(@_) }
  97 sub link {
  98     my $entry = shift;
  99     if (@_) {
 100         $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
 101                                     type => 'text/html', });
 102     } else {
 103         my $l = first { $_->rel eq 'alternate' } $entry->{entry}->link;
 104         $l ? $l->href : undef;
 105     }
 106 }
 107
 108 sub summary {
 109     my $entry = shift;
 110     if (@_) {
 111         $entry->{entry}->summary(ref($_[0]) eq 'XML::Feed::Content' ?
 112             $_[0]->body : $_[0]);
 113     } else {
 114         XML::Feed::Content->wrap({ type => 'text/html',
 115                                    body => $entry->{entry}->summary });
 116     }
 117 }
 118
 119 sub content {
 120     my $entry = shift;
 121     if (@_) {
 122         my %param;
 123         if (ref($_[0]) eq 'XML::Feed::Content') {
 124             %param = (Body => $_[0]->body, Type => $_[0]->type || 'text/html');
 125         } else {
 126             %param = (Body => $_[0], Type => 'text/html');
 127         }
 128         $entry->{entry}->content(XML::Atom::Content->new(%param));
 129     } else {
 130         my $c = $entry->{entry}->content;
 131         XML::Feed::Content->wrap({ type => $c ? $c->type : undef,
 132                                    body => $c ? $c->body : undef });
 133     }
 134 }
 135
 136 sub category {
 137     my $entry = shift;
 138     my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
 139     if (@_) {
 140         $entry->{entry}->set($ns, 'subject', $_[0]);
 141     } else {
 142         $entry->{entry}->get($ns, 'subject');
 143     }
 144 }
 145
 146 sub author {
 147     my $entry = shift;
 148     if (@_ && $_[0]) {
 149         my $person = XML::Atom::Person->new;
 150         $person->name($_[0]);
 151         $entry->{entry}->author($person);
 152     } else {
 153         $entry->{entry}->author ? $entry->{entry}->author->name : undef;
 154     }
 155 }
 156
 157 sub id { shift->{entry}->id(@_) }
 158
 159 sub issued {
 160     my $entry = shift;
 161     if (@_) {
 162         $entry->{entry}->issued($_[0]->iso8601 . 'Z') if $_[0];
 163     } else {
 164         $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
 165     }
 166 }
 167
 168 sub modified {
 169     my $entry = shift;
 170     if (@_) {
 171         $entry->{entry}->modified($_[0]->iso8601 . 'Z') if $_[0];
 172     } else {
 173         $entry->{entry}->modified ? iso2dt($entry->{entry}->modified) : undef;
 174     }
 175 }
 176
 177 1;