lib/Text/Tradition/Parser/TEI.pm

   1 package Text::Tradition::Parser::TEI;
   2
   3 use strict;
   4 use warnings;
   5 use Text::Tradition::Parser::Util qw( collate_variants );
   6 use XML::LibXML;
   7 use XML::LibXML::XPathContext;
   8
   9 =head1 NAME
  10
  11 Text::Tradition::Parser::TEI
  12
  13 =head1 SYNOPSIS
  14
  15   use Text::Tradition;
  16
  17   my $t_from_file = Text::Tradition->new(
  18     'name' => 'my text',
  19     'input' => 'TEI',
  20     'file' => '/path/to/parallel_seg_file.xml'
  21     );
  22
  23   my $t_from_string = Text::Tradition->new(
  24     'name' => 'my text',
  25     'input' => 'TEI',
  26     'string' => $parallel_seg_xml,
  27     );
  28
  29
  30 =head1 DESCRIPTION
  31
  32 Parser module for Text::Tradition, given a TEI parallel-segmentation file
  33 that describes a text and its variants.  Normally called upon
  34 initialization of Text::Tradition.
  35
  36 The witnesses for the tradition are taken from the <listWit/> element
  37 within the TEI header; the readings are taken from any <p/> element that
  38 appears in the text body (including <head/> elements therein.)
  39
  40 =head1 METHODS
  41
  42 =head2 B<parse>( $tradition, $option_hash )
  43
  44 Takes an initialized tradition and a set of options; creates the
  45 appropriate nodes and edges on the graph, as well as the appropriate
  46 witness objects.  The $option_hash must contain either a 'file' or a
  47 'string' argument with the XML to be parsed.
  48
  49 =begin testing
  50
  51 use Text::Tradition;
  52 binmode STDOUT, ":utf8";
  53 binmode STDERR, ":utf8";
  54 eval { no warnings; binmode $DB::OUT, ":utf8"; };
  55
  56 my $par_seg = 't/data/florilegium_tei_ps.xml';
  57 my $t = Text::Tradition->new(
  58     'name'  => 'inline',
  59     'input' => 'TEI',
  60     'file'  => $par_seg,
  61     );
  62
  63 is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
  64 if( $t ) {
  65     is( scalar $t->collation->readings, 311, "Collation has all readings" );
  66     is( scalar $t->collation->paths, 361, "Collation has all paths" );
  67 }
  68
  69 =end testing
  70
  71 =cut
  72
  73 my $text = {}; # Hash of arrays, one per eventual witness we find.
  74 my $substitutions = {}; # Keep track of merged readings
  75 my $app_anchors = {};   # Track apparatus references
  76 my $app_ac = {};        # Save a.c. readings
  77 my $app_count;          # Keep track of how many apps we have
  78
  79 # Create the package variables for tag names.
  80
  81 # Would really like to do this with varname variables, but apparently this
  82 # is considered a bad idea.  The long way round then.
  83 my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM )
  84     = ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
  85 sub _make_tagnames {
  86     my( $ns ) = @_;
  87     if( $ns ) {
  88         $LISTWIT = "$ns:$LISTWIT";
  89         $WITNESS = "$ns:$WITNESS";
  90         $TEXT = "$ns:$TEXT";
  91         $W = "$ns:$W";
  92         $SEG = "$ns:$SEG";
  93         $APP = "$ns:$APP";
  94         $RDG = "$ns:$RDG";
  95         $LEM = "$ns:$LEM";
  96     }
  97 }
  98
  99 # Parse the TEI file.
 100 sub parse {
 101     my( $tradition, $opts ) = @_;
 102
 103     # First, parse the XML.
 104     my $parser = XML::LibXML->new();
 105     my $doc;
 106     if( exists $opts->{'string'} ) {
 107         $doc = $parser->parse_string( $opts->{'string'} );
 108     } elsif ( exists $opts->{'file'} ) {
 109         $doc = $parser->parse_file( $opts->{'file'} );
 110     } else {
 111         warn "Could not find string or file option to parse";
 112         return;
 113     }
 114     my $tei = $doc->documentElement();
 115     my $xpc = XML::LibXML::XPathContext->new( $tei );
 116     my $ns;
 117     if( $tei->namespaceURI ) {
 118         $ns = 'tei';
 119         $xpc->registerNs( $ns, $tei->namespaceURI );
 120     }
 121     _make_tagnames( $ns );
 122
 123     # Then get the witnesses and create the witness objects.
 124     foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
 125         my $sig = $wit_el->getAttribute( 'xml:id' );
 126         my $source = $wit_el->toString();
 127         $tradition->add_witness( sigil => $sig, source => $source );
 128     }
 129     map { $text->{$_->sigil} = [] } $tradition->witnesses;
 130
 131     # Look for all word/seg node IDs and note their pre-existence.
 132     my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
 133     _save_preexisting_nodeids( @attrs );
 134
 135     # Count up how many apps we have.
 136     my @apps = $xpc->findnodes( "//$APP" );
 137     $app_count = scalar( @apps );
 138
 139     # Now go through the children of the text element and pull out the
 140     # actual text.
 141     foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
 142         foreach my $xn ( $xml_el->childNodes ) {
 143             _get_readings( $tradition, $xn );
 144         }
 145     }
 146     # Our $text global now has lists of readings, one per witness.
 147     # Join them up.
 148     my $c = $tradition->collation;
 149     foreach my $sig ( keys %$text ) {
 150         # Determine the list of readings for
 151         my $sequence = $text->{$sig};
 152         my @real_sequence = ( $c->start );
 153         push( @$sequence, $c->end );
 154         my $source = $c->start;
 155         foreach( _clean_sequence( $sig, $sequence ) ) {
 156             my $rdg = _return_rdg( $_ );
 157             push( @real_sequence, $rdg );
 158             $c->add_path( $source, $rdg, $sig );
 159             $source = $rdg;
 160         }
 161         # See if we need to make an a.c. version of the witness.
 162         if( exists $app_ac->{$sig} ) {
 163             my @uncorrected;
 164             push( @uncorrected, @real_sequence );
 165             foreach my $app ( keys %{$app_ac->{$sig}} ) {
 166                 my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} );
 167                 my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
 168                 my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
 169                 _replace_sequence( \@uncorrected, $start, $end, @new );
 170             }
 171             my $source = shift @uncorrected; # the start node
 172             warn "Something weird!" unless $source eq $c->start;
 173             foreach my $rdg ( @uncorrected ) {
 174                 unless( $c->has_path( $source, $rdg, $sig ) ) {
 175                         $c->add_path( $source, $rdg, $sig.$c->ac_label );
 176                 }
 177                 $source = $rdg;
 178             }
 179             warn "Something else weird!" unless $source eq $c->end;
 180             # print STDERR "Adding a.c. version for witness $sig\n";
 181             $tradition->witness( $sig )->is_layered( 1 );
 182         }
 183     }
 184
 185     # Calculate the ranks for the nodes.
 186         $tradition->collation->calculate_ranks();
 187
 188     # Now that we have ranks, see if we have distinct nodes with identical
 189     # text and identical rank that can be merged.
 190     $tradition->collation->flatten_ranks();
 191
 192     # And now that we've done that, calculate the common nodes.
 193     $tradition->collation->calculate_common_readings();
 194
 195     # Save the text for each witness so that we can ensure consistency
 196     # later on
 197         $tradition->collation->text_from_paths();
 198 }
 199
 200 sub _clean_sequence {
 201     my( $wit, $sequence ) = @_;
 202     my @clean_sequence;
 203     foreach my $rdg ( @$sequence ) {
 204         if( $rdg =~ /^PH-(.*)$/ ) {
 205             # It is a placeholder.  Keep it only if we need it.
 206             my $app_id = $1;
 207             if( exists $app_ac->{$wit} &&
 208                 exists $app_ac->{$wit}->{$app_id} ) {
 209                 # print STDERR "Retaining empty placeholder for $app_id\n";
 210                 push( @clean_sequence, $rdg );
 211             }
 212         } else {
 213             push( @clean_sequence, $rdg );
 214         }
 215     }
 216     return @clean_sequence;
 217 }
 218
 219 sub _replace_sequence {
 220     my( $arr, $start, $end, @new ) = @_;
 221     my( $start_idx, $end_idx );
 222     foreach my $i ( 0 .. $#{$arr} ) {
 223         $start_idx = $i if( $arr->[$i]->id eq $start );
 224         if( $arr->[$i]->id eq $end ) {
 225             $end_idx = $i;
 226             last;
 227         }
 228     }
 229     unless( $start_idx && $end_idx ) {
 230         warn "Could not find start and end";
 231         return;
 232     }
 233     my $length = $end_idx - $start_idx + 1;
 234     splice( @$arr, $start_idx, $length, @new );
 235 }
 236
 237 sub _return_rdg {
 238     my( $rdg ) = @_;
 239     # If we were passed a reading name, return the name.  If we were
 240     # passed a reading object, return the object.
 241     my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
 242     my $real = $rdg;
 243     if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
 244         $real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
 245         $real = $real->id unless $wantobj;
 246     }
 247     return $real;
 248 }
 249
 250 ## TODO test specific sorts of nodes of the parallel-seg XML.
 251
 252 ## Recursive helper function to help us navigate through nested XML,
 253 ## picking out the text.  $tradition is the tradition, needed for
 254 ## making readings; $xn is the XML node currently being looked at,
 255 ## $in_var is a flag to say that we are inside a variant, $ac is a
 256 ## flag to say that we are inside an ante-correctionem reading, and
 257 ## @cur_wits is the list of witnesses to which this XML node applies.
 258 ## Returns the list of readings, if any, created on the run.
 259
 260 {
 261     my %active_wits;
 262     my $current_app;
 263     my $seen_apps;
 264
 265     sub _get_readings {
 266         my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
 267         @cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;
 268
 269         my @new_readings;
 270         if( $xn->nodeType == XML_TEXT_NODE ) {
 271             # Some words, thus make some readings.
 272             my $str = $xn->data;
 273             return unless $str =~ /\S/; # skip whitespace-only text nodes
 274             #print STDERR "Handling text node " . $str . "\n";
 275             # Check that all the witnesses we have are active.
 276             foreach my $c ( @cur_wits ) {
 277                 warn "$c is not among active wits" unless $active_wits{$c};
 278             }
 279             $str =~ s/^\s+//;
 280             my $final = $str =~ s/\s+$//;
 281             foreach my $w ( split( /\s+/, $str ) ) {
 282                 # For now, skip punctuation.
 283                 next if $w !~ /[[:alnum:]]/;
 284                 my $rdg = _make_reading( $tradition->collation, $w );
 285                 push( @new_readings, $rdg );
 286                 foreach ( @cur_wits ) {
 287                     warn "Empty wit!" unless $_;
 288                     warn "Empty reading!" unless $rdg;
 289                     push( @{$text->{$_}}, $rdg ) unless $ac;
 290                 }
 291             }
 292         } elsif( $xn->nodeName eq 'w' ) {
 293             # Everything in this tag is one word.  Also save any original XML ID.
 294             #print STDERR "Handling word " . $xn->toString . "\n";
 295             # Check that all the witnesses we have are active.
 296             foreach my $c ( @cur_wits ) {
 297                 warn "$c is not among active wits" unless $active_wits{$c};
 298             }
 299             my $xml_id = $xn->getAttribute( 'xml:id' );
 300             my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
 301             push( @new_readings, $rdg );
 302             foreach( @cur_wits ) {
 303                 warn "Empty wit!" unless $_;
 304                 warn "Empty reading!" unless $rdg;
 305                 push( @{$text->{$_}}, $rdg ) unless $ac;
 306             }
 307         } elsif ( $xn->nodeName eq 'app' ) {
 308             $seen_apps++;
 309             $current_app = $xn->getAttribute( 'xml:id' );
 310             # print STDERR "Handling app $current_app\n";
 311             # Keep the reading sets in this app.
 312             my @sets;
 313             # Recurse through all children (i.e. rdgs) for sets of words.
 314             foreach ( $xn->childNodes ) {
 315                 my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
 316                 push( @sets, \@rdg_set ) if @rdg_set;
 317             }
 318             # Now collate these sets if we have more than one.
 319             my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
 320             map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
 321             # TODO Look through substitutions to see if we can make anything common now.
 322             # Return the entire set of unique readings.
 323             my %unique;
 324             foreach my $s ( @sets ) {
 325                 map { $unique{$_->id} = $_ } @$s;
 326             }
 327             push( @new_readings, values( %unique ) );
 328             # Exit the current app.
 329             $current_app = '';
 330         } elsif ( $xn->nodeName eq 'lem' || $xn->nodeName eq 'rdg' ) {
 331             # Alter the current witnesses and recurse.
 332             #print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
 333             # TODO handle p.c. and s.l. designations too
 334             $ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
 335             my @rdg_wits = _get_sigla( $xn );
 336             return unless @rdg_wits;  # Skip readings that appear in no witnesses
 337             my @words;
 338             foreach ( $xn->childNodes ) {
 339                 my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
 340                 push( @words, @rdg_set ) if @rdg_set;
 341             }
 342             # If we have more than one word in a reading, it should become a segment.
 343             # $tradition->collation->add_segment( @words ) if @words > 1;
 344
 345             if( $ac ) {
 346                 # Add the reading set to the a.c. readings.
 347                 foreach ( @rdg_wits ) {
 348                     $app_ac->{$_}->{$current_app} = \@words;
 349                 }
 350             } else {
 351                 # Add the reading set to the app anchors for each witness
 352                 # or put in placeholders for empty p.c. readings
 353                 foreach ( @rdg_wits ) {
 354                     my $start = @words ? $words[0]->id : "PH-$current_app";
 355                     my $end = @words ? $words[-1]->id : "PH-$current_app";
 356                     $app_anchors->{$current_app}->{$_}->{'start'} = $start;
 357                     $app_anchors->{$current_app}->{$_}->{'end'} = $end;
 358                     push( @{$text->{$_}}, $start ) unless @words;
 359                 }
 360             }
 361             push( @new_readings, @words );
 362         } elsif( $xn->nodeName eq 'witStart' ) {
 363             # Add the relevant wit(s) to the active list.
 364             #print STDERR "Handling witStart\n";
 365             map { $active_wits{$_} = 1 } @cur_wits;
 366             # Record a lacuna in all non-active witnesses if this is
 367             # the first app. Get the full list from $text.
 368             if( $seen_apps == 1 ) {
 369                 my $i = 0;
 370                 foreach my $sig ( keys %$text ) {
 371                     next if $active_wits{$sig};
 372                     my $l = $tradition->collation->add_reading( {
 373                         'id' => $current_app . "_$i",
 374                         'is_lacuna' => 1 } );
 375                     $i++;
 376                     push( @{$text->{$sig}}, $l );
 377                 }
 378             }
 379         } elsif( $xn->nodeName eq 'witEnd' ) {
 380             # Take the relevant wit(s) out of the list.
 381             #print STDERR "Handling witEnd\n";
 382             map { $active_wits{$_} = undef } @cur_wits;
 383             # Record a lacuna, unless this is the last app.
 384             unless( $seen_apps == $app_count ) {
 385                 foreach my $i ( 0 .. $#cur_wits ) {
 386                     my $w = $cur_wits[$i];
 387                     my $l = $tradition->collation->add_reading( {
 388                         'id' => $current_app . "_$i",
 389                         'is_lacuna' => 1 } );
 390                     push( @{$text->{$w}}, $l );
 391                 }
 392             }
 393         } elsif( $xn->nodeName eq 'witDetail'
 394                          || $xn->nodeName eq 'note' ) {
 395             # Ignore these for now.
 396             return;
 397         } else {
 398             # Recurse as if this tag weren't there.
 399             #print STDERR "Recursing on tag " . $xn->nodeName . "\n";
 400             foreach( $xn->childNodes ) {
 401                 push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
 402             }
 403         }
 404         return @new_readings;
 405     }
 406
 407 }
 408
 409 =begin testing
 410
 411 use XML::LibXML;
 412 use XML::LibXML::XPathContext;
 413 use Text::Tradition::Parser::TEI;
 414
 415 my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
 416 my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
 417 my $xpc = XML::LibXML::XPathContext->new( $el );
 418 my $obj = $xpc->find( '//rdg' );
 419
 420 my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
 421 is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );
 422
 423 =end testing
 424
 425 =cut
 426
 427 # Helper to extract a list of witness sigla from a reading element.
 428 sub _get_sigla {
 429     my( $rdg ) = @_;
 430     # Cope if we have been handed a NodeList.  There is only
 431     # one reading here.
 432     if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
 433         $rdg = $rdg->shift;
 434     }
 435
 436     my @wits;
 437     if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
 438         my $witstr = $rdg->getAttribute( 'wit' );
 439         return () unless $witstr;
 440         $witstr =~ s/^\s+//;
 441         $witstr =~ s/\s+$//;
 442         @wits = split( /\s+/, $witstr );
 443         map { $_ =~ s/^\#// } @wits;
 444     }
 445     return @wits;
 446 }
 447
 448 # Helper with its counters to actually make the readings.
 449 {
 450     my $word_ctr = 0;
 451     my %used_nodeids;
 452
 453     sub _save_preexisting_nodeids {
 454         foreach( @_ ) {
 455             $used_nodeids{$_->getValue()} = 1;
 456         }
 457     }
 458
 459     sub _make_reading {
 460         my( $graph, $word, $xml_id ) = @_;
 461         if( $xml_id ) {
 462             if( exists $used_nodeids{$xml_id} ) {
 463                 if( $used_nodeids{$xml_id} != 1 ) {
 464                     warn "Already used assigned XML ID somewhere else!";
 465                     $xml_id = undef;
 466                 }
 467             } else {
 468                 warn "Undetected pre-existing XML ID";
 469             }
 470         }
 471         if( !$xml_id ) {
 472             until( $xml_id ) {
 473                 my $try_id = 'w'.$word_ctr++;
 474                 next if exists $used_nodeids{$try_id};
 475                 $xml_id = $try_id;
 476             }
 477         }
 478         my $rdg = $graph->add_reading(
 479                 { 'id' => $xml_id,
 480                   'text' => $word }
 481                 );
 482         $used_nodeids{$xml_id} = $rdg;
 483         return $rdg;
 484     }
 485 }
 486
 487 1;
 488
 489 =head1 BUGS / TODO
 490
 491 =over
 492
 493 =item * More unit testing
 494
 495 =item * Handle special designations apart from a.c.
 496
 497 =item * Mark common nodes within collated variants
 498
 499 =back
 500
 501 =head1 LICENSE
 502
 503 This package is free software and is provided "as is" without express
 504 or implied warranty.  You can redistribute it and/or modify it under
 505 the same terms as Perl itself.
 506
 507 =head1 AUTHOR
 508
 509 Tara L Andrews E<lt>aurum@cpan.orgE<gt>