8 # Can't use Carp because it might cause use_ok() to accidentally succeed
9 # even though the module being used forgot to use Carp. Yes, this
12 my($file, $line) = (caller(1))[1,2];
13 warn @_, " at $file line $line\n";
18 use vars qw($VERSION @ISA @EXPORT %EXPORT_TAGS $TODO);
20 $VERSION = eval $VERSION; # make the alpha version come out as a number
22 use Test::Builder::Module;
23 @ISA = qw(Test::Builder::Module);
24 @EXPORT = qw(ok use_ok require_ok
25 is isnt like unlike is_deeply
29 eq_array eq_hash eq_set
40 Test::More - yet another framework for writing test scripts
44 use Test::More tests => $Num_Tests;
46 use Test::More qw(no_plan);
48 use Test::More skip_all => $reason;
50 BEGIN { use_ok( 'Some::Module' ); }
51 require_ok( 'Some::Module' );
53 # Various ways to say "ok"
54 ok($this eq $that, $test_name);
56 is ($this, $that, $test_name);
57 isnt($this, $that, $test_name);
59 # Rather than print STDERR "# here's what went wrong\n"
60 diag("here's what went wrong");
62 like ($this, qr/that/, $test_name);
63 unlike($this, qr/that/, $test_name);
65 cmp_ok($this, '==', $that, $test_name);
67 is_deeply($complex_structure1, $complex_structure2, $test_name);
70 skip $why, $how_many unless $have_some_feature;
72 ok( foo(), $test_name );
73 is( foo(42), 23, $test_name );
79 ok( foo(), $test_name );
80 is( foo(42), 23, $test_name );
83 can_ok($module, @methods);
84 isa_ok($object, $class);
92 my @status = Test::More::status;
97 B<STOP!> If you're just getting started writing tests, have a look at
98 Test::Simple first. This is a drop in replacement for Test::Simple
99 which you can switch to once you get the hang of basic testing.
101 The purpose of this module is to provide a wide range of testing
102 utilities. Various ways to say "ok" with better diagnostics,
103 facilities to skip tests, test future features and compare complicated
104 data structures. While you can do almost anything with a simple
105 C<ok()> function, it doesn't provide good diagnostic output.
108 =head2 I love it when a plan comes together
110 Before anything else, you need a testing plan. This basically declares
111 how many tests your script is going to run to protect against premature
114 The preferred way to do this is to declare a plan when you C<use Test::More>.
116 use Test::More tests => $Num_Tests;
118 There are rare cases when you will not know beforehand how many tests
119 your script is going to run. In this case, you can declare that you
120 have no plan. (Try to avoid using this as it weakens your test.)
122 use Test::More qw(no_plan);
124 B<NOTE>: using no_plan requires a Test::Harness upgrade else it will
125 think everything has failed. See L<CAVEATS and NOTES>).
127 In some cases, you'll want to completely skip an entire testing script.
129 use Test::More skip_all => $skip_reason;
131 Your script will declare a skip with the reason why you skipped and
132 exit immediately with a zero (success). See L<Test::Harness> for
135 If you want to control what functions Test::More will export, you
136 have to use the 'import' option. For example, to import everything
137 but 'fail', you'd do:
139 use Test::More tests => 23, import => ['!fail'];
141 Alternatively, you can use the plan() function. Useful for when you
142 have to calculate the number of tests.
145 plan tests => keys %Stuff * 3;
147 or for deciding between running the tests at all:
150 if( $^O eq 'MacOS' ) {
151 plan skip_all => 'Test irrelevant on MacOS';
160 my $tb = Test::More->builder;
166 # This implements "use Test::More 'no_diag'" but the behavior is
174 while( $idx <= $#{$list} ) {
175 my $item = $list->[$idx];
177 if( defined $item and $item eq 'no_diag' ) {
178 $class->builder->no_diag(1);
193 By convention, each test is assigned a number in order. This is
194 largely done automatically for you. However, it's often very useful to
195 assign a name to each test. Which would you rather see:
203 ok 4 - basic multi-variable
204 not ok 5 - simple exponential
205 ok 6 - force == mass * acceleration
207 The later gives you some idea of what failed. It also makes it easier
208 to find the test in your script, simply search for "simple
211 All test functions take a name argument. It's optional, but highly
212 suggested that you use it.
215 =head2 I'm ok, you're not ok.
217 The basic purpose of this module is to print out either "ok #" or "not
218 ok #" depending on if a given test succeeded or failed. Everything
221 All of the following print "ok" or "not ok" depending on if the test
222 succeeded or failed. They all also return true or false,
229 ok($this eq $that, $test_name);
231 This simply evaluates any expression (C<$this eq $that> is just a
232 simple example) and uses that to determine if the test succeeded or
233 failed. A true expression passes, a false one fails. Very simple.
237 ok( $exp{9} == 81, 'simple exponential' );
238 ok( Film->can('db_Main'), 'set_db()' );
239 ok( $p->tests == 4, 'saw tests' );
240 ok( !grep !defined $_, @items, 'items populated' );
242 (Mnemonic: "This is ok.")
244 $test_name is a very short description of the test that will be printed
245 out. It makes it very easy to find a test in your script when it fails
246 and gives others an idea of your intentions. $test_name is optional,
247 but we B<very> strongly encourage its use.
249 Should an ok() fail, it will produce some diagnostics:
251 not ok 18 - sufficient mucus
252 # Failed test 'sufficient mucus'
253 # in foo.t at line 42.
255 This is actually Test::Simple's ok() routine.
260 my($test, $name) = @_;
261 my $tb = Test::More->builder;
263 $tb->ok($test, $name);
270 is ( $this, $that, $test_name );
271 isnt( $this, $that, $test_name );
273 Similar to ok(), is() and isnt() compare their two arguments
274 with C<eq> and C<ne> respectively and use the result of that to
275 determine if the test succeeded or failed. So these:
277 # Is the ultimate answer 42?
278 is( ultimate_answer(), 42, "Meaning of Life" );
281 isnt( $foo, '', "Got some foo" );
283 are similar to these:
285 ok( ultimate_answer() eq 42, "Meaning of Life" );
286 ok( $foo ne '', "Got some foo" );
288 (Mnemonic: "This is that." "This isn't that.")
290 So why use these? They produce better diagnostics on failure. ok()
291 cannot know what you are testing for (beyond the name), but is() and
292 isnt() know what the test was and why it failed. For example this
295 my $foo = 'waffle'; my $bar = 'yarblokos';
296 is( $foo, $bar, 'Is foo the same as bar?' );
298 Will produce something like this:
300 not ok 17 - Is foo the same as bar?
301 # Failed test 'Is foo the same as bar?'
302 # in foo.t at line 139.
304 # expected: 'yarblokos'
306 So you can figure out what went wrong without rerunning the test.
308 You are encouraged to use is() and isnt() over ok() where possible,
309 however do not be tempted to use them to find out if something is
313 is( exists $brooklyn{tree}, 1, 'A tree grows in Brooklyn' );
315 This does not check if C<exists $brooklyn{tree}> is true, it checks if
316 it returns 1. Very different. Similar caveats exist for false and 0.
317 In these cases, use ok().
319 ok( exists $brooklyn{tree}, 'A tree grows in Brooklyn' );
321 For those grammatical pedants out there, there's an C<isn't()>
322 function which is an alias of isnt().
327 my $tb = Test::More->builder;
333 my $tb = Test::More->builder;
343 like( $this, qr/that/, $test_name );
345 Similar to ok(), like() matches $this against the regex C<qr/that/>.
349 like($this, qr/that/, 'this is like that');
353 ok( $this =~ /that/, 'this is like that');
355 (Mnemonic "This is like that".)
357 The second argument is a regular expression. It may be given as a
358 regex reference (i.e. C<qr//>) or (for better compatibility with older
359 perls) as a string that looks like a regex (alternative delimiters are
360 currently not supported):
362 like( $this, '/that/', 'this is like that' );
364 Regex options may be placed on the end (C<'/that/i'>).
366 Its advantages over ok() are similar to that of is() and isnt(). Better
367 diagnostics on failure.
372 my $tb = Test::More->builder;
380 unlike( $this, qr/that/, $test_name );
382 Works exactly as like(), only it checks if $this B<does not> match the
388 my $tb = Test::More->builder;
396 cmp_ok( $this, $op, $that, $test_name );
398 Halfway between ok() and is() lies cmp_ok(). This allows you to
399 compare two arguments using any binary perl operator.
401 # ok( $this eq $that );
402 cmp_ok( $this, 'eq', $that, 'this eq that' );
404 # ok( $this == $that );
405 cmp_ok( $this, '==', $that, 'this == that' );
407 # ok( $this && $that );
408 cmp_ok( $this, '&&', $that, 'this && that' );
411 Its advantage over ok() is when the test fails you'll know what $this
415 # Failed test in foo.t at line 12.
420 It's also useful in those cases where you are comparing numbers and
421 is()'s use of C<eq> will interfere:
423 cmp_ok( $big_hairy_number, '==', $another_big_hairy_number );
428 my $tb = Test::More->builder;
436 can_ok($module, @methods);
437 can_ok($object, @methods);
439 Checks to make sure the $module or $object can do these @methods
440 (works with functions, too).
442 can_ok('Foo', qw(this that whatever));
444 is almost exactly like saying:
446 ok( Foo->can('this') &&
451 only without all the typing and with a better interface. Handy for
452 quickly testing an interface.
454 No matter how many @methods you check, a single can_ok() call counts
455 as one test. If you desire otherwise, use:
457 foreach my $meth (@methods) {
458 can_ok('Foo', $meth);
464 my($proto, @methods) = @_;
465 my $class = ref $proto || $proto;
466 my $tb = Test::More->builder;
469 my $ok = $tb->ok( 0, "->can(...)" );
470 $tb->diag(' can_ok() called with empty class or reference');
475 my $ok = $tb->ok( 0, "$class->can(...)" );
476 $tb->diag(' can_ok() called with no methods');
481 foreach my $method (@methods) {
482 local($!, $@); # don't interfere with caller's $@
483 # eval sometimes resets $!
484 eval { $proto->can($method) } || push @nok, $method;
488 $name = @methods == 1 ? "$class->can('$methods[0]')"
489 : "$class->can(...)";
491 my $ok = $tb->ok( !@nok, $name );
493 $tb->diag(map " $class->can('$_') failed\n", @nok);
500 isa_ok($object, $class, $object_name);
501 isa_ok($ref, $type, $ref_name);
503 Checks to see if the given C<< $object->isa($class) >>. Also checks to make
504 sure the object was defined in the first place. Handy for this sort
507 my $obj = Some::Module->new;
508 isa_ok( $obj, 'Some::Module' );
510 where you'd otherwise have to write
512 my $obj = Some::Module->new;
513 ok( defined $obj && $obj->isa('Some::Module') );
515 to safeguard against your test script blowing up.
517 It works on references, too:
519 isa_ok( $array_ref, 'ARRAY' );
521 The diagnostics of this test normally just refer to 'the object'. If
522 you'd like them to be more specific, you can supply an $object_name
523 (for example 'Test customer').
528 my($object, $class, $obj_name) = @_;
529 my $tb = Test::More->builder;
532 $obj_name = 'The object' unless defined $obj_name;
533 my $name = "$obj_name isa $class";
534 if( !defined $object ) {
535 $diag = "$obj_name isn't defined";
537 elsif( !ref $object ) {
538 $diag = "$obj_name isn't a reference";
541 # We can't use UNIVERSAL::isa because we want to honor isa() overrides
542 local($@, $!); # eval sometimes resets $!
543 my $rslt = eval { $object->isa($class) };
545 if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
546 if( !UNIVERSAL::isa($object, $class) ) {
547 my $ref = ref $object;
548 $diag = "$obj_name isn't a '$class' it's a '$ref'";
552 WHOA! I tried to call ->isa on your object and got some weird error.
553 This should never happen. Please contact the author immediately.
560 my $ref = ref $object;
561 $diag = "$obj_name isn't a '$class' it's a '$ref'";
569 $ok = $tb->ok( 0, $name );
570 $tb->diag(" $diag\n");
573 $ok = $tb->ok( 1, $name );
587 Sometimes you just want to say that the tests have passed. Usually
588 the case is you've got some complicated condition that is difficult to
589 wedge into an ok(). In this case, you can simply use pass() (to
590 declare the test ok) or fail (for not ok). They are synonyms for
593 Use these very, very, very sparingly.
598 my $tb = Test::More->builder;
603 my $tb = Test::More->builder;
612 You usually want to test if the module you're testing loads ok, rather
613 than just vomiting if its load fails. For such purposes we have
614 C<use_ok> and C<require_ok>.
620 BEGIN { use_ok($module); }
621 BEGIN { use_ok($module, @imports); }
623 These simply use the given $module and test to make sure the load
624 happened ok. It's recommended that you run use_ok() inside a BEGIN
625 block so its functions are exported at compile-time and prototypes are
628 If @imports are given, they are passed through to the use. So this:
630 BEGIN { use_ok('Some::Module', qw(foo bar)) }
634 use Some::Module qw(foo bar);
636 Version numbers can be checked like so:
638 # Just like "use Some::Module 1.02"
639 BEGIN { use_ok('Some::Module', 1.02) }
641 Don't try to do this:
644 use_ok('Some::Module');
646 ...some code that depends on the use...
647 ...happening at compile time...
650 because the notion of "compile-time" is relative. Instead, you want:
652 BEGIN { use_ok('Some::Module') }
653 BEGIN { ...some code that depends on the use... }
659 my($module, @imports) = @_;
660 @imports = () unless @imports;
661 my $tb = Test::More->builder;
663 my($pack,$filename,$line) = caller;
665 local($@,$!); # eval sometimes interferes with $!
667 if( @imports == 1 and $imports[0] =~ /^\d+(?:\.\d+)?$/ ) {
668 # probably a version check. Perl needs to see the bare number
669 # for it to work with non-Exporter based modules.
672 use $module $imports[0];
678 use $module \@imports;
682 my $ok = $tb->ok( !$@, "use $module;" );
686 $@ =~ s{^BEGIN failed--compilation aborted at .*$}
687 {BEGIN failed--compilation aborted at $filename line $line.}m;
688 $tb->diag(<<DIAGNOSTIC);
689 Tried to use '$module'.
703 Like use_ok(), except it requires the $module or $file.
709 my $tb = Test::More->builder;
713 # Try to deterine if we've been given a module name or file.
714 # Module names must be barewords, files not.
715 $module = qq['$module'] unless _is_module_name($module);
717 local($!, $@); # eval sometimes interferes with $!
723 my $ok = $tb->ok( !$@, "require $module;" );
727 $tb->diag(<<DIAGNOSTIC);
728 Tried to require '$module'.
738 sub _is_module_name {
741 # Module names start with a letter.
742 # End with an alphanumeric.
743 # The rest is an alphanumeric or ::
744 $module =~ s/\b::\b//g;
745 $module =~ /^[a-zA-Z]\w*$/;
751 =head2 Complex data structures
753 Not everything is a simple eq check or regex. There are times you
754 need to see if two data structures are equivalent. For these
755 instances Test::More provides a handful of useful functions.
757 B<NOTE> I'm not quite sure what will happen with filehandles.
763 is_deeply( $this, $that, $test_name );
765 Similar to is(), except that if $this and $that are references, it
766 does a deep comparison walking each data structure to see if they are
767 equivalent. If the two structures are different, it will display the
768 place where they start differing.
770 is_deeply() compares the dereferenced values of references, the
771 references themselves (except for their type) are ignored. This means
772 aspects such as blessing and ties are not considered "different".
774 is_deeply() current has very limited handling of function reference
775 and globs. It merely checks if they have the same referent. This may
776 improve in the future.
778 Test::Differences and Test::Deep provide more in-depth functionality
783 use vars qw(@Data_Stack %Refs_Seen);
784 my $DNE = bless [], 'Does::Not::Exist';
786 my $tb = Test::More->builder;
788 unless( @_ == 2 or @_ == 3 ) {
790 is_deeply() takes two or three args, you gave %d.
791 This usually means you passed an array or hash instead
794 chop $msg; # clip off newline so carp() will put in line/file
796 _carp sprintf $msg, scalar @_;
801 my($this, $that, $name) = @_;
803 $tb->_unoverload_str(\$that, \$this);
806 if( !ref $this and !ref $that ) { # neither is a reference
807 $ok = $tb->is_eq($this, $that, $name);
809 elsif( !ref $this xor !ref $that ) { # one's a reference, one isn't
810 $ok = $tb->ok(0, $name);
811 $tb->diag( _format_stack({ vals => [ $this, $that ] }) );
813 else { # both references
814 local @Data_Stack = ();
815 if( _deep_check($this, $that) ) {
816 $ok = $tb->ok(1, $name);
819 $ok = $tb->ok(0, $name);
820 $tb->diag(_format_stack(@Data_Stack));
832 foreach my $entry (@Stack) {
833 my $type = $entry->{type} || '';
834 my $idx = $entry->{'idx'};
835 if( $type eq 'HASH' ) {
836 $var .= "->" unless $did_arrow++;
839 elsif( $type eq 'ARRAY' ) {
840 $var .= "->" unless $did_arrow++;
843 elsif( $type eq 'REF' ) {
848 my @vals = @{$Stack[-1]{vals}}[0,1];
850 ($vars[0] = $var) =~ s/\$FOO/ \$got/;
851 ($vars[1] = $var) =~ s/\$FOO/\$expected/;
853 my $out = "Structures begin differing at:\n";
854 foreach my $idx (0..$#vals) {
855 my $val = $vals[$idx];
856 $vals[$idx] = !defined $val ? 'undef' :
857 $val eq $DNE ? "Does not exist" :
862 $out .= "$vars[0] = $vals[0]\n";
863 $out .= "$vars[1] = $vals[1]\n";
873 return '' if !ref $thing;
875 for my $type (qw(ARRAY HASH REF SCALAR GLOB CODE Regexp)) {
876 return $type if UNIVERSAL::isa($thing, $type);
887 If you pick the right test function, you'll usually get a good idea of
888 what went wrong when it failed. But sometimes it doesn't work out
889 that way. So here we have ways for you to write your own diagnostic
890 messages which are safer than just C<print STDERR>.
896 diag(@diagnostic_message);
898 Prints a diagnostic message which is guaranteed not to interfere with
899 test output. Like C<print> @diagnostic_message is simply concatenated
902 Handy for this sort of thing:
904 ok( grep(/foo/, @users), "There's a foo user" ) or
905 diag("Since there's no foo, check that /etc/bar is set up right");
909 not ok 42 - There's a foo user
910 # Failed test 'There's a foo user'
911 # in foo.t at line 52.
912 # Since there's no foo, check that /etc/bar is set up right.
914 You might remember C<ok() or diag()> with the mnemonic C<open() or
917 B<NOTE> The exact formatting of the diagnostic output is still
918 changing, but it is guaranteed that whatever you throw at it it won't
919 interfere with the test.
924 my $tb = Test::More->builder;
933 =head2 Conditional tests
935 Sometimes running a test under certain conditions will cause the
936 test script to die. A certain function or method isn't implemented
937 (such as fork() on MacOS), some resource isn't available (like a
938 net connection) or a module isn't available. In these cases it's
939 necessary to skip tests, or declare that they are supposed to fail
940 but will work in the future (a todo test).
942 For more details on the mechanics of skip and todo tests see
945 The way Test::More handles this is with a named block. Basically, a
946 block of tests which can be skipped over or made todo. It's best if I
954 skip $why, $how_many if $condition;
956 ...normal testing code goes here...
959 This declares a block of tests that might be skipped, $how_many tests
960 there are, $why and under what $condition to skip them. An example is
961 the easiest way to illustrate:
964 eval { require HTML::Lint };
966 skip "HTML::Lint not installed", 2 if $@;
968 my $lint = new HTML::Lint;
969 isa_ok( $lint, "HTML::Lint" );
971 $lint->parse( $html );
972 is( $lint->errors, 0, "No errors found in HTML" );
975 If the user does not have HTML::Lint installed, the whole block of
976 code I<won't be run at all>. Test::More will output special ok's
977 which Test::Harness interprets as skipped, but passing, tests.
979 It's important that $how_many accurately reflects the number of tests
980 in the SKIP block so the # of tests run will match up with your plan.
981 If your plan is C<no_plan> $how_many is optional and will default to 1.
983 It's perfectly safe to nest SKIP blocks. Each SKIP block must have
984 the label C<SKIP>, or Test::More can't work its magic.
986 You don't skip tests which are failing because there's a bug in your
987 program, or for which you don't yet have code written. For that you
994 my($why, $how_many) = @_;
995 my $tb = Test::More->builder;
997 unless( defined $how_many ) {
998 # $how_many can only be avoided when no_plan is in use.
999 _carp "skip() needs to know \$how_many tests are in the block"
1000 unless $tb->has_plan eq 'no_plan';
1004 for( 1..$how_many ) {
1013 =item B<TODO: BLOCK>
1016 local $TODO = $why if $condition;
1018 ...normal testing code goes here...
1021 Declares a block of tests you expect to fail and $why. Perhaps it's
1022 because you haven't fixed a bug or haven't finished a new feature:
1025 local $TODO = "URI::Geller not finished";
1027 my $card = "Eight of clubs";
1028 is( URI::Geller->your_card, $card, 'Is THIS your card?' );
1031 URI::Geller->bend_spoon;
1032 is( $spoon, 'bent', "Spoon bending, that's original" );
1035 With a todo block, the tests inside are expected to fail. Test::More
1036 will run the tests normally, but print out special flags indicating
1037 they are "todo". Test::Harness will interpret failures as being ok.
1038 Should anything succeed, it will report it as an unexpected success.
1039 You then know the thing you had todo is done and can remove the
1042 The nice part about todo tests, as opposed to simply commenting out a
1043 block of tests, is it's like having a programmatic todo list. You know
1044 how much work is left to be done, you're aware of what bugs there are,
1045 and you'll know immediately when they're fixed.
1047 Once a todo test starts succeeding, simply move it outside the block.
1048 When the block is empty, delete it.
1050 B<NOTE>: TODO tests require a Test::Harness upgrade else it will
1051 treat it as a normal failure. See L<CAVEATS and NOTES>).
1057 todo_skip $why, $how_many if $condition;
1059 ...normal testing code...
1062 With todo tests, it's best to have the tests actually run. That way
1063 you'll know when they start passing. Sometimes this isn't possible.
1064 Often a failing test will cause the whole program to die or hang, even
1065 inside an C<eval BLOCK> with and using C<alarm>. In these extreme
1066 cases you have no choice but to skip over the broken tests entirely.
1068 The syntax and behavior is similar to a C<SKIP: BLOCK> except the
1069 tests will be marked as failing but todo. Test::Harness will
1070 interpret them as passing.
1075 my($why, $how_many) = @_;
1076 my $tb = Test::More->builder;
1078 unless( defined $how_many ) {
1079 # $how_many can only be avoided when no_plan is in use.
1080 _carp "todo_skip() needs to know \$how_many tests are in the block"
1081 unless $tb->has_plan eq 'no_plan';
1085 for( 1..$how_many ) {
1086 $tb->todo_skip($why);
1093 =item When do I use SKIP vs. TODO?
1095 B<If it's something the user might not be able to do>, use SKIP.
1096 This includes optional modules that aren't installed, running under
1097 an OS that doesn't have some feature (like fork() or symlinks), or maybe
1098 you need an Internet connection and one isn't available.
1100 B<If it's something the programmer hasn't done yet>, use TODO. This
1101 is for any code you haven't written yet, or bugs you have yet to fix,
1102 but want to put tests in your testing script (always a good idea).
1116 Indicates to the harness that things are going so badly all testing
1117 should terminate. This includes the running any additional test scripts.
1119 This is typically used when testing cannot continue such as a critical
1120 module failing to compile or a necessary external utility not being
1121 available such as a database connection failing.
1123 The test will exit with 255.
1129 my $tb = Test::More->builder;
1131 $tb->BAIL_OUT($reason);
1137 =head2 Discouraged comparison functions
1139 The use of the following functions is discouraged as they are not
1140 actually testing functions and produce no diagnostics to help figure
1141 out what went wrong. They were written before is_deeply() existed
1142 because I couldn't figure out how to display a useful diff of two
1143 arbitrary data structures.
1145 These functions are usually used inside an ok().
1147 ok( eq_array(\@this, \@that) );
1149 C<is_deeply()> can do that better and with diagnostics.
1151 is_deeply( \@this, \@that );
1153 They may be deprecated in future versions.
1159 my $is_eq = eq_array(\@this, \@that);
1161 Checks if two arrays are equivalent. This is a deep check, so
1162 multi-level structures are handled correctly.
1175 if( grep !_type($_) eq 'ARRAY', $a1, $a2 ) {
1176 warn "eq_array passed a non-array ref";
1180 return 1 if $a1 eq $a2;
1183 my $max = $#$a1 > $#$a2 ? $#$a1 : $#$a2;
1185 my $e1 = $_ > $#$a1 ? $DNE : $a1->[$_];
1186 my $e2 = $_ > $#$a2 ? $DNE : $a2->[$_];
1188 push @Data_Stack, { type => 'ARRAY', idx => $_, vals => [$e1, $e2] };
1189 $ok = _deep_check($e1,$e2);
1190 pop @Data_Stack if $ok;
1200 my $tb = Test::More->builder;
1204 # Effectively turn %Refs_Seen into a stack. This avoids picking up
1205 # the same referenced used twice (such as [\$a, \$a]) to be considered
1207 local %Refs_Seen = %Refs_Seen;
1210 # Quiet uninitialized value warnings when comparing undefs.
1213 $tb->_unoverload_str(\$e1, \$e2);
1215 # Either they're both references or both not.
1216 my $same_ref = !(!ref $e1 xor !ref $e2);
1217 my $not_ref = (!ref $e1 and !ref $e2);
1219 if( defined $e1 xor defined $e2 ) {
1222 elsif ( $e1 == $DNE xor $e2 == $DNE ) {
1225 elsif ( $same_ref and ($e1 eq $e2) ) {
1228 elsif ( $not_ref ) {
1229 push @Data_Stack, { type => '', vals => [$e1, $e2] };
1233 if( $Refs_Seen{$e1} ) {
1234 return $Refs_Seen{$e1} eq $e2;
1237 $Refs_Seen{$e1} = "$e2";
1240 my $type = _type($e1);
1241 $type = 'DIFFERENT' unless _type($e2) eq $type;
1243 if( $type eq 'DIFFERENT' ) {
1244 push @Data_Stack, { type => $type, vals => [$e1, $e2] };
1247 elsif( $type eq 'ARRAY' ) {
1248 $ok = _eq_array($e1, $e2);
1250 elsif( $type eq 'HASH' ) {
1251 $ok = _eq_hash($e1, $e2);
1253 elsif( $type eq 'REF' ) {
1254 push @Data_Stack, { type => $type, vals => [$e1, $e2] };
1255 $ok = _deep_check($$e1, $$e2);
1256 pop @Data_Stack if $ok;
1258 elsif( $type eq 'SCALAR' ) {
1259 push @Data_Stack, { type => 'REF', vals => [$e1, $e2] };
1260 $ok = _deep_check($$e1, $$e2);
1261 pop @Data_Stack if $ok;
1264 push @Data_Stack, { type => $type, vals => [$e1, $e2] };
1268 _whoa(1, "No type in _deep_check");
1278 my($check, $desc) = @_;
1282 This should never happen! Please contact the author immediately!
1290 my $is_eq = eq_hash(\%this, \%that);
1292 Determines if the two hashes contain the same keys and values. This
1299 return _deep_check(@_);
1305 if( grep !_type($_) eq 'HASH', $a1, $a2 ) {
1306 warn "eq_hash passed a non-hash ref";
1310 return 1 if $a1 eq $a2;
1313 my $bigger = keys %$a1 > keys %$a2 ? $a1 : $a2;
1314 foreach my $k (keys %$bigger) {
1315 my $e1 = exists $a1->{$k} ? $a1->{$k} : $DNE;
1316 my $e2 = exists $a2->{$k} ? $a2->{$k} : $DNE;
1318 push @Data_Stack, { type => 'HASH', idx => $k, vals => [$e1, $e2] };
1319 $ok = _deep_check($e1, $e2);
1320 pop @Data_Stack if $ok;
1330 my $is_eq = eq_set(\@this, \@that);
1332 Similar to eq_array(), except the order of the elements is B<not>
1333 important. This is a deep check, but the irrelevancy of order only
1334 applies to the top level.
1336 ok( eq_set(\@this, \@that) );
1340 is_deeply( [sort @this], [sort @that] );
1342 B<NOTE> By historical accident, this is not a true set comparison.
1343 While the order of elements does not matter, duplicate elements do.
1345 B<NOTE> eq_set() does not know how to deal with references at the top
1346 level. The following is an example of a comparison which might not work:
1348 eq_set([\1, \2], [\2, \1]);
1350 Test::Deep contains much better set comparison functions.
1356 return 0 unless @$a1 == @$a2;
1358 # There's faster ways to do this, but this is easiest.
1361 # It really doesn't matter how we sort them, as long as both arrays are
1362 # sorted with the same algorithm.
1364 # Ensure that references are not accidentally treated the same as a
1365 # string containing the reference.
1367 # Have to inline the sort routine due to a threading/sort bug.
1368 # See [rt.cpan.org 6782]
1370 # I don't know how references would be sorted so we just don't sort
1371 # them. This means eq_set doesn't really work with refs.
1373 [grep(ref, @$a1), sort( grep(!ref, @$a1) )],
1374 [grep(ref, @$a2), sort( grep(!ref, @$a2) )],
1381 =head2 Extending and Embedding Test::More
1383 Sometimes the Test::More interface isn't quite enough. Fortunately,
1384 Test::More is built on top of Test::Builder which provides a single,
1385 unified backend for any test library to use. This means two test
1386 libraries which both use Test::Builder B<can be used together in the
1389 If you simply want to do a little tweaking of how the tests behave,
1390 you can access the underlying Test::Builder object like so:
1396 my $test_builder = Test::More->builder;
1398 Returns the Test::Builder object underlying Test::More for you to play
1407 If all your tests passed, Test::Builder will exit with zero (which is
1408 normal). If anything failed it will exit with how many failed. If
1409 you run less (or more) tests than you planned, the missing (or extras)
1410 will be considered failures. If no tests were ever run Test::Builder
1411 will throw a warning and exit with 255. If the test died, even after
1412 having successfully completed all its tests, it will still be
1413 considered a failure and will exit with 255.
1415 So the exit codes are...
1417 0 all tests successful
1418 255 test died or all passed but wrong # of tests run
1419 any other number how many failed (including missing or extras)
1421 If you fail more than 254 tests, it will be reported as 254.
1423 B<NOTE> This behavior may go away in future versions.
1426 =head1 CAVEATS and NOTES
1430 =item Backwards compatibility
1432 Test::More works with Perls as old as 5.004_05.
1435 =item Overloaded objects
1437 String overloaded objects are compared B<as strings> (or in cmp_ok()'s
1438 case, strings or numbers as appropriate to the comparison op). This
1439 prevents Test::More from piercing an object's interface allowing
1440 better blackbox testing. So if a function starts returning overloaded
1441 objects instead of bare strings your tests won't notice the
1442 difference. This is good.
1444 However, it does mean that functions like is_deeply() cannot be used to
1445 test the internals of string overloaded objects. In this case I would
1446 suggest Test::Deep which contains more flexible testing functions for
1447 complex data structures.
1452 Test::More will only be aware of threads if "use threads" has been done
1453 I<before> Test::More is loaded. This is ok:
1458 This may cause problems:
1464 =item Test::Harness upgrade
1466 no_plan and todo depend on new Test::Harness features and fixes. If
1467 you're going to distribute tests that use no_plan or todo your
1468 end-users will have to upgrade Test::Harness to the latest one on
1469 CPAN. If you avoid no_plan and TODO tests, the stock Test::Harness
1472 Installing Test::More should also upgrade Test::Harness.
1479 This is a case of convergent evolution with Joshua Pritikin's Test
1480 module. I was largely unaware of its existence when I'd first
1481 written my own ok() routines. This module exists because I can't
1482 figure out how to easily wedge test names into Test's interface (along
1483 with a few other problems).
1485 The goal here is to have a testing utility that's simple to learn,
1486 quick to use and difficult to trip yourself up with while still
1487 providing more flexibility than the existing Test.pm. As such, the
1488 names of the most common routines are kept tiny, special cases and
1489 magic side-effects are kept to a minimum. WYSIWYG.
1494 L<Test::Simple> if all this confuses you and you just want to write
1495 some tests. You can upgrade to Test::More later (it's forward
1498 L<Test> is the old testing module. Its main benefit is that it has
1499 been distributed with Perl since 5.004_05.
1501 L<Test::Harness> for details on how your test results are interpreted
1504 L<Test::Differences> for more ways to test complex data structures.
1505 And it plays well with Test::More.
1507 L<Test::Class> is like XUnit but more perlish.
1509 L<Test::Deep> gives you more powerful complex data structure testing.
1511 L<Test::Unit> is XUnit style testing.
1513 L<Test::Inline> shows the idea of embedded testing.
1515 L<Bundle::Test> installs a whole bunch of useful test modules.
1520 Michael G Schwern E<lt>schwern@pobox.comE<gt> with much inspiration
1521 from Joshua Pritikin's Test module and lots of help from Barrie
1522 Slaymaker, Tony Bowden, blackstar.co.uk, chromatic, Fergal Daly and
1528 See F<http://rt.cpan.org> to report and view bugs.
1533 Copyright 2001, 2002, 2004 by Michael G Schwern E<lt>schwern@pobox.comE<gt>.
1535 This program is free software; you can redistribute it and/or
1536 modify it under the same terms as Perl itself.
1538 See F<http://www.perl.com/perl/misc/Artistic.html>