lib/Text/Tradition/Parser/GraphML.pm

   1 package Text::Tradition::Parser::GraphML;
   2
   3 use strict;
   4 use warnings;
   5 use XML::LibXML;
   6 use XML::LibXML::XPathContext;
   7
   8 =head1 NAME
   9
  10 Text::Tradition::Parser::GraphML
  11
  12 =head1 DESCRIPTION
  13
  14 Parser module for Text::Tradition, given a GraphML file that describes
  15 a collation graph.  For further information on the GraphML format for
  16 text collation, see http://gregor.middell.net/collatex/
  17
  18 =head1 METHODS
  19
  20 =over
  21
  22 =item B<parse>
  23
  24 parse( $graph, $graphml_string );
  25
  26 Takes an initialized Text::Tradition::Graph object and a string
  27 containing the GraphML; creates the appropriate nodes and edges on the
  28 graph.
  29
  30 =cut
  31
  32 use vars qw/ $xpc %nodedata /;
  33
  34 sub parse {
  35     my( $tradition, $graphml_str ) = @_;
  36
  37     my $collation = $tradition->collation;
  38     my $parser = XML::LibXML->new();
  39     my $doc = $parser->parse_string( $graphml_str );
  40     my $graphml = $doc->documentElement();
  41     $xpc = XML::LibXML::XPathContext->new( $graphml );
  42     $xpc->registerNs( 'g', 'http://graphml.graphdrawing.org/xmlns' );
  43
  44     # First get the ID keys, for witnesses and for collation data
  45     my %witnesses;
  46     foreach my $k ( $xpc->findnodes( '//g:key' ) ) {
  47         # Each key has a 'for' attribute; the edge keys are witnesses, and
  48         # the node keys contain an ID and string for each node.
  49
  50         if( $k->getAttribute( 'for' ) eq 'node' ) {
  51             # The node data keys we expect are:
  52             # 'number|name' -> unique node identifier
  53             # 'token|reading' -> reading for the node
  54             # 'identical' -> the node of which this node is
  55             #                a transposed version
  56             # 'position' -> a calculated position for the node
  57             $nodedata{ $k->getAttribute( 'attr.name' ) } = $k->getAttribute( 'id' );
  58         } else {
  59             $witnesses{ $k->getAttribute( 'id' ) } = $k->getAttribute( 'attr.name' );
  60         }
  61     }
  62
  63     my $has_explicit_positions = defined $nodedata{'position'};
  64
  65     # Add the witnesses that we have found
  66     foreach my $wit ( values %witnesses ) {
  67         $tradition->add_witness( 'sigil' => $wit );
  68     }
  69
  70     my $graph_el = $xpc->find( '/g:graphml/g:graph' )->[0];
  71
  72     # Add the nodes to the graph.  First delete the start node, because
  73     # GraphML graphs will have their own start nodes.
  74     $collation->del_reading( $collation->start() );
  75     # Map from XML IDs to node name/identity
  76     my %node_name;
  77     # Keep track of whatever extra info we're passed
  78     my $extra_data = {};
  79     my @nodes = $xpc->findnodes( '//g:node' );
  80     foreach my $n ( @nodes ) {
  81         my $id = _lookup_node_data( $n, 'number' );
  82         $id = _lookup_node_data( $n, 'name' ) unless $id;
  83         my $token = _lookup_node_data( $n, 'token' );
  84         $token = _lookup_node_data( $n, 'reading' ) unless $token;
  85         my $gnode = $collation->add_reading( $id );
  86         $node_name{ $n->getAttribute('id') } = $id;
  87         $gnode->text( $token );
  88
  89         # Now get the rest of the data, i.e. not the ID or label
  90         my $extra = {};
  91         foreach my $k ( keys %nodedata ) {
  92             next if $k =~ /^(number|token)$/;
  93             $extra->{ $k } = _lookup_node_data( $n, $k );
  94         }
  95         $extra_data->{ $id } = $extra;
  96     }
  97
  98     # Now add the edges.
  99     my @edges = $xpc->findnodes( '//g:edge' );
 100     foreach my $e ( @edges ) {
 101         my $from = $node_name{ $e->getAttribute('source') };
 102         my $to = $node_name{ $e->getAttribute('target') };
 103         # Label according to the witnesses present.
 104         my @wit_ids = $xpc->findnodes( './g:data/attribute::key', $e );
 105         my @wit_names = map { $witnesses{ $_->getValue() } } @wit_ids;
 106         # One path per witness
 107         foreach( @wit_names ) {
 108             $collation->add_path( $from, $to, $_ );
 109         }
 110         # Only a single path between two readings
 111         # my $label = $collation->path_label( @wit_names );
 112         # $collation->add_path( $from, $to, $label );
 113     }
 114
 115     ## Reverse the node_name hash so that we have two-way lookup.
 116     my %node_id = reverse %node_name;
 117
 118     ## Record the nodes that are marked as transposed.
 119     my $tr_xpath = '//g:node[g:data[@key="' . $nodedata{'identical'} . '"]]';
 120     my $transposition_nodes = $xpc->find( $tr_xpath );
 121     foreach my $tn ( @$transposition_nodes ) {
 122         my $id_xpath = sprintf( './g:data[@key="%s"]/text()',
 123                                 $nodedata{'identical'} );
 124         $collation->reading( $node_id{ $tn->getAttribute( 'id' ) } )->
 125             set_identical( $collation->reading(
 126                                $node_name{ $xpc->findvalue( $id_xpath, $tn ) } ) );
 127     }
 128
 129     # Find the beginning and end nodes of the graph.  The beginning node
 130     # has no incoming edges; the end node has no outgoing edges.
 131     my( $begin_node, $end_node );
 132     foreach my $gnode ( $collation->readings() ) {
 133         # print STDERR "Checking node " . $gnode->name . "\n";
 134         my @outgoing = $gnode->outgoing();
 135         my @incoming = $gnode->incoming();
 136
 137         unless( scalar @incoming ) {
 138             warn "Already have a beginning node" if $begin_node;
 139             $begin_node = $gnode;
 140             $collation->start( $gnode );
 141         }
 142         unless( scalar @outgoing ) {
 143             warn "Already have an ending node" if $end_node;
 144             $end_node = $gnode;
 145         }
 146     }
 147
 148     my @common_nodes = $collation->walk_witness_paths( $end_node );
 149     # Now we have added the witnesses and their paths, so have also
 150     # implicitly marked the common nodes. Now we can calculate their
 151     # explicit permissions.  This is separate because it won't always
 152     # be necessary with the GraphML parsing.
 153     if( $has_explicit_positions ) {
 154         # Record the positions that came with each graph node.
 155         # TODO we really need to translate these into our own style of
 156         # position identifier.  That's why we defer this until now.
 157         foreach my $node_id ( keys %$extra_data ) {
 158             my $pos = $extra_data->{$node_id}->{'position'};
 159             $collation->reading( $node_name{$node_id} )->position( $pos );
 160         }
 161     } else {
 162         # Calculate a position for each graph node.
 163         $collation->calculate_positions( @common_nodes );
 164     }
 165 }
 166
 167 sub _lookup_node_data {
 168     my( $xmlnode, $key ) = @_;
 169     return undef unless exists $nodedata{$key};
 170     my $lookup_xpath = './g:data[@key="%s"]/child::text()';
 171     my $data = $xpc->findvalue( sprintf( $lookup_xpath, $nodedata{$key} ),
 172                                 $xmlnode );
 173     return $data;
 174 }
 175
 176 =back
 177
 178 =head1 LICENSE
 179
 180 This package is free software and is provided "as is" without express
 181 or implied warranty.  You can redistribute it and/or modify it under
 182 the same terms as Perl itself.
 183
 184 =head1 AUTHOR
 185
 186 Tara L Andrews, aurum@cpan.org
 187
 188 =cut
 189
 190 1;