lib/Try/Tiny.pm

   1 package Try::Tiny;
   2
   3 use strict;
   4 #use warnings;
   5
   6 use vars qw(@EXPORT @EXPORT_OK $VERSION @ISA);
   7
   8 BEGIN {
   9         require Exporter;
  10         @ISA = qw(Exporter);
  11 }
  12
  13 $VERSION = "0.06";
  14
  15 $VERSION = eval $VERSION;
  16
  17 @EXPORT = @EXPORT_OK = qw(try catch finally);
  18
  19 $Carp::Internal{+__PACKAGE__}++;
  20
  21 # Need to prototype as @ not $$ because of the way Perl evaluates the prototype.
  22 # Keeping it at $$ means you only ever get 1 sub because we need to eval in a list
  23 # context & not a scalar one
  24
  25 sub try (&;@) {
  26         my ( $try, @code_refs ) = @_;
  27
  28         # we need to save this here, the eval block will be in scalar context due
  29         # to $failed
  30         my $wantarray = wantarray;
  31
  32         my ( $catch, $finally );
  33
  34         # find labeled blocks in the argument list.
  35         # catch and finally tag the blocks by blessing a scalar reference to them.
  36         foreach my $code_ref (@code_refs) {
  37                 next unless $code_ref;
  38
  39                 my $ref = ref($code_ref);
  40
  41                 if ( $ref eq 'Try::Tiny::Catch' ) {
  42                         $catch = ${$code_ref};
  43                 } elsif ( $ref eq 'Try::Tiny::Finally' ) {
  44                         $finally = ${$code_ref};
  45                 } else {
  46                         use Carp;
  47                         confess("Unknown code ref type given '${ref}'. Check your usage & try again");
  48                 }
  49         }
  50
  51         # save the value of $@ so we can set $@ back to it in the beginning of the eval
  52         my $prev_error = $@;
  53
  54         my ( @ret, $error, $failed );
  55
  56         # FIXME consider using local $SIG{__DIE__} to accumulate all errors. It's
  57         # not perfect, but we could provide a list of additional errors for
  58         # $catch->();
  59
  60         {
  61                 # localize $@ to prevent clobbering of previous value by a successful
  62                 # eval.
  63                 local $@;
  64
  65                 # failed will be true if the eval dies, because 1 will not be returned
  66                 # from the eval body
  67                 $failed = not eval {
  68                         $@ = $prev_error;
  69
  70                         # evaluate the try block in the correct context
  71                         if ( $wantarray ) {
  72                                 @ret = $try->();
  73                         } elsif ( defined $wantarray ) {
  74                                 $ret[0] = $try->();
  75                         } else {
  76                                 $try->();
  77                         };
  78
  79                         return 1; # properly set $fail to false
  80                 };
  81
  82                 # copy $@ to $error; when we leave this scope, local $@ will revert $@
  83                 # back to its previous value
  84                 $error = $@;
  85         }
  86
  87         # set up a scope guard to invoke the finally block at the end
  88         my $guard = $finally && bless \$finally, "Try::Tiny::ScopeGuard";
  89
  90         # at this point $failed contains a true value if the eval died, even if some
  91         # destructor overwrote $@ as the eval was unwinding.
  92         if ( $failed ) {
  93                 # if we got an error, invoke the catch block.
  94                 if ( $catch ) {
  95                         # This works like given($error), but is backwards compatible and
  96                         # sets $_ in the dynamic scope for the body of C<$catch>
  97                         for ($error) {
  98                                 return $catch->($error);
  99                         }
 100
 101                         # in case when() was used without an explicit return, the C<for>
 102                         # loop will be aborted and there's no useful return value
 103                 }
 104
 105                 return;
 106         } else {
 107                 # no failure, $@ is back to what it was, everything is fine
 108                 return $wantarray ? @ret : $ret[0];
 109         }
 110 }
 111
 112 sub catch (&;@) {
 113         my ( $block, @rest ) = @_;
 114
 115         return (
 116                 bless(\$block, 'Try::Tiny::Catch'),
 117                 @rest,
 118         );
 119 }
 120
 121 sub finally (&;@) {
 122         my ( $block, @rest ) = @_;
 123
 124         return (
 125                 bless(\$block, 'Try::Tiny::Finally'),
 126                 @rest,
 127         );
 128 }
 129
 130 sub Try::Tiny::ScopeGuard::DESTROY {
 131         my $self = shift;
 132         $$self->();
 133 }
 134
 135 __PACKAGE__
 136
 137 __END__
 138
 139 =pod
 140
 141 =head1 NAME
 142
 143 Try::Tiny - minimal try/catch with proper localization of $@
 144
 145 =head1 SYNOPSIS
 146
 147         # handle errors with a catch handler
 148         try {
 149                 die "foo";
 150         } catch {
 151                 warn "caught error: $_"; # not $@
 152         };
 153
 154         # just silence errors
 155         try {
 156                 die "foo";
 157         };
 158
 159 =head1 DESCRIPTION
 160
 161 This module provides bare bones C<try>/C<catch>/C<finally> statements that are designed to
 162 minimize common mistakes with eval blocks, and NOTHING else.
 163
 164 This is unlike L<TryCatch> which provides a nice syntax and avoids adding
 165 another call stack layer, and supports calling C<return> from the try block to
 166 return from the parent subroutine. These extra features come at a cost of a few
 167 dependencies, namely L<Devel::Declare> and L<Scope::Upper> which are
 168 occasionally problematic, and the additional catch filtering uses L<Moose>
 169 type constraints which may not be desirable either.
 170
 171 The main focus of this module is to provide simple and reliable error handling
 172 for those having a hard time installing L<TryCatch>, but who still want to
 173 write correct C<eval> blocks without 5 lines of boilerplate each time.
 174
 175 It's designed to work as correctly as possible in light of the various
 176 pathological edge cases (see L<BACKGROUND>) and to be compatible with any style
 177 of error values (simple strings, references, objects, overloaded objects, etc).
 178
 179 If the try block dies, it returns the value of the last statement executed in
 180 the catch block, if there is one. Otherwise, it returns C<undef> in scalar
 181 context or the empty list in list context. The following two examples both
 182 assign C<"bar"> to C<$x>.
 183
 184         my $x = try { die "foo" } catch { "bar" };
 185
 186         my $x = eval { die "foo" } || "bar";
 187
 188 You can add finally blocks making the following true.
 189
 190         my $x;
 191         try { die 'foo' } finally { $x = 'bar' };
 192         try { die 'foo' } catch { warn "Got a die: $_" } finally { $x = 'bar' };
 193
 194 Finally blocks are always executed making them suitable for cleanup code
 195 which cannot be handled using local.
 196
 197 =head1 EXPORTS
 198
 199 All functions are exported by default using L<Exporter>.
 200
 201 If you need to rename the C<try>, C<catch> or C<finally> keyword consider using
 202 L<Sub::Import> to get L<Sub::Exporter>'s flexibility.
 203
 204 =over 4
 205
 206 =item try (&;@)
 207
 208 Takes one mandatory try subroutine, an optional catch subroutine & finally
 209 subroutine.
 210
 211 The mandatory subroutine is evaluated in the context of an C<eval> block.
 212
 213 If no error occurred the value from the first block is returned, preserving
 214 list/scalar context.
 215
 216 If there was an error and the second subroutine was given it will be invoked
 217 with the error in C<$_> (localized) and as that block's first and only
 218 argument.
 219
 220 C<$@> does B<not> contain the error. Inside the C<catch> block it has the same
 221 value it had before the C<try> block was executed.
 222
 223 Note that the error may be false, but if that happens the C<catch> block will
 224 still be invoked.
 225
 226 Once all execution is finished then the finally block if given will execute.
 227
 228 =item catch (&;$)
 229
 230 Intended to be used in the second argument position of C<try>.
 231
 232 Returns a reference to the subroutine it was given but blessed as
 233 C<Try::Tiny::Catch> which allows try to decode correctly what to do
 234 with this code reference.
 235
 236         catch { ... }
 237
 238 Inside the catch block the caught error is stored in C<$_>, while previous
 239 value of C<$@> is still available for use.  This value may or may not be
 240 meaningful depending on what happened before the C<try>, but it might be a good
 241 idea to preserve it in an error stack.
 242
 243 For code that captures C<$@> when throwing new errors (i.e.
 244 L<Class::Throwable>), you'll need to do:
 245
 246         local $@ = $_;
 247
 248 =item finally (&;$)
 249
 250   try     { ... }
 251   catch   { ... }
 252   finally { ... };
 253
 254 Or
 255
 256   try     { ... }
 257   finally { ... };
 258
 259 Or even
 260
 261   try     { ... }
 262   finally { ... }
 263   catch   { ... };
 264
 265 Intended to be the second or third element of C<try>. Finally blocks are always
 266 executed in the event of a successful C<try> or if C<catch> is run. This allows
 267 you to locate cleanup code which cannot be done via C<local()> e.g. closing a file
 268 handle.
 269
 270 B<You must always do your own error handling in the finally block>. C<Try::Tiny> will
 271 not do anything about handling possible errors coming from code located in these
 272 blocks.
 273
 274 In the same way C<catch()> blesses the code reference this subroutine does the same
 275 except it bless them as C<Try::Tiny::Finally>.
 276
 277 =back
 278
 279 =head1 BACKGROUND
 280
 281 There are a number of issues with C<eval>.
 282
 283 =head2 Clobbering $@
 284
 285 When you run an eval block and it succeeds, C<$@> will be cleared, potentially
 286 clobbering an error that is currently being caught.
 287
 288 This causes action at a distance, clearing previous errors your caller may have
 289 not yet handled.
 290
 291 C<$@> must be properly localized before invoking C<eval> in order to avoid this
 292 issue.
 293
 294 More specifically, C<$@> is clobbered at the beginning of the C<eval>, which
 295 also makes it impossible to capture the previous error before you die (for
 296 instance when making exception objects with error stacks).
 297
 298 For this reason C<try> will actually set C<$@> to its previous value (before
 299 the localization) in the beginning of the C<eval> block.
 300
 301 =head2 Localizing $@ silently masks errors
 302
 303 Inside an eval block C<die> behaves sort of like:
 304
 305         sub die {
 306                 $@ = $_[0];
 307                 return_undef_from_eval();
 308         }
 309
 310 This means that if you were polite and localized C<$@> you can't die in that
 311 scope, or your error will be discarded (printing "Something's wrong" instead).
 312
 313 The workaround is very ugly:
 314
 315         my $error = do {
 316                 local $@;
 317                 eval { ... };
 318                 $@;
 319         };
 320
 321         ...
 322         die $error;
 323
 324 =head2 $@ might not be a true value
 325
 326 This code is wrong:
 327
 328         if ( $@ ) {
 329                 ...
 330         }
 331
 332 because due to the previous caveats it may have been unset.
 333
 334 C<$@> could also be an overloaded error object that evaluates to false, but
 335 that's asking for trouble anyway.
 336
 337 The classic failure mode is:
 338
 339         sub Object::DESTROY {
 340                 eval { ... }
 341         }
 342
 343         eval {
 344                 my $obj = Object->new;
 345
 346                 die "foo";
 347         };
 348
 349         if ( $@ ) {
 350
 351         }
 352
 353 In this case since C<Object::DESTROY> is not localizing C<$@> but still uses
 354 C<eval>, it will set C<$@> to C<"">.
 355
 356 The destructor is called when the stack is unwound, after C<die> sets C<$@> to
 357 C<"foo at Foo.pm line 42\n">, so by the time C<if ( $@ )> is evaluated it has
 358 been cleared by C<eval> in the destructor.
 359
 360 The workaround for this is even uglier than the previous ones. Even though we
 361 can't save the value of C<$@> from code that doesn't localize, we can at least
 362 be sure the eval was aborted due to an error:
 363
 364         my $failed = not eval {
 365                 ...
 366
 367                 return 1;
 368         };
 369
 370 This is because an C<eval> that caught a C<die> will always return a false
 371 value.
 372
 373 =head1 SHINY SYNTAX
 374
 375 Using Perl 5.10 you can use L<perlsyn/"Switch statements">.
 376
 377 The C<catch> block is invoked in a topicalizer context (like a C<given> block),
 378 but note that you can't return a useful value from C<catch> using the C<when>
 379 blocks without an explicit C<return>.
 380
 381 This is somewhat similar to Perl 6's C<CATCH> blocks. You can use it to
 382 concisely match errors:
 383
 384         try {
 385                 require Foo;
 386         } catch {
 387                 when (/^Can't locate .*?\.pm in \@INC/) { } # ignore
 388                 default { die $_ }
 389         };
 390
 391 =head1 CAVEATS
 392
 393 =over 4
 394
 395 =item *
 396
 397 C<@_> is not available within the C<try> block, so you need to copy your
 398 arglist. In case you want to work with argument values directly via C<@_>
 399 aliasing (i.e. allow C<$_[1] = "foo">), you need to pass C<@_> by reference:
 400
 401         sub foo {
 402                 my ( $self, @args ) = @_;
 403                 try { $self->bar(@args) }
 404         }
 405
 406 or
 407
 408         sub bar_in_place {
 409                 my $self = shift;
 410                 my $args = \@_;
 411                 try { $_ = $self->bar($_) for @$args }
 412         }
 413
 414 =item *
 415
 416 C<return> returns from the C<try> block, not from the parent sub (note that
 417 this is also how C<eval> works, but not how L<TryCatch> works):
 418
 419         sub bar {
 420                 try { return "foo" };
 421                 return "baz";
 422         }
 423
 424         say bar(); # "baz"
 425
 426 =item *
 427
 428 C<try> introduces another caller stack frame. L<Sub::Uplevel> is not used. L<Carp>
 429 will not report this when using full stack traces, though, because
 430 C<%Carp::Internal> is used. This lack of magic is considered a feature.
 431
 432 =item *
 433
 434 The value of C<$_> in the C<catch> block is not guaranteed to be the value of
 435 the exception thrown (C<$@>) in the C<try> block.  There is no safe way to
 436 ensure this, since C<eval> may be used unhygenically in destructors.  The only
 437 guarantee is that the C<catch> will be called if an exception is thrown.
 438
 439 =item *
 440
 441 The return value of the C<catch> block is not ignored, so if testing the result
 442 of the expression for truth on success, be sure to return a false value from
 443 the C<catch> block:
 444
 445         my $obj = try {
 446                 MightFail->new;
 447         } catch {
 448                 ...
 449
 450                 return; # avoid returning a true value;
 451         };
 452
 453         return unless $obj;
 454
 455 =item *
 456
 457 C<$SIG{__DIE__}> is still in effect.
 458
 459 Though it can be argued that C<$SIG{__DIE__}> should be disabled inside of
 460 C<eval> blocks, since it isn't people have grown to rely on it. Therefore in
 461 the interests of compatibility, C<try> does not disable C<$SIG{__DIE__}> for
 462 the scope of the error throwing code.
 463
 464 =item *
 465
 466 Lexical C<$_> may override the one set by C<catch>.
 467
 468 For example Perl 5.10's C<given> form uses a lexical C<$_>, creating some
 469 confusing behavior:
 470
 471         given ($foo) {
 472                 when (...) {
 473                         try {
 474                                 ...
 475                         } catch {
 476                                 warn $_; # will print $foo, not the error
 477                                 warn $_[0]; # instead, get the error like this
 478                         }
 479                 }
 480         }
 481
 482 =back
 483
 484 =head1 SEE ALSO
 485
 486 =over 4
 487
 488 =item L<TryCatch>
 489
 490 Much more feature complete, more convenient semantics, but at the cost of
 491 implementation complexity.
 492
 493 =item L<autodie>
 494
 495 Automatic error throwing for builtin functions and more. Also designed to
 496 work well with C<given>/C<when>.
 497
 498 =item L<Throwable>
 499
 500 A lightweight role for rolling your own exception classes.
 501
 502 =item L<Error>
 503
 504 Exception object implementation with a C<try> statement. Does not localize
 505 C<$@>.
 506
 507 =item L<Exception::Class::TryCatch>
 508
 509 Provides a C<catch> statement, but properly calling C<eval> is your
 510 responsibility.
 511
 512 The C<try> keyword pushes C<$@> onto an error stack, avoiding some of the
 513 issues with C<$@>, but you still need to localize to prevent clobbering.
 514
 515 =back
 516
 517 =head1 LIGHTNING TALK
 518
 519 I gave a lightning talk about this module, you can see the slides (Firefox
 520 only):
 521
 522 L<http://nothingmuch.woobling.org/talks/takahashi.xul?data=yapc_asia_2009/try_tiny.txt>
 523
 524 Or read the source:
 525
 526 L<http://nothingmuch.woobling.org/talks/yapc_asia_2009/try_tiny.yml>
 527
 528 =head1 VERSION CONTROL
 529
 530 L<http://github.com/nothingmuch/try-tiny/>
 531
 532 =head1 AUTHOR
 533
 534 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 535
 536 =head1 COPYRIGHT
 537
 538         Copyright (c) 2009 Yuval Kogman. All rights reserved.
 539         This program is free software; you can redistribute
 540         it and/or modify it under the terms of the MIT license.
 541
 542 =cut
 543