lib/Time/Local.pm

   1 package Time::Local;
   2 use 5.006;
   3 require Exporter;
   4 use Carp;
   5 use Config;
   6 use strict;
   7 use integer;
   8
   9 our $VERSION    = '1.04';
  10 our @ISA        = qw( Exporter );
  11 our @EXPORT     = qw( timegm timelocal );
  12 our @EXPORT_OK  = qw( timegm_nocheck timelocal_nocheck );
  13
  14 my @MonthDays = (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
  15
  16 # Determine breakpoint for rolling century
  17 my $ThisYear     = (localtime())[5];
  18 my $Breakpoint   = ($ThisYear + 50) % 100;
  19 my $NextCentury  = $ThisYear - $ThisYear % 100;
  20    $NextCentury += 100 if $Breakpoint < 50;
  21 my $Century      = $NextCentury - 100;
  22 my $SecOff       = 0;
  23
  24 my (%Options, %Cheat);
  25
  26 my $MaxInt = ((1<<(8 * $Config{intsize} - 2))-1)*2 + 1;
  27 my $MaxDay = int(($MaxInt-43200)/86400)-1;
  28
  29 # Determine the EPOC day for this machine
  30 my $Epoc = 0;
  31 if ($^O eq 'vos') {
  32 # work around posix-977 -- VOS doesn't handle dates in
  33 # the range 1970-1980.
  34   $Epoc = _daygm((0, 0, 0, 1, 0, 70, 4, 0));
  35 }
  36 elsif ($^O eq 'MacOS') {
  37   no integer;
  38
  39   $MaxDay *=2 if $^O eq 'MacOS';  # time_t unsigned ... quick hack?
  40   # MacOS time() is seconds since 1 Jan 1904, localtime
  41   # so we need to calculate an offset to apply later
  42   $Epoc = 693901;
  43   $SecOff = timelocal(localtime(0)) - timelocal(gmtime(0));
  44   $Epoc += _daygm(gmtime(0));
  45 }
  46 else {
  47   $Epoc = _daygm(gmtime(0));
  48 }
  49
  50 %Cheat=(); # clear the cache as epoc has changed
  51
  52 sub _daygm {
  53     $_[3] + ($Cheat{pack("ss",@_[4,5])} ||= do {
  54         my $month = ($_[4] + 10) % 12;
  55         my $year = $_[5] + 1900 - $month/10;
  56         365*$year + $year/4 - $year/100 + $year/400 + ($month*306 + 5)/10 - $Epoc
  57     });
  58 }
  59
  60
  61 sub _timegm {
  62     my $sec = $SecOff + $_[0]  +  60 * $_[1]  +  3600 * $_[2];
  63
  64     no integer;
  65
  66     $sec +  86400 * &_daygm;
  67 }
  68
  69
  70 sub timegm {
  71     my ($sec,$min,$hour,$mday,$month,$year) = @_;
  72
  73     if ($year >= 1000) {
  74         $year -= 1900;
  75     }
  76     elsif ($year < 100 and $year >= 0) {
  77         $year += ($year > $Breakpoint) ? $Century : $NextCentury;
  78     }
  79
  80     unless ($Options{no_range_check}) {
  81         if (abs($year) >= 0x7fff) {
  82             $year += 1900;
  83             croak "Cannot handle date ($sec, $min, $hour, $mday, $month, $year)";
  84         }
  85
  86         croak "Month '$month' out of range 0..11" if $month > 11 or $month < 0;
  87
  88         my $md = $MonthDays[$month];
  89         ++$md unless $month != 1 or $year % 4 or !($year % 400);
  90
  91         croak "Day '$mday' out of range 1..$md"   if $mday  > $md  or $mday  < 1;
  92         croak "Hour '$hour' out of range 0..23"   if $hour  > 23   or $hour  < 0;
  93         croak "Minute '$min' out of range 0..59"  if $min   > 59   or $min   < 0;
  94         croak "Second '$sec' out of range 0..59"  if $sec   > 59   or $sec   < 0;
  95     }
  96
  97     my $days = _daygm(undef, undef, undef, $mday, $month, $year);
  98
  99     unless ($Options{no_range_check} or abs($days) < $MaxDay) {
 100         $year += 1900;
 101         croak "Cannot handle date ($sec, $min, $hour, $mday, $month, $year)";
 102     }
 103
 104     $sec += $SecOff + 60*$min + 3600*$hour;
 105
 106     no integer;
 107
 108     $sec + 86400*$days;
 109 }
 110
 111
 112 sub timegm_nocheck {
 113     local $Options{no_range_check} = 1;
 114     &timegm;
 115 }
 116
 117
 118 sub timelocal {
 119     no integer;
 120     my $ref_t = &timegm;
 121     my $loc_t = _timegm(localtime($ref_t));
 122
 123     # Is there a timezone offset from GMT or are we done
 124     my $zone_off = $ref_t - $loc_t
 125         or return $loc_t;
 126
 127     # Adjust for timezone
 128     $loc_t = $ref_t + $zone_off;
 129
 130     # Are we close to a DST change or are we done
 131     my $dst_off = $ref_t - _timegm(localtime($loc_t))
 132         or return $loc_t;
 133
 134     # Adjust for DST change
 135     $loc_t += $dst_off;
 136
 137     # for a negative offset from GMT, and if the original date
 138     # was a non-extent gap in a forward DST jump, we should
 139     # now have the wrong answer - undo the DST adjust;
 140
 141     return $loc_t if $zone_off <= 0;
 142
 143     my ($s,$m,$h) = localtime($loc_t);
 144     $loc_t -= $dst_off if $s != $_[0] || $m != $_[1] || $h != $_[2];
 145
 146     $loc_t;
 147 }
 148
 149
 150 sub timelocal_nocheck {
 151     local $Options{no_range_check} = 1;
 152     &timelocal;
 153 }
 154
 155 1;
 156
 157 __END__
 158
 159 =head1 NAME
 160
 161 Time::Local - efficiently compute time from local and GMT time
 162
 163 =head1 SYNOPSIS
 164
 165     $time = timelocal($sec,$min,$hour,$mday,$mon,$year);
 166     $time = timegm($sec,$min,$hour,$mday,$mon,$year);
 167
 168 =head1 DESCRIPTION
 169
 170 These routines are the inverse of built-in perl functions localtime()
 171 and gmtime().  They accept a date as a six-element array, and return
 172 the corresponding time(2) value in seconds since the Epoch (Midnight,
 173 January 1, 1970).  This value can be positive or negative.
 174
 175 It is worth drawing particular attention to the expected ranges for
 176 the values provided.  The value for the day of the month is the actual day
 177 (ie 1..31), while the month is the number of months since January (0..11).
 178 This is consistent with the values returned from localtime() and gmtime().
 179
 180 The timelocal() and timegm() functions perform range checking on the
 181 input $sec, $min, $hour, $mday, and $mon values by default.  If you'd
 182 rather they didn't, you can explicitly import the timelocal_nocheck()
 183 and timegm_nocheck() functions.
 184
 185         use Time::Local 'timelocal_nocheck';
 186
 187         {
 188             # The 365th day of 1999
 189             print scalar localtime timelocal_nocheck 0,0,0,365,0,99;
 190
 191             # The twenty thousandth day since 1970
 192             print scalar localtime timelocal_nocheck 0,0,0,20000,0,70;
 193
 194             # And even the 10,000,000th second since 1999!
 195             print scalar localtime timelocal_nocheck 10000000,0,0,1,0,99;
 196         }
 197
 198 Your mileage may vary when trying these with minutes and hours,
 199 and it doesn't work at all for months.
 200
 201 Strictly speaking, the year should also be specified in a form consistent
 202 with localtime(), i.e. the offset from 1900.
 203 In order to make the interpretation of the year easier for humans,
 204 however, who are more accustomed to seeing years as two-digit or four-digit
 205 values, the following conventions are followed:
 206
 207 =over 4
 208
 209 =item *
 210
 211 Years greater than 999 are interpreted as being the actual year,
 212 rather than the offset from 1900.  Thus, 1963 would indicate the year
 213 Martin Luther King won the Nobel prize, not the year 2863.
 214
 215 =item *
 216
 217 Years in the range 100..999 are interpreted as offset from 1900,
 218 so that 112 indicates 2012.  This rule also applies to years less than zero
 219 (but see note below regarding date range).
 220
 221 =item *
 222
 223 Years in the range 0..99 are interpreted as shorthand for years in the
 224 rolling "current century," defined as 50 years on either side of the current
 225 year.  Thus, today, in 1999, 0 would refer to 2000, and 45 to 2045,
 226 but 55 would refer to 1955.  Twenty years from now, 55 would instead refer
 227 to 2055.  This is messy, but matches the way people currently think about
 228 two digit dates.  Whenever possible, use an absolute four digit year instead.
 229
 230 =back
 231
 232 The scheme above allows interpretation of a wide range of dates, particularly
 233 if 4-digit years are used.
 234
 235 Please note, however, that the range of dates that can be actually be handled
 236 depends on the size of an integer (time_t) on a given platform.
 237 Currently, this is 32 bits for most systems, yielding an approximate range
 238 from Dec 1901 to Jan 2038.
 239
 240 Both timelocal() and timegm() croak if given dates outside the supported
 241 range.
 242
 243 =head1 IMPLEMENTATION
 244
 245 These routines are quite efficient and yet are always guaranteed to agree
 246 with localtime() and gmtime().  We manage this by caching the start times
 247 of any months we've seen before.  If we know the start time of the month,
 248 we can always calculate any time within the month.  The start times
 249 are calculated using a mathematical formula. Unlike other algorithms
 250 that do multiple calls to gmtime().
 251
 252 timelocal() is implemented using the same cache.  We just assume that we're
 253 translating a GMT time, and then fudge it when we're done for the timezone
 254 and daylight savings arguments.  Note that the timezone is evaluated for
 255 each date because countries occasionally change their official timezones.
 256 Assuming that localtime() corrects for these changes, this routine will
 257 also be correct.
 258
 259 =head1 BUGS
 260
 261 The whole scheme for interpreting two-digit years can be considered a bug.
 262
 263 The proclivity to croak() is probably a bug.
 264
 265 =cut
 266