lib/Text/Tradition/Collation.pm

   1 package Text::Tradition::Collation;
   2
   3 use Encode qw( decode_utf8 );
   4 use File::Temp;
   5 use Graph::Easy;
   6 use IPC::Run qw( run binary );
   7 use Text::CSV_XS;
   8 use Text::Tradition::Collation::Path;
   9 use Text::Tradition::Collation::Reading;
  10 use Text::Tradition::Collation::Relationship;
  11 use Text::Tradition::Collation::Segment;
  12 use XML::LibXML;
  13 use Moose;
  14
  15 has 'graph' => (
  16     is => 'ro',
  17     isa => 'Graph::Easy',
  18     handles => {
  19         add_reading => 'add_node',
  20         add_lacuna => 'add_node',
  21         del_reading => 'del_node',
  22         del_segment => 'del_node',
  23         add_path => 'add_edge',
  24         del_path => 'del_edge',
  25         reading => 'node',
  26         path => 'edge',
  27         readings => 'nodes',
  28         segments => 'nodes',
  29         paths => 'edges',
  30         relationships => 'edges',
  31     },
  32     default => sub { Graph::Easy->new( undirected => 0 ) },
  33     );
  34
  35
  36 has 'tradition' => (  # TODO should this not be ro?
  37     is => 'rw',
  38     isa => 'Text::Tradition',
  39     );
  40
  41 has 'svg' => (
  42     is => 'ro',
  43     isa => 'Str',
  44     writer => '_save_svg',
  45     predicate => 'has_svg',
  46     );
  47
  48 has 'graphml' => (
  49     is => 'ro',
  50     isa => 'Str',
  51     writer => '_save_graphml',
  52     predicate => 'has_graphml',
  53     );
  54
  55 has 'csv' => (
  56     is => 'ro',
  57     isa => 'Str',
  58     writer => '_save_csv',
  59     predicate => 'has_csv',
  60     );
  61
  62 # Keeps track of the lemmas within the collation.  At most one lemma
  63 # per position in the graph.
  64 has 'lemmata' => (
  65     is => 'ro',
  66     isa => 'HashRef[Maybe[Str]]',
  67     default => sub { {} },
  68     );
  69
  70 has 'wit_list_separator' => (
  71     is => 'rw',
  72     isa => 'Str',
  73     default => ', ',
  74     );
  75
  76 has 'baselabel' => (
  77     is => 'rw',
  78     isa => 'Str',
  79     default => 'base text',
  80     );
  81
  82 has 'collapsed' => (
  83     is => 'rw',
  84     isa => 'Bool',
  85     );
  86
  87 has 'linear' => (
  88     is => 'rw',
  89     isa => 'Bool',
  90     default => 1,
  91     );
  92
  93 has 'ac_label' => (
  94     is => 'rw',
  95     isa => 'Str',
  96     default => ' (a.c.)',
  97     );
  98
  99
 100 # The collation can be created two ways:
 101 # 1. Collate a set of witnesses (with CollateX I guess) and process
 102 #    the results as in 2.
 103 # 2. Read a pre-prepared collation in one of a variety of formats,
 104 #    and make the graph from that.
 105
 106 # The graph itself will (for now) be immutable, and the positions
 107 # within the graph will also be immutable.  We need to calculate those
 108 # positions upon graph construction.  The equivalences between graph
 109 # nodes will be mutable, entirely determined by the user (or possibly
 110 # by some semantic pre-processing provided by the user.)  So the
 111 # constructor should just make an empty equivalences object.  The
 112 # constructor will also need to make the witness objects, if we didn't
 113 # come through option 1.
 114
 115 sub BUILD {
 116     my( $self, $args ) = @_;
 117     $self->graph->use_class('node', 'Text::Tradition::Collation::Reading');
 118     $self->graph->use_class('edge', 'Text::Tradition::Collation::Path');
 119
 120     # Pass through any graph-specific options.
 121     my $shape = exists( $args->{'shape'} ) ? $args->{'shape'} : 'ellipse';
 122     $self->graph->set_attribute( 'node', 'shape', $shape );
 123 }
 124
 125 around add_lacuna => sub {
 126     my $orig = shift;
 127     my $self = shift;
 128     my $id = shift @_;
 129     my $l = $self->$orig( '#LACUNA_' . $id . '#' );
 130     $l->is_lacuna( 1 );
 131     return $l;
 132 };
 133
 134 # Wrapper around add_path
 135
 136 around add_path => sub {
 137     my $orig = shift;
 138     my $self = shift;
 139
 140     # Make sure there are three arguments
 141     unless( @_ == 3 ) {
 142         warn "Call add_path with args source, target, witness";
 143         return;
 144     }
 145     # Make sure the proposed path does not yet exist
 146     # NOTE 'reading' will currently return readings and segments
 147     my( $source, $target, $wit ) = @_;
 148     $source = $self->reading( $source )
 149         unless ref( $source ) eq 'Text::Tradition::Collation::Reading';
 150     $target = $self->reading( $target )
 151         unless ref( $target ) eq 'Text::Tradition::Collation::Reading';
 152     foreach my $path ( $source->edges_to( $target ) ) {
 153         if( $path->label eq $wit && $path->class eq 'edge.path' ) {
 154             return;
 155         }
 156     }
 157     # Do the deed
 158     $self->$orig( @_ );
 159 };
 160
 161 # Wrapper around paths
 162 around paths => sub {
 163     my $orig = shift;
 164     my $self = shift;
 165
 166     my @result = grep { $_->sub_class eq 'path' } $self->$orig( @_ );
 167     return @result;
 168 };
 169
 170 around relationships => sub {
 171     my $orig = shift;
 172     my $self = shift;
 173     my @result = grep { $_->sub_class eq 'relationship' } $self->$orig( @_ );
 174     return @result;
 175 };
 176
 177 around readings => sub {
 178     my $orig = shift;
 179     my $self = shift;
 180     my @result = grep { $_->sub_class ne 'segment' } $self->$orig( @_ );
 181     return @result;
 182 };
 183
 184 around segments => sub {
 185     my $orig = shift;
 186     my $self = shift;
 187     my @result = grep { $_->sub_class eq 'segment' } $self->$orig( @_ );
 188     return @result;
 189 };
 190
 191 # Wrapper around merge_nodes
 192
 193 sub merge_readings {
 194     my $self = shift;
 195     my $first_node = shift;
 196     my $second_node = shift;
 197     $first_node->merge_from( $second_node );
 198     unshift( @_, $first_node, $second_node );
 199     return $self->graph->merge_nodes( @_ );
 200 }
 201
 202 # Extra graph-alike utility
 203 sub has_path {
 204     my( $self, $source, $target, $label ) = @_;
 205     my @paths = $source->edges_to( $target );
 206     my @relevant = grep { $_->label eq $label } @paths;
 207     return scalar @relevant;
 208 }
 209
 210 ## Dealing with groups of readings, i.e. segments.
 211
 212 sub add_segment {
 213     my( $self, @items ) = @_;
 214     my $segment = Text::Tradition::Collation::Segment->new( 'members' => \@items );
 215     return $segment;
 216 }
 217
 218 ## Dealing with relationships between readings.  This is a different
 219 ## sort of graph edge.  Return a success/failure value and a list of
 220 ## node pairs that have been linked.
 221
 222 sub add_relationship {
 223     my( $self, $source, $target, $options ) = @_;
 224
 225     # Make sure there is not another relationship between these two
 226     # readings or segments already
 227     $source = $self->reading( $source )
 228         unless ref( $source ) && $source->isa( 'Graph::Easy::Node' );
 229     $target = $self->reading( $target )
 230         unless ref( $target ) && $target->isa( 'Graph::Easy::Node' );
 231     foreach my $rel ( $source->edges_to( $target ), $target->edges_to( $source ) ) {
 232         if( $rel->class eq 'edge.relationship' ) {
 233             return ( undef, "Relationship already exists between these readings" );
 234         }
 235     }
 236     if( $options->{'equal_rank'} && !relationship_valid( $source, $target ) ) {
 237         return ( undef, 'Relationship creates witness loop' );
 238     }
 239
 240     # TODO Think about positional hilarity if relationships are added after positions
 241     # are assigned.
 242
 243     my @joined = ( [ $source->name, $target->name ] );  # Keep track of the nodes we join.
 244
 245     $options->{'this_relation'} = [ $source, $target ];
 246     my $rel;
 247     eval { $rel = Text::Tradition::Collation::Relationship->new( %$options ) };
 248     if( $@ ) {
 249        return ( undef, $@ );
 250     }
 251     $self->graph->add_edge( $source, $target, $rel );
 252
 253     # TODO Handle global relationship setting
 254
 255     return( 1, @joined );
 256 }
 257
 258 sub relationship_valid {
 259     my( $source, $target ) = @_;
 260     # Check that linking the source and target in a relationship won't lead
 261     # to a path loop for any witness.
 262     my @proposed_related = ( $source, $target );
 263     push( @proposed_related, $source->related_readings );
 264     push( @proposed_related, $target->related_readings );
 265     my %pr_ids;
 266     map { $pr_ids{ $_->name } = 1 } @proposed_related;
 267     # The lists of 'in' and 'out' should not have any element that appears
 268     # in 'proposed_related'.
 269     foreach my $pr ( @proposed_related ) {
 270         foreach my $e ( $pr->incoming ) {
 271             if( exists $pr_ids{ $e->from->name } ) {
 272                 return 0;
 273             }
 274         }
 275         foreach my $e ( $pr->outgoing ) {
 276             if( exists $pr_ids{ $e->to->name } ) {
 277                 return 0;
 278             }
 279         }
 280     }
 281     return 1;
 282 }
 283
 284 =head2 Output method(s)
 285
 286 =over
 287
 288 =item B<as_svg>
 289
 290 print $graph->as_svg( $recalculate );
 291
 292 Returns an SVG string that represents the graph.  Uses GraphViz to do
 293 this, because Graph::Easy doesn\'t cope well with long graphs. Unless
 294 $recalculate is passed (and is a true value), the method will return a
 295 cached copy of the SVG after the first call to the method.
 296
 297 =cut
 298
 299 sub as_svg {
 300     my( $self, $recalc ) = @_;
 301     return $self->svg if $self->has_svg;
 302
 303     $self->collapse_graph_paths();
 304
 305     my @cmd = qw/dot -Tsvg/;
 306     my( $svg, $err );
 307     my $dotfile = File::Temp->new();
 308     ## TODO REMOVE
 309     # $dotfile->unlink_on_destroy(0);
 310     binmode $dotfile, ':utf8';
 311     print $dotfile $self->as_dot();
 312     push( @cmd, $dotfile->filename );
 313     run( \@cmd, ">", binary(), \$svg );
 314     $svg = decode_utf8( $svg );
 315     $self->_save_svg( $svg );
 316     $self->expand_graph_paths();
 317     return $svg;
 318 }
 319
 320 =item B<as_dot>
 321
 322 print $graph->as_dot( $view, $recalculate );
 323
 324 Returns a string that is the collation graph expressed in dot
 325 (i.e. GraphViz) format.  The 'view' argument determines what kind of
 326 graph is produced.
 327     * 'path': a graph of witness paths through the collation (DEFAULT)
 328     * 'relationship': a graph of how collation readings relate to
 329       each other
 330
 331 =cut
 332
 333 sub as_dot {
 334     my( $self, $view ) = @_;
 335     $view = 'path' unless $view;
 336     # TODO consider making some of these things configurable
 337     my $dot = sprintf( "digraph %s {\n", $self->tradition->name );
 338     $dot .= "\tedge [ arrowhead=open ];\n";
 339     $dot .= "\tgraph [ rankdir=LR ];\n";
 340     $dot .= sprintf( "\tnode [ fontsize=%d, fillcolor=%s, style=%s, shape=%s ];\n",
 341                      11, "white", "filled", $self->graph->get_attribute( 'node', 'shape' ) );
 342
 343     foreach my $reading ( $self->readings ) {
 344         # Need not output nodes without separate labels
 345         next if $reading->name eq $reading->label;
 346         # TODO output readings or segments, but not both
 347         next if $reading->class eq 'node.segment';
 348         $dot .= sprintf( "\t\"%s\" [ label=\"%s\" ];\n", $reading->name, $reading->label );
 349     }
 350
 351     my @edges = $view eq 'relationship' ? $self->relationships : $self->paths;
 352     foreach my $edge ( @edges ) {
 353         my %variables = ( 'color' => '#000000',
 354                           'fontcolor' => '#000000',
 355                           'label' => $edge->label,
 356             );
 357         my $varopts = join( ', ', map { $_.'="'.$variables{$_}.'"' } sort keys %variables );
 358         $dot .= sprintf( "\t\"%s\" -> \"%s\" [ %s ];\n",
 359                          $edge->from->name, $edge->to->name, $varopts );
 360     }
 361     $dot .= "}\n";
 362     return $dot;
 363 }
 364
 365 =item B<as_graphml>
 366
 367 print $graph->as_graphml( $recalculate )
 368
 369 Returns a GraphML representation of the collation graph, with
 370 transposition information and position information. Unless
 371 $recalculate is passed (and is a true value), the method will return a
 372 cached copy of the SVG after the first call to the method.
 373
 374 =cut
 375
 376 sub as_graphml {
 377     my( $self, $recalc ) = @_;
 378     return $self->graphml if $self->has_graphml;
 379
 380     # Some namespaces
 381     my $graphml_ns = 'http://graphml.graphdrawing.org/xmlns';
 382     my $xsi_ns = 'http://www.w3.org/2001/XMLSchema-instance';
 383     my $graphml_schema = 'http://graphml.graphdrawing.org/xmlns ' .
 384         'http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd';
 385
 386     # Create the document and root node
 387     my $graphml = XML::LibXML->createDocument( "1.0", "UTF-8" );
 388     my $root = $graphml->createElementNS( $graphml_ns, 'graphml' );
 389     $graphml->setDocumentElement( $root );
 390     $root->setNamespace( $xsi_ns, 'xsi', 0 );
 391     $root->setAttributeNS( $xsi_ns, 'schemaLocation', $graphml_schema );
 392
 393     # TODO Add some global graph data
 394
 395     # Add the data keys for nodes
 396     my %node_data_keys;
 397     my $ndi = 0;
 398     foreach my $datum ( qw/ name reading identical rank class / ) {
 399         $node_data_keys{$datum} = 'dn'.$ndi++;
 400         my $key = $root->addNewChild( $graphml_ns, 'key' );
 401         $key->setAttribute( 'attr.name', $datum );
 402         $key->setAttribute( 'attr.type', 'string' );
 403         $key->setAttribute( 'for', 'node' );
 404         $key->setAttribute( 'id', $node_data_keys{$datum} );
 405     }
 406
 407     # Add the data keys for edges, i.e. witnesses
 408     my $edi = 0;
 409     my %edge_data_keys;
 410     foreach my $edge_key( qw/ witness_main witness_ante_corr relationship class / ) {
 411         $edge_data_keys{$edge_key} = 'de'.$edi++;
 412         my $key = $root->addNewChild( $graphml_ns, 'key' );
 413         $key->setAttribute( 'attr.name', $edge_key );
 414         $key->setAttribute( 'attr.type', 'string' );
 415         $key->setAttribute( 'for', 'edge' );
 416         $key->setAttribute( 'id', $edge_data_keys{$edge_key} );
 417     }
 418
 419     # Add the graph, its nodes, and its edges
 420     my $graph = $root->addNewChild( $graphml_ns, 'graph' );
 421     $graph->setAttribute( 'edgedefault', 'directed' );
 422     $graph->setAttribute( 'id', 'g0' ); # TODO make this meaningful
 423     $graph->setAttribute( 'parse.edgeids', 'canonical' );
 424     $graph->setAttribute( 'parse.edges', scalar($self->paths) );
 425     $graph->setAttribute( 'parse.nodeids', 'canonical' );
 426     $graph->setAttribute( 'parse.nodes', scalar($self->readings) );
 427     $graph->setAttribute( 'parse.order', 'nodesfirst' );
 428
 429     my $node_ctr = 0;
 430     my %node_hash;
 431     # Add our readings to the graph
 432     foreach my $n ( sort { $a->name cmp $b->name } $self->readings ) {
 433         my $node_el = $graph->addNewChild( $graphml_ns, 'node' );
 434         my $node_xmlid = 'n' . $node_ctr++;
 435         $node_hash{ $n->name } = $node_xmlid;
 436         $node_el->setAttribute( 'id', $node_xmlid );
 437         _add_graphml_data( $node_el, $node_data_keys{'name'}, $n->name );
 438         _add_graphml_data( $node_el, $node_data_keys{'reading'}, $n->label );
 439         _add_graphml_data( $node_el, $node_data_keys{'rank'}, $n->rank )
 440             if $n->has_rank;
 441         _add_graphml_data( $node_el, $node_data_keys{'class'}, $n->sub_class );
 442         _add_graphml_data( $node_el, $node_data_keys{'identical'}, $n->primary->name )
 443             if $n->has_primary;
 444     }
 445
 446     # Add any segments we have
 447     foreach my $n ( sort { $a->name cmp $b->name } $self->segments ) {
 448         my $node_el = $graph->addNewChild( $graphml_ns, 'node' );
 449         my $node_xmlid = 'n' . $node_ctr++;
 450         $node_hash{ $n->name } = $node_xmlid;
 451         $node_el->setAttribute( 'id', $node_xmlid );
 452         _add_graphml_data( $node_el, $node_data_keys{'class'}, $n->sub_class );
 453         _add_graphml_data( $node_el, $node_data_keys{'name'}, $n->name );
 454     }
 455
 456     # Add the path, relationship, and segment edges
 457     my $edge_ctr = 0;
 458     foreach my $e ( sort { $a->from->name cmp $b->from->name } $self->graph->edges() ) {
 459         my( $name, $from, $to ) = ( 'e'.$edge_ctr++,
 460                                     $node_hash{ $e->from->name() },
 461                                     $node_hash{ $e->to->name() } );
 462         my $edge_el = $graph->addNewChild( $graphml_ns, 'edge' );
 463         $edge_el->setAttribute( 'source', $from );
 464         $edge_el->setAttribute( 'target', $to );
 465         $edge_el->setAttribute( 'id', $name );
 466         # Add the edge class
 467         _add_graphml_data( $edge_el, $edge_data_keys{'class'}, $e->sub_class );
 468         if( $e->sub_class eq 'path' ) {
 469             # It's a witness path, so add the witness
 470             my $base = $e->label;
 471             my $key = $edge_data_keys{'witness_main'};
 472             # TODO kind of hacky
 473             if( $e->label =~ /^(.*?)\s+(\(a\.c\.\))$/ ) {
 474                 $base = $1;
 475                 $key = $edge_data_keys{'witness_ante_corr'};
 476             }
 477             _add_graphml_data( $edge_el, $key, $base );
 478         } elsif( $e->sub_class eq 'relationship' ) {
 479             # It's a relationship
 480             _add_graphml_data( $edge_el, $edge_data_keys{'relationship'}, $e->label );
 481         } # else a segment, nothing to record but source, target, class
 482     }
 483
 484     # Return the thing
 485     $self->_save_graphml( $graphml->toString(1) );
 486     return $graphml->toString(1);
 487 }
 488
 489 sub _add_graphml_data {
 490     my( $el, $key, $value ) = @_;
 491     my $data_el = $el->addNewChild( $el->namespaceURI, 'data' );
 492     return unless defined $value;
 493     $data_el->setAttribute( 'key', $key );
 494     $data_el->appendText( $value );
 495 }
 496
 497 =item B<as_csv>
 498
 499 print $graph->as_csv( $recalculate )
 500
 501 Returns a CSV alignment table representation of the collation graph, one
 502 row per witness (or witness uncorrected.) Unless $recalculate is passed
 503 (and is a true value), the method will return a cached copy of the CSV
 504 after the first call to the method.
 505
 506 =cut
 507
 508 sub as_csv {
 509     my( $self, $recalc ) = @_;
 510     return $self->csv if $self->has_csv;
 511     my $table = $self->make_alignment_table;
 512     my $csv = Text::CSV_XS->new( { binary => 1, quote_null => 0 } );
 513     my @result;
 514     foreach my $row ( @$table ) {
 515         $csv->combine( @$row );
 516         push( @result, decode_utf8( $csv->string ) );
 517     }
 518     $self->_save_csv( join( "\n", @result ) );
 519     return $self->csv;
 520 }
 521
 522 # TODO Make an alignment table at the end of initialization to check for
 523 # duplicate nodes from mis-collation.
 524
 525
 526
 527 sub make_alignment_table {
 528     my( $self, $in_rows ) = shift;
 529     unless( $self->linear ) {
 530         warn "Need a linear graph in order to make an alignment table";
 531         return;
 532     }
 533     my $table;
 534     my @all_pos = sort { $a <=> $b } $self->possible_positions;
 535     foreach my $wit ( $self->tradition->witnesses ) {
 536         # print STDERR "Making witness row(s) for " . $wit->sigil . "\n";
 537         my @row = _make_witness_row( $wit->path, \@all_pos );
 538         unshift( @row, $wit->sigil );
 539         push( @$table, \@row );
 540         if( $wit->has_ante_corr ) {
 541             my @ac_row = _make_witness_row( $wit->uncorrected_path, \@all_pos );
 542             unshift( @ac_row, $wit->sigil . $self->ac_label );
 543             push( @$table, \@ac_row );
 544         }
 545     }
 546     return $table if $in_rows;
 547
 548     # Return a table where the witnesses read in columns rather than rows.
 549     my $turned = _turn_table( $table );
 550     return $turned;
 551 }
 552
 553 sub _make_witness_row {
 554     my( $path, $positions ) = @_;
 555     my %char_hash;
 556     map { $char_hash{$_} = undef } @$positions;
 557     foreach my $rdg ( @$path ) {
 558         my $rtext = $rdg->text;
 559         $rtext = '#LACUNA#' if $rdg->is_lacuna;
 560         $char_hash{$rdg->rank} = $rtext;
 561     }
 562     my @row = map { $char_hash{$_} } @$positions;
 563     # Fill in lacuna markers for undef spots in the row
 564     my $last_el = shift @row;
 565     my @filled_row = ( $last_el );
 566     foreach my $el ( @row ) {
 567         if( $last_el && $last_el eq '#LACUNA#' && !defined $el ) {
 568             $el = '#LACUNA#';
 569         }
 570         push( @filled_row, $el );
 571         $last_el = $el;
 572     }
 573     return @filled_row;
 574 }
 575
 576 # Helper to turn the witnesses along columns rather than rows.  Assumes
 577 # equal-sized rows.
 578 sub _turn_table {
 579     my( $table ) = @_;
 580     my $result = [];
 581     return $result unless scalar @$table;
 582     my $nrows = scalar @{$table->[0]};
 583     foreach my $idx ( 0 .. $nrows - 1 ) {
 584         foreach my $wit ( 0 .. $#{$table} ) {
 585             $result->[$idx]->[$wit] = $table->[$wit]->[$idx];
 586         }
 587     }
 588     return $result;
 589 }
 590
 591
 592 sub collapse_graph_paths {
 593     my $self = shift;
 594     # Our collation graph has an path per witness.  This is great for
 595     # calculation purposes, but terrible for display.  Thus we want to
 596     # display only one path between any two nodes.
 597
 598     return if $self->collapsed;
 599
 600     print STDERR "Collapsing witness paths in graph...\n";
 601
 602     # Don't list out every witness if we have more than half to list.
 603     my $majority = int( scalar( $self->tradition->witnesses ) / 2 ) + 1;
 604     # But don't compress if there are only a few witnesses.
 605     $majority = 4 if $majority < 4;
 606     foreach my $node ( $self->readings ) {
 607         my $newlabels = {};
 608         # We will visit each node, so we only look ahead.
 609         foreach my $edge ( $node->outgoing() ) {
 610             next unless $edge->class eq 'edge.path';
 611             add_hash_entry( $newlabels, $edge->to->name, $edge->name );
 612             $self->del_path( $edge );
 613         }
 614
 615         foreach my $newdest ( keys %$newlabels ) {
 616             my $label;
 617             my @compressed_wits = @{$newlabels->{$newdest}};
 618             if( @compressed_wits < $majority ) {
 619                 $label = join( ', ', sort( @{$newlabels->{$newdest}} ) );
 620             } else {
 621                 ## TODO FIX THIS HACK
 622                 my @aclabels;
 623                 foreach my $wit ( @compressed_wits ) {
 624                     push( @aclabels, $wit ) if( $wit =~ /^(.*?)(\s*\(?a\.\s*c\.\)?)$/ );
 625                 }
 626                 $label = join( ', ', 'majority', sort( @aclabels ) );
 627             }
 628
 629             my $newpath = $self->add_path( $node, $self->reading( $newdest ), $label );
 630             $newpath->hidden_witnesses( \@compressed_wits );
 631         }
 632     }
 633
 634     $self->collapsed( 1 );
 635 }
 636
 637 sub expand_graph_paths {
 638     my $self = shift;
 639     # Our collation graph has only one path between any two nodes.
 640     # This is great for display, but not so great for analysis.
 641     # Expand this so that each witness has its own path between any
 642     # two reading nodes.
 643     return unless $self->collapsed;
 644
 645     print STDERR "Expanding witness paths in graph...\n";
 646     foreach my $path( $self->paths ) {
 647         my $from = $path->from;
 648         my $to = $path->to;
 649         warn sprintf( "No hidden witnesses on %s -> %s ?", $from->name, $to->name )
 650             unless $path->has_hidden_witnesses;
 651         my @wits = @{$path->hidden_witnesses};
 652         $self->del_path( $path );
 653         foreach ( @wits ) {
 654             $self->add_path( $from, $to, $_ );
 655         }
 656     }
 657     $self->collapsed( 0 );
 658 }
 659
 660 =back
 661
 662 =head2 Navigation methods
 663
 664 =over
 665
 666 =item B<start>
 667
 668 my $beginning = $collation->start();
 669
 670 Returns the beginning of the collation, a meta-reading with label '#START#'.
 671
 672 =cut
 673
 674 sub start {
 675     # Return the beginning reading of the graph.
 676     my $self = shift;
 677     my( $new_start ) = @_;
 678     if( $new_start ) {
 679         $self->del_reading( '#START#' );
 680         $self->graph->rename_node( $new_start, '#START#' );
 681     }
 682     # Make sure the start node has a start position.
 683     unless( $self->reading( '#START#' )->has_rank ) {
 684         $self->reading( '#START#' )->rank( '0' );
 685     }
 686     return $self->reading('#START#');
 687 }
 688
 689 =item B<end>
 690
 691 my $end = $collation->end();
 692
 693 Returns the end of the collation, a meta-reading with label '#END#'.
 694
 695 =cut
 696
 697 sub end {
 698     my $self = shift;
 699     my( $new_end ) = @_;
 700     if( $new_end ) {
 701         $self->del_reading( '#END#' );
 702         $self->graph->rename_node( $new_end, '#END#' );
 703     }
 704     return $self->reading('#END#');
 705 }
 706
 707 =item B<reading_sequence>
 708
 709 my @readings = $graph->reading_sequence( $first, $last, $path[, $alt_path] );
 710
 711 Returns the ordered list of readings, starting with $first and ending
 712 with $last, along the given witness path.  If no path is specified,
 713 assume that the path is that of the base text (if any.)
 714
 715 =cut
 716
 717 # TODO Think about returning some lazy-eval iterator.
 718
 719 sub reading_sequence {
 720     my( $self, $start, $end, $witness, $backup ) = @_;
 721
 722     $witness = $self->baselabel unless $witness;
 723     my @readings = ( $start );
 724     my %seen;
 725     my $n = $start;
 726     while( $n && $n ne $end ) {
 727         if( exists( $seen{$n->name()} ) ) {
 728             warn "Detected loop at " . $n->name();
 729             last;
 730         }
 731         $seen{$n->name()} = 1;
 732
 733         my $next = $self->next_reading( $n, $witness, $backup );
 734         warn "Did not find any path for $witness from reading " . $n->name
 735             unless $next;
 736         push( @readings, $next );
 737         $n = $next;
 738     }
 739     # Check that the last reading is our end reading.
 740     my $last = $readings[$#readings];
 741     warn "Last reading found from " . $start->label() .
 742         " for witness $witness is not the end!"
 743         unless $last eq $end;
 744
 745     return @readings;
 746 }
 747
 748 =item B<next_reading>
 749
 750 my $next_reading = $graph->next_reading( $reading, $witpath );
 751
 752 Returns the reading that follows the given reading along the given witness
 753 path.
 754
 755 =cut
 756
 757 sub next_reading {
 758     # Return the successor via the corresponding path.
 759     my $self = shift;
 760     return $self->_find_linked_reading( 'next', @_ );
 761 }
 762
 763 =item B<prior_reading>
 764
 765 my $prior_reading = $graph->prior_reading( $reading, $witpath );
 766
 767 Returns the reading that precedes the given reading along the given witness
 768 path.
 769
 770 =cut
 771
 772 sub prior_reading {
 773     # Return the predecessor via the corresponding path.
 774     my $self = shift;
 775     return $self->_find_linked_reading( 'prior', @_ );
 776 }
 777
 778 sub _find_linked_reading {
 779     my( $self, $direction, $node, $path, $alt_path ) = @_;
 780     my @linked_paths = $direction eq 'next'
 781         ? $node->outgoing() : $node->incoming();
 782     return undef unless scalar( @linked_paths );
 783
 784     # We have to find the linked path that contains all of the
 785     # witnesses supplied in $path.
 786     my( @path_wits, @alt_path_wits );
 787     @path_wits = $self->witnesses_of_label( $path ) if $path;
 788     @alt_path_wits = $self->witnesses_of_label( $alt_path ) if $alt_path;
 789     my $base_le;
 790     my $alt_le;
 791     foreach my $le ( @linked_paths ) {
 792         if( $le->name eq $self->baselabel ) {
 793             $base_le = $le;
 794         } else {
 795             my @le_wits = $self->witnesses_of_label( $le->name );
 796             if( _is_within( \@path_wits, \@le_wits ) ) {
 797                 # This is the right path.
 798                 return $direction eq 'next' ? $le->to() : $le->from();
 799             } elsif( _is_within( \@alt_path_wits, \@le_wits ) ) {
 800                 $alt_le = $le;
 801             }
 802         }
 803     }
 804     # Got this far? Return the alternate path if it exists.
 805     return $direction eq 'next' ? $alt_le->to() : $alt_le->from()
 806         if $alt_le;
 807
 808     # Got this far? Return the base path if it exists.
 809     return $direction eq 'next' ? $base_le->to() : $base_le->from()
 810         if $base_le;
 811
 812     # Got this far? We have no appropriate path.
 813     warn "Could not find $direction node from " . $node->label
 814         . " along path $path";
 815     return undef;
 816 }
 817
 818 # Some set logic.
 819 sub _is_within {
 820     my( $set1, $set2 ) = @_;
 821     my $ret = @$set1; # will be 0, i.e. false, if set1 is empty
 822     foreach my $el ( @$set1 ) {
 823         $ret = 0 unless grep { /^\Q$el\E$/ } @$set2;
 824     }
 825     return $ret;
 826 }
 827
 828
 829 ## INITIALIZATION METHODS - for use by parsers
 830 # Walk the paths for each witness in the graph, and return the nodes
 831 # that the graph has in common.  If $using_base is true, some
 832 # different logic is needed.
 833 # NOTE This does not create paths; it merely finds common readings.
 834
 835 sub walk_witness_paths {
 836     my( $self ) = @_;
 837     # For each witness, walk the path through the graph.
 838     # Then we need to find the common nodes.
 839     # TODO This method is going to fall down if we have a very gappy
 840     # text in the collation.
 841     my $paths = {};
 842     my @common_readings;
 843     foreach my $wit ( $self->tradition->witnesses ) {
 844         my $curr_reading = $self->start;
 845         my @wit_path = $self->reading_sequence( $self->start, $self->end,
 846                                                 $wit->sigil );
 847         $wit->path( \@wit_path );
 848
 849         # Detect the common readings.
 850         @common_readings = _find_common( \@common_readings, \@wit_path );
 851     }
 852
 853     # Mark all the nodes as either common or not.
 854     foreach my $cn ( @common_readings ) {
 855         print STDERR "Setting " . $cn->name . " / " . $cn->label
 856             . " as common node\n";
 857         $cn->make_common;
 858     }
 859     foreach my $n ( $self->readings() ) {
 860         $n->make_variant unless $n->is_common;
 861     }
 862     # Return an array of the common nodes in order.
 863     return @common_readings;
 864 }
 865
 866 sub _find_common {
 867     my( $common_readings, $new_path ) = @_;
 868     my @cr;
 869     if( @$common_readings ) {
 870         foreach my $n ( @$new_path ) {
 871             push( @cr, $n ) if grep { $_ eq $n } @$common_readings;
 872         }
 873     } else {
 874         push( @cr, @$new_path );
 875     }
 876     return @cr;
 877 }
 878
 879 sub _remove_common {
 880     my( $common_readings, $divergence ) = @_;
 881     my @cr;
 882     my %diverged;
 883     map { $diverged{$_->name} = 1 } @$divergence;
 884     foreach( @$common_readings ) {
 885         push( @cr, $_ ) unless $diverged{$_->name};
 886     }
 887     return @cr;
 888 }
 889
 890
 891 # For use when a collation is constructed from a base text and an apparatus.
 892 # We have the sequences of readings and just need to add path edges.
 893
 894 sub make_witness_paths {
 895     my( $self ) = @_;
 896     foreach my $wit ( $self->tradition->witnesses ) {
 897         print STDERR "Making path for " . $wit->sigil . "\n";
 898         $self->make_witness_path( $wit );
 899     }
 900 }
 901
 902 sub make_witness_path {
 903     my( $self, $wit ) = @_;
 904     my @chain = @{$wit->path};
 905     my $sig = $wit->sigil;
 906     foreach my $idx ( 0 .. $#chain-1 ) {
 907         $self->add_path( $chain[$idx], $chain[$idx+1], $sig );
 908     }
 909     if( $wit->has_ante_corr ) {
 910         @chain = @{$wit->uncorrected_path};
 911         foreach my $idx( 0 .. $#chain-1 ) {
 912             my $source = $chain[$idx];
 913             my $target = $chain[$idx+1];
 914             $self->add_path( $source, $target, $sig.$self->ac_label )
 915                 unless $self->has_path( $source, $target, $sig );
 916         }
 917     }
 918 }
 919
 920 sub calculate_ranks {
 921     my $self = shift;
 922     # Walk a version of the graph where every node linked by a relationship
 923     # edge is fundamentally the same node, and do a topological ranking on
 924     # the nodes in this graph.
 925     my $topo_graph = Graph::Easy->new();
 926     my %rel_containers;
 927     my $rel_ctr = 0;
 928     # Add the nodes
 929     foreach my $r ( $self->readings ) {
 930         next if exists $rel_containers{$r->name};
 931         my @rels = $r->related_readings( 'colocated' );
 932         if( @rels ) {
 933             # Make a relationship container.
 934             push( @rels, $r );
 935             my $rn = $topo_graph->add_node( 'rel_container_' . $rel_ctr++ );
 936             foreach( @rels ) {
 937                 $rel_containers{$_->name} = $rn;
 938             }
 939         } else {
 940             # Add a new node to mirror the old node.
 941             $rel_containers{$r->name} = $topo_graph->add_node( $r->name );
 942         }
 943     }
 944
 945     # Add the edges. Need only one edge between any pair of nodes.
 946     foreach my $r ( $self->readings ) {
 947         foreach my $n ( $r->neighbor_readings( 'forward' ) ) {
 948             $topo_graph->add_edge_once( $rel_containers{$r->name},
 949                                         $rel_containers{$n->name} );
 950         }
 951     }
 952
 953     # Now do the rankings, starting with the start node.
 954     my $topo_start = $rel_containers{$self->start->name};
 955     my $node_ranks = { $topo_start->name => 0 };
 956     my @curr_origin = ( $topo_start );
 957     # A little iterative function.
 958     while( @curr_origin ) {
 959         @curr_origin = _assign_rank( $node_ranks, @curr_origin );
 960     }
 961     # Transfer our rankings from the topological graph to the real one.
 962     foreach my $r ( $self->readings ) {
 963         $r->rank( $node_ranks->{$rel_containers{$r->name}->name} );
 964     }
 965 }
 966
 967 sub _assign_rank {
 968     my( $node_ranks, @current_nodes ) = @_;
 969     # Look at each of the children of @current_nodes.  If all the child's
 970     # parents have a rank, assign it the highest rank + 1 and add it to
 971     # @next_nodes.  Otherwise skip it.
 972     my @next_nodes;
 973     foreach my $c ( @current_nodes ) {
 974         warn "Current reading " . $c->name . "has no rank!"
 975             unless exists $node_ranks->{$c->name};
 976         # print STDERR "Looking at child of node " . $c->name . ", rank "
 977         #     . $node_ranks->{$c->name} . "\n";
 978         my @children = map { $_->to } $c->outgoing;
 979         foreach my $child ( @children ) {
 980             next if exists $node_ranks->{$child->name};
 981             my $highest_rank = -1;
 982             my $skip = 0;
 983             my @parents = map { $_->from } $child->incoming;
 984             foreach my $parent ( @parents ) {
 985                 if( exists $node_ranks->{$parent->name} ) {
 986                     $highest_rank = $node_ranks->{$parent->name}
 987                         if $highest_rank <= $node_ranks->{$parent->name};
 988                 } else {
 989                     $skip = 1;
 990                     last;
 991                 }
 992             }
 993             next if $skip;
 994             # print STDERR "Assigning rank " . ( $highest_rank + 1 ) . " to node " . $child->name . "\n";
 995             $node_ranks->{$child->name} = $highest_rank + 1;
 996             push( @next_nodes, $child );
 997         }
 998     }
 999     return @next_nodes;
1000 }
1001
1002 sub possible_positions {
1003     my $self = shift;
1004     my %all_pos;
1005     map { $all_pos{ $_->rank } = 1 } $self->readings;
1006     return keys %all_pos;
1007 }
1008
1009 # TODO think about indexing this.
1010 sub readings_at_position {
1011     my( $self, $position, $strict ) = @_;
1012     my @answer;
1013     foreach my $r ( $self->readings ) {
1014         push( @answer, $r ) if $r->is_at_position( $position, $strict );
1015     }
1016     return @answer;
1017 }
1018
1019 ## Lemmatizer functions
1020
1021 sub init_lemmata {
1022     my $self = shift;
1023
1024     foreach my $position ( $self->possible_positions ) {
1025         $self->lemmata->{$position} = undef;
1026     }
1027
1028     foreach my $cr ( $self->common_readings ) {
1029         $self->lemmata->{$cr->position->maxref} = $cr->name;
1030     }
1031 }
1032
1033 sub common_readings {
1034     my $self = shift;
1035     my @common = grep { $_->is_common } $self->readings();
1036     return sort { $a->rank <=> $b->rank } @common;
1037 }
1038
1039 =item B<lemma_readings>
1040
1041 my @state = $graph->lemma_readings( @readings_delemmatized );
1042
1043 Takes a list of readings that have just been delemmatized, and returns
1044 a set of tuples of the form ['reading', 'state'] that indicates what
1045 changes need to be made to the graph.
1046
1047 =over
1048
1049 =item *
1050
1051 A state of 1 means 'lemmatize this reading'
1052
1053 =item *
1054
1055 A state of 0 means 'delemmatize this reading'
1056
1057 =item *
1058
1059 A state of undef means 'an ellipsis belongs in the text here because
1060 no decision has been made / an earlier decision was backed out'
1061
1062 =back
1063
1064 =cut
1065
1066 sub lemma_readings {
1067     my( $self, @toggled_off_nodes ) = @_;
1068
1069     # First get the positions of those nodes which have been
1070     # toggled off.
1071     my $positions_off = {};
1072     map { $positions_off->{ $_->position->reference } = $_->name }
1073         @toggled_off_nodes;
1074
1075     # Now for each position, we have to see if a node is on, and we
1076     # have to see if a node has been turned off.  The lemmata hash
1077     # should contain fixed positions, range positions whose node was
1078     # just turned off, and range positions whose node is on.
1079     my @answer;
1080     my %fixed_positions;
1081     # TODO One of these is probably redundant.
1082     map { $fixed_positions{$_} = 0 } keys %{$self->lemmata};
1083     map { $fixed_positions{$_} = 0 } keys %{$positions_off};
1084     map { $fixed_positions{$_} = 1 } $self->possible_positions;
1085     foreach my $pos ( sort { Text::Tradition::Collation::Position::str_cmp( $a, $b ) } keys %fixed_positions ) {
1086         # Find the state of this position.  If there is an active node,
1087         # its name will be the state; otherwise the state will be 0
1088         # (nothing at this position) or undef (ellipsis at this position)
1089         my $active = undef;
1090         $active = $self->lemmata->{$pos} if exists $self->lemmata->{$pos};
1091
1092         # Is there a formerly active node that was toggled off?
1093         if( exists( $positions_off->{$pos} ) ) {
1094             my $off_node = $positions_off->{$pos};
1095             if( $active && $active ne $off_node) {
1096                 push( @answer, [ $off_node, 0 ], [ $active, 1 ] );
1097             } else {
1098                 unless( $fixed_positions{$pos} ) {
1099                     $active = 0;
1100                     delete $self->lemmata->{$pos};
1101                 }
1102                 push( @answer, [ $off_node, $active ] );
1103             }
1104
1105         # No formerly active node, so we just see if there is a currently
1106         # active one.
1107         } elsif( $active ) {
1108             # Push the active node, whatever it is.
1109             push( @answer, [ $active, 1 ] );
1110         } else {
1111             # Push the state that is there. Arbitrarily use the first node
1112             # at that position.
1113             my @pos_nodes = $self->readings_at_position( $pos );
1114             push( @answer, [ $pos_nodes[0]->name, $self->lemmata->{$pos} ] );
1115             delete $self->lemmata->{$pos} unless $fixed_positions{$pos};
1116         }
1117     }
1118
1119     return @answer;
1120 }
1121
1122 =item B<toggle_reading>
1123
1124 my @readings_delemmatized = $graph->toggle_reading( $reading_name );
1125
1126 Takes a reading node name, and either lemmatizes or de-lemmatizes
1127 it. Returns a list of all readings that are de-lemmatized as a result
1128 of the toggle.
1129
1130 =cut
1131
1132 sub toggle_reading {
1133     my( $self, $rname ) = @_;
1134
1135     return unless $rname;
1136     my $reading = $self->reading( $rname );
1137     if( !$reading || $reading->is_common() ) {
1138         # Do nothing, it's a common node.
1139         return;
1140     }
1141
1142     my $pos = $reading->position;
1143     my $fixed = $reading->position->fixed;
1144     my $old_state = $self->lemmata->{$pos->reference};
1145
1146     my @readings_off;
1147     if( $old_state && $old_state eq $rname ) {
1148         # Turn off the node. We turn on no others by default.
1149         push( @readings_off, $reading );
1150     } else {
1151         # Turn on the node.
1152         $self->lemmata->{$pos->reference} = $rname;
1153         # Any other 'on' readings in the same position should be off
1154         # if we have a fixed position.
1155         push( @readings_off, $self->same_position_as( $reading, 1 ) )
1156             if $pos->fixed;
1157         # Any node that is an identical transposed one should be off.
1158         push( @readings_off, $reading->identical_readings );
1159     }
1160     @readings_off = unique_list( @readings_off );
1161
1162     # Turn off the readings that need to be turned off.
1163     my @readings_delemmatized;
1164     foreach my $n ( @readings_off ) {
1165         my $npos = $n->position;
1166         my $state = undef;
1167         $state = $self->lemmata->{$npos->reference}
1168             if defined $self->lemmata->{$npos->reference};
1169         if( $state && $state eq $n->name ) {
1170             # this reading is still on, so turn it off
1171             push( @readings_delemmatized, $n );
1172             my $new_state = undef;
1173             if( $npos->fixed && $n eq $reading ) {
1174                 # This is the reading that was clicked, so if there are no
1175                 # other readings there and this is a fixed position, turn off
1176                 # the position.  In all other cases, restore the ellipsis.
1177                 my @other_n = $self->same_position_as( $n ); # TODO do we need strict?
1178                 $new_state = 0 unless @other_n;
1179             }
1180             $self->lemmata->{$npos->reference} = $new_state;
1181         } elsif( $old_state && $old_state eq $n->name ) {
1182             # another reading has already been turned on here
1183             push( @readings_delemmatized, $n );
1184         } # else some other reading was on anyway, so pass.
1185     }
1186     return @readings_delemmatized;
1187 }
1188
1189 sub same_position_as {
1190     my( $self, $reading, $strict ) = @_;
1191     my $pos = $reading->position;
1192     my %onpath = ( $reading->name => 1 );
1193     # TODO This might not always be sufficient.  We really want to
1194     # exclude all readings on this one's path between its two
1195     # common points.
1196     map { $onpath{$_->name} = 1 } $reading->neighbor_readings;
1197     my @same = grep { !$onpath{$_->name} }
1198         $self->readings_at_position( $reading->position, $strict );
1199     return @same;
1200 }
1201
1202 # Return the string that joins together a list of witnesses for
1203 # display on a single path.
1204 sub path_label {
1205     my $self = shift;
1206     return join( $self->wit_list_separator, @_ );
1207 }
1208
1209 sub witnesses_of_label {
1210     my( $self, $label ) = @_;
1211     my $regex = $self->wit_list_separator;
1212     my @answer = split( /\Q$regex\E/, $label );
1213     return @answer;
1214 }
1215
1216 sub unique_list {
1217     my( @list ) = @_;
1218     my %h;
1219     map { $h{$_->name} = $_ } @list;
1220     return values( %h );
1221 }
1222
1223 sub add_hash_entry {
1224     my( $hash, $key, $entry ) = @_;
1225     if( exists $hash->{$key} ) {
1226         push( @{$hash->{$key}}, $entry );
1227     } else {
1228         $hash->{$key} = [ $entry ];
1229     }
1230 }
1231
1232 no Moose;
1233 __PACKAGE__->meta->make_immutable;