lib/SQL/Translator/Utils.pm

   1 package SQL::Translator::Utils;
   2
   3 # ----------------------------------------------------------------------
   4 # $Id: Utils.pm,v 1.7 2003-05-12 15:47:23 dlc Exp $
   5 # ----------------------------------------------------------------------
   6 # Copyright (C) 2003 darren chamberlain <darren@cpan.org>
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 use strict;
  24 use base qw(Exporter);
  25 use vars qw($VERSION $DEFAULT_COMMENT @EXPORT_OK);
  26
  27 use Exporter;
  28
  29 $VERSION = 1.00;
  30 $DEFAULT_COMMENT = '-- ';
  31 @EXPORT_OK = qw(
  32     debug normalize_name header_comment parse_list_arg $DEFAULT_COMMENT
  33 );
  34
  35 # ----------------------------------------------------------------------
  36 # debug(@msg)
  37 #
  38 # Will send debugging messages to STDERR, if the caller's $DEBUG global
  39 # is set.
  40 #
  41 # This debug() function has a neat feature: Occurances of the strings
  42 # PKG, LINE, and SUB in each message will be replaced with elements
  43 # from caller():
  44 #
  45 #   debug("PKG: Bad things happened on line LINE!");
  46 #
  47 # Will be warned as:
  48 #
  49 #   [SQL::Translator: Bad things happened on line 643]
  50 #
  51 # If called from Translator.pm, on line 643.
  52 # ----------------------------------------------------------------------
  53 sub debug {
  54     my ($pkg, $file, $line, $sub) = caller(0);
  55     {
  56         no strict qw(refs);
  57         return unless ${"$pkg\::DEBUG"};
  58     }
  59
  60     $sub =~ s/^$pkg\:://;
  61
  62     while (@_) {
  63         my $x = shift;
  64         chomp $x;
  65         $x =~ s/\bPKG\b/$pkg/g;
  66         $x =~ s/\bLINE\b/$line/g;
  67         $x =~ s/\bSUB\b/$sub/g;
  68         #warn '[' . $x . "]\n";
  69         print STDERR '[' . $x . "]\n";
  70     }
  71 }
  72
  73 # ----------------------------------------------------------------------
  74 sub normalize_name {
  75     my $name = shift;
  76
  77     # The name can only begin with a-zA-Z_; if there's anything
  78     # else, prefix with _
  79     $name =~ s/^([^a-zA-Z_])/_$1/;
  80
  81     # anything other than a-zA-Z0-9_ in the non-first position
  82     # needs to be turned into _
  83     $name =~ tr/[a-zA-Z0-9_]/_/c;
  84
  85     # All duplicated _ need to be squashed into one.
  86     $name =~ tr/_/_/s;
  87
  88     # Trim a trailing _
  89     $name =~ s/_$//;
  90
  91     return $name;
  92 }
  93
  94 # ----------------------------------------------------------------------
  95 sub header_comment {
  96     my $producer = shift || caller;
  97     my $comment_char = shift;
  98     my $now = scalar localtime;
  99
 100     $comment_char = $DEFAULT_COMMENT
 101         unless defined $comment_char;
 102
 103     my $header_comment =<<"HEADER_COMMENT";
 104 ${comment_char}
 105 ${comment_char}Created by $producer
 106 ${comment_char}Created on $now
 107 ${comment_char}
 108 HEADER_COMMENT
 109
 110     # Any additional stuff passed in
 111     for my $additional_comment (@_) {
 112         $header_comment .= "${comment_char}${additional_comment}\n";
 113     }
 114
 115     return $header_comment;
 116 }
 117
 118 # ----------------------------------------------------------------------
 119 sub parse_list_arg {
 120     my $list = UNIVERSAL::isa( $_[0], 'ARRAY' ) ? shift : [ @_ ];
 121
 122     return [ map { s/^\s+|\s+$//g; $_ }
 123              map { split /,/ }
 124              grep { defined && length } @$list
 125            ];
 126 }
 127
 128 1;
 129
 130 # ----------------------------------------------------------------------
 131
 132 =pod
 133
 134 =head1 NAME
 135
 136 SQL::Translator::Utils - SQL::Translator Utility functions
 137
 138 =head1 SYNOPSIS
 139
 140   use SQL::Translator::Utils qw(debug);
 141   debug("PKG: Bad things happened");
 142
 143 =head1 DESCSIPTION
 144
 145 C<SQL::Translator::Utils> contains utility functions designed to be
 146 used from the other modules within the C<SQL::Translator> modules.
 147
 148 Nothing is exported by default.
 149
 150 =head1 EXPORTED FUNCTIONS AND CONSTANTS
 151
 152 =head2 debug
 153
 154 C<debug> takes 0 or more messages, which will be sent to STDERR using
 155 C<warn>.  Occurances of the strings I<PKG>, I<SUB>, and I<LINE>
 156 will be replaced by the calling package, subroutine, and line number,
 157 respectively, as reported by C<caller(1)>.
 158
 159 For example, from within C<foo> in F<SQL/Translator.pm>, at line 666:
 160
 161   debug("PKG: Error reading file at SUB/LINE");
 162
 163 Will warn
 164
 165   [SQL::Translator: Error reading file at foo/666]
 166
 167 The entire message is enclosed within C<[> and C<]> for visual clarity
 168 when STDERR is intermixed with STDOUT.
 169
 170 =head2 normalize_name
 171
 172 C<normalize_name> takes a string and ensures that it is suitable for
 173 use as an identifier.  This means: ensure that it starts with a letter
 174 or underscore, and that the rest of the string consists of only
 175 letters, numbers, and underscores.  A string that begins with
 176 something other than [a-zA-Z] will be prefixer with an underscore, and
 177 all other characters in the string will be replaced with underscores.
 178 Finally, a trailing underscore will be removed, because that's ugly.
 179
 180   normalize_name("Hello, world");
 181
 182 Produces:
 183
 184   Hello_world
 185
 186 A more useful example, from the C<SQL::Translator::Parser::Excel> test
 187 suite:
 188
 189   normalize_name("silly field (with random characters)");
 190
 191 returns:
 192
 193   silly_field_with_random_characters
 194
 195 =head2 header_comment
 196
 197 Create the header comment.  Takes 1 mandatory argument (the producer
 198 classname), an optional comment character (defaults to $DEFAULT_COMMENT),
 199 and 0 or more additional comments, which will be appended to the header,
 200 prefixed with the comment character.  If additional comments are provided,
 201 then a comment string must be provided ($DEFAULT_COMMENT is exported for
 202 this use).  For example, this:
 203
 204   package My::Producer;
 205
 206   use SQL::Translator::Utils qw(header_comment $DEFAULT_COMMENT);
 207
 208   print header_comment(__PACKAGE__,
 209                        $DEFAULT_COMMENT,
 210                        "Hi mom!");
 211
 212 produces:
 213
 214   --
 215   -- Created by My::Prodcuer
 216   -- Created on Fri Apr 25 06:56:02 2003
 217   --
 218   -- Hi mom!
 219   --
 220
 221 Note the gratuitous spacing.
 222
 223 =head2 parse_list_arg
 224
 225 Takes a string, list or arrayref (all of which could contain
 226 comma-separated values) and returns an array reference of the values.
 227 All of the following will return equivalent values:
 228
 229   parse_list_arg('id');
 230   parse_list_arg('id', 'name');
 231   parse_list_arg( 'id, name' );
 232   parse_list_arg( [ 'id', 'name' ] );
 233   parse_list_arg( qw[ id name ] );
 234
 235 =head2 $DEFAULT_COMMENT
 236
 237 This is the default comment string, '-- ' by default.  Useful for
 238 C<header_comment>.
 239
 240 =head1 AUTHORS
 241
 242 Darren Chamberlain E<lt>darren@cpan.orgE<gt>,
 243 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 244
 245 =cut
 246
 247 =cut