lib/Text/Tradition/Collation.pm

   1 package Text::Tradition::Collation;
   2
   3 use Encode qw( decode_utf8 );
   4 use File::Temp;
   5 use Graph;
   6 use IPC::Run qw( run binary );
   7 use Text::CSV_XS;
   8 use Text::Tradition::Collation::Reading;
   9 use Text::Tradition::Collation::RelationshipStore;
  10 use XML::LibXML;
  11 use Moose;
  12
  13 has 'sequence' => (
  14     is => 'ro',
  15     isa => 'Graph',
  16     default => sub { Graph->new() },
  17     handles => {
  18         paths => 'edges',
  19     },
  20     );
  21
  22 has 'relations' => (
  23         is => 'ro',
  24         isa => 'Text::Tradition::Collation::RelationshipStore',
  25         handles => {
  26                 relationships => 'relationships',
  27                 related_readings => 'related_readings',
  28         },
  29         writer => '_set_relations',
  30         );
  31
  32 has 'tradition' => (
  33     is => 'ro',
  34     isa => 'Text::Tradition',
  35     weak_ref => 1,
  36     );
  37
  38 has 'readings' => (
  39         isa => 'HashRef[Text::Tradition::Collation::Reading]',
  40         traits => ['Hash'],
  41     handles => {
  42         reading     => 'get',
  43         _add_reading => 'set',
  44         del_reading => 'delete',
  45         has_reading => 'exists',
  46         readings   => 'values',
  47     },
  48     default => sub { {} },
  49         );
  50
  51 has 'wit_list_separator' => (
  52     is => 'rw',
  53     isa => 'Str',
  54     default => ', ',
  55     );
  56
  57 has 'baselabel' => (
  58     is => 'rw',
  59     isa => 'Str',
  60     default => 'base text',
  61     );
  62
  63 has 'linear' => (
  64     is => 'rw',
  65     isa => 'Bool',
  66     default => 1,
  67     );
  68
  69 has 'collapse_punctuation' => (
  70         is => 'rw',
  71         isa => 'Bool',
  72         default => 1,
  73         );
  74
  75 has 'ac_label' => (
  76     is => 'rw',
  77     isa => 'Str',
  78     default => ' (a.c.)',
  79     );
  80
  81 has 'start' => (
  82         is => 'ro',
  83         isa => 'Text::Tradition::Collation::Reading',
  84         writer => '_set_start',
  85         weak_ref => 1,
  86         );
  87
  88 has 'end' => (
  89         is => 'ro',
  90         isa => 'Text::Tradition::Collation::Reading',
  91         writer => '_set_end',
  92         weak_ref => 1,
  93         );
  94
  95 # The collation can be created two ways:
  96 # 1. Collate a set of witnesses (with CollateX I guess) and process
  97 #    the results as in 2.
  98 # 2. Read a pre-prepared collation in one of a variety of formats,
  99 #    and make the graph from that.
 100
 101 # The graph itself will (for now) be immutable, and the positions
 102 # within the graph will also be immutable.  We need to calculate those
 103 # positions upon graph construction.  The equivalences between graph
 104 # nodes will be mutable, entirely determined by the user (or possibly
 105 # by some semantic pre-processing provided by the user.)  So the
 106 # constructor should just make an empty equivalences object.  The
 107 # constructor will also need to make the witness objects, if we didn't
 108 # come through option 1.
 109
 110 sub BUILD {
 111     my $self = shift;
 112     $self->_set_relations( Text::Tradition::Collation::RelationshipStore->new( 'collation' => $self ) );
 113     $self->_set_start( $self->add_reading( { 'collation' => $self, 'is_start' => 1 } ) );
 114     $self->_set_end( $self->add_reading( { 'collation' => $self, 'is_end' => 1 } ) );
 115 }
 116
 117 ### Reading construct/destruct functions
 118
 119 sub add_reading {
 120         my( $self, $reading ) = @_;
 121         unless( ref( $reading ) eq 'Text::Tradition::Collation::Reading' ) {
 122                 my %args = %$reading;
 123                 $reading = Text::Tradition::Collation::Reading->new(
 124                         'collation' => $self,
 125                         %args );
 126         }
 127         # First check to see if a reading with this ID exists.
 128         if( $self->reading( $reading->id ) ) {
 129                 warn "Collation already has a reading with id " . $reading->id;
 130                 return undef;
 131         }
 132         $self->_add_reading( $reading->id => $reading );
 133         # Once the reading has been added, put it in both graphs.
 134         $self->sequence->add_vertex( $reading->id );
 135         $self->relations->add_reading( $reading->id );
 136         return $reading;
 137 };
 138
 139 around del_reading => sub {
 140         my $orig = shift;
 141         my $self = shift;
 142         my $arg = shift;
 143
 144         if( ref( $arg ) eq 'Text::Tradition::Collation::Reading' ) {
 145                 $arg = $arg->id;
 146         }
 147         # Remove the reading from the graphs.
 148         $self->sequence->delete_vertex( $arg );
 149         $self->relations->delete_reading( $arg );
 150
 151         # Carry on.
 152         $self->$orig( $arg );
 153 };
 154
 155 # merge_readings( $main, $to_be_deleted );
 156
 157 sub merge_readings {
 158         my $self = shift;
 159
 160         # We only need the IDs for adding paths to the graph, not the reading
 161         # objects themselves.
 162     my( $kept, $deleted, $combine_char ) = $self->_stringify_args( @_ );
 163
 164     # The kept reading should inherit the paths and the relationships
 165     # of the deleted reading.
 166         foreach my $path ( $self->sequence->edges_at( $deleted ) ) {
 167                 my @vector = ( $kept );
 168                 push( @vector, $path->[1] ) if $path->[0] eq $deleted;
 169                 unshift( @vector, $path->[0] ) if $path->[1] eq $deleted;
 170                 next if $vector[0] eq $vector[1]; # Don't add a self loop
 171                 my %wits = %{$self->sequence->get_edge_attributes( @$path )};
 172                 $self->sequence->add_edge( @vector );
 173                 my $fwits = $self->sequence->get_edge_attributes( @vector );
 174                 @wits{keys %$fwits} = values %$fwits;
 175                 $self->sequence->set_edge_attributes( @vector, \%wits );
 176         }
 177         $self->relations->merge_readings( $kept, $deleted, $combine_char );
 178
 179         # Do the deletion deed.
 180         if( $combine_char ) {
 181                 my $kept_obj = $self->reading( $kept );
 182                 my $new_text = join( $combine_char, $kept_obj->text,
 183                         $self->reading( $deleted )->text );
 184                 $kept_obj->alter_text( $new_text );
 185         }
 186         $self->del_reading( $deleted );
 187 }
 188
 189
 190 # Helper function for manipulating the graph.
 191 sub _stringify_args {
 192         my( $self, $first, $second, $arg ) = @_;
 193     $first = $first->id
 194         if ref( $first ) eq 'Text::Tradition::Collation::Reading';
 195     $second = $second->id
 196         if ref( $second ) eq 'Text::Tradition::Collation::Reading';
 197     return( $first, $second, $arg );
 198 }
 199
 200 ### Path logic
 201
 202 sub add_path {
 203         my $self = shift;
 204
 205         # We only need the IDs for adding paths to the graph, not the reading
 206         # objects themselves.
 207     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 208
 209         # Connect the readings
 210     $self->sequence->add_edge( $source, $target );
 211     # Note the witness in question
 212     $self->sequence->set_edge_attribute( $source, $target, $wit, 1 );
 213 };
 214
 215 sub del_path {
 216         my $self = shift;
 217         my @args;
 218         if( ref( $_[0] ) eq 'ARRAY' ) {
 219                 my $e = shift @_;
 220                 @args = ( @$e, @_ );
 221         } else {
 222                 @args = @_;
 223         }
 224
 225         # We only need the IDs for adding paths to the graph, not the reading
 226         # objects themselves.
 227     my( $source, $target, $wit ) = $self->_stringify_args( @args );
 228
 229         if( $self->sequence->has_edge_attribute( $source, $target, $wit ) ) {
 230                 $self->sequence->delete_edge_attribute( $source, $target, $wit );
 231         }
 232         unless( keys %{$self->sequence->get_edge_attributes( $source, $target )} ) {
 233                 $self->sequence->delete_edge( $source, $target );
 234         }
 235 }
 236
 237
 238 # Extra graph-alike utility
 239 sub has_path {
 240         my $self = shift;
 241     my( $source, $target, $wit ) = $self->_stringify_args( @_ );
 242         return undef unless $self->sequence->has_edge( $source, $target );
 243         return $self->sequence->has_edge_attribute( $source, $target, $wit );
 244 }
 245
 246 =head2 add_relationship( $reading1, $reading2, $definition )
 247
 248 Adds the specified relationship between the two readings.  A relationship
 249 is transitive (i.e. undirected); the options for its definition may be found
 250 in Text::Tradition::Collation::Relationship.
 251
 252 =cut
 253
 254 # Wouldn't it be lovely if edges could be objects, and all this type checking
 255 # and attribute management could be done via Moose?
 256
 257 sub add_relationship {
 258         my $self = shift;
 259     my( $source, $target, $opts ) = $self->_stringify_args( @_ );
 260     my( $ret, @vectors ) = $self->relations->add_relationship( $source,
 261         $self->reading( $source ), $target, $self->reading( $target ), $opts );
 262     # Force a full rank recalculation every time. Yuck.
 263     $self->calculate_ranks() if $ret && $self->end->has_rank;
 264     return( $ret, @vectors );
 265 }
 266
 267 =head2 reading_witnesses( $reading )
 268
 269 Return a list of sigils corresponding to the witnesses in which the reading appears.
 270
 271 =cut
 272
 273 sub reading_witnesses {
 274         my( $self, $reading ) = @_;
 275         # We need only check either the incoming or the outgoing edges; I have
 276         # arbitrarily chosen "incoming".  Thus, special-case the start node.
 277         if( $reading eq $self->start ) {
 278                 return map { $_->sigil } $self->tradition->witnesses;
 279         }
 280         my %all_witnesses;
 281         foreach my $e ( $self->sequence->edges_to( $reading ) ) {
 282                 my $wits = $self->sequence->get_edge_attributes( @$e );
 283                 @all_witnesses{ keys %$wits } = 1;
 284         }
 285         return keys %all_witnesses;
 286 }
 287
 288 =head2 Output method(s)
 289
 290 =over
 291
 292 =item B<as_svg>
 293
 294 print $collation->as_svg();
 295
 296 Returns an SVG string that represents the graph, via as_dot and graphviz.
 297
 298 =cut
 299
 300 sub as_svg {
 301     my( $self ) = @_;
 302
 303     my @cmd = qw/dot -Tsvg/;
 304     my( $svg, $err );
 305     my $dotfile = File::Temp->new();
 306     ## TODO REMOVE
 307     # $dotfile->unlink_on_destroy(0);
 308     binmode $dotfile, ':utf8';
 309     print $dotfile $self->as_dot();
 310     push( @cmd, $dotfile->filename );
 311     run( \@cmd, ">", binary(), \$svg );
 312     $svg = decode_utf8( $svg );
 313     return $svg;
 314 }
 315
 316 =item B<svg_subgraph>
 317
 318 print $collation->svg_subgraph( $from, $to )
 319
 320 Returns an SVG string that represents the portion of the graph given by the
 321 specified range.  The $from and $to variables refer to ranks within the graph.
 322
 323 =cut
 324
 325 sub svg_subgraph {
 326     my( $self, $from, $to ) = @_;
 327
 328     my $dot = $self->as_dot( $from, $to );
 329     unless( $dot ) {
 330         warn "Could not output a graph with range $from - $to";
 331         return;
 332     }
 333
 334     my @cmd = qw/dot -Tsvg/;
 335     my( $svg, $err );
 336     my $dotfile = File::Temp->new();
 337     ## TODO REMOVE
 338     # $dotfile->unlink_on_destroy(0);
 339     binmode $dotfile, ':utf8';
 340     print $dotfile $dot;
 341     push( @cmd, $dotfile->filename );
 342     run( \@cmd, ">", binary(), \$svg );
 343     $svg = decode_utf8( $svg );
 344     return $svg;
 345 }
 346
 347
 348 =item B<as_dot>
 349
 350 print $collation->as_dot();
 351
 352 Returns a string that is the collation graph expressed in dot
 353 (i.e. GraphViz) format.  The 'view' argument determines what kind of
 354 graph is produced.
 355     * 'path': a graph of witness paths through the collation (DEFAULT)
 356     * 'relationship': a graph of how collation readings relate to
 357       each other
 358
 359 =cut
 360
 361 sub as_dot {
 362     my( $self, $startrank, $endrank ) = @_;
 363
 364     # Check the arguments
 365     if( $startrank ) {
 366         return if $endrank && $startrank > $endrank;
 367         return if $startrank > $self->end->rank;
 368         }
 369         if( defined $endrank ) {
 370                 return if $endrank < 0;
 371                 $endrank = undef if $endrank == $self->end->rank;
 372         }
 373
 374     # TODO consider making some of these things configurable
 375     my $graph_name = $self->tradition->name;
 376     $graph_name =~ s/[^\w\s]//g;
 377     $graph_name = join( '_', split( /\s+/, $graph_name ) );
 378     my $dot = sprintf( "digraph %s {\n", $graph_name );
 379     $dot .= "\tedge [ arrowhead=open ];\n";
 380     $dot .= "\tgraph [ rankdir=LR,bgcolor=none ];\n";
 381     $dot .= sprintf( "\tnode [ fontsize=%d, fillcolor=%s, style=%s, shape=%s ];\n",
 382                      11, "white", "filled", "ellipse" );
 383
 384         # Output substitute start/end readings if necessary
 385         if( $startrank ) {
 386                 $dot .= "\t\"#SUBSTART#\" [ label=\"...\" ];\n";
 387         }
 388         if( $endrank ) {
 389                 $dot .= "\t\"#SUBEND#\" [ label=\"...\" ];\n";
 390         }
 391         my %used;  # Keep track of the readings that actually appear in the graph
 392         my %subedges;
 393         my %subend;
 394     foreach my $reading ( $self->readings ) {
 395         # Only output readings within our rank range.
 396         next if $startrank && $reading->rank < $startrank;
 397         next if $endrank && $reading->rank > $endrank;
 398         $used{$reading->id} = 1;
 399         $subedges{$reading->id} = '#SUBSTART#'
 400                 if $startrank && $startrank == $reading->rank;
 401         $subedges{$reading->id} = '#SUBEND#'
 402                 if $endrank && $endrank == $reading->rank;
 403         # Need not output nodes without separate labels
 404         next if $reading->id eq $reading->text;
 405         my $label = $reading->punctuated_form;
 406         $label =~ s/\"/\\\"/g;
 407         $dot .= sprintf( "\t\"%s\" [ label=\"%s\" ];\n", $reading->id, $label );
 408     }
 409
 410     # Add substitute start and end edges if necessary
 411     foreach my $node ( keys %subedges ) {
 412                 my @vector = ( $subedges{$node}, $node );
 413                 @vector = reverse( @vector ) if $vector[0] =~ /END/;
 414         my $witstr = join( ', ', sort $self->reading_witnesses( $self->reading( $node ) ) );
 415         my %variables = ( 'color' => '#000000',
 416                           'fontcolor' => '#000000',
 417                           'label' => $witstr,
 418             );
 419         my $varopts = join( ', ', map { $_.'="'.$variables{$_}.'"' } sort keys %variables );
 420                 $dot .= sprintf( "\t\"%s\" -> \"%s\" [ %s ];\n", @vector, $varopts );
 421         }
 422
 423         # Add the real edges
 424     my @edges = $self->paths;
 425     foreach my $edge ( @edges ) {
 426         # Do we need to output this edge?
 427         if( $used{$edge->[0]} && $used{$edge->[1]} ) {;
 428                         my %variables = ( 'color' => '#000000',
 429                                                           'fontcolor' => '#000000',
 430                                                           'label' => join( ', ', $self->path_display_label( $edge ) ),
 431                                 );
 432                         my $varopts = join( ', ', map { $_.'="'.$variables{$_}.'"' } sort keys %variables );
 433                         # Account for the rank gap if necessary
 434                         my $rankgap = $self->reading( $edge->[1] )->rank
 435                                 - $self->reading( $edge->[0] )->rank;
 436                         $varopts .= ", minlen=$rankgap" if $rankgap > 1;
 437                         $dot .= sprintf( "\t\"%s\" -> \"%s\" [ %s ];\n",
 438                                                          $edge->[0], $edge->[1], $varopts );
 439         }
 440     }
 441
 442     $dot .= "}\n";
 443     return $dot;
 444 }
 445
 446 sub path_witnesses {
 447         my( $self, @edge ) = @_;
 448         # If edge is an arrayref, cope.
 449         if( @edge == 1 && ref( $edge[0] ) eq 'ARRAY' ) {
 450                 my $e = shift @edge;
 451                 @edge = @$e;
 452         }
 453         my @wits = keys %{$self->sequence->get_edge_attributes( @edge )};
 454         return sort @wits;
 455 }
 456
 457 sub path_display_label {
 458         my( $self, $edge ) = @_;
 459         my @wits = $self->path_witnesses( $edge );
 460         my $maj = scalar( $self->tradition->witnesses ) * 0.6;
 461         if( scalar @wits > $maj ) {
 462                 return 'majority';
 463         } else {
 464                 return join( ', ', @wits );
 465         }
 466 }
 467
 468
 469 =item B<as_graphml>
 470
 471 print $collation->as_graphml( $recalculate )
 472
 473 Returns a GraphML representation of the collation graph, with
 474 transposition information and position information. Unless
 475 $recalculate is passed (and is a true value), the method will return a
 476 cached copy of the SVG after the first call to the method.
 477
 478 =begin testing
 479
 480 use Text::Tradition;
 481
 482 my $READINGS = 311;
 483 my $PATHS = 361;
 484
 485 my $datafile = 't/data/florilegium_tei_ps.xml';
 486 my $tradition = Text::Tradition->new( 'input' => 'TEI',
 487                                       'name' => 'test0',
 488                                       'file' => $datafile,
 489                                       'linear' => 1 );
 490
 491 ok( $tradition, "Got a tradition object" );
 492 is( scalar $tradition->witnesses, 13, "Found all witnesses" );
 493 ok( $tradition->collation, "Tradition has a collation" );
 494
 495 my $c = $tradition->collation;
 496 is( scalar $c->readings, $READINGS, "Collation has all readings" );
 497 is( scalar $c->paths, $PATHS, "Collation has all paths" );
 498 is( scalar $c->relationships, 0, "Collation has all relationships" );
 499
 500 # Add a few relationships
 501 $c->add_relationship( 'w123', 'w125', { 'type' => 'collated' } );
 502 $c->add_relationship( 'w193', 'w196', { 'type' => 'collated' } );
 503 $c->add_relationship( 'w257', 'w262', { 'type' => 'transposition' } );
 504
 505 # Now write it to GraphML and parse it again.
 506
 507 my $graphml = $c->as_graphml;
 508 my $st = Text::Tradition->new( 'input' => 'Self', 'string' => $graphml );
 509 is( scalar $st->collation->readings, $READINGS, "Reparsed collation has all readings" );
 510 is( scalar $st->collation->paths, $PATHS, "Reparsed collation has all paths" );
 511 is( scalar $st->collation->relationships, 3, "Reparsed collation has new relationships" );
 512
 513 =end testing
 514
 515 =cut
 516
 517 sub as_graphml {
 518     my( $self ) = @_;
 519
 520     # Some namespaces
 521     my $graphml_ns = 'http://graphml.graphdrawing.org/xmlns';
 522     my $xsi_ns = 'http://www.w3.org/2001/XMLSchema-instance';
 523     my $graphml_schema = 'http://graphml.graphdrawing.org/xmlns ' .
 524         'http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd';
 525
 526     # Create the document and root node
 527     my $graphml = XML::LibXML->createDocument( "1.0", "UTF-8" );
 528     my $root = $graphml->createElementNS( $graphml_ns, 'graphml' );
 529     $graphml->setDocumentElement( $root );
 530     $root->setNamespace( $xsi_ns, 'xsi', 0 );
 531     $root->setAttributeNS( $xsi_ns, 'schemaLocation', $graphml_schema );
 532
 533     # Add the data keys for the graph
 534     my %graph_data_keys;
 535     my $gdi = 0;
 536     my @graph_attributes = qw/ version wit_list_separator baselabel linear ac_label /;
 537     foreach my $datum ( @graph_attributes ) {
 538         $graph_data_keys{$datum} = 'dg'.$gdi++;
 539         my $key = $root->addNewChild( $graphml_ns, 'key' );
 540         $key->setAttribute( 'attr.name', $datum );
 541         $key->setAttribute( 'attr.type', $key eq 'linear' ? 'boolean' : 'string' );
 542         $key->setAttribute( 'for', 'graph' );
 543         $key->setAttribute( 'id', $graph_data_keys{$datum} );
 544     }
 545
 546     # Add the data keys for nodes
 547     my %node_data_keys;
 548     my $ndi = 0;
 549     my %node_data = (
 550         id => 'string',
 551         text => 'string',
 552         rank => 'string',
 553         is_start => 'boolean',
 554         is_end => 'boolean',
 555         is_lacuna => 'boolean',
 556         );
 557     foreach my $datum ( keys %node_data ) {
 558         $node_data_keys{$datum} = 'dn'.$ndi++;
 559         my $key = $root->addNewChild( $graphml_ns, 'key' );
 560         $key->setAttribute( 'attr.name', $datum );
 561         $key->setAttribute( 'attr.type', $node_data{$datum} );
 562         $key->setAttribute( 'for', 'node' );
 563         $key->setAttribute( 'id', $node_data_keys{$datum} );
 564     }
 565
 566     # Add the data keys for edges, i.e. witnesses
 567     my $edi = 0;
 568     my %edge_data_keys;
 569     my %edge_data = (
 570         class => 'string',                              # Class, deprecated soon
 571         witness => 'string',                    # ID/label for a path
 572         relationship => 'string',               # ID/label for a relationship
 573         extra => 'boolean',                             # Path key
 574         scope => 'string',                              # Relationship key
 575         non_correctable => 'boolean',   # Relationship key
 576         non_independent => 'boolean',   # Relationship key
 577         );
 578     foreach my $datum ( keys %edge_data ) {
 579         $edge_data_keys{$datum} = 'de'.$edi++;
 580         my $key = $root->addNewChild( $graphml_ns, 'key' );
 581         $key->setAttribute( 'attr.name', $datum );
 582         $key->setAttribute( 'attr.type', $edge_data{$datum} );
 583         $key->setAttribute( 'for', 'edge' );
 584         $key->setAttribute( 'id', $edge_data_keys{$datum} );
 585     }
 586
 587     # Add the collation graph itself
 588     my $sgraph = $root->addNewChild( $graphml_ns, 'graph' );
 589     $sgraph->setAttribute( 'edgedefault', 'directed' );
 590     $sgraph->setAttribute( 'id', $self->tradition->name );
 591     $sgraph->setAttribute( 'parse.edgeids', 'canonical' );
 592     $sgraph->setAttribute( 'parse.edges', scalar($self->paths) );
 593     $sgraph->setAttribute( 'parse.nodeids', 'canonical' );
 594     $sgraph->setAttribute( 'parse.nodes', scalar($self->readings) );
 595     $sgraph->setAttribute( 'parse.order', 'nodesfirst' );
 596
 597     # Collation attribute data
 598     foreach my $datum ( @graph_attributes ) {
 599         my $value = $datum eq 'version' ? '3.0' : $self->$datum;
 600                 _add_graphml_data( $sgraph, $graph_data_keys{$datum}, $value );
 601         }
 602
 603     my $node_ctr = 0;
 604     my %node_hash;
 605     # Add our readings to the graph
 606     foreach my $n ( sort { $a->id cmp $b->id } $self->readings ) {
 607         # Add to the main graph
 608         my $node_el = $sgraph->addNewChild( $graphml_ns, 'node' );
 609         my $node_xmlid = 'n' . $node_ctr++;
 610         $node_hash{ $n->id } = $node_xmlid;
 611         $node_el->setAttribute( 'id', $node_xmlid );
 612         foreach my $d ( keys %node_data ) {
 613                 my $nval = $n->$d;
 614                 $nval = $n->punctuated_form if $d eq 'text';
 615                 _add_graphml_data( $node_el, $node_data_keys{$d}, $nval )
 616                         if defined $nval;
 617         }
 618     }
 619
 620     # Add the path edges to the sequence graph
 621     my $edge_ctr = 0;
 622     foreach my $e ( sort { $a->[0] cmp $b->[0] } $self->sequence->edges() ) {
 623         # We add an edge in the graphml for every witness in $e.
 624         foreach my $wit ( $self->path_witnesses( $e ) ) {
 625                         my( $id, $from, $to ) = ( 'e'.$edge_ctr++,
 626                                                                                 $node_hash{ $e->[0] },
 627                                                                                 $node_hash{ $e->[1] } );
 628                         my $edge_el = $sgraph->addNewChild( $graphml_ns, 'edge' );
 629                         $edge_el->setAttribute( 'source', $from );
 630                         $edge_el->setAttribute( 'target', $to );
 631                         $edge_el->setAttribute( 'id', $id );
 632
 633                         # It's a witness path, so add the witness
 634                         my $base = $wit;
 635                         my $key = $edge_data_keys{'witness'};
 636                         # Is this an ante-corr witness?
 637                         my $aclabel = $self->ac_label;
 638                         if( $wit =~ /^(.*)\Q$aclabel\E$/ ) {
 639                                 # Keep the base witness
 640                                 $base = $1;
 641                                 # ...and record that this is an 'extra' reading path
 642                                 _add_graphml_data( $edge_el, $edge_data_keys{'extra'}, $aclabel );
 643                         }
 644                         _add_graphml_data( $edge_el, $edge_data_keys{'witness'}, $base );
 645                         _add_graphml_data( $edge_el, $edge_data_keys{'class'}, 'path' );
 646                 }
 647         }
 648
 649         # Add the relationship graph to the XML
 650         $self->relations->as_graphml( $graphml_ns, $root, \%node_hash,
 651                 $node_data_keys{'id'}, \%edge_data_keys );
 652
 653     # Save and return the thing
 654     my $result = decode_utf8( $graphml->toString(1) );
 655     return $result;
 656 }
 657
 658 sub _add_graphml_data {
 659     my( $el, $key, $value ) = @_;
 660     return unless defined $value;
 661     my $data_el = $el->addNewChild( $el->namespaceURI, 'data' );
 662     $data_el->setAttribute( 'key', $key );
 663     $data_el->appendText( $value );
 664 }
 665
 666 =item B<as_csv>
 667
 668 print $collation->as_csv( $recalculate )
 669
 670 Returns a CSV alignment table representation of the collation graph, one
 671 row per witness (or witness uncorrected.)
 672
 673 =cut
 674
 675 sub as_csv {
 676     my( $self ) = @_;
 677     my $table = $self->make_alignment_table;
 678     my $csv = Text::CSV_XS->new( { binary => 1, quote_null => 0 } );
 679     my @result;
 680     # Make the header row
 681     $csv->combine( map { $_->{'witness'} } @{$table->{'alignment'}} );
 682         push( @result, decode_utf8( $csv->string ) );
 683     # Make the rest of the rows
 684     foreach my $idx ( 0 .. $table->{'length'} - 1 ) {
 685         my @rowobjs = map { $_->{'tokens'}->[$idx] } @{$table->{'alignment'}};
 686         my @row = map { $_ ? $_->{'t'} : $_ } @rowobjs;
 687         $csv->combine( @row );
 688         push( @result, decode_utf8( $csv->string ) );
 689     }
 690     return join( "\n", @result );
 691 }
 692
 693 =item B<make_alignment_table>
 694
 695 my $table = $collation->make_alignment_table( $use_refs, \@wits_to_include )
 696
 697 Return a reference to an alignment table, in a slightly enhanced CollateX
 698 format which looks like this:
 699
 700  $table = { alignment => [ { witness => "SIGIL",
 701                              tokens => [ { t => "READINGTEXT" }, ... ] },
 702                            { witness => "SIG2",
 703                              tokens => [ { t => "READINGTEXT" }, ... ] },
 704                            ... ],
 705             length => TEXTLEN };
 706
 707 If $use_refs is set to 1, the reading object is returned in the table
 708 instead of READINGTEXT; if not, the text of the reading is returned.
 709 If $wits_to_include is set to a hashref, only the witnesses whose sigil
 710 keys have a true hash value will be included.
 711
 712 =cut
 713
 714 sub make_alignment_table {
 715     my( $self, $noderefs, $include ) = @_;
 716     unless( $self->linear ) {
 717         warn "Need a linear graph in order to make an alignment table";
 718         return;
 719     }
 720     my $table = { 'alignment' => [], 'length' => $self->end->rank - 1 };
 721     my @all_pos = ( 1 .. $self->end->rank - 1 );
 722     foreach my $wit ( sort { $a->sigil cmp $b->sigil } $self->tradition->witnesses ) {
 723         if( $include ) {
 724                 next unless $include->{$wit->sigil};
 725         }
 726         # print STDERR "Making witness row(s) for " . $wit->sigil . "\n";
 727         my @wit_path = $self->reading_sequence( $self->start, $self->end, $wit->sigil );
 728         my @row = _make_witness_row( \@wit_path, \@all_pos, $noderefs );
 729         push( @{$table->{'alignment'}},
 730                 { 'witness' => $wit->sigil, 'tokens' => \@row } );
 731         if( $wit->is_layered ) {
 732                 my @wit_ac_path = $self->reading_sequence( $self->start, $self->end,
 733                         $wit->sigil.$self->ac_label, $wit->sigil );
 734             my @ac_row = _make_witness_row( \@wit_ac_path, \@all_pos, $noderefs );
 735                         push( @{$table->{'alignment'}},
 736                                 { 'witness' => $wit->sigil.$self->ac_label, 'tokens' => \@ac_row } );
 737         }
 738     }
 739         return $table;
 740 }
 741
 742 sub _make_witness_row {
 743     my( $path, $positions, $noderefs ) = @_;
 744     my %char_hash;
 745     map { $char_hash{$_} = undef } @$positions;
 746     my $debug = 0;
 747     foreach my $rdg ( @$path ) {
 748         my $rtext = $rdg->text;
 749         $rtext = '#LACUNA#' if $rdg->is_lacuna;
 750         print STDERR "rank " . $rdg->rank . "\n" if $debug;
 751         # print STDERR "No rank for " . $rdg->id . "\n" unless defined $rdg->rank;
 752         $char_hash{$rdg->rank} = $noderefs ? { 't' => $rdg }
 753                                                                            : { 't' => $rtext };
 754     }
 755     my @row = map { $char_hash{$_} } @$positions;
 756     # Fill in lacuna markers for undef spots in the row
 757     my $last_el = shift @row;
 758     my @filled_row = ( $last_el );
 759     foreach my $el ( @row ) {
 760         # If we are using node reference, make the lacuna node appear many times
 761         # in the table.  If not, use the lacuna tag.
 762         if( $last_el && _el_is_lacuna( $last_el ) && !defined $el ) {
 763             $el = $noderefs ? $last_el : { 't' => '#LACUNA#' };
 764         }
 765         push( @filled_row, $el );
 766         $last_el = $el;
 767     }
 768     return @filled_row;
 769 }
 770
 771 # Tiny utility function to say if a table element is a lacuna
 772 sub _el_is_lacuna {
 773     my $el = shift;
 774     return 1 if $el->{'t'} eq '#LACUNA#';
 775     return 1 if ref( $el->{'t'} ) eq 'Text::Tradition::Collation::Reading'
 776         && $el->{'t'}->is_lacuna;
 777     return 0;
 778 }
 779
 780 # Helper to turn the witnesses along columns rather than rows.  Assumes
 781 # equal-sized rows.
 782 sub _turn_table {
 783     my( $table ) = @_;
 784     my $result = [];
 785     return $result unless scalar @$table;
 786     my $nrows = scalar @{$table->[0]};
 787     foreach my $idx ( 0 .. $nrows - 1 ) {
 788         foreach my $wit ( 0 .. $#{$table} ) {
 789             $result->[$idx]->[$wit] = $table->[$wit]->[$idx];
 790         }
 791     }
 792     return $result;
 793 }
 794
 795 =back
 796
 797 =head2 Navigation methods
 798
 799 =over
 800
 801 =item B<start>
 802
 803 my $beginning = $collation->start();
 804
 805 Returns the beginning of the collation, a meta-reading with label '#START#'.
 806
 807 =item B<end>
 808
 809 my $end = $collation->end();
 810
 811 Returns the end of the collation, a meta-reading with label '#END#'.
 812
 813
 814 =item B<reading_sequence>
 815
 816 my @readings = $collation->reading_sequence( $first, $last, $path[, $alt_path] );
 817
 818 Returns the ordered list of readings, starting with $first and ending
 819 with $last, along the given witness path.  If no path is specified,
 820 assume that the path is that of the base text (if any.)
 821
 822 =cut
 823
 824 # TODO Think about returning some lazy-eval iterator.
 825
 826 sub reading_sequence {
 827     my( $self, $start, $end, $witness, $backup ) = @_;
 828
 829     $witness = $self->baselabel unless $witness;
 830     my @readings = ( $start );
 831     my %seen;
 832     my $n = $start;
 833     while( $n && $n->id ne $end->id ) {
 834         if( exists( $seen{$n->id} ) ) {
 835             warn "Detected loop at " . $n->id;
 836             last;
 837         }
 838         $seen{$n->id} = 1;
 839
 840         my $next = $self->next_reading( $n, $witness, $backup );
 841         unless( $next ) {
 842             warn "Did not find any path for $witness from reading " . $n->id;
 843             last;
 844         }
 845         push( @readings, $next );
 846         $n = $next;
 847     }
 848     # Check that the last reading is our end reading.
 849     my $last = $readings[$#readings];
 850     warn "Last reading found from " . $start->text .
 851         " for witness $witness is not the end!"
 852         unless $last->id eq $end->id;
 853
 854     return @readings;
 855 }
 856
 857 =item B<next_reading>
 858
 859 my $next_reading = $collation->next_reading( $reading, $witpath );
 860
 861 Returns the reading that follows the given reading along the given witness
 862 path.
 863
 864 =cut
 865
 866 sub next_reading {
 867     # Return the successor via the corresponding path.
 868     my $self = shift;
 869     my $answer = $self->_find_linked_reading( 'next', @_ );
 870         return undef unless $answer;
 871     return $self->reading( $answer );
 872 }
 873
 874 =item B<prior_reading>
 875
 876 my $prior_reading = $collation->prior_reading( $reading, $witpath );
 877
 878 Returns the reading that precedes the given reading along the given witness
 879 path.
 880
 881 =cut
 882
 883 sub prior_reading {
 884     # Return the predecessor via the corresponding path.
 885     my $self = shift;
 886     my $answer = $self->_find_linked_reading( 'prior', @_ );
 887     return $self->reading( $answer );
 888 }
 889
 890 sub _find_linked_reading {
 891     my( $self, $direction, $node, $path, $alt_path ) = @_;
 892     my @linked_paths = $direction eq 'next'
 893         ? $self->sequence->edges_from( $node )
 894         : $self->sequence->edges_to( $node );
 895     return undef unless scalar( @linked_paths );
 896
 897     # We have to find the linked path that contains all of the
 898     # witnesses supplied in $path.
 899     my( @path_wits, @alt_path_wits );
 900     @path_wits = sort( $self->witnesses_of_label( $path ) ) if $path;
 901     @alt_path_wits = sort( $self->witnesses_of_label( $alt_path ) ) if $alt_path;
 902     my $base_le;
 903     my $alt_le;
 904     foreach my $le ( @linked_paths ) {
 905         if( $self->sequence->has_edge_attribute( @$le, $self->baselabel ) ) {
 906             $base_le = $le;
 907         }
 908                 my @le_wits = $self->path_witnesses( $le );
 909                 if( _is_within( \@path_wits, \@le_wits ) ) {
 910                         # This is the right path.
 911                         return $direction eq 'next' ? $le->[1] : $le->[0];
 912                 } elsif( _is_within( \@alt_path_wits, \@le_wits ) ) {
 913                         $alt_le = $le;
 914                 }
 915     }
 916     # Got this far? Return the alternate path if it exists.
 917     return $direction eq 'next' ? $alt_le->[1] : $alt_le->[0]
 918         if $alt_le;
 919
 920     # Got this far? Return the base path if it exists.
 921     return $direction eq 'next' ? $base_le->[1] : $base_le->[0]
 922         if $base_le;
 923
 924     # Got this far? We have no appropriate path.
 925     warn "Could not find $direction node from " . $node->id
 926         . " along path $path";
 927     return undef;
 928 }
 929
 930 # Some set logic.
 931 sub _is_within {
 932     my( $set1, $set2 ) = @_;
 933     my $ret = @$set1; # will be 0, i.e. false, if set1 is empty
 934     foreach my $el ( @$set1 ) {
 935         $ret = 0 unless grep { /^\Q$el\E$/ } @$set2;
 936     }
 937     return $ret;
 938 }
 939
 940
 941 ## INITIALIZATION METHODS - for use by parsers
 942
 943 # For use when a collation is constructed from a base text and an apparatus.
 944 # We have the sequences of readings and just need to add path edges.
 945 # When we are done, clear out the witness path attributes, as they are no
 946 # longer needed.
 947 # TODO Find a way to replace the witness path attributes with encapsulated functions?
 948
 949 sub make_witness_paths {
 950     my( $self ) = @_;
 951     foreach my $wit ( $self->tradition->witnesses ) {
 952         # print STDERR "Making path for " . $wit->sigil . "\n";
 953         $self->make_witness_path( $wit );
 954     }
 955 }
 956
 957 sub make_witness_path {
 958     my( $self, $wit ) = @_;
 959     my @chain = @{$wit->path};
 960     my $sig = $wit->sigil;
 961     foreach my $idx ( 0 .. $#chain-1 ) {
 962         $self->add_path( $chain[$idx], $chain[$idx+1], $sig );
 963     }
 964     if( $wit->is_layered ) {
 965         @chain = @{$wit->uncorrected_path};
 966         foreach my $idx( 0 .. $#chain-1 ) {
 967             my $source = $chain[$idx];
 968             my $target = $chain[$idx+1];
 969             $self->add_path( $source, $target, $sig.$self->ac_label )
 970                 unless $self->has_path( $source, $target, $sig );
 971         }
 972     }
 973     $wit->clear_path;
 974     $wit->clear_uncorrected_path;
 975 }
 976
 977 sub calculate_ranks {
 978     my $self = shift;
 979     # Walk a version of the graph where every node linked by a relationship
 980     # edge is fundamentally the same node, and do a topological ranking on
 981     # the nodes in this graph.
 982     my $topo_graph = Graph->new();
 983     my %rel_containers;
 984     my $rel_ctr = 0;
 985     # Add the nodes
 986     foreach my $r ( $self->readings ) {
 987         next if exists $rel_containers{$r->id};
 988         my @rels = $r->related_readings( 'colocated' );
 989         if( @rels ) {
 990             # Make a relationship container.
 991             push( @rels, $r );
 992             my $rn = 'rel_container_' . $rel_ctr++;
 993             $topo_graph->add_vertex( $rn );
 994             foreach( @rels ) {
 995                 $rel_containers{$_->id} = $rn;
 996             }
 997         } else {
 998             # Add a new node to mirror the old node.
 999             $rel_containers{$r->id} = $r->id;
1000             $topo_graph->add_vertex( $r->id );
1001         }
1002     }
1003
1004     # Add the edges.
1005     foreach my $r ( $self->readings ) {
1006         foreach my $n ( $self->sequence->successors( $r->id ) ) {
1007                 my( $tfrom, $tto ) = ( $rel_containers{$r->id},
1008                         $rel_containers{$n} );
1009                 $DB::single = 1 unless $tfrom && $tto;
1010             $topo_graph->add_edge( $tfrom, $tto );
1011         }
1012     }
1013
1014     # Now do the rankings, starting with the start node.
1015     my $topo_start = $rel_containers{$self->start->id};
1016     my $node_ranks = { $topo_start => 0 };
1017     my @curr_origin = ( $topo_start );
1018     # A little iterative function.
1019     while( @curr_origin ) {
1020         @curr_origin = _assign_rank( $topo_graph, $node_ranks, @curr_origin );
1021     }
1022     # Transfer our rankings from the topological graph to the real one.
1023     foreach my $r ( $self->readings ) {
1024         if( defined $node_ranks->{$rel_containers{$r->id}} ) {
1025             $r->rank( $node_ranks->{$rel_containers{$r->id}} );
1026         } else {
1027             $DB::single = 1;
1028             die "No rank calculated for node " . $r->id
1029                 . " - do you have a cycle in the graph?";
1030         }
1031     }
1032 }
1033
1034 sub _assign_rank {
1035     my( $graph, $node_ranks, @current_nodes ) = @_;
1036     # Look at each of the children of @current_nodes.  If all the child's
1037     # parents have a rank, assign it the highest rank + 1 and add it to
1038     # @next_nodes.  Otherwise skip it; we will return when the highest-ranked
1039     # parent gets a rank.
1040     my @next_nodes;
1041     foreach my $c ( @current_nodes ) {
1042         warn "Current reading $c has no rank!"
1043             unless exists $node_ranks->{$c};
1044         # print STDERR "Looking at child of node $c, rank "
1045         #     . $node_ranks->{$c} . "\n";
1046         foreach my $child ( $graph->successors( $c ) ) {
1047             next if exists $node_ranks->{$child};
1048             my $highest_rank = -1;
1049             my $skip = 0;
1050             foreach my $parent ( $graph->predecessors( $child ) ) {
1051                 if( exists $node_ranks->{$parent} ) {
1052                     $highest_rank = $node_ranks->{$parent}
1053                         if $highest_rank <= $node_ranks->{$parent};
1054                 } else {
1055                     $skip = 1;
1056                     last;
1057                 }
1058             }
1059             next if $skip;
1060             my $c_rank = $highest_rank + 1;
1061             # print STDERR "Assigning rank $c_rank to node $child \n";
1062             $node_ranks->{$child} = $c_rank;
1063             push( @next_nodes, $child );
1064         }
1065     }
1066     return @next_nodes;
1067 }
1068
1069 # Another method to make up for rough collation methods.  If the same reading
1070 # appears multiple times at the same rank, collapse the nodes.
1071 sub flatten_ranks {
1072     my $self = shift;
1073     my %unique_rank_rdg;
1074     foreach my $rdg ( $self->readings ) {
1075         next unless $rdg->has_rank;
1076         my $key = $rdg->rank . "||" . $rdg->text;
1077         if( exists $unique_rank_rdg{$key} ) {
1078             # Combine!
1079                 # print STDERR "Combining readings at same rank: $key\n";
1080             $self->merge_readings( $unique_rank_rdg{$key}, $rdg );
1081         } else {
1082             $unique_rank_rdg{$key} = $rdg;
1083         }
1084     }
1085 }
1086
1087
1088 ## Utility functions
1089
1090 # Return the string that joins together a list of witnesses for
1091 # display on a single path.
1092 sub witnesses_of_label {
1093     my( $self, $label ) = @_;
1094     my $regex = $self->wit_list_separator;
1095     my @answer = split( /\Q$regex\E/, $label );
1096     return @answer;
1097 }
1098
1099 =begin testing
1100
1101 use Text::Tradition;
1102
1103 my $cxfile = 't/data/Collatex-16.xml';
1104 my $t = Text::Tradition->new(
1105     'name'  => 'inline',
1106     'input' => 'CollateX',
1107     'file'  => $cxfile,
1108     );
1109 my $c = $t->collation;
1110
1111 is( $c->common_predecessor( $c->reading('n9'), $c->reading('n23') )->id,
1112     'n20', "Found correct common predecessor" );
1113 is( $c->common_successor( $c->reading('n9'), $c->reading('n23') )->id,
1114     '#END#', "Found correct common successor" );
1115
1116 is( $c->common_predecessor( $c->reading('n19'), $c->reading('n17') )->id,
1117     'n16', "Found correct common predecessor for readings on same path" );
1118 is( $c->common_successor( $c->reading('n21'), $c->reading('n26') )->id,
1119     '#END#', "Found correct common successor for readings on same path" );
1120
1121 =end testing
1122
1123 =cut
1124
1125 ## Return the closest reading that is a predecessor of both the given readings.
1126 sub common_predecessor {
1127         my $self = shift;
1128         return $self->common_in_path( @_, 'predecessors' );
1129 }
1130
1131 sub common_successor {
1132         my $self = shift;
1133         return $self->common_in_path( @_, 'successors' );
1134 }
1135
1136 sub common_in_path {
1137         my( $self, $r1, $r2, $dir ) = @_;
1138         my $iter = $r1->rank > $r2->rank ? $r1->rank : $r2->rank;
1139         $iter = $self->end->rank - $iter if $dir eq 'successors';
1140         my @candidates;
1141         my @last_checked = ( $r1, $r2 );
1142         my %all_seen;
1143         while( !@candidates ) {
1144                 my @new_lc;
1145                 foreach my $lc ( @last_checked ) {
1146                         foreach my $p ( $lc->$dir ) {
1147                                 if( $all_seen{$p->id} ) {
1148                                         push( @candidates, $p );
1149                                 } else {
1150                                         $all_seen{$p->id} = 1;
1151                                         push( @new_lc, $p );
1152                                 }
1153                         }
1154                 }
1155                 @last_checked = @new_lc;
1156         }
1157         my @answer = sort { $a->rank <=> $b->rank } @candidates;
1158         return $dir eq 'predecessors' ? pop( @answer ) : shift ( @answer );
1159 }
1160
1161 no Moose;
1162 __PACKAGE__->meta->make_immutable;
1163
1164 =head1 BUGS / TODO
1165
1166 =over
1167
1168 =item * Think about making Relationship objects again
1169
1170 =back