lib/Text/Tradition/Collation/Reading.pm

   1 package Text::Tradition::Collation::Reading;
   2
   3 use Moose;
   4 use overload '""' => \&_stringify, 'fallback' => 1;
   5
   6 =head1 NAME
   7
   8 Text::Tradition::Collation::Reading - represents a reading (usually a word) in a collation.
   9
  10 =head1 DESCRIPTION
  11
  12 Text::Tradition is a library for representation and analysis of collated
  13 texts, particularly medieval ones.  A 'reading' refers to a unit of text,
  14 usually a word, that appears in one or more witnesses (manuscripts) of the
  15 tradition; the text of a given witness is composed of a set of readings in
  16 a particular sequence
  17
  18 =head1 METHODS
  19
  20 =head2 new
  21
  22 Creates a new reading in the given collation with the given attributes.
  23 Options include:
  24
  25 =over 4
  26
  27 =item collation - The Text::Tradition::Collation object to which this reading belongs.  Required.
  28
  29 =item id - A unique identifier for this reading. Required.
  30
  31 =item text - The word or other text of the reading.
  32
  33 =item is_start - The reading is the starting point for the collation.
  34
  35 =item is_end - The reading is the ending point for the collation.
  36
  37 =item is_lacuna - The 'reading' represents a known gap in the text.
  38
  39 =item is_ph - A temporary placeholder for apparatus parsing purposes.  Do not use unless you know what you are doing.
  40
  41 =item rank - The sequence number of the reading. This should probably not be set manually.
  42
  43 =back
  44
  45 One of 'text', 'is_start', 'is_end', or 'is_lacuna' is required.
  46
  47 =head2 collation
  48
  49 =head2 id
  50
  51 =head2 text
  52
  53 =head2 is_start
  54
  55 =head2 is_end
  56
  57 =head2 is_lacuna
  58
  59 =head2 rank
  60
  61 Accessor methods for the given attributes.
  62
  63 =cut
  64
  65 has 'collation' => (
  66         is => 'ro',
  67         isa => 'Text::Tradition::Collation',
  68         # required => 1,
  69         weak_ref => 1,
  70         );
  71
  72 has 'id' => (
  73         is => 'ro',
  74         isa => 'Str',
  75         required => 1,
  76         );
  77
  78 has 'text' => (
  79         is => 'ro',
  80         isa => 'Str',
  81         required => 1,
  82         writer => 'alter_text',
  83         );
  84
  85 has 'is_start' => (
  86         is => 'ro',
  87         isa => 'Bool',
  88         default => undef,
  89         );
  90
  91 has 'is_end' => (
  92         is => 'ro',
  93         isa => 'Bool',
  94         default => undef,
  95         );
  96
  97 has 'is_lacuna' => (
  98     is => 'ro',
  99     isa => 'Bool',
 100         default => undef,
 101     );
 102
 103 has 'is_ph' => (
 104         is => 'ro',
 105         isa => 'Bool',
 106         default => undef,
 107         );
 108
 109 has 'is_common' => (
 110         is => 'rw',
 111         isa => 'Bool',
 112         default => undef,
 113         );
 114
 115 has 'rank' => (
 116     is => 'rw',
 117     isa => 'Int',
 118     predicate => 'has_rank',
 119     clearer => 'clear_rank',
 120     );
 121
 122 ## For prefix/suffix readings
 123
 124 has 'join_prior' => (
 125         is => 'ro',
 126         isa => 'Bool',
 127         default => undef,
 128         );
 129
 130 has 'join_next' => (
 131         is => 'ro',
 132         isa => 'Bool',
 133         default => undef,
 134         );
 135
 136
 137 around BUILDARGS => sub {
 138         my $orig = shift;
 139         my $class = shift;
 140         my $args;
 141         if( @_ == 1 ) {
 142                 $args = shift;
 143         } else {
 144                 $args = { @_ };
 145         }
 146
 147         # If one of our special booleans is set, we change the text and the
 148         # ID to match.
 149         if( exists $args->{'is_lacuna'} && !exists $args->{'text'} ) {
 150                 $args->{'text'} = '#LACUNA#';
 151         } elsif( exists $args->{'is_start'} ) {
 152                 $args->{'id'} = '#START#';  # Change the ID to ensure we have only one
 153                 $args->{'text'} = '#START#';
 154                 $args->{'rank'} = 0;
 155         } elsif( exists $args->{'is_end'} ) {
 156                 $args->{'id'} = '#END#';        # Change the ID to ensure we have only one
 157                 $args->{'text'} = '#END#';
 158         } elsif( exists $args->{'is_ph'} ) {
 159                 $args->{'text'} = $args->{'id'};
 160         }
 161
 162         $class->$orig( $args );
 163 };
 164
 165 =head2 is_meta
 166
 167 A meta attribute (ha ha), which should be true if any of our 'special'
 168 booleans are true.  Implies that the reading does not represent a bit
 169 of text found in a witness.
 170
 171 =cut
 172
 173 sub is_meta {
 174         my $self = shift;
 175         return $self->is_start || $self->is_end || $self->is_lacuna || $self->is_ph;
 176 }
 177
 178 =head1 Convenience methods
 179
 180 =head2 related_readings
 181
 182 Calls Collation's related_readings with $self as the first argument.
 183
 184 =cut
 185
 186 sub related_readings {
 187         my $self = shift;
 188         return $self->collation->related_readings( $self, @_ );
 189 }
 190
 191 =head2 witnesses
 192
 193 Calls Collation's reading_witnesses with $self as the first argument.
 194
 195 =cut
 196
 197 sub witnesses {
 198         my $self = shift;
 199         return $self->collation->reading_witnesses( $self, @_ );
 200 }
 201
 202 =head2 predecessors
 203
 204 Returns a list of Reading objects that immediately precede $self in the collation.
 205
 206 =cut
 207
 208 sub predecessors {
 209         my $self = shift;
 210         my @pred = $self->collation->sequence->predecessors( $self->id );
 211         return map { $self->collation->reading( $_ ) } @pred;
 212 }
 213
 214 =head2 successors
 215
 216 Returns a list of Reading objects that immediately follow $self in the collation.
 217
 218 =cut
 219
 220 sub successors {
 221         my $self = shift;
 222         my @succ = $self->collation->sequence->successors( $self->id );
 223         return map { $self->collation->reading( $_ ) } @succ;
 224 }
 225
 226 =head2 set_identical( $other_reading)
 227
 228 Backwards compatibility method, to add a transposition relationship
 229 between $self and $other_reading.  Don't use this.
 230
 231 =cut
 232
 233 sub set_identical {
 234         my( $self, $other ) = @_;
 235         return $self->collation->add_relationship( $self, $other,
 236                 { 'type' => 'transposition' } );
 237 }
 238
 239 sub _stringify {
 240         my $self = shift;
 241         return $self->id;
 242 }
 243
 244 sub TO_JSON {
 245         my $self = shift;
 246         return $self->text;
 247 }
 248
 249 no Moose;
 250 __PACKAGE__->meta->make_immutable;
 251
 252 1;
 253