lib/SQL/Translator/Utils.pm

   1 package SQL::Translator::Utils;
   2
   3 # ----------------------------------------------------------------------
   4 # $Id: Utils.pm,v 1.12 2004-02-09 23:04:26 kycl4rk Exp $
   5 # ----------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 use strict;
  24 use base qw(Exporter);
  25 use vars qw($VERSION $DEFAULT_COMMENT @EXPORT_OK);
  26
  27 use Exporter;
  28
  29 $VERSION = sprintf "%d.%02d", q$Revision: 1.12 $ =~ /(\d+)\.(\d+)/;
  30 $DEFAULT_COMMENT = '-- ';
  31 @EXPORT_OK = qw(
  32     debug normalize_name header_comment parse_list_arg $DEFAULT_COMMENT
  33 );
  34
  35 # ----------------------------------------------------------------------
  36 # debug(@msg)
  37 #
  38 # Will send debugging messages to STDERR, if the caller's $DEBUG global
  39 # is set.
  40 #
  41 # This debug() function has a neat feature: Occurances of the strings
  42 # PKG, LINE, and SUB in each message will be replaced with elements
  43 # from caller():
  44 #
  45 #   debug("PKG: Bad things happened on line LINE!");
  46 #
  47 # Will be warned as:
  48 #
  49 #   [SQL::Translator: Bad things happened on line 643]
  50 #
  51 # If called from Translator.pm, on line 643.
  52 # ----------------------------------------------------------------------
  53 sub debug {
  54     my ($pkg, $file, $line, $sub) = caller(0);
  55     {
  56         no strict qw(refs);
  57         return unless ${"$pkg\::DEBUG"};
  58     }
  59
  60     $sub =~ s/^$pkg\:://;
  61
  62     while (@_) {
  63         my $x = shift;
  64         chomp $x;
  65         $x =~ s/\bPKG\b/$pkg/g;
  66         $x =~ s/\bLINE\b/$line/g;
  67         $x =~ s/\bSUB\b/$sub/g;
  68         #warn '[' . $x . "]\n";
  69         print STDERR '[' . $x . "]\n";
  70     }
  71 }
  72
  73 # ----------------------------------------------------------------------
  74 sub normalize_name {
  75     my $name = shift or return '';
  76
  77     # The name can only begin with a-zA-Z_; if there's anything
  78     # else, prefix with _
  79     $name =~ s/^([^a-zA-Z_])/_$1/;
  80
  81     # anything other than a-zA-Z0-9_ in the non-first position
  82     # needs to be turned into _
  83     $name =~ tr/[a-zA-Z0-9_]/_/c;
  84
  85     # All duplicated _ need to be squashed into one.
  86     $name =~ tr/_/_/s;
  87
  88     # Trim a trailing _
  89     $name =~ s/_$//;
  90
  91     return $name;
  92 }
  93
  94 # ----------------------------------------------------------------------
  95 sub header_comment {
  96     my $producer = shift || caller;
  97     my $comment_char = shift;
  98     my $now = scalar localtime;
  99
 100     $comment_char = $DEFAULT_COMMENT
 101         unless defined $comment_char;
 102
 103     my $header_comment =<<"HEADER_COMMENT";
 104 ${comment_char}
 105 ${comment_char}Created by $producer
 106 ${comment_char}Created on $now
 107 ${comment_char}
 108 HEADER_COMMENT
 109
 110     # Any additional stuff passed in
 111     for my $additional_comment (@_) {
 112         $header_comment .= "${comment_char}${additional_comment}\n";
 113     }
 114
 115     return $header_comment;
 116 }
 117
 118 # ----------------------------------------------------------------------
 119 # parse_list_arg
 120 #
 121 # Meant to accept a list, an array reference, or a string of
 122 # comma-separated values.  Retuns an array reference of the
 123 # arguments.  Modified to also handle a list of references.
 124 # ----------------------------------------------------------------------
 125 sub parse_list_arg {
 126     my $list = UNIVERSAL::isa( $_[0], 'ARRAY' ) ? shift : [ @_ ];
 127
 128     #
 129     # This protects stringification of references.
 130     #
 131     if ( @$list && ref $list->[0] ) {
 132         return $list;
 133     }
 134     #
 135     # This processes string-like arguments.
 136     #
 137     else {
 138         return [
 139             map { s/^\s+|\s+$//g; $_ }
 140             map { split /,/ }
 141             grep { defined && length } @$list
 142         ];
 143     }
 144 }
 145
 146 1;
 147
 148 # ----------------------------------------------------------------------
 149
 150 =pod
 151
 152 =head1 NAME
 153
 154 SQL::Translator::Utils - SQL::Translator Utility functions
 155
 156 =head1 SYNOPSIS
 157
 158   use SQL::Translator::Utils qw(debug);
 159   debug("PKG: Bad things happened");
 160
 161 =head1 DESCSIPTION
 162
 163 C<SQL::Translator::Utils> contains utility functions designed to be
 164 used from the other modules within the C<SQL::Translator> modules.
 165
 166 Nothing is exported by default.
 167
 168 =head1 EXPORTED FUNCTIONS AND CONSTANTS
 169
 170 =head2 debug
 171
 172 C<debug> takes 0 or more messages, which will be sent to STDERR using
 173 C<warn>.  Occurances of the strings I<PKG>, I<SUB>, and I<LINE>
 174 will be replaced by the calling package, subroutine, and line number,
 175 respectively, as reported by C<caller(1)>.
 176
 177 For example, from within C<foo> in F<SQL/Translator.pm>, at line 666:
 178
 179   debug("PKG: Error reading file at SUB/LINE");
 180
 181 Will warn
 182
 183   [SQL::Translator: Error reading file at foo/666]
 184
 185 The entire message is enclosed within C<[> and C<]> for visual clarity
 186 when STDERR is intermixed with STDOUT.
 187
 188 =head2 normalize_name
 189
 190 C<normalize_name> takes a string and ensures that it is suitable for
 191 use as an identifier.  This means: ensure that it starts with a letter
 192 or underscore, and that the rest of the string consists of only
 193 letters, numbers, and underscores.  A string that begins with
 194 something other than [a-zA-Z] will be prefixer with an underscore, and
 195 all other characters in the string will be replaced with underscores.
 196 Finally, a trailing underscore will be removed, because that's ugly.
 197
 198   normalize_name("Hello, world");
 199
 200 Produces:
 201
 202   Hello_world
 203
 204 A more useful example, from the C<SQL::Translator::Parser::Excel> test
 205 suite:
 206
 207   normalize_name("silly field (with random characters)");
 208
 209 returns:
 210
 211   silly_field_with_random_characters
 212
 213 =head2 header_comment
 214
 215 Create the header comment.  Takes 1 mandatory argument (the producer
 216 classname), an optional comment character (defaults to $DEFAULT_COMMENT),
 217 and 0 or more additional comments, which will be appended to the header,
 218 prefixed with the comment character.  If additional comments are provided,
 219 then a comment string must be provided ($DEFAULT_COMMENT is exported for
 220 this use).  For example, this:
 221
 222   package My::Producer;
 223
 224   use SQL::Translator::Utils qw(header_comment $DEFAULT_COMMENT);
 225
 226   print header_comment(__PACKAGE__,
 227                        $DEFAULT_COMMENT,
 228                        "Hi mom!");
 229
 230 produces:
 231
 232   --
 233   -- Created by My::Prodcuer
 234   -- Created on Fri Apr 25 06:56:02 2003
 235   --
 236   -- Hi mom!
 237   --
 238
 239 Note the gratuitous spacing.
 240
 241 =head2 parse_list_arg
 242
 243 Takes a string, list or arrayref (all of which could contain
 244 comma-separated values) and returns an array reference of the values.
 245 All of the following will return equivalent values:
 246
 247   parse_list_arg('id');
 248   parse_list_arg('id', 'name');
 249   parse_list_arg( 'id, name' );
 250   parse_list_arg( [ 'id', 'name' ] );
 251   parse_list_arg( qw[ id name ] );
 252
 253 =head2 $DEFAULT_COMMENT
 254
 255 This is the default comment string, '-- ' by default.  Useful for
 256 C<header_comment>.
 257
 258 =head1 AUTHORS
 259
 260 Darren Chamberlain E<lt>darren@cpan.orgE<gt>,
 261 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 262
 263 =cut
 264
 265 =cut