lib/Symbol.pm

   1 package Symbol;
   2
   3 =head1 NAME
   4
   5 Symbol - manipulate Perl symbols and their names
   6
   7 =head1 SYNOPSIS
   8
   9     use Symbol;
  10
  11     $sym = gensym;
  12     open($sym, "filename");
  13     $_ = <$sym>;
  14     # etc.
  15
  16     ungensym $sym;      # no effect
  17
  18     print qualify("x"), "\n";              # "Test::x"
  19     print qualify("x", "FOO"), "\n"        # "FOO::x"
  20     print qualify("BAR::x"), "\n";         # "BAR::x"
  21     print qualify("BAR::x", "FOO"), "\n";  # "BAR::x"
  22     print qualify("STDOUT", "FOO"), "\n";  # "main::STDOUT" (global)
  23     print qualify(\*x), "\n";              # returns \*x
  24     print qualify(\*x, "FOO"), "\n";       # returns \*x
  25
  26 =head1 DESCRIPTION
  27
  28 C<Symbol::gensym> creates an anonymous glob and returns a reference
  29 to it.  Such a glob reference can be used as a file or directory
  30 handle.
  31
  32 For backward compatibility with older implementations that didn't
  33 support anonymous globs, C<Symbol::ungensym> is also provided.
  34 But it doesn't do anything.
  35
  36 C<Symbol::qualify> turns unqualified symbol names into qualified
  37 variable names (e.g. "myvar" -E<gt> "MyPackage::myvar").  If it is given a
  38 second parameter, C<qualify> uses it as the default package;
  39 otherwise, it uses the package of its caller.  Regardless, global
  40 variable names (e.g. "STDOUT", "ENV", "SIG") are always qualfied with
  41 "main::".
  42
  43 Qualification applies only to symbol names (strings).  References are
  44 left unchanged under the assumption that they are glob references,
  45 which are qualified by their nature.
  46
  47 =cut
  48
  49 BEGIN { require 5.002; }
  50
  51 require Exporter;
  52 @ISA = qw(Exporter);
  53
  54 @EXPORT = qw(gensym ungensym qualify);
  55
  56 my $genpkg = "Symbol::";
  57 my $genseq = 0;
  58
  59 my %global = map {$_ => 1} qw(ARGV ARGVOUT ENV INC SIG STDERR STDIN STDOUT);
  60
  61 #
  62 # Note that we never _copy_ the glob; we just make a ref to it.
  63 # If we did copy it, then SVf_FAKE would be set on the copy, and
  64 # glob-specific behaviors (e.g. C<*$ref = \&func>) wouldn't work.
  65 #
  66 sub gensym () {
  67     my $name = "GEN" . $genseq++;
  68     my $ref = \*{$genpkg . $name};
  69     delete $$genpkg{$name};
  70     $ref;
  71 }
  72
  73 sub ungensym ($) {}
  74
  75 sub qualify ($;$) {
  76     my ($name) = @_;
  77     if (!ref($name) && index($name, '::') == -1 && index($name, "'") == -1) {
  78         my $pkg;
  79         # Global names: special character, "^x", or other.
  80         if ($name =~ /^([^a-z])|(\^[a-z])$/i || $global{$name}) {
  81             $pkg = "main";
  82         }
  83         else {
  84             $pkg = (@_ > 1) ? $_[1] : caller;
  85         }
  86         $name = $pkg . "::" . $name;
  87     }
  88     $name;
  89 }
  90
  91 1;