lib/Time/Local.pm

   1 package Time::Local;
   2
   3 require Exporter;
   4 use Carp;
   5 use Config;
   6 use strict;
   7 use integer;
   8
   9 use vars qw( $VERSION @ISA @EXPORT @EXPORT_OK );
  10 $VERSION   = '1.18_01';
  11
  12 @ISA       = qw( Exporter );
  13 @EXPORT    = qw( timegm timelocal );
  14 @EXPORT_OK = qw( timegm_nocheck timelocal_nocheck );
  15
  16 my @MonthDays = ( 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 );
  17
  18 # Determine breakpoint for rolling century
  19 my $ThisYear    = ( localtime() )[5];
  20 my $Breakpoint  = ( $ThisYear + 50 ) % 100;
  21 my $NextCentury = $ThisYear - $ThisYear % 100;
  22 $NextCentury += 100 if $Breakpoint < 50;
  23 my $Century = $NextCentury - 100;
  24 my $SecOff  = 0;
  25
  26 my ( %Options, %Cheat );
  27
  28 use constant SECS_PER_MINUTE => 60;
  29 use constant SECS_PER_HOUR   => 3600;
  30 use constant SECS_PER_DAY    => 86400;
  31
  32 my $MaxInt = ( ( 1 << ( 8 * $Config{ivsize} - 2 ) ) - 1 ) * 2 + 1;
  33 my $MaxDay = int( ( $MaxInt - ( SECS_PER_DAY / 2 ) ) / SECS_PER_DAY ) - 1;
  34
  35 if ( $^O eq 'MacOS' ) {
  36     # time_t is unsigned...
  37     $MaxInt = ( 1 << ( 8 * $Config{ivsize} ) ) - 1;
  38 }
  39
  40 # Determine the EPOC day for this machine
  41 my $Epoc = 0;
  42 if ( $^O eq 'vos' ) {
  43     # work around posix-977 -- VOS doesn't handle dates in the range
  44     # 1970-1980.
  45     $Epoc = _daygm( 0, 0, 0, 1, 0, 70, 4, 0 );
  46 }
  47 elsif ( $^O eq 'MacOS' ) {
  48     $MaxDay *=2 if $^O eq 'MacOS';  # time_t unsigned ... quick hack?
  49     # MacOS time() is seconds since 1 Jan 1904, localtime
  50     # so we need to calculate an offset to apply later
  51     $Epoc = 693901;
  52     $SecOff = timelocal( localtime(0)) - timelocal( gmtime(0) ) ;
  53     $Epoc += _daygm( gmtime(0) );
  54 }
  55 else {
  56     $Epoc = _daygm( gmtime(0) );
  57 }
  58
  59 %Cheat = ();    # clear the cache as epoc has changed
  60
  61 sub _daygm {
  62
  63     # This is written in such a byzantine way in order to avoid
  64     # lexical variables and sub calls, for speed
  65     return $_[3] + (
  66         $Cheat{ pack( 'ss', @_[ 4, 5 ] ) } ||= do {
  67             my $month = ( $_[4] + 10 ) % 12;
  68             my $year  = $_[5] + 1900 - $month / 10;
  69
  70             ( ( 365 * $year )
  71               + ( $year / 4 )
  72               - ( $year / 100 )
  73               + ( $year / 400 )
  74               + ( ( ( $month * 306 ) + 5 ) / 10 )
  75             )
  76             - $Epoc;
  77         }
  78     );
  79 }
  80
  81 sub _timegm {
  82     my $sec =
  83         $SecOff + $_[0] + ( SECS_PER_MINUTE * $_[1] ) + ( SECS_PER_HOUR * $_[2] );
  84
  85     return $sec + ( SECS_PER_DAY * &_daygm );
  86 }
  87
  88 sub timegm {
  89     my ( $sec, $min, $hour, $mday, $month, $year ) = @_;
  90
  91     if ( $year >= 1000 ) {
  92         $year -= 1900;
  93     }
  94     elsif ( $year < 100 and $year >= 0 ) {
  95         $year += ( $year > $Breakpoint ) ? $Century : $NextCentury;
  96     }
  97
  98     unless ( $Options{no_range_check} ) {
  99         if ( abs($year) >= 0x7fff ) {
 100             $year += 1900;
 101             croak
 102                 "Cannot handle date ($sec, $min, $hour, $mday, $month, *$year*)";
 103         }
 104
 105         croak "Month '$month' out of range 0..11"
 106             if $month > 11
 107             or $month < 0;
 108
 109         my $md = $MonthDays[$month];
 110         ++$md
 111             if $month == 1 && _is_leap_year( $year + 1900 );
 112
 113         croak "Day '$mday' out of range 1..$md"  if $mday > $md or $mday < 1;
 114         croak "Hour '$hour' out of range 0..23"  if $hour > 23  or $hour < 0;
 115         croak "Minute '$min' out of range 0..59" if $min > 59   or $min < 0;
 116         croak "Second '$sec' out of range 0..59" if $sec > 59   or $sec < 0;
 117     }
 118
 119     my $days = _daygm( undef, undef, undef, $mday, $month, $year );
 120
 121     unless ($Options{no_range_check} or abs($days) < $MaxDay) {
 122         my $msg = '';
 123         $msg .= "Day too big - $days > $MaxDay\n" if $days > $MaxDay;
 124
 125         $year += 1900;
 126         $msg .=  "Cannot handle date ($sec, $min, $hour, $mday, $month, $year)";
 127
 128         croak $msg;
 129     }
 130
 131     return $sec
 132            + $SecOff
 133            + ( SECS_PER_MINUTE * $min )
 134            + ( SECS_PER_HOUR * $hour )
 135            + ( SECS_PER_DAY * $days );
 136 }
 137
 138 sub _is_leap_year {
 139     return 0 if $_[0] % 4;
 140     return 1 if $_[0] % 100;
 141     return 0 if $_[0] % 400;
 142
 143     return 1;
 144 }
 145
 146 sub timegm_nocheck {
 147     local $Options{no_range_check} = 1;
 148     return &timegm;
 149 }
 150
 151 sub timelocal {
 152     my $ref_t = &timegm;
 153     my $loc_for_ref_t = _timegm( localtime($ref_t) );
 154
 155     my $zone_off = $loc_for_ref_t - $ref_t
 156         or return $loc_for_ref_t;
 157
 158     # Adjust for timezone
 159     my $loc_t = $ref_t - $zone_off;
 160
 161     # Are we close to a DST change or are we done
 162     my $dst_off = $ref_t - _timegm( localtime($loc_t) );
 163
 164     # If this evaluates to true, it means that the value in $loc_t is
 165     # the _second_ hour after a DST change where the local time moves
 166     # backward.
 167     if ( ! $dst_off &&
 168          ( ( $ref_t - SECS_PER_HOUR ) - _timegm( localtime( $loc_t - SECS_PER_HOUR ) ) < 0 )
 169        ) {
 170         return $loc_t - SECS_PER_HOUR;
 171     }
 172
 173     # Adjust for DST change
 174     $loc_t += $dst_off;
 175
 176     return $loc_t if $dst_off > 0;
 177
 178     # If the original date was a non-extent gap in a forward DST jump,
 179     # we should now have the wrong answer - undo the DST adjustment
 180     my ( $s, $m, $h ) = localtime($loc_t);
 181     $loc_t -= $dst_off if $s != $_[0] || $m != $_[1] || $h != $_[2];
 182
 183     return $loc_t;
 184 }
 185
 186 sub timelocal_nocheck {
 187     local $Options{no_range_check} = 1;
 188     return &timelocal;
 189 }
 190
 191 1;
 192
 193 __END__
 194
 195 =head1 NAME
 196
 197 Time::Local - efficiently compute time from local and GMT time
 198
 199 =head1 SYNOPSIS
 200
 201     $time = timelocal($sec,$min,$hour,$mday,$mon,$year);
 202     $time = timegm($sec,$min,$hour,$mday,$mon,$year);
 203
 204 =head1 DESCRIPTION
 205
 206 This module provides functions that are the inverse of built-in perl
 207 functions C<localtime()> and C<gmtime()>. They accept a date as a
 208 six-element array, and return the corresponding C<time(2)> value in
 209 seconds since the system epoch (Midnight, January 1, 1970 GMT on Unix,
 210 for example). This value can be positive or negative, though POSIX
 211 only requires support for positive values, so dates before the
 212 system's epoch may not work on all operating systems.
 213
 214 It is worth drawing particular attention to the expected ranges for
 215 the values provided. The value for the day of the month is the actual
 216 day (ie 1..31), while the month is the number of months since January
 217 (0..11). This is consistent with the values returned from
 218 C<localtime()> and C<gmtime()>.
 219
 220 =head1 FUNCTIONS
 221
 222 =head2 C<timelocal()> and C<timegm()>
 223
 224 This module exports two functions by default, C<timelocal()> and
 225 C<timegm()>.
 226
 227 The C<timelocal()> and C<timegm()> functions perform range checking on
 228 the input $sec, $min, $hour, $mday, and $mon values by default.
 229
 230 =head2 C<timelocal_nocheck()> and C<timegm_nocheck()>
 231
 232 If you are working with data you know to be valid, you can speed your
 233 code up by using the "nocheck" variants, C<timelocal_nocheck()> and
 234 C<timegm_nocheck()>. These variants must be explicitly imported.
 235
 236     use Time::Local 'timelocal_nocheck';
 237
 238     # The 365th day of 1999
 239     print scalar localtime timelocal_nocheck 0,0,0,365,0,99;
 240
 241 If you supply data which is not valid (month 27, second 1,000) the
 242 results will be unpredictable (so don't do that).
 243
 244 =head2 Year Value Interpretation
 245
 246 Strictly speaking, the year should be specified in a form consistent
 247 with C<localtime()>, i.e. the offset from 1900. In order to make the
 248 interpretation of the year easier for humans, however, who are more
 249 accustomed to seeing years as two-digit or four-digit values, the
 250 following conventions are followed:
 251
 252 =over 4
 253
 254 =item *
 255
 256 Years greater than 999 are interpreted as being the actual year,
 257 rather than the offset from 1900. Thus, 1964 would indicate the year
 258 Martin Luther King won the Nobel prize, not the year 3864.
 259
 260 =item *
 261
 262 Years in the range 100..999 are interpreted as offset from 1900, so
 263 that 112 indicates 2012. This rule also applies to years less than
 264 zero (but see note below regarding date range).
 265
 266 =item *
 267
 268 Years in the range 0..99 are interpreted as shorthand for years in the
 269 rolling "current century," defined as 50 years on either side of the
 270 current year. Thus, today, in 1999, 0 would refer to 2000, and 45 to
 271 2045, but 55 would refer to 1955. Twenty years from now, 55 would
 272 instead refer to 2055. This is messy, but matches the way people
 273 currently think about two digit dates. Whenever possible, use an
 274 absolute four digit year instead.
 275
 276 =back
 277
 278 The scheme above allows interpretation of a wide range of dates,
 279 particularly if 4-digit years are used.
 280
 281 =head2 Limits of time_t
 282
 283 The range of dates that can be actually be handled depends on the size
 284 of C<time_t> (usually a signed integer) on the given
 285 platform. Currently, this is 32 bits for most systems, yielding an
 286 approximate range from Dec 1901 to Jan 2038.
 287
 288 Both C<timelocal()> and C<timegm()> croak if given dates outside the
 289 supported range.
 290
 291 =head2 Ambiguous Local Times (DST)
 292
 293 Because of DST changes, there are many time zones where the same local
 294 time occurs for two different GMT times on the same day. For example,
 295 in the "Europe/Paris" time zone, the local time of 2001-10-28 02:30:00
 296 can represent either 2001-10-28 00:30:00 GMT, B<or> 2001-10-28
 297 01:30:00 GMT.
 298
 299 When given an ambiguous local time, the timelocal() function should
 300 always return the epoch for the I<earlier> of the two possible GMT
 301 times.
 302
 303 =head2 Non-Existent Local Times (DST)
 304
 305 When a DST change causes a locale clock to skip one hour forward,
 306 there will be an hour's worth of local times that don't exist. Again,
 307 for the "Europe/Paris" time zone, the local clock jumped from
 308 2001-03-25 01:59:59 to 2001-03-25 03:00:00.
 309
 310 If the C<timelocal()> function is given a non-existent local time, it
 311 will simply return an epoch value for the time one hour later.
 312
 313 =head2 Negative Epoch Values
 314
 315 Negative epoch (C<time_t>) values are not officially supported by the
 316 POSIX standards, so this module's tests do not test them. On some
 317 systems, they are known not to work. These include MacOS (pre-OSX) and
 318 Win32.
 319
 320 On systems which do support negative epoch values, this module should
 321 be able to cope with dates before the start of the epoch, down the
 322 minimum value of time_t for the system.
 323
 324 =head1 IMPLEMENTATION
 325
 326 These routines are quite efficient and yet are always guaranteed to
 327 agree with C<localtime()> and C<gmtime()>. We manage this by caching
 328 the start times of any months we've seen before. If we know the start
 329 time of the month, we can always calculate any time within the month.
 330 The start times are calculated using a mathematical formula. Unlike
 331 other algorithms that do multiple calls to C<gmtime()>.
 332
 333 The C<timelocal()> function is implemented using the same cache. We
 334 just assume that we're translating a GMT time, and then fudge it when
 335 we're done for the timezone and daylight savings arguments. Note that
 336 the timezone is evaluated for each date because countries occasionally
 337 change their official timezones. Assuming that C<localtime()> corrects
 338 for these changes, this routine will also be correct.
 339
 340 =head1 BUGS
 341
 342 The whole scheme for interpreting two-digit years can be considered a
 343 bug.
 344
 345 =head1 SUPPORT
 346
 347 Support for this module is provided via the datetime@perl.org email
 348 list. See http://lists.perl.org/ for more details.
 349
 350 Please submit bugs to the CPAN RT system at
 351 http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Time-Local or via email
 352 at bug-time-local@rt.cpan.org.
 353
 354 =head1 COPYRIGHT
 355
 356 Copyright (c) 1997-2003 Graham Barr, 2003-2007 David Rolsky.  All
 357 rights reserved.  This program is free software; you can redistribute
 358 it and/or modify it under the same terms as Perl itself.
 359
 360 The full text of the license can be found in the LICENSE file included
 361 with this module.
 362
 363 =head1 AUTHOR
 364
 365 This module is based on a Perl 4 library, timelocal.pl, that was
 366 included with Perl 4.036, and was most likely written by Tom
 367 Christiansen.
 368
 369 The current version was written by Graham Barr.
 370
 371 It is now being maintained separately from the Perl core by Dave
 372 Rolsky, <autarch@urth.org>.
 373
 374 =cut