lib/Text/Tradition.pm

   1 package Text::Tradition;
   2
   3 use JSON qw / from_json /;
   4 use Module::Load;
   5 use Moose;
   6 use Text::Tradition::Collation;
   7 use Text::Tradition::Stemma;
   8 use Text::Tradition::Witness;
   9 use Text::Tradition::User;
  10
  11 use vars qw( $VERSION );
  12 $VERSION = "0.5";
  13
  14 has 'collation' => (
  15     is => 'ro',
  16     isa => 'Text::Tradition::Collation',
  17     writer => '_save_collation',
  18     );
  19
  20 has 'witness_hash' => (
  21     traits => ['Hash'],
  22     isa => 'HashRef[Text::Tradition::Witness]',
  23     handles => {
  24         witness     => 'get',
  25         add_witness => 'set',
  26         del_witness => 'delete',
  27         has_witness => 'exists',
  28         witnesses   => 'values',
  29     },
  30     default => sub { {} },
  31     );
  32
  33 has 'name' => (
  34     is => 'rw',
  35     isa => 'Str',
  36     default => 'Tradition',
  37     );
  38
  39 has 'language' => (
  40         is => 'rw',
  41         isa => 'Str',
  42         predicate => 'has_language',
  43         );
  44
  45 has 'stemmata' => (
  46         traits => ['Array'],
  47         isa => 'ArrayRef[Text::Tradition::Stemma]',
  48         handles => {
  49                 stemmata => 'elements',
  50                 _add_stemma => 'push',
  51                 stemma => 'get',
  52                 stemma_count => 'count',
  53                 clear_stemmata => 'clear',
  54         },
  55         default => sub { [] },
  56         );
  57
  58 has 'user' => (
  59     is => 'rw',
  60     isa => 'Text::Tradition::User',
  61     required => 0,
  62     predicate => 'has_user',
  63     clearer => 'clear_user',
  64     );
  65
  66 # Create the witness before trying to add it
  67 around 'add_witness' => sub {
  68     my $orig = shift;
  69     my $self = shift;
  70     # TODO allow add of a Witness object?
  71     my %args = @_ == 1 ? %{$_[0]} : @_;
  72     $args{'tradition'} = $self;
  73     $args{'language'} = $self->language
  74         if( $self->language && !exists $args{'language'} );
  75     my $new_wit = Text::Tradition::Witness->new( %args );
  76     $self->$orig( $new_wit->sigil => $new_wit );
  77     return $new_wit;
  78 };
  79
  80 # Allow deletion of witness by object as well as by sigil
  81 around 'del_witness' => sub {
  82     my $orig = shift;
  83     my $self = shift;
  84     my @key_args;
  85     foreach my $arg ( @_ ) {
  86         push( @key_args,
  87               ref( $arg ) eq 'Text::Tradition::Witness' ? $arg->sigil : $arg );
  88     }
  89     return $self->$orig( @key_args );
  90 };
  91
  92 # Don't allow an empty hash value
  93 around 'witness' => sub {
  94     my( $orig, $self, $arg ) = @_;
  95     return unless $self->has_witness( $arg );
  96     return $self->$orig( $arg );
  97 };
  98
  99 =head1 NAME
 100
 101 Text::Tradition - a software model for a set of collated texts
 102
 103 =head1 SYNOPSIS
 104
 105   use Text::Tradition;
 106   my $t = Text::Tradition->new(
 107     'name' => 'this is a text',
 108     'input' => 'TEI',
 109     'file' => '/path/to/tei_parallel_seg_file.xml' );
 110
 111   my @text_wits = $t->witnesses();
 112   my $manuscript_a = $t->witness( 'A' );
 113
 114   $t = Text::Tradition->new();
 115   $t->add_witness( 'sourcetype' => 'xmldesc',
 116     'file' => '/path/to/teitranscription.xml' );
 117   $t->add_witness( 'sourcetype => 'plaintext', 'sigil' => 'Q',
 118     'string' => 'The quick brown fox jumped over the lazy dogs' );
 119   ## TODO
 120   $t->collate_texts;
 121
 122   my $text_path_svg = $t->collation->as_svg();
 123   ## See Text::Tradition::Collation for more on text collation itself
 124
 125 =head1 DESCRIPTION
 126
 127 Text::Tradition is a library for representation and analysis of collated
 128 texts, particularly medieval ones.  A 'tradition' refers to the aggregation
 129 of surviving versions of a text, generally preserved in multiple
 130 manuscripts (or 'witnesses').  A Tradition object thus has one more more
 131 Witnesses, as well as a Collation that represents the unity of all versions
 132 of the text.
 133
 134 =head1 METHODS
 135
 136 =head2 new
 137
 138 Creates and returns a new text tradition object.  The following options are
 139 accepted.
 140
 141 General options:
 142
 143 =over 4
 144
 145 =item B<name> - The name of the text.
 146
 147 =back
 148
 149 Initialization based on a collation file:
 150
 151 =over 4
 152
 153 =item B<input> - The input format of the collation file.  Can be one of the
 154 following:
 155
 156 =over 4
 157
 158 =item * Self - a GraphML format produced by this module
 159
 160 =item * CollateX - a GraphML format produced by CollateX
 161
 162 =item * CTE - a TEI XML format produced by Classical Text Editor
 163
 164 =item * JSON - an alignment table in JSON format, as produced by CollateX and other tools
 165
 166 =item * KUL - a specific CSV format for variants, not documented here
 167
 168 =item * TEI - a TEI parallel segmentation format file
 169
 170 =item * Tabular - a comma- or tab-separated collation.  Takes an additional
 171 option, 'sep_char', which defaults to the tab character.
 172
 173 =back
 174
 175 =item B<file> - The name of the file that contains the data.  One of 'file'
 176 or 'string' should be specified.
 177
 178 =item B<string> - A text string that contains the data.  One of 'file' or
 179 'string' should be specified.
 180
 181 =item B<base> - The name of a text file that contains the base text, to be
 182 used with input formats that require it (currently only KUL).
 183
 184 =back
 185
 186 Initialization based on a list of witnesses [NOT YET IMPLEMENTED]:
 187
 188 =over 4
 189
 190 =item B<witnesses> - A reference to an array of Text::Tradition::Witness
 191 objects that carry the text to be collated.
 192
 193 =item B<collator> - A reference to a collation program that will accept
 194 Witness objects.
 195
 196 =back
 197
 198 =head2 B<witnesses>
 199
 200 Return the Text::Tradition::Witness objects associated with this tradition,
 201 as an array.
 202
 203 =head2 B<witness>( $sigil )
 204
 205 Returns the Text::Tradition::Witness object whose sigil is $sigil, or undef
 206 if there is no such object within the tradition.
 207
 208 =head2 B<add_witness>( %opts )
 209
 210 Instantiate a new witness with the given options (see documentation for
 211 Text::Tradition::Witness) and add it to the tradition.
 212
 213 =head2 B<del_witness>( $sigil )
 214
 215 Delete the witness with the given sigil from the tradition.  Returns the
 216 witness object for the deleted witness.
 217
 218 =begin testing
 219
 220 use_ok( 'Text::Tradition', "can use module" );
 221
 222 my $t = Text::Tradition->new( 'name' => 'empty' );
 223 is( ref( $t ), 'Text::Tradition', "initialized an empty Tradition object" );
 224 is( $t->name, 'empty', "object has the right name" );
 225 is( scalar $t->witnesses, 0, "object has no witnesses" );
 226
 227 my $simple = 't/data/simple.txt';
 228 my $s = Text::Tradition->new(
 229     'name'  => 'inline',
 230     'input' => 'Tabular',
 231     'file'  => $simple,
 232     );
 233 is( ref( $s ), 'Text::Tradition', "initialized a Tradition object" );
 234 is( $s->name, 'inline', "object has the right name" );
 235 is( scalar $s->witnesses, 3, "object has three witnesses" );
 236
 237 my $wit_a = $s->witness('A');
 238 is( ref( $wit_a ), 'Text::Tradition::Witness', "Found a witness A" );
 239 if( $wit_a ) {
 240     is( $wit_a->sigil, 'A', "Witness A has the right sigil" );
 241 }
 242 is( $s->witness('X'), undef, "There is no witness X" );
 243 ok( !exists $s->{'witnesses'}->{'X'}, "Witness key X not created" );
 244
 245 my $wit_d = $s->add_witness( 'sigil' => 'D', 'sourcetype' => 'collation' );
 246 is( ref( $wit_d ), 'Text::Tradition::Witness', "new witness created" );
 247 is( $wit_d->sigil, 'D', "witness has correct sigil" );
 248 is( scalar $s->witnesses, 4, "object now has four witnesses" );
 249
 250 my $del = $s->del_witness( 'D' );
 251 is( $del, $wit_d, "Deleted correct witness" );
 252 is( scalar $s->witnesses, 3, "object has three witnesses again" );
 253
 254 # TODO test initialization by witness list when we have it
 255
 256 =end testing
 257
 258 =cut
 259
 260
 261 sub BUILD {
 262     my( $self, $init_args ) = @_;
 263
 264     # First, make a collation object. This will use only those arguments in
 265     # init_args that apply to the collation.
 266         my $collation = Text::Tradition::Collation->new( %$init_args,
 267                                                                                                         'tradition' => $self );
 268         $self->_save_collation( $collation );
 269
 270     if( exists $init_args->{'input'} ) {
 271         # Call the appropriate parser on the given data
 272         my @format_standalone = qw/ Self CollateText CollateX CTE JSON TEI Tabular /;
 273         my @format_basetext = qw/ KUL /;
 274         my $use_base;
 275         my $format = $init_args->{'input'};
 276         if( $format && !( grep { $_ eq $format } @format_standalone )
 277             && !( grep { $_ eq $format } @format_basetext ) ) {
 278             warn "Unrecognized input format $format; not parsing";
 279             return;
 280         }
 281         if( $format && grep { $_ eq $format } @format_basetext ) {
 282             $use_base = 1;
 283             if( !exists $init_args->{'base'} ) {
 284                 warn "Cannot make a collation from $format without a base text";
 285                 return;
 286             }
 287         }
 288
 289         # Now do the parsing.
 290         if( $format ) {
 291             if( $use_base ) {
 292                 $format = 'BaseText';   # Use the BaseText module for parsing,
 293                                         # but retain the original input arg.
 294             }
 295             my $mod = "Text::Tradition::Parser::$format";
 296             load( $mod );
 297             $mod->can('parse')->( $self, $init_args );
 298         }
 299     }
 300     return $self;
 301 }
 302
 303 =head2 add_json_witnesses( $jsonstring, $options )
 304
 305 Adds a set of witnesses from a JSON array specification. This is a wrapper
 306 to parse the JSON and call add_witness (with the specified $options) for
 307 each element therein.
 308
 309 =cut
 310
 311 sub add_json_witnesses {
 312         my( $self, $jsonstr, $extraopts ) = @_;
 313         my $witarray = from_json( $jsonstr );
 314         foreach my $witspec ( @{$witarray->{witnesses}} ) {
 315                 my $opts = $extraopts || {};
 316                 $opts->{'sourcetype'} = 'json';
 317                 $opts->{'object'} = $witspec;
 318                 $self->add_witness( $opts );
 319         }
 320 }
 321
 322 =head2 add_stemma( $dotfile )
 323
 324 Initializes a Text::Tradition::Stemma object from the given dotfile,
 325 and associates it with the tradition.
 326
 327 =begin testing
 328
 329 use Text::Tradition;
 330
 331 my $t = Text::Tradition->new(
 332     'name'  => 'simple test',
 333     'input' => 'Tabular',
 334     'file'  => 't/data/simple.txt',
 335     );
 336
 337 is( $t->stemma_count, 0, "No stemmas added yet" );
 338 my $s;
 339 ok( $s = $t->add_stemma( dotfile => 't/data/simple.dot' ), "Added a simple stemma" );
 340 is( ref( $s ), 'Text::Tradition::Stemma', "Got a stemma object returned" );
 341 is( $t->stemma_count, 1, "Tradition claims to have a stemma" );
 342 is( $t->stemma(0), $s, "Tradition hands back the right stemma" );
 343
 344 =end testing
 345
 346 =cut
 347
 348 sub add_stemma {
 349         my $self = shift;
 350         my %opts = @_;
 351         my $stemma_fh;
 352         if( $opts{'dotfile'} ) {
 353                 open $stemma_fh, '<', $opts{'dotfile'}
 354                         or warn "Could not open file " . $opts{'dotfile'};
 355         } elsif( $opts{'dot'} ) {
 356                 my $str = $opts{'dot'};
 357                 open $stemma_fh, '<', \$str;
 358         }
 359         # Assume utf-8
 360         binmode $stemma_fh, ':utf8';
 361         my $stemma = Text::Tradition::Stemma->new(
 362                 'collation' => $self->collation,
 363                 'dot' => $stemma_fh );
 364         $self->_add_stemma( $stemma ) if $stemma;
 365         return $stemma;
 366 }
 367
 368 sub lemmatize {
 369         my $self = shift;
 370         unless( $self->has_language ) {
 371                 warn "Please set a language to lemmatize a tradition";
 372                 return;
 373         }
 374         my $mod = "Text::Tradition::Language::" . $self->language;
 375         load( $mod );
 376         $mod->can( 'lemmatize' )->( $self );
 377 }
 378
 379 no Moose;
 380 __PACKAGE__->meta->make_immutable;
 381
 382
 383 =head1 BUGS / TODO
 384
 385 =over
 386
 387 =item * Allow tradition to be initialized via passing to a collator.
 388
 389 =back
 390
 391 =head1 LICENSE
 392
 393 This package is free software and is provided "as is" without express
 394 or implied warranty.  You can redistribute it and/or modify it under
 395 the same terms as Perl itself.
 396
 397 =head1 AUTHOR
 398
 399 Tara L Andrews E<lt>aurum@cpan.orgE<gt>