lib/XML/Feed/Atom.pm

   1 # $Id: Atom.pm 1958 2006-08-14 05:31:27Z btrott $
   2
   3 package XML::Feed::Atom;
   4 use strict;
   5
   6 use base qw( XML::Feed );
   7 use XML::Atom::Feed;
   8 use XML::Atom::Util qw( iso2dt );
   9 use List::Util qw( first );
  10 use DateTime::Format::W3CDTF;
  11
  12 sub init_empty {
  13     my ($feed, %args) = @_;
  14     $args{'Version'} ||= '1.0';
  15
  16     $feed->{atom} = XML::Atom::Feed->new(%args);
  17     $feed;
  18 }
  19
  20 sub init_string {
  21     my $feed = shift;
  22     my($str) = @_;
  23     if ($str) {
  24         $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
  25             or return $feed->error(XML::Atom::Feed->errstr);
  26     }
  27     $feed;
  28 }
  29
  30 sub format { 'Atom' }
  31
  32 sub title { shift->{atom}->title(@_) }
  33 sub link {
  34     my $feed = shift;
  35     if (@_) {
  36         $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
  37                                   type => 'text/html', });
  38     } else {
  39         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $feed->{atom}->link;
  40         $l ? $l->href : undef;
  41     }
  42 }
  43 sub description { shift->{atom}->tagline(@_) }
  44 sub copyright   { shift->{atom}->copyright(@_) }
  45 sub language    { shift->{atom}->language(@_) }
  46 sub generator   { shift->{atom}->generator(@_) }
  47
  48 sub author {
  49     my $feed = shift;
  50     if (@_ && $_[0]) {
  51         my $person = XML::Atom::Person->new(Version => 1.0);
  52         $person->name($_[0]);
  53         $feed->{atom}->author($person);
  54     } else {
  55         $feed->{atom}->author ? $feed->{atom}->author->name : undef;
  56     }
  57 }
  58
  59 sub modified {
  60     my $feed = shift;
  61     if (@_) {
  62         $feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
  63     } else {
  64         $feed->{atom}->modified ? iso2dt($feed->{atom}->modified) : undef;
  65     }
  66 }
  67
  68 sub entries {
  69     my @entries;
  70     for my $entry ($_[0]->{atom}->entries) {
  71         push @entries, XML::Feed::Entry::Atom->wrap($entry);
  72     }
  73
  74     @entries;
  75 }
  76
  77 sub add_entry {
  78     my $feed = shift;
  79     my($entry) = @_;
  80     $feed->{atom}->add_entry($entry->unwrap);
  81 }
  82
  83 sub as_xml { $_[0]->{atom}->as_xml }
  84
  85 package XML::Feed::Entry::Atom;
  86 use strict;
  87
  88 use base qw( XML::Feed::Entry );
  89 use XML::Atom::Util qw( iso2dt );
  90 use XML::Feed::Content;
  91 use XML::Atom::Entry;
  92 use List::Util qw( first );
  93
  94 sub init_empty {
  95     my $entry = shift;
  96     $entry->{entry} = XML::Atom::Entry->new(Version => 1.0);
  97     1;
  98 }
  99
 100 sub title { shift->{entry}->title(@_) }
 101 sub link {
 102     my $entry = shift;
 103     if (@_) {
 104         $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
 105                                     type => 'text/html', });
 106     } else {
 107         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $entry->{entry}->link;
 108         $l ? $l->href : undef;
 109     }
 110 }
 111
 112 sub summary {
 113     my $entry = shift;
 114     if (@_) {
 115         $entry->{entry}->summary(ref($_[0]) eq 'XML::Feed::Content' ?
 116             $_[0]->body : $_[0]);
 117     } else {
 118         XML::Feed::Content->wrap({ type => 'html',
 119                                    body => $entry->{entry}->summary });
 120     }
 121 }
 122
 123 sub content {
 124     my $entry = shift;
 125     if (@_) {
 126         my %param;
 127         if (ref($_[0]) eq 'XML::Feed::Content') {
 128             %param = (Body => $_[0]->body);
 129         } else {
 130             %param = (Body => $_[0]);
 131         }
 132         $entry->{entry}->content(XML::Atom::Content->new(%param, Version => 1.0));
 133     } else {
 134         my $c = $entry->{entry}->content;
 135
 136         # map Atom types to MIME types
 137         my $type = $c ? $c->type : undef;
 138         if ($type) {
 139             $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
 140             $type = 'text/plain' if $type eq 'text';
 141         }
 142
 143         XML::Feed::Content->wrap({ type => $type,
 144                                    body => $c ? $c->body : undef });
 145     }
 146 }
 147
 148 sub category {
 149     my $entry = shift;
 150     my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
 151     if (@_) {
 152         $entry->{entry}->add_category({ term => $_[0] });
 153     } else {
 154         my $category = $entry->{entry}->category;
 155         $category ? ($category->label || $category->term) : $entry->{entry}->get($ns, 'subject');
 156     }
 157 }
 158
 159 sub author {
 160     my $entry = shift;
 161     if (@_ && $_[0]) {
 162         my $person = XML::Atom::Person->new(Version => 1.0);
 163         $person->name($_[0]);
 164         $entry->{entry}->author($person);
 165     } else {
 166         $entry->{entry}->author ? $entry->{entry}->author->name : undef;
 167     }
 168 }
 169
 170 sub id { shift->{entry}->id(@_) }
 171
 172 sub issued {
 173     my $entry = shift;
 174     if (@_) {
 175         $entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 176     } else {
 177         $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
 178     }
 179 }
 180
 181 sub modified {
 182     my $entry = shift;
 183     if (@_) {
 184         $entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 185     } else {
 186         $entry->{entry}->modified ? iso2dt($entry->{entry}->modified) : undef;
 187     }
 188 }
 189
 190 1;