lib/Test/Harness.pm

   1 # -*- Mode: cperl; cperl-indent-level: 4 -*-
   2 # $Id: Harness.pm,v 1.31 2002/05/18 20:19:06 schwern Exp $
   3
   4 package Test::Harness;
   5
   6 require 5.004;
   7 use Test::Harness::Straps;
   8 use Test::Harness::Assert;
   9 use Exporter;
  10 use Benchmark;
  11 use Config;
  12 use strict;
  13
  14 use vars qw($VERSION $Verbose $Switches $Have_Devel_Corestack $Curtest
  15             $Columns $verbose $switches $ML
  16             @ISA @EXPORT @EXPORT_OK
  17            );
  18
  19 # Backwards compatibility for exportable variable names.
  20 *verbose  = \$Verbose;
  21 *switches = \$Switches;
  22
  23 $Have_Devel_Corestack = 0;
  24
  25 $VERSION = '2.23';
  26
  27 $ENV{HARNESS_ACTIVE} = 1;
  28
  29 END {
  30     # For VMS.
  31     delete $ENV{HARNESS_ACTIVE};
  32 }
  33
  34 # Some experimental versions of OS/2 build have broken $?
  35 my $Ignore_Exitcode = $ENV{HARNESS_IGNORE_EXITCODE};
  36
  37 my $Files_In_Dir = $ENV{HARNESS_FILELEAK_IN_DIR};
  38
  39 my $Strap = Test::Harness::Straps->new;
  40
  41 @ISA = ('Exporter');
  42 @EXPORT    = qw(&runtests);
  43 @EXPORT_OK = qw($verbose $switches);
  44
  45 $Verbose  = $ENV{HARNESS_VERBOSE} || 0;
  46 $Switches = "-w";
  47 $Columns  = $ENV{HARNESS_COLUMNS} || $ENV{COLUMNS} || 80;
  48 $Columns--;             # Some shells have trouble with a full line of text.
  49
  50
  51 =head1 NAME
  52
  53 Test::Harness - run perl standard test scripts with statistics
  54
  55 =head1 SYNOPSIS
  56
  57   use Test::Harness;
  58
  59   runtests(@test_files);
  60
  61 =head1 DESCRIPTION
  62
  63 B<STOP!> If all you want to do is write a test script, consider using
  64 Test::Simple.  Otherwise, read on.
  65
  66 (By using the Test module, you can write test scripts without
  67 knowing the exact output this module expects.  However, if you need to
  68 know the specifics, read on!)
  69
  70 Perl test scripts print to standard output C<"ok N"> for each single
  71 test, where C<N> is an increasing sequence of integers. The first line
  72 output by a standard test script is C<"1..M"> with C<M> being the
  73 number of tests that should be run within the test
  74 script. Test::Harness::runtests(@tests) runs all the testscripts
  75 named as arguments and checks standard output for the expected
  76 C<"ok N"> strings.
  77
  78 After all tests have been performed, runtests() prints some
  79 performance statistics that are computed by the Benchmark module.
  80
  81 =head2 The test script output
  82
  83 The following explains how Test::Harness interprets the output of your
  84 test program.
  85
  86 =over 4
  87
  88 =item B<'1..M'>
  89
  90 This header tells how many tests there will be.  For example, C<1..10>
  91 means you plan on running 10 tests.  This is a safeguard in case your
  92 test dies quietly in the middle of its run.
  93
  94 It should be the first non-comment line output by your test program.
  95
  96 In certain instances, you may not know how many tests you will
  97 ultimately be running.  In this case, it is permitted for the 1..M
  98 header to appear as the B<last> line output by your test (again, it
  99 can be followed by further comments).
 100
 101 Under B<no> circumstances should 1..M appear in the middle of your
 102 output or more than once.
 103
 104
 105 =item B<'ok', 'not ok'.  Ok?>
 106
 107 Any output from the testscript to standard error is ignored and
 108 bypassed, thus will be seen by the user. Lines written to standard
 109 output containing C</^(not\s+)?ok\b/> are interpreted as feedback for
 110 runtests().  All other lines are discarded.
 111
 112 C</^not ok/> indicates a failed test.  C</^ok/> is a successful test.
 113
 114
 115 =item B<test numbers>
 116
 117 Perl normally expects the 'ok' or 'not ok' to be followed by a test
 118 number.  It is tolerated if the test numbers after 'ok' are
 119 omitted. In this case Test::Harness maintains temporarily its own
 120 counter until the script supplies test numbers again. So the following
 121 test script
 122
 123     print <<END;
 124     1..6
 125     not ok
 126     ok
 127     not ok
 128     ok
 129     ok
 130     END
 131
 132 will generate
 133
 134     FAILED tests 1, 3, 6
 135     Failed 3/6 tests, 50.00% okay
 136
 137 =item B<test names>
 138
 139 Anything after the test number but before the # is considered to be
 140 the name of the test.
 141
 142   ok 42 this is the name of the test
 143
 144 Currently, Test::Harness does nothing with this information.
 145
 146 =item B<Skipping tests>
 147
 148 If the standard output line contains the substring C< # Skip> (with
 149 variations in spacing and case) after C<ok> or C<ok NUMBER>, it is
 150 counted as a skipped test.  If the whole testscript succeeds, the
 151 count of skipped tests is included in the generated output.
 152 C<Test::Harness> reports the text after C< # Skip\S*\s+> as a reason
 153 for skipping.
 154
 155   ok 23 # skip Insufficient flogiston pressure.
 156
 157 Similarly, one can include a similar explanation in a C<1..0> line
 158 emitted if the test script is skipped completely:
 159
 160   1..0 # Skipped: no leverage found
 161
 162 =item B<Todo tests>
 163
 164 If the standard output line contains the substring C< # TODO> after
 165 C<not ok> or C<not ok NUMBER>, it is counted as a todo test.  The text
 166 afterwards is the thing that has to be done before this test will
 167 succeed.
 168
 169   not ok 13 # TODO harness the power of the atom
 170
 171 =begin _deprecated
 172
 173 Alternatively, you can specify a list of what tests are todo as part
 174 of the test header.
 175
 176   1..23 todo 5 12 23
 177
 178 This only works if the header appears at the beginning of the test.
 179
 180 This style is B<deprecated>.
 181
 182 =end _deprecated
 183
 184 These tests represent a feature to be implemented or a bug to be fixed
 185 and act as something of an executable "thing to do" list.  They are
 186 B<not> expected to succeed.  Should a todo test begin succeeding,
 187 Test::Harness will report it as a bonus.  This indicates that whatever
 188 you were supposed to do has been done and you should promote this to a
 189 normal test.
 190
 191 =item B<Bail out!>
 192
 193 As an emergency measure, a test script can decide that further tests
 194 are useless (e.g. missing dependencies) and testing should stop
 195 immediately. In that case the test script prints the magic words
 196
 197   Bail out!
 198
 199 to standard output. Any message after these words will be displayed by
 200 C<Test::Harness> as the reason why testing is stopped.
 201
 202 =item B<Comments>
 203
 204 Additional comments may be put into the testing output on their own
 205 lines.  Comment lines should begin with a '#', Test::Harness will
 206 ignore them.
 207
 208   ok 1
 209   # Life is good, the sun is shining, RAM is cheap.
 210   not ok 2
 211   # got 'Bush' expected 'Gore'
 212
 213 =item B<Anything else>
 214
 215 Any other output Test::Harness sees it will silently ignore B<BUT WE
 216 PLAN TO CHANGE THIS!> If you wish to place additional output in your
 217 test script, please use a comment.
 218
 219 =back
 220
 221
 222 =head2 Taint mode
 223
 224 Test::Harness will honor the C<-T> in the #! line on your test files.  So
 225 if you begin a test with:
 226
 227     #!perl -T
 228
 229 the test will be run with taint mode on.
 230
 231
 232 =head2 Configuration variables.
 233
 234 These variables can be used to configure the behavior of
 235 Test::Harness.  They are exported on request.
 236
 237 =over 4
 238
 239 =item B<$Test::Harness::verbose>
 240
 241 The global variable $Test::Harness::verbose is exportable and can be
 242 used to let runtests() display the standard output of the script
 243 without altering the behavior otherwise.
 244
 245 =item B<$Test::Harness::switches>
 246
 247 The global variable $Test::Harness::switches is exportable and can be
 248 used to set perl command line options used for running the test
 249 script(s). The default value is C<-w>.
 250
 251 =back
 252
 253
 254 =head2 Failure
 255
 256 It will happen, your tests will fail.  After you mop up your ego, you
 257 can begin examining the summary report:
 258
 259   t/base..............ok
 260   t/nonumbers.........ok
 261   t/ok................ok
 262   t/test-harness......ok
 263   t/waterloo..........dubious
 264           Test returned status 3 (wstat 768, 0x300)
 265   DIED. FAILED tests 1, 3, 5, 7, 9, 11, 13, 15, 17, 19
 266           Failed 10/20 tests, 50.00% okay
 267   Failed Test  Stat Wstat Total Fail  Failed  List of Failed
 268   -----------------------------------------------------------------------
 269   t/waterloo.t    3   768    20   10  50.00%  1 3 5 7 9 11 13 15 17 19
 270   Failed 1/5 test scripts, 80.00% okay. 10/44 subtests failed, 77.27% okay.
 271
 272 Everything passed but t/waterloo.t.  It failed 10 of 20 tests and
 273 exited with non-zero status indicating something dubious happened.
 274
 275 The columns in the summary report mean:
 276
 277 =over 4
 278
 279 =item B<Failed Test>
 280
 281 The test file which failed.
 282
 283 =item B<Stat>
 284
 285 If the test exited with non-zero, this is its exit status.
 286
 287 =item B<Wstat>
 288
 289 The wait status of the test I<umm, I need a better explanation here>.
 290
 291 =item B<Total>
 292
 293 Total number of tests expected to run.
 294
 295 =item B<Fail>
 296
 297 Number which failed, either from "not ok" or because they never ran.
 298
 299 =item B<Failed>
 300
 301 Percentage of the total tests which failed.
 302
 303 =item B<List of Failed>
 304
 305 A list of the tests which failed.  Successive failures may be
 306 abbreviated (ie. 15-20 to indicate that tests 15, 16, 17, 18, 19 and
 307 20 failed).
 308
 309 =back
 310
 311
 312 =head2 Functions
 313
 314 Test::Harness currently only has one function, here it is.
 315
 316 =over 4
 317
 318 =item B<runtests>
 319
 320   my $allok = runtests(@test_files);
 321
 322 This runs all the given @test_files and divines whether they passed
 323 or failed based on their output to STDOUT (details above).  It prints
 324 out each individual test which failed along with a summary report and
 325 a how long it all took.
 326
 327 It returns true if everything was ok, false otherwise.
 328
 329 =for _private
 330 This is just _run_all_tests() plus _show_results()
 331
 332 =cut
 333
 334 sub runtests {
 335     my(@tests) = @_;
 336
 337     local ($\, $,);
 338
 339     my($tot, $failedtests) = _run_all_tests(@tests);
 340     _show_results($tot, $failedtests);
 341
 342     my $ok = _all_ok($tot);
 343
 344     assert(($ok xor keys %$failedtests),
 345            q{ok status jives with $failedtests});
 346
 347     return $ok;
 348 }
 349
 350 =begin _private
 351
 352 =item B<_all_ok>
 353
 354   my $ok = _all_ok(\%tot);
 355
 356 Tells you if this test run is overall successful or not.
 357
 358 =cut
 359
 360 sub _all_ok {
 361     my($tot) = shift;
 362
 363     return $tot->{bad} == 0 && ($tot->{max} || $tot->{skipped}) ? 1 : 0;
 364 }
 365
 366 =item B<_globdir>
 367
 368   my @files = _globdir $dir;
 369
 370 Returns all the files in a directory.  This is shorthand for backwards
 371 compatibility on systems where glob() doesn't work right.
 372
 373 =cut
 374
 375 sub _globdir {
 376     opendir DIRH, shift;
 377     my @f = readdir DIRH;
 378     closedir DIRH;
 379
 380     return @f;
 381 }
 382
 383 =item B<_run_all_tests>
 384
 385   my($total, $failed) = _run_all_tests(@test_files);
 386
 387 Runs all the given @test_files (as runtests()) but does it quietly (no
 388 report).  $total is a hash ref summary of all the tests run.  Its keys
 389 and values are this:
 390
 391     bonus           Number of individual todo tests unexpectedly passed
 392     max             Number of individual tests ran
 393     ok              Number of individual tests passed
 394     sub_skipped     Number of individual tests skipped
 395     todo            Number of individual todo tests
 396
 397     files           Number of test files ran
 398     good            Number of test files passed
 399     bad             Number of test files failed
 400     tests           Number of test files originally given
 401     skipped         Number of test files skipped
 402
 403 If $total->{bad} == 0 and $total->{max} > 0, you've got a successful
 404 test.
 405
 406 $failed is a hash ref of all the test scripts which failed.  Each key
 407 is the name of a test script, each value is another hash representing
 408 how that script failed.  Its keys are these:
 409
 410     name        Name of the test which failed
 411     estat       Script's exit value
 412     wstat       Script's wait status
 413     max         Number of individual tests
 414     failed      Number which failed
 415     percent     Percentage of tests which failed
 416     canon       List of tests which failed (as string).
 417
 418 Needless to say, $failed should be empty if everything passed.
 419
 420 B<NOTE> Currently this function is still noisy.  I'm working on it.
 421
 422 =cut
 423
 424 #'#
 425 sub _run_all_tests {
 426     my(@tests) = @_;
 427     local($|) = 1;
 428     my(%failedtests);
 429
 430     # Test-wide totals.
 431     my(%tot) = (
 432                 bonus    => 0,
 433                 max      => 0,
 434                 ok       => 0,
 435                 files    => 0,
 436                 bad      => 0,
 437                 good     => 0,
 438                 tests    => scalar @tests,
 439                 sub_skipped  => 0,
 440                 todo     => 0,
 441                 skipped  => 0,
 442                 bench    => 0,
 443                );
 444
 445     my @dir_files = _globdir $Files_In_Dir if defined $Files_In_Dir;
 446     my $t_start = new Benchmark;
 447
 448     my $width = _leader_width(@tests);
 449     foreach my $tfile (@tests) {
 450
 451         my($leader, $ml) = _mk_leader($tfile, $width);
 452         local $ML = $ml;
 453         print $leader;
 454
 455         $tot{files}++;
 456
 457         $Strap->{_seen_header} = 0;
 458         my %results = $Strap->analyze_file($tfile);
 459
 460         # state of the current test.
 461         my @failed = grep { !$results{details}[$_-1]{ok} }
 462                      1..@{$results{details}};
 463         my %test = (
 464                     ok          => $results{ok},
 465                     'next'      => $Strap->{'next'},
 466                     max         => $results{max},
 467                     failed      => \@failed,
 468                     bonus       => $results{bonus},
 469                     skipped     => $results{skip},
 470                     skip_reason => $Strap->{_skip_reason},
 471                     skip_all    => $Strap->{skip_all},
 472                     ml          => $ml,
 473                    );
 474
 475         $tot{bonus}       += $results{bonus};
 476         $tot{max}         += $results{max};
 477         $tot{ok}          += $results{ok};
 478         $tot{todo}        += $results{todo};
 479         $tot{sub_skipped} += $results{skip};
 480
 481         my($estatus, $wstatus) = @results{qw(exit wait)};
 482
 483         if ($wstatus) {
 484             $failedtests{$tfile} = _dubious_return(\%test, \%tot,
 485                                                   $estatus, $wstatus);
 486             $failedtests{$tfile}{name} = $tfile;
 487         }
 488         elsif ($results{passing}) {
 489             if ($test{max} and $test{skipped} + $test{bonus}) {
 490                 my @msg;
 491                 push(@msg, "$test{skipped}/$test{max} skipped: $test{skip_reason}")
 492                     if $test{skipped};
 493                 push(@msg, "$test{bonus}/$test{max} unexpectedly succeeded")
 494                     if $test{bonus};
 495                 print "$test{ml}ok\n        ".join(', ', @msg)."\n";
 496             } elsif ($test{max}) {
 497                 print "$test{ml}ok\n";
 498             } elsif (defined $test{skip_all}) {
 499                 print "skipped\n        all skipped: $test{skip_all}\n";
 500                 $tot{skipped}++;
 501             } else {
 502                 print "\n        skipped test on this platform\n";
 503                 $tot{skipped}++;
 504             }
 505             $tot{good}++;
 506         }
 507         else {
 508             if ($test{max}) {
 509                 if ($test{'next'} <= $test{max}) {
 510                     push @{$test{failed}}, $test{'next'}..$test{max};
 511                 }
 512                 if (@{$test{failed}}) {
 513                     my ($txt, $canon) = canonfailed($test{max},$test{skipped},
 514                                                     @{$test{failed}});
 515                     print "$test{ml}$txt";
 516                     $failedtests{$tfile} = { canon   => $canon,
 517                                              max     => $test{max},
 518                                              failed  => scalar @{$test{failed}},
 519                                              name    => $tfile,
 520                                              percent => 100*(scalar @{$test{failed}})/$test{max},
 521                                              estat   => '',
 522                                              wstat   => '',
 523                                            };
 524                 } else {
 525                     print "Don't know which tests failed: got $test{ok} ok, ".
 526                           "expected $test{max}\n";
 527                     $failedtests{$tfile} = { canon   => '??',
 528                                              max     => $test{max},
 529                                              failed  => '??',
 530                                              name    => $tfile,
 531                                              percent => undef,
 532                                              estat   => '',
 533                                              wstat   => '',
 534                                            };
 535                 }
 536                 $tot{bad}++;
 537             } elsif ($test{'next'} == 0) {
 538                 print "FAILED before any test output arrived\n";
 539                 $tot{bad}++;
 540                 $failedtests{$tfile} = { canon       => '??',
 541                                          max         => '??',
 542                                          failed      => '??',
 543                                          name        => $tfile,
 544                                          percent     => undef,
 545                                          estat       => '',
 546                                          wstat       => '',
 547                                        };
 548             }
 549         }
 550
 551         if (defined $Files_In_Dir) {
 552             my @new_dir_files = _globdir $Files_In_Dir;
 553             if (@new_dir_files != @dir_files) {
 554                 my %f;
 555                 @f{@new_dir_files} = (1) x @new_dir_files;
 556                 delete @f{@dir_files};
 557                 my @f = sort keys %f;
 558                 print "LEAKED FILES: @f\n";
 559                 @dir_files = @new_dir_files;
 560             }
 561         }
 562     }
 563     $tot{bench} = timediff(new Benchmark, $t_start);
 564
 565     $Strap->_restore_PERL5LIB;
 566
 567     return(\%tot, \%failedtests);
 568 }
 569
 570 =item B<_mk_leader>
 571
 572   my($leader, $ml) = _mk_leader($test_file, $width);
 573
 574 Generates the 't/foo........' $leader for the given $test_file as well
 575 as a similar version which will overwrite the current line (by use of
 576 \r and such).  $ml may be empty if Test::Harness doesn't think you're
 577 on TTY.
 578
 579 The $width is the width of the "yada/blah.." string.
 580
 581 =cut
 582
 583 sub _mk_leader {
 584     my($te, $width) = @_;
 585     chomp($te);
 586     $te =~ s/\.\w+$/./;
 587
 588     if ($^O eq 'VMS') { $te =~ s/^.*\.t\./\[.t./s; }
 589     my $blank = (' ' x 77);
 590     my $leader = "$te" . '.' x ($width - length($te));
 591     my $ml = "";
 592
 593     $ml = "\r$blank\r$leader"
 594       if -t STDOUT and not $ENV{HARNESS_NOTTY} and not $Verbose;
 595
 596     return($leader, $ml);
 597 }
 598
 599 =item B<_leader_width>
 600
 601   my($width) = _leader_width(@test_files);
 602
 603 Calculates how wide the leader should be based on the length of the
 604 longest test name.
 605
 606 =cut
 607
 608 sub _leader_width {
 609     my $maxlen = 0;
 610     my $maxsuflen = 0;
 611     foreach (@_) {
 612         my $suf    = /\.(\w+)$/ ? $1 : '';
 613         my $len    = length;
 614         my $suflen = length $suf;
 615         $maxlen    = $len    if $len    > $maxlen;
 616         $maxsuflen = $suflen if $suflen > $maxsuflen;
 617     }
 618     # + 3 : we want three dots between the test name and the "ok"
 619     return $maxlen + 3 - $maxsuflen;
 620 }
 621
 622
 623 sub _show_results {
 624     my($tot, $failedtests) = @_;
 625
 626     my $pct;
 627     my $bonusmsg = _bonusmsg($tot);
 628
 629     if (_all_ok($tot)) {
 630         print "All tests successful$bonusmsg.\n";
 631     } elsif (!$tot->{tests}){
 632         die "FAILED--no tests were run for some reason.\n";
 633     } elsif (!$tot->{max}) {
 634         my $blurb = $tot->{tests}==1 ? "script" : "scripts";
 635         die "FAILED--$tot->{tests} test $blurb could be run, ".
 636             "alas--no output ever seen\n";
 637     } else {
 638         $pct = sprintf("%.2f", $tot->{good} / $tot->{tests} * 100);
 639         my $percent_ok = 100*$tot->{ok}/$tot->{max};
 640         my $subpct = sprintf " %d/%d subtests failed, %.2f%% okay.",
 641                               $tot->{max} - $tot->{ok}, $tot->{max},
 642                               $percent_ok;
 643
 644         my($fmt_top, $fmt) = _create_fmts($failedtests);
 645
 646         # Now write to formats
 647         for my $script (sort keys %$failedtests) {
 648           $Curtest = $failedtests->{$script};
 649           write;
 650         }
 651         if ($tot->{bad}) {
 652             $bonusmsg =~ s/^,\s*//;
 653             print "$bonusmsg.\n" if $bonusmsg;
 654             die "Failed $tot->{bad}/$tot->{tests} test scripts, $pct% okay.".
 655                 "$subpct\n";
 656         }
 657     }
 658
 659     printf("Files=%d, Tests=%d, %s\n",
 660            $tot->{files}, $tot->{max}, timestr($tot->{bench}, 'nop'));
 661 }
 662
 663
 664 my %Handlers = ();
 665 $Strap->{callback} = sub {
 666     my($self, $line, $type, $totals) = @_;
 667     print $line if $Verbose;
 668
 669     my $meth = $Handlers{$type};
 670     $meth->($self, $line, $type, $totals) if $meth;
 671 };
 672
 673
 674 $Handlers{header} = sub {
 675     my($self, $line, $type, $totals) = @_;
 676
 677     warn "Test header seen more than once!\n" if $self->{_seen_header};
 678
 679     $self->{_seen_header}++;
 680
 681     warn "1..M can only appear at the beginning or end of tests\n"
 682       if $totals->{seen} &&
 683          $totals->{max}  < $totals->{seen};
 684 };
 685
 686 $Handlers{test} = sub {
 687     my($self, $line, $type, $totals) = @_;
 688
 689     my $curr = $totals->{seen};
 690     my $next = $self->{'next'};
 691     my $max  = $totals->{max};
 692     my $detail = $totals->{details}[-1];
 693
 694     if( $detail->{ok} ) {
 695         _print_ml("ok $curr/$max");
 696
 697         if( $detail->{type} eq 'skip' ) {
 698             $self->{_skip_reason} = $detail->{reason}
 699               unless defined $self->{_skip_reason};
 700             $self->{_skip_reason} = 'various reasons'
 701               if $self->{_skip_reason} ne $detail->{reason};
 702         }
 703     }
 704     else {
 705         _print_ml("NOK $curr");
 706     }
 707
 708     if( $curr > $next ) {
 709         print "Test output counter mismatch [test $curr]\n";
 710     }
 711     elsif( $curr < $next ) {
 712         print "Confused test output: test $curr answered after ".
 713               "test ", $next - 1, "\n";
 714     }
 715
 716 };
 717
 718 $Handlers{bailout} = sub {
 719     my($self, $line, $type, $totals) = @_;
 720
 721     die "FAILED--Further testing stopped" .
 722       ($self->{bailout_reason} ? ": $self->{bailout_reason}\n" : ".\n");
 723 };
 724
 725
 726 sub _print_ml {
 727     print join '', $ML, @_ if $ML;
 728 }
 729
 730
 731 sub _bonusmsg {
 732     my($tot) = @_;
 733
 734     my $bonusmsg = '';
 735     $bonusmsg = (" ($tot->{bonus} subtest".($tot->{bonus} > 1 ? 's' : '').
 736                " UNEXPECTEDLY SUCCEEDED)")
 737         if $tot->{bonus};
 738
 739     if ($tot->{skipped}) {
 740         $bonusmsg .= ", $tot->{skipped} test"
 741                      . ($tot->{skipped} != 1 ? 's' : '');
 742         if ($tot->{sub_skipped}) {
 743             $bonusmsg .= " and $tot->{sub_skipped} subtest"
 744                          . ($tot->{sub_skipped} != 1 ? 's' : '');
 745         }
 746         $bonusmsg .= ' skipped';
 747     }
 748     elsif ($tot->{sub_skipped}) {
 749         $bonusmsg .= ", $tot->{sub_skipped} subtest"
 750                      . ($tot->{sub_skipped} != 1 ? 's' : '')
 751                      . " skipped";
 752     }
 753
 754     return $bonusmsg;
 755 }
 756
 757 # Test program go boom.
 758 sub _dubious_return {
 759     my($test, $tot, $estatus, $wstatus) = @_;
 760     my ($failed, $canon, $percent) = ('??', '??');
 761
 762     printf "$test->{ml}dubious\n\tTest returned status $estatus ".
 763            "(wstat %d, 0x%x)\n",
 764            $wstatus,$wstatus;
 765     print "\t\t(VMS status is $estatus)\n" if $^O eq 'VMS';
 766
 767     if (corestatus($wstatus)) { # until we have a wait module
 768         if ($Have_Devel_Corestack) {
 769             Devel::CoreStack::stack($^X);
 770         } else {
 771             print "\ttest program seems to have generated a core\n";
 772         }
 773     }
 774
 775     $tot->{bad}++;
 776
 777     if ($test->{max}) {
 778         if ($test->{'next'} == $test->{max} + 1 and not @{$test->{failed}}) {
 779             print "\tafter all the subtests completed successfully\n";
 780             $percent = 0;
 781             $failed = 0;        # But we do not set $canon!
 782         }
 783         else {
 784             push @{$test->{failed}}, $test->{'next'}..$test->{max};
 785             $failed = @{$test->{failed}};
 786             (my $txt, $canon) = canonfailed($test->{max},$test->{skipped},@{$test->{failed}});
 787             $percent = 100*(scalar @{$test->{failed}})/$test->{max};
 788             print "DIED. ",$txt;
 789         }
 790     }
 791
 792     return { canon => $canon,  max => $test->{max} || '??',
 793              failed => $failed,
 794              percent => $percent,
 795              estat => $estatus, wstat => $wstatus,
 796            };
 797 }
 798
 799
 800 sub _create_fmts {
 801     my($failedtests) = @_;
 802
 803     my $failed_str = "Failed Test";
 804     my $middle_str = " Stat Wstat Total Fail  Failed  ";
 805     my $list_str = "List of Failed";
 806
 807     # Figure out our longest name string for formatting purposes.
 808     my $max_namelen = length($failed_str);
 809     foreach my $script (keys %$failedtests) {
 810         my $namelen = length $failedtests->{$script}->{name};
 811         $max_namelen = $namelen if $namelen > $max_namelen;
 812     }
 813
 814     my $list_len = $Columns - length($middle_str) - $max_namelen;
 815     if ($list_len < length($list_str)) {
 816         $list_len = length($list_str);
 817         $max_namelen = $Columns - length($middle_str) - $list_len;
 818         if ($max_namelen < length($failed_str)) {
 819             $max_namelen = length($failed_str);
 820             $Columns = $max_namelen + length($middle_str) + $list_len;
 821         }
 822     }
 823
 824     my $fmt_top = "format STDOUT_TOP =\n"
 825                   . sprintf("%-${max_namelen}s", $failed_str)
 826                   . $middle_str
 827                   . $list_str . "\n"
 828                   . "-" x $Columns
 829                   . "\n.\n";
 830
 831     my $fmt = "format STDOUT =\n"
 832               . "@" . "<" x ($max_namelen - 1)
 833               . "  @>> @>>>> @>>>> @>>> ^##.##%  "
 834               . "^" . "<" x ($list_len - 1) . "\n"
 835               . '{ $Curtest->{name}, $Curtest->{estat},'
 836               . '  $Curtest->{wstat}, $Curtest->{max},'
 837               . '  $Curtest->{failed}, $Curtest->{percent},'
 838               . '  $Curtest->{canon}'
 839               . "\n}\n"
 840               . "~~" . " " x ($Columns - $list_len - 2) . "^"
 841               . "<" x ($list_len - 1) . "\n"
 842               . '$Curtest->{canon}'
 843               . "\n.\n";
 844
 845     eval $fmt_top;
 846     die $@ if $@;
 847     eval $fmt;
 848     die $@ if $@;
 849
 850     return($fmt_top, $fmt);
 851 }
 852
 853 {
 854     my $tried_devel_corestack;
 855
 856     sub corestatus {
 857         my($st) = @_;
 858
 859         eval {
 860             local $^W = 0;  # *.ph files are often *very* noisy
 861             require 'wait.ph'
 862         };
 863         return if $@;
 864         my $did_core = defined &WCOREDUMP ? WCOREDUMP($st) : $st & 0200;
 865
 866         eval { require Devel::CoreStack; $Have_Devel_Corestack++ }
 867           unless $tried_devel_corestack++;
 868
 869         return $did_core;
 870     }
 871 }
 872
 873 sub canonfailed ($@) {
 874     my($max,$skipped,@failed) = @_;
 875     my %seen;
 876     @failed = sort {$a <=> $b} grep !$seen{$_}++, @failed;
 877     my $failed = @failed;
 878     my @result = ();
 879     my @canon = ();
 880     my $min;
 881     my $last = $min = shift @failed;
 882     my $canon;
 883     if (@failed) {
 884         for (@failed, $failed[-1]) { # don't forget the last one
 885             if ($_ > $last+1 || $_ == $last) {
 886                 if ($min == $last) {
 887                     push @canon, $last;
 888                 } else {
 889                     push @canon, "$min-$last";
 890                 }
 891                 $min = $_;
 892             }
 893             $last = $_;
 894         }
 895         local $" = ", ";
 896         push @result, "FAILED tests @canon\n";
 897         $canon = join ' ', @canon;
 898     } else {
 899         push @result, "FAILED test $last\n";
 900         $canon = $last;
 901     }
 902
 903     push @result, "\tFailed $failed/$max tests, ";
 904     push @result, sprintf("%.2f",100*(1-$failed/$max)), "% okay";
 905     my $ender = 's' x ($skipped > 1);
 906     my $good = $max - $failed - $skipped;
 907     my $goodper = sprintf("%.2f",100*($good/$max));
 908     push @result, " (less $skipped skipped test$ender: $good okay, ".
 909                   "$goodper%)"
 910          if $skipped;
 911     push @result, "\n";
 912     my $txt = join "", @result;
 913     ($txt, $canon);
 914 }
 915
 916 =end _private
 917
 918 =back
 919
 920 =cut
 921
 922
 923 1;
 924 __END__
 925
 926
 927 =head1 EXPORT
 928
 929 C<&runtests> is exported by Test::Harness per default.
 930
 931 C<$verbose> and C<$switches> are exported upon request.
 932
 933
 934 =head1 DIAGNOSTICS
 935
 936 =over 4
 937
 938 =item C<All tests successful.\nFiles=%d,  Tests=%d, %s>
 939
 940 If all tests are successful some statistics about the performance are
 941 printed.
 942
 943 =item C<FAILED tests %s\n\tFailed %d/%d tests, %.2f%% okay.>
 944
 945 For any single script that has failing subtests statistics like the
 946 above are printed.
 947
 948 =item C<Test returned status %d (wstat %d)>
 949
 950 Scripts that return a non-zero exit status, both C<$? E<gt>E<gt> 8>
 951 and C<$?> are printed in a message similar to the above.
 952
 953 =item C<Failed 1 test, %.2f%% okay. %s>
 954
 955 =item C<Failed %d/%d tests, %.2f%% okay. %s>
 956
 957 If not all tests were successful, the script dies with one of the
 958 above messages.
 959
 960 =item C<FAILED--Further testing stopped: %s>
 961
 962 If a single subtest decides that further testing will not make sense,
 963 the script dies with this message.
 964
 965 =back
 966
 967 =head1 ENVIRONMENT
 968
 969 =over 4
 970
 971 =item C<HARNESS_ACTIVE>
 972
 973 Harness sets this before executing the individual tests.  This allows
 974 the tests to determine if they are being executed through the harness
 975 or by any other means.
 976
 977 =item C<HARNESS_COLUMNS>
 978
 979 This value will be used for the width of the terminal. If it is not
 980 set then it will default to C<COLUMNS>. If this is not set, it will
 981 default to 80. Note that users of Bourne-sh based shells will need to
 982 C<export COLUMNS> for this module to use that variable.
 983
 984 =item C<HARNESS_COMPILE_TEST>
 985
 986 When true it will make harness attempt to compile the test using
 987 C<perlcc> before running it.
 988
 989 B<NOTE> This currently only works when sitting in the perl source
 990 directory!
 991
 992 =item C<HARNESS_FILELEAK_IN_DIR>
 993
 994 When set to the name of a directory, harness will check after each
 995 test whether new files appeared in that directory, and report them as
 996
 997   LEAKED FILES: scr.tmp 0 my.db
 998
 999 If relative, directory name is with respect to the current directory at
1000 the moment runtests() was called.  Putting absolute path into
1001 C<HARNESS_FILELEAK_IN_DIR> may give more predictable results.
1002
1003 =item C<HARNESS_IGNORE_EXITCODE>
1004
1005 Makes harness ignore the exit status of child processes when defined.
1006
1007 =item C<HARNESS_NOTTY>
1008
1009 When set to a true value, forces it to behave as though STDOUT were
1010 not a console.  You may need to set this if you don't want harness to
1011 output more frequent progress messages using carriage returns.  Some
1012 consoles may not handle carriage returns properly (which results in a
1013 somewhat messy output).
1014
1015 =item C<HARNESS_PERL_SWITCHES>
1016
1017 Its value will be prepended to the switches used to invoke perl on
1018 each test.  For example, setting C<HARNESS_PERL_SWITCHES> to C<-W> will
1019 run all tests with all warnings enabled.
1020
1021 =item C<HARNESS_VERBOSE>
1022
1023 If true, Test::Harness will output the verbose results of running
1024 its tests.  Setting $Test::Harness::verbose will override this.
1025
1026 =back
1027
1028 =head1 EXAMPLE
1029
1030 Here's how Test::Harness tests itself
1031
1032   $ cd ~/src/devel/Test-Harness
1033   $ perl -Mblib -e 'use Test::Harness qw(&runtests $verbose);
1034     $verbose=0; runtests @ARGV;' t/*.t
1035   Using /home/schwern/src/devel/Test-Harness/blib
1036   t/base..............ok
1037   t/nonumbers.........ok
1038   t/ok................ok
1039   t/test-harness......ok
1040   All tests successful.
1041   Files=4, Tests=24, 2 wallclock secs ( 0.61 cusr + 0.41 csys = 1.02 CPU)
1042
1043 =head1 SEE ALSO
1044
1045 L<Test> and L<Test::Simple> for writing test scripts, L<Benchmark> for
1046 the underlying timing routines, L<Devel::CoreStack> to generate core
1047 dumps from failed tests and L<Devel::Cover> for test coverage
1048 analysis.
1049
1050 =head1 AUTHORS
1051
1052 Either Tim Bunce or Andreas Koenig, we don't know. What we know for
1053 sure is, that it was inspired by Larry Wall's TEST script that came
1054 with perl distributions for ages. Numerous anonymous contributors
1055 exist.  Andreas Koenig held the torch for many years.
1056
1057 Current maintainer is Michael G Schwern E<lt>schwern@pobox.comE<gt>
1058
1059 =head1 TODO
1060
1061 Provide a way of running tests quietly (ie. no printing) for automated
1062 validation of tests.  This will probably take the form of a version
1063 of runtests() which rather than printing its output returns raw data
1064 on the state of the tests.  (Partially done in Test::Harness::Straps)
1065
1066 Fix HARNESS_COMPILE_TEST without breaking its core usage.
1067
1068 Figure a way to report test names in the failure summary.
1069
1070 Rework the test summary so long test names are not truncated as badly.
1071 (Partially done with new skip test styles)
1072
1073 Deal with VMS's "not \nok 4\n" mistake.
1074
1075 Add option for coverage analysis.
1076
1077 =for _private
1078 Keeping whittling away at _run_all_tests()
1079
1080 =for _private
1081 Clean up how the summary is printed.  Get rid of those damned formats.
1082
1083 =head1 BUGS
1084
1085 HARNESS_COMPILE_TEST currently assumes it's run from the Perl source
1086 directory.
1087
1088 =cut