lib/Web/Simple/Application.pm

   1 package Web::Simple::Application;
   2
   3 use Moo;
   4
   5 has 'config' => (
   6   is => 'ro',
   7   default => sub {
   8     my ($self) = @_;
   9     +{ $self->default_config }
  10   },
  11   trigger => sub {
  12     my ($self, $value) = @_;
  13     my %default = $self->default_config;
  14     my @not = grep !exists $value->{$_}, keys %default;
  15     @{$value}{@not} = @default{@not};
  16   }
  17 );
  18
  19 sub default_config { () }
  20
  21 has '_dispatcher' => (is => 'lazy');
  22
  23 sub _build__dispatcher {
  24   my $self = shift;
  25   require Web::Dispatch;
  26   require Web::Simple::DispatchNode;
  27   my $final = $self->_build_final_dispatcher;
  28   Web::Dispatch->new(
  29     app => sub { $self->dispatch_request(@_), $final },
  30     node_class => 'Web::Simple::DispatchNode',
  31     node_args => { app_object => $self }
  32   );
  33 }
  34
  35 sub _build_final_dispatcher {
  36   [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
  37 }
  38
  39 sub run_if_script {
  40   # ->to_psgi_app is true for require() but also works for plackup
  41   return $_[0]->to_psgi_app if caller(1);
  42   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  43   $self->run(@_);
  44 }
  45
  46 sub _run_cgi {
  47   my $self = shift;
  48   require Plack::Server::CGI;
  49   Plack::Server::CGI->run($self->to_psgi_app);
  50 }
  51
  52 sub _run_fcgi {
  53   my $self = shift;
  54   require Plack::Server::FCGI;
  55   Plack::Server::FCGI->run($self->to_psgi_app);
  56 }
  57
  58 sub to_psgi_app {
  59   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  60   $self->_dispatcher->to_app;
  61 }
  62
  63 sub run {
  64   my $self = shift;
  65   if ($ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}) {
  66     return $self->_run_fcgi;
  67   } elsif ($ENV{GATEWAY_INTERFACE}) {
  68     return $self->_run_cgi;
  69   }
  70   unless (@ARGV && $ARGV[0] =~ m{^[A-Z/]}) {
  71     return $self->_run_cli(@ARGV);
  72   }
  73
  74   my @args = @ARGV;
  75
  76   unshift(@args, 'GET') if $args[0] =~ m{^/};
  77
  78   $self->_run_test_request(@args);
  79 }
  80
  81 sub _run_test_request {
  82   my ($self, $method, $path, @rest) = @_;
  83
  84   require HTTP::Request;
  85   require Plack::Test;
  86
  87   my $request = HTTP::Request->new($method => $path);
  88   if ($method eq 'POST' or $method eq 'PUT' and @rest) {
  89     my $content = do {
  90       require URI;
  91       my $url = URI->new('http:');
  92       $url->query_form(@rest);
  93       $url->query;
  94     };
  95     $request->header('Content-Type' => 'application/x-www-form-urlencoded');
  96     $request->header('Content-Length' => length($content));
  97     $request->content($content);
  98   }
  99   my $response;
 100   Plack::Test::test_psgi(
 101     $self->to_psgi_app, sub { $response = shift->($request) }
 102   );
 103   print STDERR $response->status_line."\n";
 104   print STDERR $response->headers_as_string("\n")."\n";
 105   print STDOUT $response->content."\n";
 106 }
 107
 108 sub _run_cli {
 109   my $self = shift;
 110   die $self->_cli_usage;
 111 }
 112
 113 sub _cli_usage {
 114   "To run this script in CGI test mode, pass a URL path beginning with /:\n".
 115   "\n".
 116   "  $0 /some/path\n".
 117   "  $0 /\n"
 118 }
 119
 120 1;
 121
 122 =head1 NAME
 123
 124 Web::Simple::Application - A base class for your Web-Simple application
 125
 126 =head1 DESCRIPTION
 127
 128 This is a base class for your L<Web::Simple> application.  You probably don't
 129 need to construct this class yourself, since L<Web::Simple> does the 'heavy
 130 lifting' for you in that regards.
 131
 132 =head1 METHODS
 133
 134 This class exposes the following public methods.
 135
 136 =head2 default_config
 137
 138 Merges with the C<config> initializer to provide configuration information for
 139 your application.  For example:
 140
 141   sub default_config {
 142     (
 143       title => 'Bloggery',
 144       posts_dir => $FindBin::Bin.'/posts',
 145     );
 146   }
 147
 148 Now, the C<config> attribute of C<$self>  will be set to a HashRef
 149 containing keys 'title' and 'posts_dir'.
 150
 151 The keys from default_config are merged into any config supplied, so
 152 if you construct your application like:
 153
 154   MyWebSimpleApp::Web->new(
 155     config => { title => 'Spoon', environment => 'dev' }
 156   )
 157
 158 then C<config> will contain:
 159
 160   {
 161     title => 'Spoon',
 162     posts_dir => '/path/to/myapp/posts',
 163     environment => 'dev'
 164   }
 165
 166 =head2 run_if_script
 167
 168 The run_if_script method is designed to be used at the end of the script
 169 or .pm file where your application class is defined - for example:
 170
 171   ## my_web_simple_app.pl
 172   #!/usr/bin/env perl
 173   use Web::Simple 'HelloWorld';
 174
 175   {
 176     package HelloWorld;
 177
 178     sub dispatch_request {
 179       sub (GET) {
 180         [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
 181       },
 182       sub () {
 183         [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
 184       }
 185     }
 186   }
 187
 188   HelloWorld->run_if_script;
 189
 190 This returns a true value, so your file is now valid as a module - so
 191
 192   require 'my_web_simple_app.pl';
 193
 194   my $hw = HelloWorld->new;
 195
 196 will work fine (and you can rename it to lib/HelloWorld.pm later to make it
 197 a real use-able module).
 198
 199 However, it detects if it's being run as a script (via testing $0) and if
 200 so attempts to do the right thing.
 201
 202 If run under a CGI environment, your application will execute as a CGI.
 203
 204 If run under a FastCGI environment, your application will execute as a
 205 FastCGI process (this works both for dynamic shared-hosting-style FastCGI
 206 and for apache FastCgiServer style setups).
 207
 208 If run from the commandline with a URL path, it runs a GET request against
 209 that path -
 210
 211   $ perl -Ilib examples/hello-world/hello-world.cgi /
 212   200 OK
 213   Content-Type: text/plain
 214
 215   Hello world!
 216
 217 Additionally, you can treat the file as though it were a standard PSGI
 218 application file (*.psgi).  For example you can start up up with C<plackup>
 219
 220   plackup my_web_simple_app.pl
 221
 222 or C<starman>
 223
 224   starman my_web_simple_app.pl
 225
 226 =head2 to_psgi_app
 227
 228 This method is called by L</run_if_script> to create the L<PSGI> app coderef
 229 for use via L<Plack> and L<plackup>. If you want to globally add middleware,
 230 you can override this method:
 231
 232   use Web::Simple 'HelloWorld';
 233   use Plack::Builder;
 234
 235   {
 236     package HelloWorld;
 237
 238
 239     around 'to_psgi_app', sub {
 240       my ($orig, $self) = (shift, shift);
 241       my $app = $self->$orig(@_);
 242       builder {
 243         enable ...; ## whatever middleware you want
 244         $app;
 245       };
 246     };
 247   }
 248
 249 This method can also be used to mount a Web::Simple application within
 250 a separate C<*.psgi> file -
 251
 252   use strictures 1;
 253   use Plack::Builder;
 254   use WSApp;
 255   use AnotherWSApp;
 256
 257   builder {
 258     mount '/' => WSApp->to_psgi_app;
 259     mount '/another' => AnotherWSApp->to_psgi_app;
 260   };
 261
 262 This method can be called as a class method, in which case it implicitly
 263 calls ->new, or as an object method ... in which case it doesn't.
 264
 265 =head2 run
 266
 267 Used for running your application under stand-alone CGI and FCGI modes. Also
 268 useful for testing:
 269
 270     my $app = MyWebSimpleApp::Web->new;
 271     my $c = HTTP::Request::AsCGI->new(@args)->setup;
 272     $app->run;
 273
 274 =head1 AUTHORS
 275
 276 See L<Web::Simple> for authors.
 277
 278 =head1 COPYRIGHT AND LICENSE
 279
 280 See L<Web::Simple> for the copyright and license.
 281
 282 =cut