lib/Text/Tradition/Collation/Reading.pm

   1 package Text::Tradition::Collation::Reading;
   2
   3 use Moose;
   4 use overload '""' => \&_stringify, 'fallback' => 1;
   5
   6 =head1 NAME
   7
   8 Text::Tradition::Collation::Reading - represents a reading (usually a word) in a collation.
   9
  10 =head1 DESCRIPTION
  11
  12 Text::Tradition is a library for representation and analysis of collated
  13 texts, particularly medieval ones.  A 'reading' refers to a unit of text,
  14 usually a word, that appears in one or more witnesses (manuscripts) of the
  15 tradition; the text of a given witness is composed of a set of readings in
  16 a particular sequence
  17
  18 =head1 METHODS
  19
  20 =head2 new
  21
  22 Creates a new reading in the given collation with the given attributes.
  23 Options include:
  24
  25 =over 4
  26
  27 =item collation - The Text::Tradition::Collation object to which this reading belongs.  Required.
  28
  29 =item id - A unique identifier for this reading. Required.
  30
  31 =item text - The word or other text of the reading.
  32
  33 =item is_start - The reading is the starting point for the collation.
  34
  35 =item is_end - The reading is the ending point for the collation.
  36
  37 =item is_lacuna - The 'reading' represents a known gap in the text.
  38
  39 =item is_ph - A temporary placeholder for apparatus parsing purposes.  Do not use unless you know what you are doing.
  40
  41 =item rank - The sequence number of the reading. This should probably not be set manually.
  42
  43 =back
  44
  45 One of 'text', 'is_start', 'is_end', or 'is_lacuna' is required.
  46
  47 =head2 collation
  48
  49 =head2 id
  50
  51 =head2 text
  52
  53 =head2 is_start
  54
  55 =head2 is_end
  56
  57 =head2 is_lacuna
  58
  59 =head2 rank
  60
  61 Accessor methods for the given attributes.
  62
  63 =cut
  64
  65 has 'collation' => (
  66         is => 'ro',
  67         isa => 'Text::Tradition::Collation',
  68         # required => 1,
  69         weak_ref => 1,
  70         );
  71
  72 has 'id' => (
  73         is => 'ro',
  74         isa => 'Str',
  75         required => 1,
  76         );
  77
  78 has 'text' => (
  79         is => 'ro',
  80         isa => 'Str',
  81         required => 1,
  82         writer => 'alter_text',
  83         );
  84
  85 has 'is_start' => (
  86         is => 'ro',
  87         isa => 'Bool',
  88         default => undef,
  89         );
  90
  91 has 'is_end' => (
  92         is => 'ro',
  93         isa => 'Bool',
  94         default => undef,
  95         );
  96
  97 has 'is_lacuna' => (
  98     is => 'ro',
  99     isa => 'Bool',
 100         default => undef,
 101     );
 102
 103 has 'is_ph' => (
 104         is => 'ro',
 105         isa => 'Bool',
 106         default => undef,
 107         );
 108
 109 has 'rank' => (
 110     is => 'rw',
 111     isa => 'Int',
 112     predicate => 'has_rank',
 113     );
 114
 115
 116 around BUILDARGS => sub {
 117         my $orig = shift;
 118         my $class = shift;
 119         my $args;
 120         if( @_ == 1 ) {
 121                 $args = shift;
 122         } else {
 123                 $args = { @_ };
 124         }
 125
 126         # If one of our special booleans is set, we change the text and the
 127         # ID to match.
 128         if( exists $args->{'is_lacuna'} && !exists $args->{'text'} ) {
 129                 $args->{'text'} = '#LACUNA#';
 130         } elsif( exists $args->{'is_start'} ) {
 131                 $args->{'id'} = '#START#';  # Change the ID to ensure we have only one
 132                 $args->{'text'} = '#START#';
 133                 $args->{'rank'} = 0;
 134         } elsif( exists $args->{'is_end'} ) {
 135                 $args->{'id'} = '#END#';        # Change the ID to ensure we have only one
 136                 $args->{'text'} = '#END#';
 137         } elsif( exists $args->{'is_ph'} ) {
 138                 $args->{'text'} = $args->{'id'};
 139         }
 140
 141         $class->$orig( $args );
 142 };
 143
 144 =head2 is_meta
 145
 146 A meta attribute (ha ha), which should be true if any of our 'special'
 147 booleans are true.  Implies that the reading does not represent a bit
 148 of text found in a witness.
 149
 150 =cut
 151
 152 sub is_meta {
 153         my $self = shift;
 154         return $self->is_start || $self->is_end || $self->is_lacuna || $self->is_ph;
 155 }
 156
 157 # Some syntactic sugar
 158 sub related_readings {
 159         my $self = shift;
 160         return $self->collation->related_readings( $self, @_ );
 161 }
 162
 163 sub predecessors {
 164         my $self = shift;
 165         my @pred = $self->collation->sequence->predecessors( $self->id );
 166         return map { $self->collation->reading( $_ ) } @pred;
 167 }
 168
 169 sub successors {
 170         my $self = shift;
 171         my @succ = $self->collation->sequence->successors( $self->id );
 172         return map { $self->collation->reading( $_ ) } @succ;
 173 }
 174
 175 sub set_identical {
 176         my( $self, $other ) = @_;
 177         return $self->collation->add_relationship( $self, $other,
 178                 { 'type' => 'transposition' } );
 179 }
 180
 181 sub _stringify {
 182         my $self = shift;
 183         return $self->id;
 184 }
 185
 186 no Moose;
 187 __PACKAGE__->meta->make_immutable;
 188
 189 1;
 190