lib/Test/Harness.pm

   1 # -*- Mode: cperl; cperl-indent-level: 4 -*-
   2 # $Id: Harness.pm,v 1.33 2002/05/29 23:02:48 schwern Exp $
   3
   4 package Test::Harness;
   5
   6 require 5.004;
   7 use Test::Harness::Straps;
   8 use Test::Harness::Assert;
   9 use Exporter;
  10 use Benchmark;
  11 use Config;
  12 use strict;
  13
  14 use vars qw($VERSION $Verbose $Switches $Have_Devel_Corestack $Curtest
  15             $Columns $verbose $switches $ML
  16             @ISA @EXPORT @EXPORT_OK
  17            );
  18
  19 # Backwards compatibility for exportable variable names.
  20 *verbose  = \$Verbose;
  21 *switches = \$Switches;
  22
  23 $Have_Devel_Corestack = 0;
  24
  25 $VERSION = '2.24';
  26
  27 $ENV{HARNESS_ACTIVE} = 1;
  28
  29 END {
  30     # For VMS.
  31     delete $ENV{HARNESS_ACTIVE};
  32 }
  33
  34 # Some experimental versions of OS/2 build have broken $?
  35 my $Ignore_Exitcode = $ENV{HARNESS_IGNORE_EXITCODE};
  36
  37 my $Files_In_Dir = $ENV{HARNESS_FILELEAK_IN_DIR};
  38
  39 my $Strap = Test::Harness::Straps->new;
  40
  41 @ISA = ('Exporter');
  42 @EXPORT    = qw(&runtests);
  43 @EXPORT_OK = qw($verbose $switches);
  44
  45 $Verbose  = $ENV{HARNESS_VERBOSE} || 0;
  46 $Switches = "-w";
  47 $Columns  = $ENV{HARNESS_COLUMNS} || $ENV{COLUMNS} || 80;
  48 $Columns--;             # Some shells have trouble with a full line of text.
  49
  50
  51 =head1 NAME
  52
  53 Test::Harness - run perl standard test scripts with statistics
  54
  55 =head1 SYNOPSIS
  56
  57   use Test::Harness;
  58
  59   runtests(@test_files);
  60
  61 =head1 DESCRIPTION
  62
  63 B<STOP!> If all you want to do is write a test script, consider using
  64 Test::Simple.  Otherwise, read on.
  65
  66 (By using the Test module, you can write test scripts without
  67 knowing the exact output this module expects.  However, if you need to
  68 know the specifics, read on!)
  69
  70 Perl test scripts print to standard output C<"ok N"> for each single
  71 test, where C<N> is an increasing sequence of integers. The first line
  72 output by a standard test script is C<"1..M"> with C<M> being the
  73 number of tests that should be run within the test
  74 script. Test::Harness::runtests(@tests) runs all the testscripts
  75 named as arguments and checks standard output for the expected
  76 C<"ok N"> strings.
  77
  78 After all tests have been performed, runtests() prints some
  79 performance statistics that are computed by the Benchmark module.
  80
  81 =head2 The test script output
  82
  83 The following explains how Test::Harness interprets the output of your
  84 test program.
  85
  86 =over 4
  87
  88 =item B<'1..M'>
  89
  90 This header tells how many tests there will be.  For example, C<1..10>
  91 means you plan on running 10 tests.  This is a safeguard in case your
  92 test dies quietly in the middle of its run.
  93
  94 It should be the first non-comment line output by your test program.
  95
  96 In certain instances, you may not know how many tests you will
  97 ultimately be running.  In this case, it is permitted for the 1..M
  98 header to appear as the B<last> line output by your test (again, it
  99 can be followed by further comments).
 100
 101 Under B<no> circumstances should 1..M appear in the middle of your
 102 output or more than once.
 103
 104
 105 =item B<'ok', 'not ok'.  Ok?>
 106
 107 Any output from the testscript to standard error is ignored and
 108 bypassed, thus will be seen by the user. Lines written to standard
 109 output containing C</^(not\s+)?ok\b/> are interpreted as feedback for
 110 runtests().  All other lines are discarded.
 111
 112 C</^not ok/> indicates a failed test.  C</^ok/> is a successful test.
 113
 114
 115 =item B<test numbers>
 116
 117 Perl normally expects the 'ok' or 'not ok' to be followed by a test
 118 number.  It is tolerated if the test numbers after 'ok' are
 119 omitted. In this case Test::Harness maintains temporarily its own
 120 counter until the script supplies test numbers again. So the following
 121 test script
 122
 123     print <<END;
 124     1..6
 125     not ok
 126     ok
 127     not ok
 128     ok
 129     ok
 130     END
 131
 132 will generate
 133
 134     FAILED tests 1, 3, 6
 135     Failed 3/6 tests, 50.00% okay
 136
 137 =item B<test names>
 138
 139 Anything after the test number but before the # is considered to be
 140 the name of the test.
 141
 142   ok 42 this is the name of the test
 143
 144 Currently, Test::Harness does nothing with this information.
 145
 146 =item B<Skipping tests>
 147
 148 If the standard output line contains the substring C< # Skip> (with
 149 variations in spacing and case) after C<ok> or C<ok NUMBER>, it is
 150 counted as a skipped test.  If the whole testscript succeeds, the
 151 count of skipped tests is included in the generated output.
 152 C<Test::Harness> reports the text after C< # Skip\S*\s+> as a reason
 153 for skipping.
 154
 155   ok 23 # skip Insufficient flogiston pressure.
 156
 157 Similarly, one can include a similar explanation in a C<1..0> line
 158 emitted if the test script is skipped completely:
 159
 160   1..0 # Skipped: no leverage found
 161
 162 =item B<Todo tests>
 163
 164 If the standard output line contains the substring C< # TODO> after
 165 C<not ok> or C<not ok NUMBER>, it is counted as a todo test.  The text
 166 afterwards is the thing that has to be done before this test will
 167 succeed.
 168
 169   not ok 13 # TODO harness the power of the atom
 170
 171 =begin _deprecated
 172
 173 Alternatively, you can specify a list of what tests are todo as part
 174 of the test header.
 175
 176   1..23 todo 5 12 23
 177
 178 This only works if the header appears at the beginning of the test.
 179
 180 This style is B<deprecated>.
 181
 182 =end _deprecated
 183
 184 These tests represent a feature to be implemented or a bug to be fixed
 185 and act as something of an executable "thing to do" list.  They are
 186 B<not> expected to succeed.  Should a todo test begin succeeding,
 187 Test::Harness will report it as a bonus.  This indicates that whatever
 188 you were supposed to do has been done and you should promote this to a
 189 normal test.
 190
 191 =item B<Bail out!>
 192
 193 As an emergency measure, a test script can decide that further tests
 194 are useless (e.g. missing dependencies) and testing should stop
 195 immediately. In that case the test script prints the magic words
 196
 197   Bail out!
 198
 199 to standard output. Any message after these words will be displayed by
 200 C<Test::Harness> as the reason why testing is stopped.
 201
 202 =item B<Comments>
 203
 204 Additional comments may be put into the testing output on their own
 205 lines.  Comment lines should begin with a '#', Test::Harness will
 206 ignore them.
 207
 208   ok 1
 209   # Life is good, the sun is shining, RAM is cheap.
 210   not ok 2
 211   # got 'Bush' expected 'Gore'
 212
 213 =item B<Anything else>
 214
 215 Any other output Test::Harness sees it will silently ignore B<BUT WE
 216 PLAN TO CHANGE THIS!> If you wish to place additional output in your
 217 test script, please use a comment.
 218
 219 =back
 220
 221
 222 =head2 Taint mode
 223
 224 Test::Harness will honor the C<-T> in the #! line on your test files.  So
 225 if you begin a test with:
 226
 227     #!perl -T
 228
 229 the test will be run with taint mode on.
 230
 231
 232 =head2 Configuration variables.
 233
 234 These variables can be used to configure the behavior of
 235 Test::Harness.  They are exported on request.
 236
 237 =over 4
 238
 239 =item B<$Test::Harness::verbose>
 240
 241 The global variable $Test::Harness::verbose is exportable and can be
 242 used to let runtests() display the standard output of the script
 243 without altering the behavior otherwise.
 244
 245 =item B<$Test::Harness::switches>
 246
 247 The global variable $Test::Harness::switches is exportable and can be
 248 used to set perl command line options used for running the test
 249 script(s). The default value is C<-w>.
 250
 251 =back
 252
 253
 254 =head2 Failure
 255
 256 It will happen, your tests will fail.  After you mop up your ego, you
 257 can begin examining the summary report:
 258
 259   t/base..............ok
 260   t/nonumbers.........ok
 261   t/ok................ok
 262   t/test-harness......ok
 263   t/waterloo..........dubious
 264           Test returned status 3 (wstat 768, 0x300)
 265   DIED. FAILED tests 1, 3, 5, 7, 9, 11, 13, 15, 17, 19
 266           Failed 10/20 tests, 50.00% okay
 267   Failed Test  Stat Wstat Total Fail  Failed  List of Failed
 268   -----------------------------------------------------------------------
 269   t/waterloo.t    3   768    20   10  50.00%  1 3 5 7 9 11 13 15 17 19
 270   Failed 1/5 test scripts, 80.00% okay. 10/44 subtests failed, 77.27% okay.
 271
 272 Everything passed but t/waterloo.t.  It failed 10 of 20 tests and
 273 exited with non-zero status indicating something dubious happened.
 274
 275 The columns in the summary report mean:
 276
 277 =over 4
 278
 279 =item B<Failed Test>
 280
 281 The test file which failed.
 282
 283 =item B<Stat>
 284
 285 If the test exited with non-zero, this is its exit status.
 286
 287 =item B<Wstat>
 288
 289 The wait status of the test I<umm, I need a better explanation here>.
 290
 291 =item B<Total>
 292
 293 Total number of tests expected to run.
 294
 295 =item B<Fail>
 296
 297 Number which failed, either from "not ok" or because they never ran.
 298
 299 =item B<Failed>
 300
 301 Percentage of the total tests which failed.
 302
 303 =item B<List of Failed>
 304
 305 A list of the tests which failed.  Successive failures may be
 306 abbreviated (ie. 15-20 to indicate that tests 15, 16, 17, 18, 19 and
 307 20 failed).
 308
 309 =back
 310
 311
 312 =head2 Functions
 313
 314 Test::Harness currently only has one function, here it is.
 315
 316 =over 4
 317
 318 =item B<runtests>
 319
 320   my $allok = runtests(@test_files);
 321
 322 This runs all the given @test_files and divines whether they passed
 323 or failed based on their output to STDOUT (details above).  It prints
 324 out each individual test which failed along with a summary report and
 325 a how long it all took.
 326
 327 It returns true if everything was ok, false otherwise.
 328
 329 =for _private
 330 This is just _run_all_tests() plus _show_results()
 331
 332 =cut
 333
 334 sub runtests {
 335     my(@tests) = @_;
 336
 337     local ($\, $,);
 338
 339     my($tot, $failedtests) = _run_all_tests(@tests);
 340     _show_results($tot, $failedtests);
 341
 342     my $ok = _all_ok($tot);
 343
 344     assert(($ok xor keys %$failedtests),
 345            q{ok status jives with $failedtests});
 346
 347     return $ok;
 348 }
 349
 350 =begin _private
 351
 352 =item B<_all_ok>
 353
 354   my $ok = _all_ok(\%tot);
 355
 356 Tells you if this test run is overall successful or not.
 357
 358 =cut
 359
 360 sub _all_ok {
 361     my($tot) = shift;
 362
 363     return $tot->{bad} == 0 && ($tot->{max} || $tot->{skipped}) ? 1 : 0;
 364 }
 365
 366 =item B<_globdir>
 367
 368   my @files = _globdir $dir;
 369
 370 Returns all the files in a directory.  This is shorthand for backwards
 371 compatibility on systems where glob() doesn't work right.
 372
 373 =cut
 374
 375 sub _globdir {
 376     opendir DIRH, shift;
 377     my @f = readdir DIRH;
 378     closedir DIRH;
 379
 380     return @f;
 381 }
 382
 383 =item B<_run_all_tests>
 384
 385   my($total, $failed) = _run_all_tests(@test_files);
 386
 387 Runs all the given @test_files (as runtests()) but does it quietly (no
 388 report).  $total is a hash ref summary of all the tests run.  Its keys
 389 and values are this:
 390
 391     bonus           Number of individual todo tests unexpectedly passed
 392     max             Number of individual tests ran
 393     ok              Number of individual tests passed
 394     sub_skipped     Number of individual tests skipped
 395     todo            Number of individual todo tests
 396
 397     files           Number of test files ran
 398     good            Number of test files passed
 399     bad             Number of test files failed
 400     tests           Number of test files originally given
 401     skipped         Number of test files skipped
 402
 403 If $total->{bad} == 0 and $total->{max} > 0, you've got a successful
 404 test.
 405
 406 $failed is a hash ref of all the test scripts which failed.  Each key
 407 is the name of a test script, each value is another hash representing
 408 how that script failed.  Its keys are these:
 409
 410     name        Name of the test which failed
 411     estat       Script's exit value
 412     wstat       Script's wait status
 413     max         Number of individual tests
 414     failed      Number which failed
 415     percent     Percentage of tests which failed
 416     canon       List of tests which failed (as string).
 417
 418 Needless to say, $failed should be empty if everything passed.
 419
 420 B<NOTE> Currently this function is still noisy.  I'm working on it.
 421
 422 =cut
 423
 424 #'#
 425 sub _run_all_tests {
 426     my(@tests) = @_;
 427     local($|) = 1;
 428     my(%failedtests);
 429
 430     # Test-wide totals.
 431     my(%tot) = (
 432                 bonus    => 0,
 433                 max      => 0,
 434                 ok       => 0,
 435                 files    => 0,
 436                 bad      => 0,
 437                 good     => 0,
 438                 tests    => scalar @tests,
 439                 sub_skipped  => 0,
 440                 todo     => 0,
 441                 skipped  => 0,
 442                 bench    => 0,
 443                );
 444
 445     my @dir_files = _globdir $Files_In_Dir if defined $Files_In_Dir;
 446     my $t_start = new Benchmark;
 447
 448     my $width = _leader_width(@tests);
 449     foreach my $tfile (@tests) {
 450
 451         my($leader, $ml) = _mk_leader($tfile, $width);
 452         local $ML = $ml;
 453         print $leader;
 454
 455         $tot{files}++;
 456
 457         $Strap->{_seen_header} = 0;
 458         my %results = $Strap->analyze_file($tfile) or
 459           do { warn "$Strap->{error}\n";  next };
 460
 461         # state of the current test.
 462         my @failed = grep { !$results{details}[$_-1]{ok} }
 463                      1..@{$results{details}};
 464         my %test = (
 465                     ok          => $results{ok},
 466                     'next'      => $Strap->{'next'},
 467                     max         => $results{max},
 468                     failed      => \@failed,
 469                     bonus       => $results{bonus},
 470                     skipped     => $results{skip},
 471                     skip_reason => $Strap->{_skip_reason},
 472                     skip_all    => $Strap->{skip_all},
 473                     ml          => $ml,
 474                    );
 475
 476         $tot{bonus}       += $results{bonus};
 477         $tot{max}         += $results{max};
 478         $tot{ok}          += $results{ok};
 479         $tot{todo}        += $results{todo};
 480         $tot{sub_skipped} += $results{skip};
 481
 482         my($estatus, $wstatus) = @results{qw(exit wait)};
 483
 484         if ($wstatus) {
 485             $failedtests{$tfile} = _dubious_return(\%test, \%tot,
 486                                                   $estatus, $wstatus);
 487             $failedtests{$tfile}{name} = $tfile;
 488         }
 489         elsif ($results{passing}) {
 490             if ($test{max} and $test{skipped} + $test{bonus}) {
 491                 my @msg;
 492                 push(@msg, "$test{skipped}/$test{max} skipped: $test{skip_reason}")
 493                     if $test{skipped};
 494                 push(@msg, "$test{bonus}/$test{max} unexpectedly succeeded")
 495                     if $test{bonus};
 496                 print "$test{ml}ok\n        ".join(', ', @msg)."\n";
 497             } elsif ($test{max}) {
 498                 print "$test{ml}ok\n";
 499             } elsif (length $test{skip_all}) {
 500                 print "skipped\n        all skipped: $test{skip_all}\n";
 501                 $tot{skipped}++;
 502             } else {
 503                 print "skipped\n        all skipped: no reason given\n";
 504                 $tot{skipped}++;
 505             }
 506             $tot{good}++;
 507         }
 508         else {
 509             if ($test{max}) {
 510                 if ($test{'next'} <= $test{max}) {
 511                     push @{$test{failed}}, $test{'next'}..$test{max};
 512                 }
 513                 if (@{$test{failed}}) {
 514                     my ($txt, $canon) = canonfailed($test{max},$test{skipped},
 515                                                     @{$test{failed}});
 516                     print "$test{ml}$txt";
 517                     $failedtests{$tfile} = { canon   => $canon,
 518                                              max     => $test{max},
 519                                              failed  => scalar @{$test{failed}},
 520                                              name    => $tfile,
 521                                              percent => 100*(scalar @{$test{failed}})/$test{max},
 522                                              estat   => '',
 523                                              wstat   => '',
 524                                            };
 525                 } else {
 526                     print "Don't know which tests failed: got $test{ok} ok, ".
 527                           "expected $test{max}\n";
 528                     $failedtests{$tfile} = { canon   => '??',
 529                                              max     => $test{max},
 530                                              failed  => '??',
 531                                              name    => $tfile,
 532                                              percent => undef,
 533                                              estat   => '',
 534                                              wstat   => '',
 535                                            };
 536                 }
 537                 $tot{bad}++;
 538             } elsif ($test{'next'} == 0) {
 539                 print "FAILED before any test output arrived\n";
 540                 $tot{bad}++;
 541                 $failedtests{$tfile} = { canon       => '??',
 542                                          max         => '??',
 543                                          failed      => '??',
 544                                          name        => $tfile,
 545                                          percent     => undef,
 546                                          estat       => '',
 547                                          wstat       => '',
 548                                        };
 549             }
 550         }
 551
 552         if (defined $Files_In_Dir) {
 553             my @new_dir_files = _globdir $Files_In_Dir;
 554             if (@new_dir_files != @dir_files) {
 555                 my %f;
 556                 @f{@new_dir_files} = (1) x @new_dir_files;
 557                 delete @f{@dir_files};
 558                 my @f = sort keys %f;
 559                 print "LEAKED FILES: @f\n";
 560                 @dir_files = @new_dir_files;
 561             }
 562         }
 563     }
 564     $tot{bench} = timediff(new Benchmark, $t_start);
 565
 566     $Strap->_restore_PERL5LIB;
 567
 568     return(\%tot, \%failedtests);
 569 }
 570
 571 =item B<_mk_leader>
 572
 573   my($leader, $ml) = _mk_leader($test_file, $width);
 574
 575 Generates the 't/foo........' $leader for the given $test_file as well
 576 as a similar version which will overwrite the current line (by use of
 577 \r and such).  $ml may be empty if Test::Harness doesn't think you're
 578 on TTY.
 579
 580 The $width is the width of the "yada/blah.." string.
 581
 582 =cut
 583
 584 sub _mk_leader {
 585     my($te, $width) = @_;
 586     chomp($te);
 587     $te =~ s/\.\w+$/./;
 588
 589     if ($^O eq 'VMS') { $te =~ s/^.*\.t\./\[.t./s; }
 590     my $blank = (' ' x 77);
 591     my $leader = "$te" . '.' x ($width - length($te));
 592     my $ml = "";
 593
 594     $ml = "\r$blank\r$leader"
 595       if -t STDOUT and not $ENV{HARNESS_NOTTY} and not $Verbose;
 596
 597     return($leader, $ml);
 598 }
 599
 600 =item B<_leader_width>
 601
 602   my($width) = _leader_width(@test_files);
 603
 604 Calculates how wide the leader should be based on the length of the
 605 longest test name.
 606
 607 =cut
 608
 609 sub _leader_width {
 610     my $maxlen = 0;
 611     my $maxsuflen = 0;
 612     foreach (@_) {
 613         my $suf    = /\.(\w+)$/ ? $1 : '';
 614         my $len    = length;
 615         my $suflen = length $suf;
 616         $maxlen    = $len    if $len    > $maxlen;
 617         $maxsuflen = $suflen if $suflen > $maxsuflen;
 618     }
 619     # + 3 : we want three dots between the test name and the "ok"
 620     return $maxlen + 3 - $maxsuflen;
 621 }
 622
 623
 624 sub _show_results {
 625     my($tot, $failedtests) = @_;
 626
 627     my $pct;
 628     my $bonusmsg = _bonusmsg($tot);
 629
 630     if (_all_ok($tot)) {
 631         print "All tests successful$bonusmsg.\n";
 632     } elsif (!$tot->{tests}){
 633         die "FAILED--no tests were run for some reason.\n";
 634     } elsif (!$tot->{max}) {
 635         my $blurb = $tot->{tests}==1 ? "script" : "scripts";
 636         die "FAILED--$tot->{tests} test $blurb could be run, ".
 637             "alas--no output ever seen\n";
 638     } else {
 639         $pct = sprintf("%.2f", $tot->{good} / $tot->{tests} * 100);
 640         my $percent_ok = 100*$tot->{ok}/$tot->{max};
 641         my $subpct = sprintf " %d/%d subtests failed, %.2f%% okay.",
 642                               $tot->{max} - $tot->{ok}, $tot->{max},
 643                               $percent_ok;
 644
 645         my($fmt_top, $fmt) = _create_fmts($failedtests);
 646
 647         # Now write to formats
 648         for my $script (sort keys %$failedtests) {
 649           $Curtest = $failedtests->{$script};
 650           write;
 651         }
 652         if ($tot->{bad}) {
 653             $bonusmsg =~ s/^,\s*//;
 654             print "$bonusmsg.\n" if $bonusmsg;
 655             die "Failed $tot->{bad}/$tot->{tests} test scripts, $pct% okay.".
 656                 "$subpct\n";
 657         }
 658     }
 659
 660     printf("Files=%d, Tests=%d, %s\n",
 661            $tot->{files}, $tot->{max}, timestr($tot->{bench}, 'nop'));
 662 }
 663
 664
 665 my %Handlers = ();
 666 $Strap->{callback} = sub {
 667     my($self, $line, $type, $totals) = @_;
 668     print $line if $Verbose;
 669
 670     my $meth = $Handlers{$type};
 671     $meth->($self, $line, $type, $totals) if $meth;
 672 };
 673
 674
 675 $Handlers{header} = sub {
 676     my($self, $line, $type, $totals) = @_;
 677
 678     warn "Test header seen more than once!\n" if $self->{_seen_header};
 679
 680     $self->{_seen_header}++;
 681
 682     warn "1..M can only appear at the beginning or end of tests\n"
 683       if $totals->{seen} &&
 684          $totals->{max}  < $totals->{seen};
 685 };
 686
 687 $Handlers{test} = sub {
 688     my($self, $line, $type, $totals) = @_;
 689
 690     my $curr = $totals->{seen};
 691     my $next = $self->{'next'};
 692     my $max  = $totals->{max};
 693     my $detail = $totals->{details}[-1];
 694
 695     if( $detail->{ok} ) {
 696         _print_ml("ok $curr/$max");
 697
 698         if( $detail->{type} eq 'skip' ) {
 699             $self->{_skip_reason} = $detail->{reason}
 700               unless defined $self->{_skip_reason};
 701             $self->{_skip_reason} = 'various reasons'
 702               if $self->{_skip_reason} ne $detail->{reason};
 703         }
 704     }
 705     else {
 706         _print_ml("NOK $curr");
 707     }
 708
 709     if( $curr > $next ) {
 710         print "Test output counter mismatch [test $curr]\n";
 711     }
 712     elsif( $curr < $next ) {
 713         print "Confused test output: test $curr answered after ".
 714               "test ", $next - 1, "\n";
 715     }
 716
 717 };
 718
 719 $Handlers{bailout} = sub {
 720     my($self, $line, $type, $totals) = @_;
 721
 722     die "FAILED--Further testing stopped" .
 723       ($self->{bailout_reason} ? ": $self->{bailout_reason}\n" : ".\n");
 724 };
 725
 726
 727 sub _print_ml {
 728     print join '', $ML, @_ if $ML;
 729 }
 730
 731
 732 sub _bonusmsg {
 733     my($tot) = @_;
 734
 735     my $bonusmsg = '';
 736     $bonusmsg = (" ($tot->{bonus} subtest".($tot->{bonus} > 1 ? 's' : '').
 737                " UNEXPECTEDLY SUCCEEDED)")
 738         if $tot->{bonus};
 739
 740     if ($tot->{skipped}) {
 741         $bonusmsg .= ", $tot->{skipped} test"
 742                      . ($tot->{skipped} != 1 ? 's' : '');
 743         if ($tot->{sub_skipped}) {
 744             $bonusmsg .= " and $tot->{sub_skipped} subtest"
 745                          . ($tot->{sub_skipped} != 1 ? 's' : '');
 746         }
 747         $bonusmsg .= ' skipped';
 748     }
 749     elsif ($tot->{sub_skipped}) {
 750         $bonusmsg .= ", $tot->{sub_skipped} subtest"
 751                      . ($tot->{sub_skipped} != 1 ? 's' : '')
 752                      . " skipped";
 753     }
 754
 755     return $bonusmsg;
 756 }
 757
 758 # Test program go boom.
 759 sub _dubious_return {
 760     my($test, $tot, $estatus, $wstatus) = @_;
 761     my ($failed, $canon, $percent) = ('??', '??');
 762
 763     printf "$test->{ml}dubious\n\tTest returned status $estatus ".
 764            "(wstat %d, 0x%x)\n",
 765            $wstatus,$wstatus;
 766     print "\t\t(VMS status is $estatus)\n" if $^O eq 'VMS';
 767
 768     if (corestatus($wstatus)) { # until we have a wait module
 769         if ($Have_Devel_Corestack) {
 770             Devel::CoreStack::stack($^X);
 771         } else {
 772             print "\ttest program seems to have generated a core\n";
 773         }
 774     }
 775
 776     $tot->{bad}++;
 777
 778     if ($test->{max}) {
 779         if ($test->{'next'} == $test->{max} + 1 and not @{$test->{failed}}) {
 780             print "\tafter all the subtests completed successfully\n";
 781             $percent = 0;
 782             $failed = 0;        # But we do not set $canon!
 783         }
 784         else {
 785             push @{$test->{failed}}, $test->{'next'}..$test->{max};
 786             $failed = @{$test->{failed}};
 787             (my $txt, $canon) = canonfailed($test->{max},$test->{skipped},@{$test->{failed}});
 788             $percent = 100*(scalar @{$test->{failed}})/$test->{max};
 789             print "DIED. ",$txt;
 790         }
 791     }
 792
 793     return { canon => $canon,  max => $test->{max} || '??',
 794              failed => $failed,
 795              percent => $percent,
 796              estat => $estatus, wstat => $wstatus,
 797            };
 798 }
 799
 800
 801 sub _create_fmts {
 802     my($failedtests) = @_;
 803
 804     my $failed_str = "Failed Test";
 805     my $middle_str = " Stat Wstat Total Fail  Failed  ";
 806     my $list_str = "List of Failed";
 807
 808     # Figure out our longest name string for formatting purposes.
 809     my $max_namelen = length($failed_str);
 810     foreach my $script (keys %$failedtests) {
 811         my $namelen = length $failedtests->{$script}->{name};
 812         $max_namelen = $namelen if $namelen > $max_namelen;
 813     }
 814
 815     my $list_len = $Columns - length($middle_str) - $max_namelen;
 816     if ($list_len < length($list_str)) {
 817         $list_len = length($list_str);
 818         $max_namelen = $Columns - length($middle_str) - $list_len;
 819         if ($max_namelen < length($failed_str)) {
 820             $max_namelen = length($failed_str);
 821             $Columns = $max_namelen + length($middle_str) + $list_len;
 822         }
 823     }
 824
 825     my $fmt_top = "format STDOUT_TOP =\n"
 826                   . sprintf("%-${max_namelen}s", $failed_str)
 827                   . $middle_str
 828                   . $list_str . "\n"
 829                   . "-" x $Columns
 830                   . "\n.\n";
 831
 832     my $fmt = "format STDOUT =\n"
 833               . "@" . "<" x ($max_namelen - 1)
 834               . "  @>> @>>>> @>>>> @>>> ^##.##%  "
 835               . "^" . "<" x ($list_len - 1) . "\n"
 836               . '{ $Curtest->{name}, $Curtest->{estat},'
 837               . '  $Curtest->{wstat}, $Curtest->{max},'
 838               . '  $Curtest->{failed}, $Curtest->{percent},'
 839               . '  $Curtest->{canon}'
 840               . "\n}\n"
 841               . "~~" . " " x ($Columns - $list_len - 2) . "^"
 842               . "<" x ($list_len - 1) . "\n"
 843               . '$Curtest->{canon}'
 844               . "\n.\n";
 845
 846     eval $fmt_top;
 847     die $@ if $@;
 848     eval $fmt;
 849     die $@ if $@;
 850
 851     return($fmt_top, $fmt);
 852 }
 853
 854 {
 855     my $tried_devel_corestack;
 856
 857     sub corestatus {
 858         my($st) = @_;
 859
 860         eval {
 861             local $^W = 0;  # *.ph files are often *very* noisy
 862             require 'wait.ph'
 863         };
 864         return if $@;
 865         my $did_core = defined &WCOREDUMP ? WCOREDUMP($st) : $st & 0200;
 866
 867         eval { require Devel::CoreStack; $Have_Devel_Corestack++ }
 868           unless $tried_devel_corestack++;
 869
 870         return $did_core;
 871     }
 872 }
 873
 874 sub canonfailed ($@) {
 875     my($max,$skipped,@failed) = @_;
 876     my %seen;
 877     @failed = sort {$a <=> $b} grep !$seen{$_}++, @failed;
 878     my $failed = @failed;
 879     my @result = ();
 880     my @canon = ();
 881     my $min;
 882     my $last = $min = shift @failed;
 883     my $canon;
 884     if (@failed) {
 885         for (@failed, $failed[-1]) { # don't forget the last one
 886             if ($_ > $last+1 || $_ == $last) {
 887                 if ($min == $last) {
 888                     push @canon, $last;
 889                 } else {
 890                     push @canon, "$min-$last";
 891                 }
 892                 $min = $_;
 893             }
 894             $last = $_;
 895         }
 896         local $" = ", ";
 897         push @result, "FAILED tests @canon\n";
 898         $canon = join ' ', @canon;
 899     } else {
 900         push @result, "FAILED test $last\n";
 901         $canon = $last;
 902     }
 903
 904     push @result, "\tFailed $failed/$max tests, ";
 905     push @result, sprintf("%.2f",100*(1-$failed/$max)), "% okay";
 906     my $ender = 's' x ($skipped > 1);
 907     my $good = $max - $failed - $skipped;
 908     my $goodper = sprintf("%.2f",100*($good/$max));
 909     push @result, " (less $skipped skipped test$ender: $good okay, ".
 910                   "$goodper%)"
 911          if $skipped;
 912     push @result, "\n";
 913     my $txt = join "", @result;
 914     ($txt, $canon);
 915 }
 916
 917 =end _private
 918
 919 =back
 920
 921 =cut
 922
 923
 924 1;
 925 __END__
 926
 927
 928 =head1 EXPORT
 929
 930 C<&runtests> is exported by Test::Harness per default.
 931
 932 C<$verbose> and C<$switches> are exported upon request.
 933
 934
 935 =head1 DIAGNOSTICS
 936
 937 =over 4
 938
 939 =item C<All tests successful.\nFiles=%d,  Tests=%d, %s>
 940
 941 If all tests are successful some statistics about the performance are
 942 printed.
 943
 944 =item C<FAILED tests %s\n\tFailed %d/%d tests, %.2f%% okay.>
 945
 946 For any single script that has failing subtests statistics like the
 947 above are printed.
 948
 949 =item C<Test returned status %d (wstat %d)>
 950
 951 Scripts that return a non-zero exit status, both C<$? E<gt>E<gt> 8>
 952 and C<$?> are printed in a message similar to the above.
 953
 954 =item C<Failed 1 test, %.2f%% okay. %s>
 955
 956 =item C<Failed %d/%d tests, %.2f%% okay. %s>
 957
 958 If not all tests were successful, the script dies with one of the
 959 above messages.
 960
 961 =item C<FAILED--Further testing stopped: %s>
 962
 963 If a single subtest decides that further testing will not make sense,
 964 the script dies with this message.
 965
 966 =back
 967
 968 =head1 ENVIRONMENT
 969
 970 =over 4
 971
 972 =item C<HARNESS_ACTIVE>
 973
 974 Harness sets this before executing the individual tests.  This allows
 975 the tests to determine if they are being executed through the harness
 976 or by any other means.
 977
 978 =item C<HARNESS_COLUMNS>
 979
 980 This value will be used for the width of the terminal. If it is not
 981 set then it will default to C<COLUMNS>. If this is not set, it will
 982 default to 80. Note that users of Bourne-sh based shells will need to
 983 C<export COLUMNS> for this module to use that variable.
 984
 985 =item C<HARNESS_COMPILE_TEST>
 986
 987 When true it will make harness attempt to compile the test using
 988 C<perlcc> before running it.
 989
 990 B<NOTE> This currently only works when sitting in the perl source
 991 directory!
 992
 993 =item C<HARNESS_FILELEAK_IN_DIR>
 994
 995 When set to the name of a directory, harness will check after each
 996 test whether new files appeared in that directory, and report them as
 997
 998   LEAKED FILES: scr.tmp 0 my.db
 999
1000 If relative, directory name is with respect to the current directory at
1001 the moment runtests() was called.  Putting absolute path into
1002 C<HARNESS_FILELEAK_IN_DIR> may give more predictable results.
1003
1004 =item C<HARNESS_IGNORE_EXITCODE>
1005
1006 Makes harness ignore the exit status of child processes when defined.
1007
1008 =item C<HARNESS_NOTTY>
1009
1010 When set to a true value, forces it to behave as though STDOUT were
1011 not a console.  You may need to set this if you don't want harness to
1012 output more frequent progress messages using carriage returns.  Some
1013 consoles may not handle carriage returns properly (which results in a
1014 somewhat messy output).
1015
1016 =item C<HARNESS_PERL_SWITCHES>
1017
1018 Its value will be prepended to the switches used to invoke perl on
1019 each test.  For example, setting C<HARNESS_PERL_SWITCHES> to C<-W> will
1020 run all tests with all warnings enabled.
1021
1022 =item C<HARNESS_VERBOSE>
1023
1024 If true, Test::Harness will output the verbose results of running
1025 its tests.  Setting $Test::Harness::verbose will override this.
1026
1027 =back
1028
1029 =head1 EXAMPLE
1030
1031 Here's how Test::Harness tests itself
1032
1033   $ cd ~/src/devel/Test-Harness
1034   $ perl -Mblib -e 'use Test::Harness qw(&runtests $verbose);
1035     $verbose=0; runtests @ARGV;' t/*.t
1036   Using /home/schwern/src/devel/Test-Harness/blib
1037   t/base..............ok
1038   t/nonumbers.........ok
1039   t/ok................ok
1040   t/test-harness......ok
1041   All tests successful.
1042   Files=4, Tests=24, 2 wallclock secs ( 0.61 cusr + 0.41 csys = 1.02 CPU)
1043
1044 =head1 SEE ALSO
1045
1046 L<Test> and L<Test::Simple> for writing test scripts, L<Benchmark> for
1047 the underlying timing routines, L<Devel::CoreStack> to generate core
1048 dumps from failed tests and L<Devel::Cover> for test coverage
1049 analysis.
1050
1051 =head1 AUTHORS
1052
1053 Either Tim Bunce or Andreas Koenig, we don't know. What we know for
1054 sure is, that it was inspired by Larry Wall's TEST script that came
1055 with perl distributions for ages. Numerous anonymous contributors
1056 exist.  Andreas Koenig held the torch for many years.
1057
1058 Current maintainer is Michael G Schwern E<lt>schwern@pobox.comE<gt>
1059
1060 =head1 TODO
1061
1062 Provide a way of running tests quietly (ie. no printing) for automated
1063 validation of tests.  This will probably take the form of a version
1064 of runtests() which rather than printing its output returns raw data
1065 on the state of the tests.  (Partially done in Test::Harness::Straps)
1066
1067 Fix HARNESS_COMPILE_TEST without breaking its core usage.
1068
1069 Figure a way to report test names in the failure summary.
1070
1071 Rework the test summary so long test names are not truncated as badly.
1072 (Partially done with new skip test styles)
1073
1074 Deal with VMS's "not \nok 4\n" mistake.
1075
1076 Add option for coverage analysis.
1077
1078 =for _private
1079 Keeping whittling away at _run_all_tests()
1080
1081 =for _private
1082 Clean up how the summary is printed.  Get rid of those damned formats.
1083
1084 =head1 BUGS
1085
1086 HARNESS_COMPILE_TEST currently assumes it's run from the Perl source
1087 directory.
1088
1089 =cut