lib/Web/Dispatch/Parser.pm

   1 package Web::Dispatch::Parser;
   2
   3 sub DEBUG () { 0 }
   4
   5 BEGIN {
   6   if ($ENV{WEB_DISPATCH_PARSER_DEBUG}) {
   7     no warnings 'redefine';
   8     *DEBUG = sub () { 1 }
   9   }
  10 }
  11
  12 use Sub::Quote;
  13 use Web::Dispatch::Predicates;
  14 use Moo;
  15
  16 has _cache => (
  17   is => 'lazy', default => quote_sub q{ {} }
  18 );
  19
  20 sub diag { if (DEBUG) { warn $_[0] } }
  21
  22 sub _blam {
  23   my ($self, $error) = @_;
  24   my $hat = (' ' x (pos||0)).'^';
  25   die "Error parsing dispatch specification: ${error}\n
  26 ${_}
  27 ${hat} here\n";
  28 }
  29
  30 sub parse {
  31   my ($self, $spec) = @_;
  32   $spec =~ s/\s+//g; # whitespace is not valid
  33   return $self->_cache->{$spec} ||= $self->_parse_spec($spec);
  34 }
  35
  36 sub _parse_spec {
  37   my ($self, $spec, $nested) = @_;
  38   return sub { {} } unless length($spec);
  39   for ($_[1]) {
  40     my @match;
  41     PARSE: { do {
  42       push @match, $self->_parse_spec_section($_)
  43         or $self->_blam("Unable to work out what the next section is");
  44       if (/\G\)/gc) {
  45         $self->_blam("Found closing ) with no opening (") unless $nested;
  46         last PARSE;
  47       }
  48       last PARSE if (pos == length);
  49       $match[-1] = $self->_parse_spec_combinator($_, $match[-1])
  50         or $self->_blam('No valid combinator - expected + or |');
  51     } until (pos == length) }; # accept trailing whitespace
  52     if ($nested and pos == length) {
  53       pos = $nested - 1;
  54       $self->_blam("No closing ) found for opening (");
  55     }
  56     return $match[0] if (@match == 1);
  57     return match_and(@match);
  58   }
  59 }
  60
  61 sub _parse_spec_combinator {
  62   my ($self, $spec, $match) = @_;
  63   for ($_[1]) {
  64
  65     /\G\+/gc and
  66       return $match;
  67
  68     /\G\|/gc and
  69       return do {
  70         my @match = $match;
  71         PARSE: { do {
  72           push @match, $self->_parse_spec_section($_)
  73             or $self->_blam("Unable to work out what the next section is");
  74           last PARSE if (pos == length);
  75           last PARSE unless /\G\|/gc; # give up when next thing isn't |
  76         } until (pos == length) }; # accept trailing whitespace
  77         return match_or(@match);
  78       };
  79   }
  80   return;
  81 }
  82
  83 sub _parse_spec_section {
  84   my ($self) = @_;
  85   for ($_[1]) {
  86
  87     # GET POST PUT HEAD ...
  88
  89     /\G([A-Z]+)/gc and
  90       return match_method($1);
  91
  92     # /...
  93
  94     /\G(?=\/)/gc and
  95       return $self->_url_path_match($_);
  96
  97     # .* and .html
  98
  99     /\G\.(\*|\w+)/gc and
 100       return match_extension($1);
 101
 102     # (...)
 103
 104     /\G\(/gc and
 105       return $self->_parse_spec($_, pos);
 106
 107     # !something
 108
 109     /\G!/gc and
 110       return match_not($self->_parse_spec_section($_));
 111
 112     # ?<param spec>
 113     /\G\?/gc and
 114       return $self->_parse_param_handler($_, 'query');
 115
 116     # %<param spec>
 117     /\G\%/gc and
 118       return $self->_parse_param_handler($_, 'body');
 119
 120     # *<param spec>
 121     /\G\*/gc and
 122       return $self->_parse_param_handler($_, 'uploads');
 123   }
 124   return; # () will trigger the blam in our caller
 125 }
 126
 127 sub _url_path_match {
 128   my ($self) = @_;
 129   for ($_[1]) {
 130     my @path;
 131     my $end = '';
 132     my $keep_dot;
 133     PATH: while (/\G\//gc) {
 134       /\G\.\.\./gc
 135         and do {
 136           $end = '(/.*)';
 137           last PATH;
 138         };
 139       push @path, $self->_url_path_segment_match($_)
 140         or $self->_blam("Couldn't parse path match segment");
 141       /\G\.\.\./gc
 142         and do {
 143           $end = '(.*)';
 144           last PATH;
 145         };
 146       /\G\.\*/gc
 147         and do {
 148           $keep_dot = 1;
 149           last PATH;
 150         };
 151     }
 152     if (@path && !$end && !$keep_dot) {
 153       length and $_ .= '(?:\.\w+)?' for $path[-1];
 154     }
 155     my $re = '^('.join('/','',@path).')'.$end.'$';
 156     $re = qr/$re/;
 157     if ($end) {
 158       return match_path_strip($re);
 159     } else {
 160       return match_path($re);
 161     }
 162   }
 163   return;
 164 }
 165
 166 sub _url_path_segment_match {
 167   my ($self) = @_;
 168   for ($_[1]) {
 169     # trailing / -> require / on end of URL
 170     /\G(?:(?=[+|\)])|$)/gc and
 171       return '';
 172     # word chars only -> exact path part match
 173     /
 174         \G(
 175             (?:             # start matching at a space followed by:
 176                     [\w\-]  # word chars or dashes
 177                 |           # OR
 178                     \.      # a period
 179                     (?!\.)  # not followed by another period
 180             )
 181             +               # then grab as far as possible
 182         )
 183     /gcx and
 184       return "\Q$1";
 185     # ** -> capture unlimited path parts
 186     /\G\*\*/gc and
 187       return '(.*?[^/])';
 188     # * -> capture path part
 189     /\G\*/gc and
 190       return '([^/]+?)';
 191   }
 192   return ();
 193 }
 194
 195 sub _parse_param_handler {
 196   my ($self, $spec, $type) = @_;
 197
 198   for ($_[1]) {
 199     my (@required, @single, %multi, $star, $multistar, %positional, $have_kw);
 200     my %spec;
 201     my $pos_idx = 0;
 202     PARAM: { do {
 203
 204       # ?:foo or ?@:foo
 205
 206       my $is_kw = /\G\:/gc;
 207
 208       # ?@foo or ?@*
 209
 210       my $multi = /\G\@/gc;
 211
 212       # @* or *
 213
 214       if (/\G\*/gc) {
 215
 216         $self->_blam("* is always named; no need to supply :") if $is_kw;
 217
 218         if ($star) {
 219           $self->_blam("Can only use one * or \@* in a parameter match");
 220         }
 221
 222         $spec{star} = { multi => $multi };
 223       } else {
 224
 225         # @foo= or foo= or @foo~ or foo~
 226
 227         /\G(\w+)/gc or $self->_blam('Expected parameter name');
 228
 229         my $name = $1;
 230
 231         # check for = or ~ on the end
 232
 233         /\G\=/gc
 234           ? push(@{$spec{required}||=[]}, $name)
 235           : (/\G\~/gc or $self->_blam('Expected = or ~ after parameter name'));
 236
 237         # record positional or keyword
 238
 239         push @{$spec{$is_kw ? 'named' : 'positional'}||=[]},
 240           { name => $name, multi => $multi };
 241       }
 242     } while (/\G\&/gc) }
 243
 244     return Web::Dispatch::Predicates->can("match_${type}")->(\%spec);
 245   }
 246 }
 247
 248 1;