lib/SQL/Translator.pm

   1 use MooseX::Declare;
   2 class SQL::Translator {
   3     use TryCatch;
   4     use MooseX::Types::Moose qw(Bool HashRef Int Str Undef);
   5     use MooseX::Aliases;
   6     use SQL::Translator::Types qw(DBIHandle Parser Producer Schema);
   7     use SQL::Translator::Object::Schema;
   8
   9     our $VERSION = '0.001';
  10     $VERSION = eval $VERSION;
  11
  12     has 'parser' => (
  13         isa => Str,
  14         is => 'rw',
  15         alias => 'from',
  16     );
  17
  18     has 'producer' => (
  19         isa => Str,
  20         is => 'rw',
  21         alias => 'to',
  22     );
  23
  24     has '_parser' => (
  25         isa => Parser,
  26         is => 'rw',
  27         lazy_build => 1,
  28         handles => [ qw(parse) ],
  29         predicate => 'has_parser',
  30     );
  31
  32     has '_producer' => (
  33         isa => Producer,
  34         is => 'rw',
  35         lazy_build => 1,
  36         handles => [ qw(produce) ],
  37         predicate => 'has_producer',
  38     );
  39
  40     has 'dbh' => (
  41         isa => DBIHandle,
  42         is => 'ro',
  43         predicate => 'has_dbh',
  44     );
  45
  46     has 'schema' => (
  47         isa => Schema,
  48         is => 'rw',
  49         lazy => 1,
  50         clearer => '_clear_schema',
  51         default => sub { SQL::Translator::Object::Schema->new },
  52     );
  53
  54     has 'parser_args' => (
  55         isa => HashRef,
  56         is => 'rw',
  57         predicate => 'has_parser_args',
  58     );
  59
  60     has 'producer_args' => (
  61         isa => HashRef,
  62         is => 'rw',
  63         predicate => 'has_producer_args',
  64     );
  65
  66     has 'data' => (
  67         isa => Str,
  68         is => 'rw',
  69     );
  70
  71     has 'version' => (isa => Str, is => 'ro', default => $VERSION);
  72     has 'add_drop_table' => (isa => Bool, is => 'rw', default => 0);
  73     has 'no_comments' => (isa => Bool, is => 'rw', default => 0);
  74     has 'show_warnings' => (isa => Bool, is => 'rw', default => 0);
  75     has 'trace' => (isa => Bool, is => 'rw', default => 0);
  76     has 'quote_table_names' => (isa => Bool, is => 'rw', default => 0);
  77     has 'quote_field_names' => (isa => Bool, is => 'rw', default => 0);
  78     has 'filename' => (isa => Str, is => 'rw');
  79
  80     has '_producer_mapping' => (
  81         isa => HashRef,
  82         is => 'ro',
  83         default => sub { { MySQL => 'SQL::MySQL', SQLite => 'SQL::SQLite', PostgreSQL => 'SQL::PostgreSQL', XML => 'XML', YAML => 'YAML' } }
  84     );
  85
  86     method _build__parser {
  87         my $class = 'SQL::Translator::Parser';
  88
  89         Class::MOP::load_class($class);
  90
  91         my $parser;
  92         if ($self->has_dbh) {
  93             $parser = $class->new({ translator => $self, dbh => $self->dbh });
  94         } else {
  95             $parser = $class->new({ translator => $self, type => $self->parser || '' });
  96         }
  97
  98         return $parser;
  99     }
 100
 101     method _build__producer {
 102         my $mapping = $self->_producer_mapping;
 103
 104         my $class = 'SQL::Translator::Producer';
 105         my $role = $class . '::' . $mapping->{$self->producer};
 106
 107         Class::MOP::load_class($class);
 108         Class::MOP::load_class($role);
 109
 110         my $producer = $class->new({ translator => $self });
 111         $role->meta->apply($producer);
 112
 113         return $producer;
 114     }
 115
 116     method translate(:$data, :$producer?, :$producer_args?, :$parser?, :$parser_args?) {
 117         my $return;
 118
 119         $self->_clear_schema if defined $parser;
 120         $data ||= $self->data;
 121
 122         $parser ||= $self->parser unless $self->has_parser;
 123         if (defined $parser) {
 124             $self->_clear_parser;
 125             $self->parser($parser);
 126             $self->parse($data);
 127             $return = $self->schema;
 128         }
 129
 130         $producer ||= $self->producer unless $self->has_producer;
 131         if (defined $producer) {
 132             $self->_clear_producer;
 133             $self->producer($producer);
 134             $return = $self->produce;
 135         }
 136
 137         return $return;
 138     }
 139
 140     method parser_type { return $self->parser }
 141     method producer_type { return $self->producer }
 142
 143     method engine_version(Int|Str|Undef $v, Str $target = 'perl') {
 144         return undef unless $v;
 145
 146         my @vers;
 147
 148         # X.Y.Z style
 149         if ( $v =~ / ^ (\d+) \. (\d{1,3}) (?: \. (\d{1,3}) )? $ /x ) {
 150             push @vers, $1, $2, $3;
 151         }
 152
 153         # XYYZZ (mysql) style
 154         elsif ( $v =~ / ^ (\d) (\d{2}) (\d{2}) $ /x ) {
 155             push @vers, $1, $2, $3;
 156         }
 157
 158         # XX.YYYZZZ (perl) style or simply X
 159         elsif ( $v =~ / ^ (\d+) (?: \. (\d{3}) (\d{3}) )? $ /x ) {
 160             push @vers, $1, $2, $3;
 161         }
 162         else {
 163             #how do I croak sanely here?
 164             die "Unparseable MySQL version '$v'";
 165         }
 166
 167         if ($target eq 'perl') {
 168             return sprintf ('%d.%03d%03d', map { $_ || 0 } (@vers) );
 169         }
 170         elsif ($target eq 'mysql') {
 171             return sprintf ('%d%02d%02d', map { $_ || 0 } (@vers) );
 172         }
 173         else {
 174             #how do I croak sanely here?
 175             die "Unknown version target '$target'";
 176         }
 177     }
 178 }