lib/Term/ReadLine.pm

   1 =head1 NAME
   2
   3 Term::ReadLine - Perl interface to various C<readline> packages. If
   4 no real package is found, substitutes stubs instead of basic functions.
   5
   6 =head1 SYNOPSIS
   7
   8   use Term::ReadLine;
   9   $term = new Term::ReadLine 'Simple Perl calc';
  10   $prompt = "Enter your arithmetic expression: ";
  11   $OUT = $term->OUT || STDOUT;
  12   while ( defined ($_ = $term->readline($prompt)) ) {
  13     $res = eval($_), "\n";
  14     warn $@ if $@;
  15     print $OUT $res, "\n" unless $@;
  16     $term->addhistory($_) if /\S/;
  17   }
  18
  19 =head1 DESCRIPTION
  20
  21 This package is just a front end to some other packages. At the moment
  22 this description is written, the only such package is Term-ReadLine,
  23 available on CPAN near you. The real target of this stub package is to
  24 set up a common interface to whatever Readline emerges with time.
  25
  26 =head1 Minimal set of supported functions
  27
  28 All the supported functions should be called as methods, i.e., either as
  29
  30   $term = new Term::ReadLine 'name';
  31
  32 or as
  33
  34   $term->addhistory('row');
  35
  36 where $term is a return value of Term::ReadLine-E<gt>Init.
  37
  38 =over 12
  39
  40 =item C<ReadLine>
  41
  42 returns the actual package that executes the commands. Among possible
  43 values are C<Term::ReadLine::Gnu>, C<Term::ReadLine::Perl>,
  44 C<Term::ReadLine::Stub Exporter>.
  45
  46 =item C<new>
  47
  48 returns the handle for subsequent calls to following
  49 functions. Argument is the name of the application. Optionally can be
  50 followed by two arguments for C<IN> and C<OUT> filehandles. These
  51 arguments should be globs.
  52
  53 =item C<readline>
  54
  55 gets an input line, I<possibly> with actual C<readline>
  56 support. Trailing newline is removed. Returns C<undef> on C<EOF>.
  57
  58 =item C<addhistory>
  59
  60 adds the line to the history of input, from where it can be used if
  61 the actual C<readline> is present.
  62
  63 =item C<IN>, $C<OUT>
  64
  65 return the filehandles for input and output or C<undef> if C<readline>
  66 input and output cannot be used for Perl.
  67
  68 =item C<MinLine>
  69
  70 If argument is specified, it is an advice on minimal size of line to
  71 be included into history.  C<undef> means do not include anything into
  72 history. Returns the old value.
  73
  74 =item C<findConsole>
  75
  76 returns an array with two strings that give most appropriate names for
  77 files for input and output using conventions C<"E<lt>$in">, C<"E<gt>out">.
  78
  79 =item Attribs
  80
  81 returns a reference to a hash which describes internal configuration
  82 of the package. Names of keys in this hash conform to standard
  83 conventions with the leading C<rl_> stripped.
  84
  85 =item C<Features>
  86
  87 Returns a reference to a hash with keys being features present in
  88 current implementation. Several optional features are used in the
  89 minimal interface: C<appname> should be present if the first argument
  90 to C<new> is recognized, and C<minline> should be present if
  91 C<MinLine> method is not dummy.  C<autohistory> should be present if
  92 lines are put into history automatically (maybe subject to
  93 C<MinLine>), and C<addhistory> if C<addhistory> method is not dummy.
  94
  95 If C<Features> method reports a feature C<attribs> as present, the
  96 method C<Attribs> is not dummy.
  97
  98 =back
  99
 100 =head1 Additional supported functions
 101
 102 Actually C<Term::ReadLine> can use some other package, that will
 103 support reacher set of commands.
 104
 105 All these commands are callable via method interface and have names
 106 which conform to standard conventions with the leading C<rl_> stripped.
 107
 108 The stub package included with the perl distribution allows some
 109 additional methods:
 110
 111 =over 12
 112
 113 =item C<tkRunning>
 114
 115 makes Tk event loop run when waiting for user input (i.e., during
 116 C<readline> method).
 117
 118 =item C<ornaments>
 119
 120 makes the command line stand out by using termcap data.  The argument
 121 to C<ornaments> should be 0, 1, or a string of a form
 122 C<"aa,bb,cc,dd">.  Four components of this string should be names of
 123 I<terminal capacities>, first two will be issued to make the prompt
 124 standout, last two to make the input line standout.
 125
 126 =item C<newTTY>
 127
 128 takes two arguments which are input filehandle and output filehandle.
 129 Switches to use these filehandles.
 130
 131 =back
 132
 133 One can check whether the currently loaded ReadLine package supports
 134 these methods by checking for corresponding C<Features>.
 135
 136 =head1 EXPORTS
 137
 138 None
 139
 140 =head1 ENVIRONMENT
 141
 142 The environment variable C<PERL_RL> governs which ReadLine clone is
 143 loaded. If the value is false, a dummy interface is used. If the value
 144 is true, it should be tail of the name of the package to use, such as
 145 C<Perl> or C<Gnu>.
 146
 147 As a special case, if the value of this variable is space-separated,
 148 the tail might be used to disable the ornaments by setting the tail to
 149 be C<o=0> or C<ornaments=0>.  The head should be as described above, say
 150
 151 If the variable is not set, or if the head of space-separated list is
 152 empty, the best available package is loaded.
 153
 154   export "PERL_RL=Perl o=0"     # Use Perl ReadLine without ornaments
 155   export "PERL_RL= o=0"         # Use best available ReadLine without ornaments
 156
 157 (Note that processing of C<PERL_RL> for ornaments is in the discretion of the
 158 particular used C<Term::ReadLine::*> package).
 159
 160 =cut
 161
 162 use strict;
 163
 164 package Term::ReadLine::Stub;
 165 our @ISA = qw'Term::ReadLine::Tk Term::ReadLine::TermCap';
 166
 167 $DB::emacs = $DB::emacs;        # To peacify -w
 168 our @rl_term_set;
 169 *rl_term_set = \@Term::ReadLine::TermCap::rl_term_set;
 170
 171 sub ReadLine {'Term::ReadLine::Stub'}
 172 sub readline {
 173   my $self = shift;
 174   my ($in,$out,$str) = @$self;
 175   my $prompt = shift;
 176   print $out $rl_term_set[0], $prompt, $rl_term_set[1], $rl_term_set[2];
 177   $self->register_Tk
 178      if not $Term::ReadLine::registered and $Term::ReadLine::toloop
 179         and defined &Tk::DoOneEvent;
 180   #$str = scalar <$in>;
 181   $str = $self->get_line;
 182   $str =~ s/^\s*\Q$prompt\E// if ($^O eq 'MacOS');
 183   print $out $rl_term_set[3];
 184   # bug in 5.000: chomping empty string creats length -1:
 185   chomp $str if defined $str;
 186   $str;
 187 }
 188 sub addhistory {}
 189
 190 sub findConsole {
 191     my $console;
 192
 193     if ($^O eq 'MacOS') {
 194         $console = "Dev:Console";
 195     } elsif (-e "/dev/tty") {
 196         $console = "/dev/tty";
 197     } elsif (-e "con" or $^O eq 'MSWin32') {
 198         $console = "con";
 199     } else {
 200         $console = "sys\$command";
 201     }
 202
 203     if (($^O eq 'amigaos') || ($^O eq 'beos') || ($^O eq 'epoc')) {
 204         $console = undef;
 205     }
 206     elsif ($^O eq 'os2') {
 207       if ($DB::emacs) {
 208         $console = undef;
 209       } else {
 210         $console = "/dev/con";
 211       }
 212     }
 213
 214     my $consoleOUT = $console;
 215     $console = "&STDIN" unless defined $console;
 216     if (!defined $consoleOUT) {
 217       $consoleOUT = defined fileno(STDERR) ? "&STDERR" : "&STDOUT";
 218     }
 219     ($console,$consoleOUT);
 220 }
 221
 222 sub new {
 223   die "method new called with wrong number of arguments"
 224     unless @_==2 or @_==4;
 225   #local (*FIN, *FOUT);
 226   my ($FIN, $FOUT, $ret);
 227   if (@_==2) {
 228     my($console, $consoleOUT) = findConsole;
 229
 230     open(FIN, "<$console");
 231     open(FOUT,">$consoleOUT");
 232     #OUT->autoflush(1);         # Conflicts with debugger?
 233     my $sel = select(FOUT);
 234     $| = 1;                             # for DB::OUT
 235     select($sel);
 236     $ret = bless [\*FIN, \*FOUT];
 237   } else {                      # Filehandles supplied
 238     $FIN = $_[2]; $FOUT = $_[3];
 239     #OUT->autoflush(1);         # Conflicts with debugger?
 240     my $sel = select($FOUT);
 241     $| = 1;                             # for DB::OUT
 242     select($sel);
 243     $ret = bless [$FIN, $FOUT];
 244   }
 245   if ($ret->Features->{ornaments}
 246       and not ($ENV{PERL_RL} and $ENV{PERL_RL} =~ /\bo\w*=0/)) {
 247     local $Term::ReadLine::termcap_nowarn = 1;
 248     $ret->ornaments(1);
 249   }
 250   return $ret;
 251 }
 252
 253 sub newTTY {
 254   my ($self, $in, $out) = @_;
 255   $self->[0] = $in;
 256   $self->[1] = $out;
 257   my $sel = select($out);
 258   $| = 1;                               # for DB::OUT
 259   select($sel);
 260 }
 261
 262 sub IN { shift->[0] }
 263 sub OUT { shift->[1] }
 264 sub MinLine { undef }
 265 sub Attribs { {} }
 266
 267 my %features = (tkRunning => 1, ornaments => 1, 'newTTY' => 1);
 268 sub Features { \%features }
 269
 270 package Term::ReadLine;         # So late to allow the above code be defined?
 271
 272 our $VERSION = '1.00';
 273
 274 my ($which) = exists $ENV{PERL_RL} ? split /\s+/, $ENV{PERL_RL} : undef;
 275 if ($which) {
 276   if ($which =~ /\bgnu\b/i){
 277     eval "use Term::ReadLine::Gnu;";
 278   } elsif ($which =~ /\bperl\b/i) {
 279     eval "use Term::ReadLine::Perl;";
 280   } else {
 281     eval "use Term::ReadLine::$which;";
 282   }
 283 } elsif (defined $which and $which ne '') {     # Defined but false
 284   # Do nothing fancy
 285 } else {
 286   eval "use Term::ReadLine::Gnu; 1" or eval "use Term::ReadLine::Perl; 1";
 287 }
 288
 289 #require FileHandle;
 290
 291 # To make possible switch off RL in debugger: (Not needed, work done
 292 # in debugger).
 293 our @ISA;
 294 if (defined &Term::ReadLine::Gnu::readline) {
 295   @ISA = qw(Term::ReadLine::Gnu Term::ReadLine::Stub);
 296 } elsif (defined &Term::ReadLine::Perl::readline) {
 297   @ISA = qw(Term::ReadLine::Perl Term::ReadLine::Stub);
 298 } else {
 299   @ISA = qw(Term::ReadLine::Stub);
 300 }
 301
 302 package Term::ReadLine::TermCap;
 303
 304 # Prompt-start, prompt-end, command-line-start, command-line-end
 305 #     -- zero-width beautifies to emit around prompt and the command line.
 306 our @rl_term_set = ("","","","");
 307 # string encoded:
 308 our $rl_term_set = ',,,';
 309
 310 our $terminal;
 311 sub LoadTermCap {
 312   return if defined $terminal;
 313
 314   require Term::Cap;
 315   $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
 316 }
 317
 318 sub ornaments {
 319   shift;
 320   return $rl_term_set unless @_;
 321   $rl_term_set = shift;
 322   $rl_term_set ||= ',,,';
 323   $rl_term_set = 'us,ue,md,me' if $rl_term_set eq '1';
 324   my @ts = split /,/, $rl_term_set, 4;
 325   eval { LoadTermCap };
 326   unless (defined $terminal) {
 327     warn("Cannot find termcap: $@\n") unless $Term::ReadLine::termcap_nowarn;
 328     $rl_term_set = ',,,';
 329     return;
 330   }
 331   @rl_term_set = map {$_ ? $terminal->Tputs($_,1) || '' : ''} @ts;
 332   return $rl_term_set;
 333 }
 334
 335
 336 package Term::ReadLine::Tk;
 337
 338 our($count_handle, $count_DoOne, $count_loop);
 339 $count_handle = $count_DoOne = $count_loop = 0;
 340
 341 our($giveup);
 342 sub handle {$giveup = 1; $count_handle++}
 343
 344 sub Tk_loop {
 345   # Tk->tkwait('variable',\$giveup);    # needs Widget
 346   $count_DoOne++, Tk::DoOneEvent(0) until $giveup;
 347   $count_loop++;
 348   $giveup = 0;
 349 }
 350
 351 sub register_Tk {
 352   my $self = shift;
 353   $Term::ReadLine::registered++
 354     or Tk->fileevent($self->IN,'readable',\&handle);
 355 }
 356
 357 sub tkRunning {
 358   $Term::ReadLine::toloop = $_[1] if @_ > 1;
 359   $Term::ReadLine::toloop;
 360 }
 361
 362 sub get_c {
 363   my $self = shift;
 364   $self->Tk_loop if $Term::ReadLine::toloop && defined &Tk::DoOneEvent;
 365   return getc $self->IN;
 366 }
 367
 368 sub get_line {
 369   my $self = shift;
 370   $self->Tk_loop if $Term::ReadLine::toloop && defined &Tk::DoOneEvent;
 371   my $in = $self->IN;
 372   local ($/) = "\n";
 373   return scalar <$in>;
 374 }
 375
 376 1;
 377