lib/Text/Tradition/Collation/Reading.pm

   1 package Text::Tradition::Collation::Reading;
   2
   3 use Moose;
   4 use overload '""' => \&_stringify, 'fallback' => 1;
   5
   6 =head1 NAME
   7
   8 Text::Tradition::Collation::Reading - represents a reading (usually a word) in a collation.
   9
  10 =head1 DESCRIPTION
  11
  12 Text::Tradition is a library for representation and analysis of collated
  13 texts, particularly medieval ones.  A 'reading' refers to a unit of text,
  14 usually a word, that appears in one or more witnesses (manuscripts) of the
  15 tradition; the text of a given witness is composed of a set of readings in
  16 a particular sequence
  17
  18 =head1 METHODS
  19
  20 =head2 new
  21
  22 Creates a new reading in the given collation with the given attributes.
  23 Options include:
  24
  25 =over 4
  26
  27 =item collation - The Text::Tradition::Collation object to which this reading belongs.  Required.
  28
  29 =item id - A unique identifier for this reading. Required.
  30
  31 =item text - The word or other text of the reading.
  32
  33 =item is_start - The reading is the starting point for the collation.
  34
  35 =item is_end - The reading is the ending point for the collation.
  36
  37 =item is_lacuna - The 'reading' represents a known gap in the text.
  38
  39 =item is_ph - A temporary placeholder for apparatus parsing purposes.  Do not use unless you know what you are doing.
  40
  41 =item rank - The sequence number of the reading. This should probably not be set manually.
  42
  43 =back
  44
  45 One of 'text', 'is_start', 'is_end', or 'is_lacuna' is required.
  46
  47 =head2 collation
  48
  49 =head2 id
  50
  51 =head2 text
  52
  53 =head2 is_start
  54
  55 =head2 is_end
  56
  57 =head2 is_lacuna
  58
  59 =head2 rank
  60
  61 Accessor methods for the given attributes.
  62
  63 =cut
  64
  65 has 'collation' => (
  66         is => 'ro',
  67         isa => 'Text::Tradition::Collation',
  68         # required => 1,
  69         weak_ref => 1,
  70         );
  71
  72 has 'id' => (
  73         is => 'ro',
  74         isa => 'Str',
  75         required => 1,
  76         );
  77
  78 has 'text' => (
  79         is => 'ro',
  80         isa => 'Str',
  81         required => 1,
  82         writer => 'alter_text',
  83         );
  84
  85 has 'is_start' => (
  86         is => 'ro',
  87         isa => 'Bool',
  88         default => undef,
  89         );
  90
  91 has 'is_end' => (
  92         is => 'ro',
  93         isa => 'Bool',
  94         default => undef,
  95         );
  96
  97 has 'is_lacuna' => (
  98     is => 'ro',
  99     isa => 'Bool',
 100         default => undef,
 101     );
 102
 103 has 'is_ph' => (
 104         is => 'ro',
 105         isa => 'Bool',
 106         default => undef,
 107         );
 108
 109 has 'is_common' => (
 110         is => 'rw',
 111         isa => 'Bool',
 112         default => undef,
 113         );
 114
 115 has 'rank' => (
 116     is => 'rw',
 117     isa => 'Int',
 118     predicate => 'has_rank',
 119     );
 120
 121 ## For prefix/suffix readings
 122
 123 has 'join_prior' => (
 124         is => 'ro',
 125         isa => 'Bool',
 126         default => undef,
 127         );
 128
 129 has 'join_next' => (
 130         is => 'ro',
 131         isa => 'Bool',
 132         default => undef,
 133         );
 134
 135
 136 around BUILDARGS => sub {
 137         my $orig = shift;
 138         my $class = shift;
 139         my $args;
 140         if( @_ == 1 ) {
 141                 $args = shift;
 142         } else {
 143                 $args = { @_ };
 144         }
 145
 146         # If one of our special booleans is set, we change the text and the
 147         # ID to match.
 148         if( exists $args->{'is_lacuna'} && !exists $args->{'text'} ) {
 149                 $args->{'text'} = '#LACUNA#';
 150         } elsif( exists $args->{'is_start'} ) {
 151                 $args->{'id'} = '#START#';  # Change the ID to ensure we have only one
 152                 $args->{'text'} = '#START#';
 153                 $args->{'rank'} = 0;
 154         } elsif( exists $args->{'is_end'} ) {
 155                 $args->{'id'} = '#END#';        # Change the ID to ensure we have only one
 156                 $args->{'text'} = '#END#';
 157         } elsif( exists $args->{'is_ph'} ) {
 158                 $args->{'text'} = $args->{'id'};
 159         }
 160
 161         $class->$orig( $args );
 162 };
 163
 164 =head2 is_meta
 165
 166 A meta attribute (ha ha), which should be true if any of our 'special'
 167 booleans are true.  Implies that the reading does not represent a bit
 168 of text found in a witness.
 169
 170 =cut
 171
 172 sub is_meta {
 173         my $self = shift;
 174         return $self->is_start || $self->is_end || $self->is_lacuna || $self->is_ph;
 175 }
 176
 177 =head1 Convenience methods
 178
 179 =head2 related_readings
 180
 181 Calls Collation's related_readings with $self as the first argument.
 182
 183 =cut
 184
 185 sub related_readings {
 186         my $self = shift;
 187         return $self->collation->related_readings( $self, @_ );
 188 }
 189
 190 =head2 witnesses
 191
 192 Calls Collation's reading_witnesses with $self as the first argument.
 193
 194 =cut
 195
 196 sub witnesses {
 197         my $self = shift;
 198         return $self->collation->reading_witnesses( $self, @_ );
 199 }
 200
 201 =head2 predecessors
 202
 203 Returns a list of Reading objects that immediately precede $self in the collation.
 204
 205 =cut
 206
 207 sub predecessors {
 208         my $self = shift;
 209         my @pred = $self->collation->sequence->predecessors( $self->id );
 210         return map { $self->collation->reading( $_ ) } @pred;
 211 }
 212
 213 =head2 successors
 214
 215 Returns a list of Reading objects that immediately follow $self in the collation.
 216
 217 =cut
 218
 219 sub successors {
 220         my $self = shift;
 221         my @succ = $self->collation->sequence->successors( $self->id );
 222         return map { $self->collation->reading( $_ ) } @succ;
 223 }
 224
 225 =head2 set_identical( $other_reading)
 226
 227 Backwards compatibility method, to add a transposition relationship
 228 between $self and $other_reading.  Don't use this.
 229
 230 =cut
 231
 232 sub set_identical {
 233         my( $self, $other ) = @_;
 234         return $self->collation->add_relationship( $self, $other,
 235                 { 'type' => 'transposition' } );
 236 }
 237
 238 sub _stringify {
 239         my $self = shift;
 240         return $self->id;
 241 }
 242
 243 sub TO_JSON {
 244         my $self = shift;
 245         return $self->text;
 246 }
 247
 248 no Moose;
 249 __PACKAGE__->meta->make_immutable;
 250
 251 1;
 252