lib/SQL/Translator.pm

   1 use MooseX::Declare;
   2 class SQL::Translator {
   3     use TryCatch;
   4     use MooseX::Types::Moose qw(Bool HashRef Int Str Undef);
   5     use MooseX::Aliases;
   6     use SQL::Translator::Types qw(DBIHandle Parser Producer Schema);
   7     use SQL::Translator::Object::Schema;
   8
   9     our $VERSION = '0.001';
  10
  11     has 'parser' => (
  12         isa => Str,
  13         is => 'rw',
  14         alias => 'from',
  15     );
  16
  17     has 'producer' => (
  18         isa => Str,
  19         is => 'rw',
  20         alias => 'to',
  21     );
  22
  23     has '_parser' => (
  24         isa => Parser,
  25         is => 'rw',
  26         lazy_build => 1,
  27         handles => [ qw(parse) ],
  28         predicate => 'has_parser',
  29     );
  30
  31     has '_producer' => (
  32         isa => Producer,
  33         is => 'rw',
  34         lazy_build => 1,
  35         handles => [ qw(produce) ],
  36         predicate => 'has_producer',
  37     );
  38
  39     has 'dbh' => (
  40         isa => DBIHandle,
  41         is => 'ro',
  42         predicate => 'has_dbh',
  43     );
  44
  45     has 'schema' => (
  46         isa => Schema,
  47         is => 'rw',
  48         lazy => 1,
  49         clearer => '_clear_schema',
  50         default => sub { SQL::Translator::Object::Schema->new },
  51     );
  52
  53     has 'parser_args' => (
  54         isa => HashRef,
  55         is => 'rw',
  56         predicate => 'has_parser_args',
  57     );
  58
  59     has 'producer_args' => (
  60         isa => HashRef,
  61         is => 'rw',
  62         predicate => 'has_producer_args',
  63     );
  64
  65     has 'add_drop_table' => (isa => Bool, is => 'rw', default => 0);
  66     has 'no_comments' => (isa => Bool, is => 'rw', default => 0);
  67     has 'show_warnings' => (isa => Bool, is => 'rw', default => 1);
  68     has 'trace' => (isa => Bool, is => 'rw', default => 0);
  69     has 'quote_table_names' => (isa => Bool, is => 'rw', default => 0);
  70     has 'quote_field_names' => (isa => Bool, is => 'rw', default => 0);
  71     has 'version' => (isa => Str, is => 'rw');
  72     has 'filename' => (isa => Str, is => 'rw');
  73
  74     has '_producer_mapping' => (
  75         isa => HashRef,
  76         is => 'ro',
  77         default => sub { { MySQL => 'SQL::MySQL', SQLite => 'SQL::SQLite', PostgreSQL => 'SQL::PostgreSQL', XML => 'XML', YAML => 'YAML' } }
  78     );
  79
  80     method _build__parser {
  81         my $class = 'SQL::Translator::Parser';
  82
  83         Class::MOP::load_class($class);
  84
  85         my $parser;
  86         if ($self->has_dbh) {
  87             $parser = $class->new({ translator => $self, dbh => $self->dbh });
  88         } else {
  89             $parser = $class->new({ translator => $self, type => $self->parser || '' });
  90         }
  91
  92         return $parser;
  93     }
  94
  95     method _build__producer {
  96         my $mapping = $self->_producer_mapping;
  97
  98         my $class = 'SQL::Translator::Producer';
  99         my $role = $class . '::' . $mapping->{$self->producer};
 100
 101         Class::MOP::load_class($class);
 102         Class::MOP::load_class($role);
 103
 104         my $producer = $class->new({ translator => $self });
 105         $role->meta->apply($producer);
 106
 107         return $producer;
 108     }
 109
 110     method translate(:$data, :$producer?, :$producer_args?, :$parser?, :$parser_args?) {
 111         my $return;
 112
 113         $self->_clear_schema if defined $parser;
 114
 115         $parser ||= $self->parser unless $self->has_parser;
 116         if (defined $parser) {
 117             $self->_clear_parser;
 118             $self->parser($parser);
 119             $self->parse($data);
 120             $return = $self->schema;
 121         }
 122
 123         $producer ||= $self->producer unless $self->has_producer;
 124         if (defined $producer) {
 125             $self->_clear_producer;
 126             $self->producer($producer);
 127             $return = $self->produce;
 128         }
 129
 130         return $return;
 131     }
 132
 133     method parser_type { return $self->parser }
 134     method producer_type { return $self->producer }
 135
 136     method engine_version(Int|Str|Undef $v, Str $target = 'perl') {
 137         return undef unless $v;
 138
 139         my @vers;
 140
 141         # X.Y.Z style
 142         if ( $v =~ / ^ (\d+) \. (\d{1,3}) (?: \. (\d{1,3}) )? $ /x ) {
 143             push @vers, $1, $2, $3;
 144         }
 145
 146         # XYYZZ (mysql) style
 147         elsif ( $v =~ / ^ (\d) (\d{2}) (\d{2}) $ /x ) {
 148             push @vers, $1, $2, $3;
 149         }
 150
 151         # XX.YYYZZZ (perl) style or simply X
 152         elsif ( $v =~ / ^ (\d+) (?: \. (\d{3}) (\d{3}) )? $ /x ) {
 153             push @vers, $1, $2, $3;
 154         }
 155         else {
 156             #how do I croak sanely here?
 157             die "Unparseable MySQL version '$v'";
 158         }
 159
 160         if ($target eq 'perl') {
 161             return sprintf ('%d.%03d%03d', map { $_ || 0 } (@vers) );
 162         }
 163         elsif ($target eq 'mysql') {
 164             return sprintf ('%d%02d%02d', map { $_ || 0 } (@vers) );
 165         }
 166         else {
 167             #how do I croak sanely here?
 168             die "Unknown version target '$target'";
 169         }
 170     }
 171 }