lib/Time/Local.pm

   1 package Time::Local;
   2 require 5.000;
   3 require Exporter;
   4 use Carp;
   5 use strict;
   6
   7 our $VERSION    = '1.00';
   8 our @ISA        = qw( Exporter );
   9 our @EXPORT     = qw( timegm timelocal );
  10 our @EXPORT_OK  = qw( timegm_nocheck timelocal_nocheck );
  11
  12 # Set up constants
  13 our $SEC  = 1;
  14 our $MIN  = 60 * $SEC;
  15 our $HR   = 60 * $MIN;
  16 our $DAY  = 24 * $HR;
  17 # Determine breakpoint for rolling century
  18     my $ThisYear = (localtime())[5];
  19     my $NextCentury = int($ThisYear / 100) * 100;
  20     my $Breakpoint = ($ThisYear + 50) % 100;
  21        $NextCentury += 100 if $Breakpoint < 50;
  22
  23 our(%Options, %Cheat);
  24
  25 sub timegm {
  26     my (@date) = @_;
  27     if ($date[5] > 999) {
  28         $date[5] -= 1900;
  29     }
  30     elsif ($date[5] >= 0 && $date[5] < 100) {
  31         $date[5] -= 100 if $date[5] > $Breakpoint;
  32         $date[5] += $NextCentury;
  33     }
  34     my $ym = pack('C2', @date[5,4]);
  35     my $cheat = $Cheat{$ym} || &cheat($ym, @date);
  36     $cheat
  37     + $date[0] * $SEC
  38     + $date[1] * $MIN
  39     + $date[2] * $HR
  40     + ($date[3]-1) * $DAY;
  41 }
  42
  43 sub timegm_nocheck {
  44     local $Options{no_range_check} = 1;
  45     &timegm;
  46 }
  47
  48 sub timelocal {
  49     my $t = &timegm;
  50     my $tt = $t;
  51
  52     my (@lt) = localtime($t);
  53     my (@gt) = gmtime($t);
  54     if ($t < $DAY and ($lt[5] >= 70 or $gt[5] >= 70 )) {
  55         # Wrap error, too early a date
  56         # Try a safer date
  57         $tt += $DAY;
  58         @lt = localtime($tt);
  59         @gt = gmtime($tt);
  60     }
  61
  62     my $tzsec = ($gt[1] - $lt[1]) * $MIN + ($gt[2] - $lt[2]) * $HR;
  63
  64     if($lt[5] > $gt[5]) {
  65         $tzsec -= $DAY;
  66     }
  67     elsif($gt[5] > $lt[5]) {
  68         $tzsec += $DAY;
  69     }
  70     else {
  71         $tzsec += ($gt[7] - $lt[7]) * $DAY;
  72     }
  73
  74     $tzsec += $HR if($lt[8]);
  75
  76     my $time = $t + $tzsec;
  77     my @test = localtime($time + ($tt - $t));
  78     $time -= $HR if $test[2] != $_[2];
  79     $time;
  80 }
  81
  82 sub timelocal_nocheck {
  83     local $Options{no_range_check} = 1;
  84     &timelocal;
  85 }
  86
  87 sub cheat {
  88     my($ym, @date) = @_;
  89     my($sec, $min, $hour, $day, $month, $year) = @date;
  90     unless ($Options{no_range_check}) {
  91         croak "Month '$month' out of range 0..11" if $month > 11 || $month < 0;
  92         croak "Day '$day' out of range 1..31"     if $day > 31  || $day < 1;
  93         croak "Hour '$hour' out of range 0..23"   if $hour > 23 || $hour < 0;
  94         croak "Minute '$min' out of range 0..59" if $min > 59   || $min < 0;
  95         croak "Second '$sec' out of range 0..59" if $sec > 59   || $sec < 0;
  96     }
  97     my $guess = $^T;
  98     my @g = gmtime($guess);
  99     my $lastguess = "";
 100     my $counter = 0;
 101     while (my $diff = $year - $g[5]) {
 102         my $thisguess;
 103         croak "Can't handle date (".join(", ",@date).")" if ++$counter > 255;
 104         $guess += $diff * (363 * $DAY);
 105         @g = gmtime($guess);
 106         if (($thisguess = "@g") eq $lastguess){
 107             croak "Can't handle date (".join(", ",@date).")";
 108             #date beyond this machine's integer limit
 109         }
 110         $lastguess = $thisguess;
 111     }
 112     while (my $diff = $month - $g[4]) {
 113         my $thisguess;
 114         croak "Can't handle date (".join(", ",@date).")" if ++$counter > 255;
 115         $guess += $diff * (27 * $DAY);
 116         @g = gmtime($guess);
 117         if (($thisguess = "@g") eq $lastguess){
 118             croak "Can't handle date (".join(", ",@date).")";
 119             #date beyond this machine's integer limit
 120         }
 121         $lastguess = $thisguess;
 122     }
 123     my @gfake = gmtime($guess-1); #still being sceptic
 124     if ("@gfake" eq $lastguess){
 125         croak "Can't handle date (".join(", ",@date).")";
 126         #date beyond this machine's integer limit
 127     }
 128     $g[3]--;
 129     $guess -= $g[0] * $SEC + $g[1] * $MIN + $g[2] * $HR + $g[3] * $DAY;
 130     $Cheat{$ym} = $guess;
 131 }
 132
 133 1;
 134
 135 __END__
 136
 137 =head1 NAME
 138
 139 Time::Local - efficiently compute time from local and GMT time
 140
 141 =head1 SYNOPSIS
 142
 143     $time = timelocal($sec,$min,$hours,$mday,$mon,$year);
 144     $time = timegm($sec,$min,$hours,$mday,$mon,$year);
 145
 146 =head1 DESCRIPTION
 147
 148 These routines are the inverse of built-in perl fuctions localtime()
 149 and gmtime().  They accept a date as a six-element array, and return
 150 the corresponding time(2) value in seconds since the Epoch (Midnight,
 151 January 1, 1970).  This value can be positive or negative.
 152
 153 It is worth drawing particular attention to the expected ranges for
 154 the values provided.  While the day of the month is expected to be in
 155 the range 1..31, the month should be in the range 0..11.
 156 This is consistent with the values returned from localtime() and gmtime().
 157
 158 The timelocal() and timegm() functions perform range checking on the
 159 input $sec, $min, $hours, $mday, and $mon values by default.  If you'd
 160 rather they didn't, you can explicitly import the timelocal_nocheck()
 161 and timegm_nocheck() functions.
 162
 163         use Time::Local 'timelocal_nocheck';
 164
 165         {
 166             # The 365th day of 1999
 167             print scalar localtime timelocal_nocheck 0,0,0,365,0,99;
 168
 169             # The twenty thousandth day since 1970
 170             print scalar localtime timelocal_nocheck 0,0,0,20000,0,70;
 171
 172             # And even the 10,000,000th second since 1999!
 173             print scalar localtime timelocal_nocheck 10000000,0,0,1,0,99;
 174         }
 175
 176 Your mileage may vary when trying these with minutes and hours,
 177 and it doesn't work at all for months.
 178
 179 Strictly speaking, the year should also be specified in a form consistent
 180 with localtime(), i.e. the offset from 1900.
 181 In order to make the interpretation of the year easier for humans,
 182 however, who are more accustomed to seeing years as two-digit or four-digit
 183 values, the following conventions are followed:
 184
 185 =over 4
 186
 187 =item *
 188
 189 Years greater than 999 are interpreted as being the actual year,
 190 rather than the offset from 1900.  Thus, 1963 would indicate the year
 191 Martin Luther King won the Nobel prize, not the year 2863.
 192
 193 =item *
 194
 195 Years in the range 100..999 are interpreted as offset from 1900,
 196 so that 112 indicates 2012.  This rule also applies to years less than zero
 197 (but see note below regarding date range).
 198
 199 =item *
 200
 201 Years in the range 0..99 are interpreted as shorthand for years in the
 202 rolling "current century," defined as 50 years on either side of the current
 203 year.  Thus, today, in 1999, 0 would refer to 2000, and 45 to 2045,
 204 but 55 would refer to 1955.  Twenty years from now, 55 would instead refer
 205 to 2055.  This is messy, but matches the way people currently think about
 206 two digit dates.  Whenever possible, use an absolute four digit year instead.
 207
 208 =back
 209
 210 The scheme above allows interpretation of a wide range of dates, particularly
 211 if 4-digit years are used.
 212
 213 Please note, however, that the range of dates that can be actually be handled
 214 depends on the size of an integer (time_t) on a given platform.
 215 Currently, this is 32 bits for most systems, yielding an approximate range
 216 from Dec 1901 to Jan 2038.
 217
 218 Both timelocal() and timegm() croak if given dates outside the supported
 219 range.
 220
 221 =head1 IMPLEMENTATION
 222
 223 These routines are quite efficient and yet are always guaranteed to agree
 224 with localtime() and gmtime().  We manage this by caching the start times
 225 of any months we've seen before.  If we know the start time of the month,
 226 we can always calculate any time within the month.  The start times
 227 themselves are guessed by successive approximation starting at the
 228 current time, since most dates seen in practice are close to the
 229 current date.  Unlike algorithms that do a binary search (calling gmtime
 230 once for each bit of the time value, resulting in 32 calls), this algorithm
 231 calls it at most 6 times, and usually only once or twice.  If you hit
 232 the month cache, of course, it doesn't call it at all.
 233
 234 timelocal() is implemented using the same cache.  We just assume that we're
 235 translating a GMT time, and then fudge it when we're done for the timezone
 236 and daylight savings arguments.  Note that the timezone is evaluated for
 237 each date because countries occasionally change their official timezones.
 238 Assuming that localtime() corrects for these changes, this routine will
 239 also be correct.  The daylight savings offset is currently assumed
 240 to be one hour.
 241
 242 =head1 BUGS
 243
 244 The whole scheme for interpreting two-digit years can be considered a bug.
 245
 246 Note that the cache currently handles only years from 1900 through 2155.
 247
 248 The proclivity to croak() is probably a bug.
 249
 250 =cut