lib/XML/Feed/Atom.pm

   1 # $Id: Atom.pm 1958 2006-08-14 05:31:27Z btrott $
   2
   3 package XML::Feed::Atom;
   4 use strict;
   5
   6 use base qw( XML::Feed );
   7 use XML::Atom::Feed;
   8 use XML::Atom::Util qw( iso2dt );
   9 use List::Util qw( first );
  10 use DateTime::Format::W3CDTF;
  11
  12 sub init_empty {
  13     my ($feed, %args) = @_;
  14     $args{'Version'} ||= '1.0';
  15
  16     $feed->{atom} = XML::Atom::Feed->new(%args);
  17     $feed;
  18 }
  19
  20 sub init_string {
  21     my $feed = shift;
  22     my($str) = @_;
  23     if ($str) {
  24         $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
  25             or return $feed->error(XML::Atom::Feed->errstr);
  26     }
  27     $feed;
  28 }
  29
  30 sub format { 'Atom' }
  31
  32 sub title { shift->{atom}->title(@_) }
  33 sub link {
  34     my $feed = shift;
  35     if (@_) {
  36         $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
  37                                   type => 'text/html', });
  38     } else {
  39         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $feed->{atom}->link;
  40         $l ? $l->href : undef;
  41     }
  42 }
  43 sub description { shift->{atom}->tagline(@_) }
  44 sub copyright   { shift->{atom}->copyright(@_) }
  45 sub language    { shift->{atom}->language(@_) }
  46 sub generator   { shift->{atom}->generator(@_) }
  47 sub id          { shift->{atom}->id(@_) }
  48 sub updated     { shift->{atom}->updated(@_) }
  49 sub add_link    { shift->{atom}->add_link(@_) }
  50
  51 sub author {
  52     my $feed = shift;
  53     if (@_ && $_[0]) {
  54         my $person = XML::Atom::Person->new(Version => 1.0);
  55         $person->name($_[0]);
  56         $feed->{atom}->author($person);
  57     } else {
  58         $feed->{atom}->author ? $feed->{atom}->author->name : undef;
  59     }
  60 }
  61
  62 sub modified {
  63     my $feed = shift;
  64     if (@_) {
  65         $feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
  66     } else {
  67         return iso2dt($feed->{atom}->modified) if $feed->{atom}->modified;
  68         return iso2dt($feed->{atom}->updated)  if $feed->{atom}->updated;
  69         return undef;
  70     }
  71 }
  72
  73 sub entries {
  74     my @entries;
  75     for my $entry ($_[0]->{atom}->entries) {
  76         push @entries, XML::Feed::Entry::Atom->wrap($entry);
  77     }
  78
  79     @entries;
  80 }
  81
  82 sub add_entry {
  83     my $feed = shift;
  84     my($entry) = @_;
  85     $feed->{atom}->add_entry($entry->unwrap);
  86 }
  87
  88 sub as_xml { $_[0]->{atom}->as_xml }
  89
  90 package XML::Feed::Entry::Atom;
  91 use strict;
  92
  93 use base qw( XML::Feed::Entry );
  94 use XML::Atom::Util qw( iso2dt );
  95 use XML::Feed::Content;
  96 use XML::Atom::Entry;
  97 use List::Util qw( first );
  98
  99 sub init_empty {
 100     my $entry = shift;
 101     $entry->{entry} = XML::Atom::Entry->new(Version => 1.0);
 102     1;
 103 }
 104
 105 sub title { shift->{entry}->title(@_) }
 106 sub source { shift->{entry}->source(@_) }
 107 sub updated { shift->{entry}->updated(@_) }
 108
 109 sub link {
 110     my $entry = shift;
 111     if (@_) {
 112         $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
 113                                     type => 'text/html', });
 114     } else {
 115         my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $entry->{entry}->link;
 116         $l ? $l->href : undef;
 117     }
 118 }
 119
 120 sub summary {
 121     my $entry = shift;
 122     if (@_) {
 123         $entry->{entry}->summary(ref($_[0]) eq 'XML::Feed::Content' ?
 124             $_[0]->body : $_[0]);
 125     } else {
 126         XML::Feed::Content->wrap({ type => 'html',
 127                                    body => $entry->{entry}->summary });
 128     }
 129 }
 130
 131 my %types = (
 132         'text/xhtml' => 'xhtml',
 133         'text/html'  => 'html',
 134         'text/plain' => 'text',
 135 );
 136
 137 sub content {
 138     my $entry = shift;
 139     if (@_) {
 140         my %param;
 141         if (ref($_[0]) eq 'XML::Feed::Content') {
 142                         if (defined $_[0]->type && defined $types{$_[0]->type}) {
 143                     %param = (Body => $_[0]->body, Type => $types{$_[0]->type});
 144                         } else {
 145                     %param = (Body => $_[0]->body);
 146                         }
 147         } else {
 148             %param = (Body => $_[0]);
 149         }
 150         $entry->{entry}->content(XML::Atom::Content->new(%param, Version => 1.0));
 151     } else {
 152         my $c = $entry->{entry}->content;
 153
 154         # map Atom types to MIME types
 155         my $type = $c ? $c->type : undef;
 156         if ($type) {
 157             $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
 158             $type = 'text/plain' if $type eq 'text';
 159         }
 160
 161         XML::Feed::Content->wrap({ type => $type,
 162                                    body => $c ? $c->body : undef });
 163     }
 164 }
 165
 166 sub category {
 167     my $entry = shift;
 168     my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
 169     if (@_) {
 170         $entry->{entry}->add_category({ term => $_[0] });
 171     } else {
 172         my $category = $entry->{entry}->category;
 173         my @return = $category ? ($category->label || $category->term) : $entry->{entry}->getlist($ns, 'subject');
 174         return wantarray? @return : $return[0];
 175     }
 176 }
 177
 178 sub author {
 179     my $entry = shift;
 180     if (@_ && $_[0]) {
 181         my $person = XML::Atom::Person->new(Version => 1.0);
 182         $person->name($_[0]);
 183         $entry->{entry}->author($person);
 184     } else {
 185         $entry->{entry}->author ? $entry->{entry}->author->name : undef;
 186     }
 187 }
 188
 189 sub id { shift->{entry}->id(@_) }
 190
 191 sub issued {
 192     my $entry = shift;
 193     if (@_) {
 194         $entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 195     } else {
 196         $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
 197     }
 198 }
 199
 200 sub modified {
 201     my $entry = shift;
 202     if (@_) {
 203         $entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
 204     } else {
 205         return iso2dt($entry->{entry}->modified) if $entry->{entry}->modified;
 206         return iso2dt($entry->{entry}->updated)  if $entry->{entry}->updated;
 207         return undef;
 208     }
 209 }
 210
 211 1;