lib/SelfLoader.pm

   1 package SelfLoader;
   2
   3 use 5.009005; # due to new regexp features
   4 use strict;
   5
   6 use Exporter;
   7 our @ISA = qw(Exporter);
   8 our @EXPORT = qw(AUTOLOAD);
   9 our $VERSION = "1.11";
  10 sub Version {$VERSION}
  11 sub DEBUG () { 0 }
  12
  13 my %Cache;      # private cache for all SelfLoader's client packages
  14
  15 # allow checking for valid ': attrlist' attachments
  16 # see also AutoSplit
  17
  18 my $attr_list = qr{
  19     \s* : \s*
  20     (?:
  21         # one attribute
  22         (?> # no backtrack
  23             (?! \d) \w+
  24             (?<nested> \( (?: [^()]++ | (?&nested)++ )*+ \) ) ?
  25         )
  26         (?: \s* : \s* | \s+ (?! :) )
  27     )*
  28 }x;
  29
  30 # in croak and carp, protect $@ from "require Carp;" RT #40216
  31
  32 sub croak { { local $@; require Carp; } goto &Carp::croak }
  33 sub carp { { local $@; require Carp; } goto &Carp::carp }
  34
  35 AUTOLOAD {
  36     our $AUTOLOAD;
  37     print STDERR "SelfLoader::AUTOLOAD for $AUTOLOAD\n" if DEBUG;
  38     my $SL_code = $Cache{$AUTOLOAD};
  39     my $save = $@; # evals in both AUTOLOAD and _load_stubs can corrupt $@
  40     unless ($SL_code) {
  41         # Maybe this pack had stubs before __DATA__, and never initialized.
  42         # Or, this maybe an automatic DESTROY method call when none exists.
  43         $AUTOLOAD =~ m/^(.*)::/;
  44         SelfLoader->_load_stubs($1) unless exists $Cache{"${1}::<DATA"};
  45         $SL_code = $Cache{$AUTOLOAD};
  46         $SL_code = "sub $AUTOLOAD { }"
  47             if (!$SL_code and $AUTOLOAD =~ m/::DESTROY$/);
  48         croak "Undefined subroutine $AUTOLOAD" unless $SL_code;
  49     }
  50     print STDERR "SelfLoader::AUTOLOAD eval: $SL_code\n" if DEBUG;
  51
  52     eval $SL_code;
  53     if ($@) {
  54         $@ =~ s/ at .*\n//;
  55         croak $@;
  56     }
  57     $@ = $save;
  58     defined(&$AUTOLOAD) || die "SelfLoader inconsistency error";
  59     delete $Cache{$AUTOLOAD};
  60     goto &$AUTOLOAD
  61 }
  62
  63 sub load_stubs { shift->_load_stubs((caller)[0]) }
  64
  65 sub _load_stubs {
  66     # $endlines is used by Devel::SelfStubber to capture lines after __END__
  67     my($self, $callpack, $endlines) = @_;
  68     no strict "refs";
  69     my $fh = \*{"${callpack}::DATA"};
  70     use strict;
  71     my $currpack = $callpack;
  72     my($line,$name,@lines, @stubs, $protoype);
  73
  74     print STDERR "SelfLoader::load_stubs($callpack)\n" if DEBUG;
  75     croak("$callpack doesn't contain an __DATA__ token")
  76         unless defined fileno($fh);
  77     # Protect: fork() shares the file pointer between the parent and the kid
  78     if(sysseek($fh, tell($fh), 0)) {
  79       open my $nfh, '<&', $fh or croak "reopen: $!";# dup() the fd
  80       close $fh or die "close: $1";                 # autocloses, but be paranoid
  81       open $fh, '<&', $nfh or croak "reopen2: $!";  # dup() the fd "back"
  82       close $nfh or die "close after reopen: $1";   # autocloses, but be paranoid
  83     }
  84     $Cache{"${currpack}::<DATA"} = 1;   # indicate package is cached
  85
  86     local($/) = "\n";
  87     while(defined($line = <$fh>) and $line !~ m/^__END__/) {
  88         if ($line =~ m/^sub\s+([\w:]+)\s*((?:\([\\\$\@\%\&\*\;]*\))?(?:$attr_list)?)/) {
  89             push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
  90             $protoype = $2;
  91             @lines = ($line);
  92             if (index($1,'::') == -1) {         # simple sub name
  93                 $name = "${currpack}::$1";
  94             } else {                            # sub name with package
  95                 $name = $1;
  96                 $name =~ m/^(.*)::/;
  97                 if (defined(&{"${1}::AUTOLOAD"})) {
  98                     \&{"${1}::AUTOLOAD"} == \&SelfLoader::AUTOLOAD ||
  99                         die 'SelfLoader Error: attempt to specify Selfloading',
 100                             " sub $name in non-selfloading module $1";
 101                 } else {
 102                     $self->export($1,'AUTOLOAD');
 103                 }
 104             }
 105         } elsif ($line =~ m/^package\s+([\w:]+)/) { # A package declared
 106             push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
 107             $self->_package_defined($line);
 108             $name = '';
 109             @lines = ();
 110             $currpack = $1;
 111             $Cache{"${currpack}::<DATA"} = 1;   # indicate package is cached
 112             if (defined(&{"${1}::AUTOLOAD"})) {
 113                 \&{"${1}::AUTOLOAD"} == \&SelfLoader::AUTOLOAD ||
 114                     die 'SelfLoader Error: attempt to specify Selfloading',
 115                         " package $currpack which already has AUTOLOAD";
 116             } else {
 117                 $self->export($currpack,'AUTOLOAD');
 118             }
 119         } else {
 120             push(@lines,$line);
 121         }
 122     }
 123     if (defined($line) && $line =~ /^__END__/) { # __END__
 124         unless ($line =~ /^__END__\s*DATA/) {
 125             if ($endlines) {
 126                 # Devel::SelfStubber would like us to capture the lines after
 127                 # __END__ so it can write out the entire file
 128                 @$endlines = <$fh>;
 129             }
 130             close($fh);
 131         }
 132     }
 133     push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
 134     eval join('', @stubs) if @stubs;
 135 }
 136
 137
 138 sub _add_to_cache {
 139     my($self,$fullname,$pack,$lines, $protoype) = @_;
 140     return () unless $fullname;
 141     carp("Redefining sub $fullname")
 142       if exists $Cache{$fullname};
 143     $Cache{$fullname} = join('', "package $pack; ",@$lines);
 144     print STDERR "SelfLoader cached $fullname: $Cache{$fullname}" if DEBUG;
 145     # return stub to be eval'd
 146     defined($protoype) ? "sub $fullname $protoype;" : "sub $fullname;"
 147 }
 148
 149 sub _package_defined {}
 150
 151 1;
 152 __END__
 153
 154 =head1 NAME
 155
 156 SelfLoader - load functions only on demand
 157
 158 =head1 SYNOPSIS
 159
 160     package FOOBAR;
 161     use SelfLoader;
 162
 163     ... (initializing code)
 164
 165     __DATA__
 166     sub {....
 167
 168
 169 =head1 DESCRIPTION
 170
 171 This module tells its users that functions in the FOOBAR package are to be
 172 autoloaded from after the C<__DATA__> token.  See also
 173 L<perlsub/"Autoloading">.
 174
 175 =head2 The __DATA__ token
 176
 177 The C<__DATA__> token tells the perl compiler that the perl code
 178 for compilation is finished. Everything after the C<__DATA__> token
 179 is available for reading via the filehandle FOOBAR::DATA,
 180 where FOOBAR is the name of the current package when the C<__DATA__>
 181 token is reached. This works just the same as C<__END__> does in
 182 package 'main', but for other modules data after C<__END__> is not
 183 automatically retrievable, whereas data after C<__DATA__> is.
 184 The C<__DATA__> token is not recognized in versions of perl prior to
 185 5.001m.
 186
 187 Note that it is possible to have C<__DATA__> tokens in the same package
 188 in multiple files, and that the last C<__DATA__> token in a given
 189 package that is encountered by the compiler is the one accessible
 190 by the filehandle. This also applies to C<__END__> and main, i.e. if
 191 the 'main' program has an C<__END__>, but a module 'require'd (_not_ 'use'd)
 192 by that program has a 'package main;' declaration followed by an 'C<__DATA__>',
 193 then the C<DATA> filehandle is set to access the data after the C<__DATA__>
 194 in the module, _not_ the data after the C<__END__> token in the 'main'
 195 program, since the compiler encounters the 'require'd file later.
 196
 197 =head2 SelfLoader autoloading
 198
 199 The B<SelfLoader> works by the user placing the C<__DATA__>
 200 token I<after> perl code which needs to be compiled and
 201 run at 'require' time, but I<before> subroutine declarations
 202 that can be loaded in later - usually because they may never
 203 be called.
 204
 205 The B<SelfLoader> will read from the FOOBAR::DATA filehandle to
 206 load in the data after C<__DATA__>, and load in any subroutine
 207 when it is called. The costs are the one-time parsing of the
 208 data after C<__DATA__>, and a load delay for the _first_
 209 call of any autoloaded function. The benefits (hopefully)
 210 are a speeded up compilation phase, with no need to load
 211 functions which are never used.
 212
 213 The B<SelfLoader> will stop reading from C<__DATA__> if
 214 it encounters the C<__END__> token - just as you would expect.
 215 If the C<__END__> token is present, and is followed by the
 216 token DATA, then the B<SelfLoader> leaves the FOOBAR::DATA
 217 filehandle open on the line after that token.
 218
 219 The B<SelfLoader> exports the C<AUTOLOAD> subroutine to the
 220 package using the B<SelfLoader>, and this loads the called
 221 subroutine when it is first called.
 222
 223 There is no advantage to putting subroutines which will _always_
 224 be called after the C<__DATA__> token.
 225
 226 =head2 Autoloading and package lexicals
 227
 228 A 'my $pack_lexical' statement makes the variable $pack_lexical
 229 local _only_ to the file up to the C<__DATA__> token. Subroutines
 230 declared elsewhere _cannot_ see these types of variables,
 231 just as if you declared subroutines in the package but in another
 232 file, they cannot see these variables.
 233
 234 So specifically, autoloaded functions cannot see package
 235 lexicals (this applies to both the B<SelfLoader> and the Autoloader).
 236 The C<vars> pragma provides an alternative to defining package-level
 237 globals that will be visible to autoloaded routines. See the documentation
 238 on B<vars> in the pragma section of L<perlmod>.
 239
 240 =head2 SelfLoader and AutoLoader
 241
 242 The B<SelfLoader> can replace the AutoLoader - just change 'use AutoLoader'
 243 to 'use SelfLoader' (though note that the B<SelfLoader> exports
 244 the AUTOLOAD function - but if you have your own AUTOLOAD and
 245 are using the AutoLoader too, you probably know what you're doing),
 246 and the C<__END__> token to C<__DATA__>. You will need perl version 5.001m
 247 or later to use this (version 5.001 with all patches up to patch m).
 248
 249 There is no need to inherit from the B<SelfLoader>.
 250
 251 The B<SelfLoader> works similarly to the AutoLoader, but picks up the
 252 subs from after the C<__DATA__> instead of in the 'lib/auto' directory.
 253 There is a maintenance gain in not needing to run AutoSplit on the module
 254 at installation, and a runtime gain in not needing to keep opening and
 255 closing files to load subs. There is a runtime loss in needing
 256 to parse the code after the C<__DATA__>. Details of the B<AutoLoader> and
 257 another view of these distinctions can be found in that module's
 258 documentation.
 259
 260 =head2 __DATA__, __END__, and the FOOBAR::DATA filehandle.
 261
 262 This section is only relevant if you want to use
 263 the C<FOOBAR::DATA> together with the B<SelfLoader>.
 264
 265 Data after the C<__DATA__> token in a module is read using the
 266 FOOBAR::DATA filehandle. C<__END__> can still be used to denote the end
 267 of the C<__DATA__> section if followed by the token DATA - this is supported
 268 by the B<SelfLoader>. The C<FOOBAR::DATA> filehandle is left open if an
 269 C<__END__> followed by a DATA is found, with the filehandle positioned at
 270 the start of the line after the C<__END__> token. If no C<__END__> token is
 271 present, or an C<__END__> token with no DATA token on the same line, then
 272 the filehandle is closed.
 273
 274 The B<SelfLoader> reads from wherever the current
 275 position of the C<FOOBAR::DATA> filehandle is, until the
 276 EOF or C<__END__>. This means that if you want to use
 277 that filehandle (and ONLY if you want to), you should either
 278
 279 1. Put all your subroutine declarations immediately after
 280 the C<__DATA__> token and put your own data after those
 281 declarations, using the C<__END__> token to mark the end
 282 of subroutine declarations. You must also ensure that the B<SelfLoader>
 283 reads first by  calling 'SelfLoader-E<gt>load_stubs();', or by using a
 284 function which is selfloaded;
 285
 286 or
 287
 288 2. You should read the C<FOOBAR::DATA> filehandle first, leaving
 289 the handle open and positioned at the first line of subroutine
 290 declarations.
 291
 292 You could conceivably do both.
 293
 294 =head2 Classes and inherited methods.
 295
 296 For modules which are not classes, this section is not relevant.
 297 This section is only relevant if you have methods which could
 298 be inherited.
 299
 300 A subroutine stub (or forward declaration) looks like
 301
 302   sub stub;
 303
 304 i.e. it is a subroutine declaration without the body of the
 305 subroutine. For modules which are not classes, there is no real
 306 need for stubs as far as autoloading is concerned.
 307
 308 For modules which ARE classes, and need to handle inherited methods,
 309 stubs are needed to ensure that the method inheritance mechanism works
 310 properly. You can load the stubs into the module at 'require' time, by
 311 adding the statement 'SelfLoader-E<gt>load_stubs();' to the module to do
 312 this.
 313
 314 The alternative is to put the stubs in before the C<__DATA__> token BEFORE
 315 releasing the module, and for this purpose the C<Devel::SelfStubber>
 316 module is available.  However this does require the extra step of ensuring
 317 that the stubs are in the module. If this is done I strongly recommend
 318 that this is done BEFORE releasing the module - it should NOT be done
 319 at install time in general.
 320
 321 =head1 Multiple packages and fully qualified subroutine names
 322
 323 Subroutines in multiple packages within the same file are supported - but you
 324 should note that this requires exporting the C<SelfLoader::AUTOLOAD> to
 325 every package which requires it. This is done automatically by the
 326 B<SelfLoader> when it first loads the subs into the cache, but you should
 327 really specify it in the initialization before the C<__DATA__> by putting
 328 a 'use SelfLoader' statement in each package.
 329
 330 Fully qualified subroutine names are also supported. For example,
 331
 332    __DATA__
 333    sub foo::bar {23}
 334    package baz;
 335    sub dob {32}
 336
 337 will all be loaded correctly by the B<SelfLoader>, and the B<SelfLoader>
 338 will ensure that the packages 'foo' and 'baz' correctly have the
 339 B<SelfLoader> C<AUTOLOAD> method when the data after C<__DATA__> is first
 340 parsed.
 341
 342 =cut