lib/SelfLoader.pm

   1 package SelfLoader;
   2 # use Carp;
   3 require Exporter;
   4 @ISA = qw(Exporter);
   5 @EXPORT = qw(AUTOLOAD);
   6 $VERSION = "1.0903";
   7 sub Version {$VERSION}
   8 $DEBUG = 0;
   9
  10 my %Cache;      # private cache for all SelfLoader's client packages
  11
  12 # allow checking for valid ': attrlist' attachments
  13 my $nested;
  14 $nested = qr{ \( (?: (?> [^()]+ ) | (??{ $nested }) )* \) }x;
  15 my $one_attr = qr{ (?> (?! \d) \w+ (?:$nested)? ) (?:\s*\:\s*|\s+(?!\:)) }x;
  16 my $attr_list = qr{ \s* : \s* (?: $one_attr )* }x;
  17
  18 sub croak { require Carp; goto &Carp::croak }
  19
  20 AUTOLOAD {
  21     print STDERR "SelfLoader::AUTOLOAD for $AUTOLOAD\n" if $DEBUG;
  22     my $SL_code = $Cache{$AUTOLOAD};
  23     my $save = $@; # evals in both AUTOLOAD and _load_stubs can corrupt $@
  24     unless ($SL_code) {
  25         # Maybe this pack had stubs before __DATA__, and never initialized.
  26         # Or, this maybe an automatic DESTROY method call when none exists.
  27         $AUTOLOAD =~ m/^(.*)::/;
  28         SelfLoader->_load_stubs($1) unless exists $Cache{"${1}::<DATA"};
  29         $SL_code = $Cache{$AUTOLOAD};
  30         $SL_code = "sub $AUTOLOAD { }"
  31             if (!$SL_code and $AUTOLOAD =~ m/::DESTROY$/);
  32         croak "Undefined subroutine $AUTOLOAD" unless $SL_code;
  33     }
  34     print STDERR "SelfLoader::AUTOLOAD eval: $SL_code\n" if $DEBUG;
  35
  36     eval $SL_code;
  37     if ($@) {
  38         $@ =~ s/ at .*\n//;
  39         croak $@;
  40     }
  41     $@ = $save;
  42     defined(&$AUTOLOAD) || die "SelfLoader inconsistency error";
  43     delete $Cache{$AUTOLOAD};
  44     goto &$AUTOLOAD
  45 }
  46
  47 sub load_stubs { shift->_load_stubs((caller)[0]) }
  48
  49 sub _load_stubs {
  50     # $endlines is used by Devel::SelfStubber to capture lines after __END__
  51     my($self, $callpack, $endlines) = @_;
  52     my $fh = \*{"${callpack}::DATA"};
  53     my $currpack = $callpack;
  54     my($line,$name,@lines, @stubs, $protoype);
  55
  56     print STDERR "SelfLoader::load_stubs($callpack)\n" if $DEBUG;
  57     croak("$callpack doesn't contain an __DATA__ token")
  58         unless fileno($fh);
  59     $Cache{"${currpack}::<DATA"} = 1;   # indicate package is cached
  60
  61     local($/) = "\n";
  62     while(defined($line = <$fh>) and $line !~ m/^__END__/) {
  63         if ($line =~ m/^sub\s+([\w:]+)\s*((?:\([\\\$\@\%\&\*\;]*\))?(?:$attr_list)?)/) {
  64             push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
  65             $protoype = $2;
  66             @lines = ($line);
  67             if (index($1,'::') == -1) {         # simple sub name
  68                 $name = "${currpack}::$1";
  69             } else {                            # sub name with package
  70                 $name = $1;
  71                 $name =~ m/^(.*)::/;
  72                 if (defined(&{"${1}::AUTOLOAD"})) {
  73                     \&{"${1}::AUTOLOAD"} == \&SelfLoader::AUTOLOAD ||
  74                         die 'SelfLoader Error: attempt to specify Selfloading',
  75                             " sub $name in non-selfloading module $1";
  76                 } else {
  77                     $self->export($1,'AUTOLOAD');
  78                 }
  79             }
  80         } elsif ($line =~ m/^package\s+([\w:]+)/) { # A package declared
  81             push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
  82             $self->_package_defined($line);
  83             $name = '';
  84             @lines = ();
  85             $currpack = $1;
  86             $Cache{"${currpack}::<DATA"} = 1;   # indicate package is cached
  87             if (defined(&{"${1}::AUTOLOAD"})) {
  88                 \&{"${1}::AUTOLOAD"} == \&SelfLoader::AUTOLOAD ||
  89                     die 'SelfLoader Error: attempt to specify Selfloading',
  90                         " package $currpack which already has AUTOLOAD";
  91             } else {
  92                 $self->export($currpack,'AUTOLOAD');
  93             }
  94         } else {
  95             push(@lines,$line);
  96         }
  97     }
  98     if (defined($line) && $line =~ /^__END__/) { # __END__
  99         unless ($line =~ /^__END__\s*DATA/) {
 100             if ($endlines) {
 101                 # Devel::SelfStubber would like us to capture the lines after
 102                 # __END__ so it can write out the entire file
 103                 @$endlines = <$fh>;
 104             }
 105             close($fh);
 106         }
 107     }
 108     push(@stubs, $self->_add_to_cache($name, $currpack, \@lines, $protoype));
 109     eval join('', @stubs) if @stubs;
 110 }
 111
 112
 113 sub _add_to_cache {
 114     my($self,$fullname,$pack,$lines, $protoype) = @_;
 115     return () unless $fullname;
 116     (require Carp), Carp::carp("Redefining sub $fullname")
 117       if exists $Cache{$fullname};
 118     $Cache{$fullname} = join('', "package $pack; ",@$lines);
 119     print STDERR "SelfLoader cached $fullname: $Cache{$fullname}" if $DEBUG;
 120     # return stub to be eval'd
 121     defined($protoype) ? "sub $fullname $protoype;" : "sub $fullname;"
 122 }
 123
 124 sub _package_defined {}
 125
 126 1;
 127 __END__
 128
 129 =head1 NAME
 130
 131 SelfLoader - load functions only on demand
 132
 133 =head1 SYNOPSIS
 134
 135     package FOOBAR;
 136     use SelfLoader;
 137
 138     ... (initializing code)
 139
 140     __DATA__
 141     sub {....
 142
 143
 144 =head1 DESCRIPTION
 145
 146 This module tells its users that functions in the FOOBAR package are to be
 147 autoloaded from after the C<__DATA__> token.  See also
 148 L<perlsub/"Autoloading">.
 149
 150 =head2 The __DATA__ token
 151
 152 The C<__DATA__> token tells the perl compiler that the perl code
 153 for compilation is finished. Everything after the C<__DATA__> token
 154 is available for reading via the filehandle FOOBAR::DATA,
 155 where FOOBAR is the name of the current package when the C<__DATA__>
 156 token is reached. This works just the same as C<__END__> does in
 157 package 'main', but for other modules data after C<__END__> is not
 158 automatically retrievable, whereas data after C<__DATA__> is.
 159 The C<__DATA__> token is not recognized in versions of perl prior to
 160 5.001m.
 161
 162 Note that it is possible to have C<__DATA__> tokens in the same package
 163 in multiple files, and that the last C<__DATA__> token in a given
 164 package that is encountered by the compiler is the one accessible
 165 by the filehandle. This also applies to C<__END__> and main, i.e. if
 166 the 'main' program has an C<__END__>, but a module 'require'd (_not_ 'use'd)
 167 by that program has a 'package main;' declaration followed by an 'C<__DATA__>',
 168 then the C<DATA> filehandle is set to access the data after the C<__DATA__>
 169 in the module, _not_ the data after the C<__END__> token in the 'main'
 170 program, since the compiler encounters the 'require'd file later.
 171
 172 =head2 SelfLoader autoloading
 173
 174 The B<SelfLoader> works by the user placing the C<__DATA__>
 175 token I<after> perl code which needs to be compiled and
 176 run at 'require' time, but I<before> subroutine declarations
 177 that can be loaded in later - usually because they may never
 178 be called.
 179
 180 The B<SelfLoader> will read from the FOOBAR::DATA filehandle to
 181 load in the data after C<__DATA__>, and load in any subroutine
 182 when it is called. The costs are the one-time parsing of the
 183 data after C<__DATA__>, and a load delay for the _first_
 184 call of any autoloaded function. The benefits (hopefully)
 185 are a speeded up compilation phase, with no need to load
 186 functions which are never used.
 187
 188 The B<SelfLoader> will stop reading from C<__DATA__> if
 189 it encounters the C<__END__> token - just as you would expect.
 190 If the C<__END__> token is present, and is followed by the
 191 token DATA, then the B<SelfLoader> leaves the FOOBAR::DATA
 192 filehandle open on the line after that token.
 193
 194 The B<SelfLoader> exports the C<AUTOLOAD> subroutine to the
 195 package using the B<SelfLoader>, and this loads the called
 196 subroutine when it is first called.
 197
 198 There is no advantage to putting subroutines which will _always_
 199 be called after the C<__DATA__> token.
 200
 201 =head2 Autoloading and package lexicals
 202
 203 A 'my $pack_lexical' statement makes the variable $pack_lexical
 204 local _only_ to the file up to the C<__DATA__> token. Subroutines
 205 declared elsewhere _cannot_ see these types of variables,
 206 just as if you declared subroutines in the package but in another
 207 file, they cannot see these variables.
 208
 209 So specifically, autoloaded functions cannot see package
 210 lexicals (this applies to both the B<SelfLoader> and the Autoloader).
 211 The C<vars> pragma provides an alternative to defining package-level
 212 globals that will be visible to autoloaded routines. See the documentation
 213 on B<vars> in the pragma section of L<perlmod>.
 214
 215 =head2 SelfLoader and AutoLoader
 216
 217 The B<SelfLoader> can replace the AutoLoader - just change 'use AutoLoader'
 218 to 'use SelfLoader' (though note that the B<SelfLoader> exports
 219 the AUTOLOAD function - but if you have your own AUTOLOAD and
 220 are using the AutoLoader too, you probably know what you're doing),
 221 and the C<__END__> token to C<__DATA__>. You will need perl version 5.001m
 222 or later to use this (version 5.001 with all patches up to patch m).
 223
 224 There is no need to inherit from the B<SelfLoader>.
 225
 226 The B<SelfLoader> works similarly to the AutoLoader, but picks up the
 227 subs from after the C<__DATA__> instead of in the 'lib/auto' directory.
 228 There is a maintenance gain in not needing to run AutoSplit on the module
 229 at installation, and a runtime gain in not needing to keep opening and
 230 closing files to load subs. There is a runtime loss in needing
 231 to parse the code after the C<__DATA__>. Details of the B<AutoLoader> and
 232 another view of these distinctions can be found in that module's
 233 documentation.
 234
 235 =head2 __DATA__, __END__, and the FOOBAR::DATA filehandle.
 236
 237 This section is only relevant if you want to use
 238 the C<FOOBAR::DATA> together with the B<SelfLoader>.
 239
 240 Data after the C<__DATA__> token in a module is read using the
 241 FOOBAR::DATA filehandle. C<__END__> can still be used to denote the end
 242 of the C<__DATA__> section if followed by the token DATA - this is supported
 243 by the B<SelfLoader>. The C<FOOBAR::DATA> filehandle is left open if an
 244 C<__END__> followed by a DATA is found, with the filehandle positioned at
 245 the start of the line after the C<__END__> token. If no C<__END__> token is
 246 present, or an C<__END__> token with no DATA token on the same line, then
 247 the filehandle is closed.
 248
 249 The B<SelfLoader> reads from wherever the current
 250 position of the C<FOOBAR::DATA> filehandle is, until the
 251 EOF or C<__END__>. This means that if you want to use
 252 that filehandle (and ONLY if you want to), you should either
 253
 254 1. Put all your subroutine declarations immediately after
 255 the C<__DATA__> token and put your own data after those
 256 declarations, using the C<__END__> token to mark the end
 257 of subroutine declarations. You must also ensure that the B<SelfLoader>
 258 reads first by  calling 'SelfLoader-E<gt>load_stubs();', or by using a
 259 function which is selfloaded;
 260
 261 or
 262
 263 2. You should read the C<FOOBAR::DATA> filehandle first, leaving
 264 the handle open and positioned at the first line of subroutine
 265 declarations.
 266
 267 You could conceivably do both.
 268
 269 =head2 Classes and inherited methods.
 270
 271 For modules which are not classes, this section is not relevant.
 272 This section is only relevant if you have methods which could
 273 be inherited.
 274
 275 A subroutine stub (or forward declaration) looks like
 276
 277   sub stub;
 278
 279 i.e. it is a subroutine declaration without the body of the
 280 subroutine. For modules which are not classes, there is no real
 281 need for stubs as far as autoloading is concerned.
 282
 283 For modules which ARE classes, and need to handle inherited methods,
 284 stubs are needed to ensure that the method inheritance mechanism works
 285 properly. You can load the stubs into the module at 'require' time, by
 286 adding the statement 'SelfLoader-E<gt>load_stubs();' to the module to do
 287 this.
 288
 289 The alternative is to put the stubs in before the C<__DATA__> token BEFORE
 290 releasing the module, and for this purpose the C<Devel::SelfStubber>
 291 module is available.  However this does require the extra step of ensuring
 292 that the stubs are in the module. If this is done I strongly recommend
 293 that this is done BEFORE releasing the module - it should NOT be done
 294 at install time in general.
 295
 296 =head1 Multiple packages and fully qualified subroutine names
 297
 298 Subroutines in multiple packages within the same file are supported - but you
 299 should note that this requires exporting the C<SelfLoader::AUTOLOAD> to
 300 every package which requires it. This is done automatically by the
 301 B<SelfLoader> when it first loads the subs into the cache, but you should
 302 really specify it in the initialization before the C<__DATA__> by putting
 303 a 'use SelfLoader' statement in each package.
 304
 305 Fully qualified subroutine names are also supported. For example,
 306
 307    __DATA__
 308    sub foo::bar {23}
 309    package baz;
 310    sub dob {32}
 311
 312 will all be loaded correctly by the B<SelfLoader>, and the B<SelfLoader>
 313 will ensure that the packages 'foo' and 'baz' correctly have the
 314 B<SelfLoader> C<AUTOLOAD> method when the data after C<__DATA__> is first
 315 parsed.
 316
 317 =cut