lib/SQL/Translator/Schema.pm

   1 package SQL::Translator::Schema;
   2
   3 # ----------------------------------------------------------------------
   4 # $Id: Schema.pm,v 1.9 2003-10-03 23:56:21 kycl4rk Exp $
   5 # ----------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =pod
  24
  25 =head1 NAME
  26
  27 SQL::Translator::Schema - SQL::Translator schema object
  28
  29 =head1 SYNOPSIS
  30
  31   use SQL::Translator::Schema;
  32   my $schema = SQL::Translator::Schema->new;
  33   my $table  = $schema->add_table( name => 'foo' );
  34   my $view   = $schema->add_view( name => 'bar', sql => '...' );
  35
  36 =head1 DESCSIPTION
  37
  38 C<SQL::Translator::Schema> is the object that accepts, validates, and
  39 returns the database structure.
  40
  41 =head1 METHODS
  42
  43 =cut
  44
  45 use strict;
  46 use Class::Base;
  47 use SQL::Translator::Schema::Constants;
  48 use SQL::Translator::Schema::Table;
  49 use SQL::Translator::Schema::Trigger;
  50 use SQL::Translator::Schema::View;
  51 use SQL::Translator::Utils 'parse_list_arg';
  52
  53 use base 'Class::Base';
  54 use vars qw[ $VERSION $TABLE_ORDER $VIEW_ORDER $TRIGGER_ORDER ];
  55
  56 $VERSION = sprintf "%d.%02d", q$Revision: 1.9 $ =~ /(\d+)\.(\d+)/;
  57
  58 # ----------------------------------------------------------------------
  59 sub init {
  60
  61 =pod
  62
  63 =head2 new
  64
  65 Object constructor.
  66
  67   my $schema   =  SQL::Translator->new(
  68       name     => 'Foo',
  69       database => 'MySQL',
  70   );
  71
  72 =cut
  73
  74     my ( $self, $config ) = @_;
  75     $self->params( $config, qw[ name database ] ) || return undef;
  76     return $self;
  77 }
  78
  79 # ----------------------------------------------------------------------
  80 sub add_table {
  81
  82 =pod
  83
  84 =head2 add_table
  85
  86 Add a table object.  Returns the new SQL::Translator::Schema::Table object.
  87 The "name" parameter is required.  If you try to create a table with the
  88 same name as an existing table, you will get an error and the table will
  89 not be created.
  90
  91   my $t1 = $schema->add_table( name => 'foo' ) or die $schema->error;
  92   my $t2 = SQL::Translator::Schema::Table->new( name => 'bar' );
  93   $t2    = $schema->add_table( $table_bar ) or die $schema->error;
  94
  95 =cut
  96
  97     my $self        = shift;
  98     my $table_class = 'SQL::Translator::Schema::Table';
  99     my $table;
 100
 101     if ( UNIVERSAL::isa( $_[0], $table_class ) ) {
 102         $table = shift;
 103         $table->schema( $self );
 104     }
 105     else {
 106         my %args = @_;
 107         $args{'schema'} = $self;
 108         $table = $table_class->new( \%args ) or return
 109             $self->error( $table_class->error );
 110     }
 111
 112     $table->order( ++$TABLE_ORDER );
 113     my $table_name = $table->name or return $self->error('No table name');
 114
 115     if ( defined $self->{'tables'}{ $table_name } ) {
 116         return $self->error(qq[Can't create table: "$table_name" exists]);
 117     }
 118     else {
 119         $self->{'tables'}{ $table_name } = $table;
 120     }
 121
 122     return $table;
 123 }
 124
 125 # ----------------------------------------------------------------------
 126 sub add_trigger {
 127
 128 =pod
 129
 130 =head2 add_trigger
 131
 132 Add a trigger object.  Returns the new SQL::Translator::Schema::Trigger object.
 133 The "name" parameter is required.  If you try to create a trigger with the
 134 same name as an existing trigger, you will get an error and the trigger will
 135 not be created.
 136
 137   my $t1 = $schema->add_trigger( name => 'foo' );
 138   my $t2 = SQL::Translator::Schema::Trigger->new( name => 'bar' );
 139   $t2    = $schema->add_trigger( $trigger_bar ) or die $schema->error;
 140
 141 =cut
 142
 143     my $self          = shift;
 144     my $trigger_class = 'SQL::Translator::Schema::Trigger';
 145     my $trigger;
 146
 147     if ( UNIVERSAL::isa( $_[0], $trigger_class ) ) {
 148         $trigger = shift;
 149     }
 150     else {
 151         my %args = @_;
 152         return $self->error('No trigger name') unless $args{'name'};
 153         $trigger = $trigger_class->new( \%args ) or
 154             return $self->error( $trigger_class->error );
 155     }
 156
 157     $trigger->order( ++$TRIGGER_ORDER );
 158     my $trigger_name = $trigger->name or return $self->error('No trigger name');
 159
 160     if ( defined $self->{'triggers'}{ $trigger_name } ) {
 161         return $self->error(qq[Can't create trigger: "$trigger_name" exists]);
 162     }
 163     else {
 164         $self->{'triggers'}{ $trigger_name } = $trigger;
 165     }
 166
 167     return $trigger;
 168 }
 169
 170 # ----------------------------------------------------------------------
 171 sub add_view {
 172
 173 =pod
 174
 175 =head2 add_view
 176
 177 Add a view object.  Returns the new SQL::Translator::Schema::View object.
 178 The "name" parameter is required.  If you try to create a view with the
 179 same name as an existing view, you will get an error and the view will
 180 not be created.
 181
 182   my $v1 = $schema->add_view( name => 'foo' );
 183   my $v2 = SQL::Translator::Schema::View->new( name => 'bar' );
 184   $v2    = $schema->add_view( $view_bar ) or die $schema->error;
 185
 186 =cut
 187
 188     my $self        = shift;
 189     my $view_class = 'SQL::Translator::Schema::View';
 190     my $view;
 191
 192     if ( UNIVERSAL::isa( $_[0], $view_class ) ) {
 193         $view = shift;
 194     }
 195     else {
 196         my %args = @_;
 197         return $self->error('No view name') unless $args{'name'};
 198         $view = $view_class->new( \%args ) or return $view_class->error;
 199     }
 200
 201     $view->order( ++$VIEW_ORDER );
 202     my $view_name = $view->name or return $self->error('No view name');
 203
 204     if ( defined $self->{'views'}{ $view_name } ) {
 205         return $self->error(qq[Can't create view: "$view_name" exists]);
 206     }
 207     else {
 208         $self->{'views'}{ $view_name } = $view;
 209     }
 210
 211     return $view;
 212 }
 213
 214 # ----------------------------------------------------------------------
 215 sub database {
 216
 217 =pod
 218
 219 =head2 database
 220
 221 Get or set the schema's database.  (optional)
 222
 223   my $database = $schema->database('PostgreSQL');
 224
 225 =cut
 226
 227     my $self = shift;
 228     $self->{'database'} = shift if @_;
 229     return $self->{'database'} || '';
 230 }
 231
 232 # ----------------------------------------------------------------------
 233 sub is_valid {
 234
 235 =pod
 236
 237 =head2 is_valid
 238
 239 Returns true if all the tables and views are valid.
 240
 241   my $ok = $schema->is_valid or die $schema->error;
 242
 243 =cut
 244
 245     my $self = shift;
 246
 247     return $self->error('No tables') unless $self->get_tables;
 248
 249     for my $object ( $self->get_tables, $self->get_views ) {
 250         return $object->error unless $object->is_valid;
 251     }
 252
 253     return 1;
 254 }
 255
 256 # ----------------------------------------------------------------------
 257 sub get_table {
 258
 259 =pod
 260
 261 =head2 get_table
 262
 263 Returns a table by the name provided.
 264
 265   my $table = $schema->get_table('foo');
 266
 267 =cut
 268
 269     my $self       = shift;
 270     my $table_name = shift or return $self->error('No table name');
 271     return $self->error( qq[Table "$table_name" does not exist] ) unless
 272         exists $self->{'tables'}{ $table_name };
 273     return $self->{'tables'}{ $table_name };
 274 }
 275
 276 # ----------------------------------------------------------------------
 277 sub get_tables {
 278
 279 =pod
 280
 281 =head2 get_tables
 282
 283 Returns all the tables as an array or array reference.
 284
 285   my @tables = $schema->get_tables;
 286
 287 =cut
 288
 289     my $self   = shift;
 290     my @tables =
 291         map  { $_->[1] }
 292         sort { $a->[0] <=> $b->[0] }
 293         map  { [ $_->order, $_ ] }
 294         values %{ $self->{'tables'} };
 295
 296     if ( @tables ) {
 297         return wantarray ? @tables : \@tables;
 298     }
 299     else {
 300         $self->error('No tables');
 301         return wantarray ? () : undef;
 302     }
 303 }
 304
 305 # ----------------------------------------------------------------------
 306 sub get_view {
 307
 308 =pod
 309
 310 =head2 get_view
 311
 312 Returns a view by the name provided.
 313
 314   my $view = $schema->get_view('foo');
 315
 316 =cut
 317
 318     my $self      = shift;
 319     my $view_name = shift or return $self->error('No view name');
 320     return $self->error('View "$view_name" does not exist') unless
 321         exists $self->{'views'}{ $view_name };
 322     return $self->{'views'}{ $view_name };
 323 }
 324
 325 # ----------------------------------------------------------------------
 326 sub get_views {
 327
 328 =pod
 329
 330 =head2 get_views
 331
 332 Returns all the views as an array or array reference.
 333
 334   my @views = $schema->get_views;
 335
 336 =cut
 337
 338     my $self  = shift;
 339     my @views =
 340         map  { $_->[1] }
 341         sort { $a->[0] <=> $b->[0] }
 342         map  { [ $_->order, $_ ] }
 343         values %{ $self->{'views'} };
 344
 345     if ( @views ) {
 346         return wantarray ? @views : \@views;
 347     }
 348     else {
 349         $self->error('No views');
 350         return wantarray ? () : undef;
 351     }
 352 }
 353
 354 # ----------------------------------------------------------------------
 355 sub make_natural_joins {
 356
 357 =pod
 358
 359 =head2 make_natural_joins
 360
 361 Creates foriegn key relationships among like-named fields in different
 362 tables.  Accepts the following arguments:
 363
 364 =over 4
 365
 366 =item * join_pk_only
 367
 368 A True or False argument which determins whether or not to perform
 369 the joins from primary keys to fields of the same name in other tables
 370
 371 =item * skip_fields
 372
 373 A list of fields to skip in the joins
 374
 375 =back 4
 376
 377   $schema->make_natural_joins(
 378       join_pk_only => 1,
 379       skip_fields  => 'name,department_id',
 380   );
 381
 382 =cut
 383
 384     my $self         = shift;
 385     my %args         = @_;
 386     my $join_pk_only = $args{'join_pk_only'} || 0;
 387     my %skip_fields  = map { s/^\s+|\s+$//g; $_, 1 } @{
 388         parse_list_arg( $args{'skip_fields'} )
 389     };
 390
 391     my ( %common_keys, %pk );
 392     for my $table ( $self->get_tables ) {
 393         for my $field ( $table->get_fields ) {
 394             my $field_name = $field->name or next;
 395             next if $skip_fields{ $field_name };
 396             $pk{ $field_name } = 1 if $field->is_primary_key;
 397             push @{ $common_keys{ $field_name } }, $table->name;
 398         }
 399     }
 400
 401     for my $field ( keys %common_keys ) {
 402         next if $join_pk_only and !defined $pk{ $field };
 403
 404         my @table_names = @{ $common_keys{ $field } };
 405         next unless scalar @table_names > 1;
 406
 407         for my $i ( 0 .. $#table_names ) {
 408             my $table1 = $self->get_table( $table_names[ $i ] ) or next;
 409
 410             for my $j ( 1 .. $#table_names ) {
 411                 my $table2 = $self->get_table( $table_names[ $j ] ) or next;
 412                 next if $table1->name eq $table2->name;
 413
 414                 $table1->add_constraint(
 415                     type             => FOREIGN_KEY,
 416                     fields           => $field,
 417                     reference_table  => $table2->name,
 418                     reference_fields => $field,
 419                 );
 420             }
 421         }
 422     }
 423
 424     return 1;
 425 }
 426
 427 # ----------------------------------------------------------------------
 428 sub name {
 429
 430 =pod
 431
 432 =head2 name
 433
 434 Get or set the schema's name.  (optional)
 435
 436   my $schema_name = $schema->name('Foo Database');
 437
 438 =cut
 439
 440     my $self = shift;
 441     $self->{'name'} = shift if @_;
 442     return $self->{'name'} || '';
 443 }
 444
 445 # ----------------------------------------------------------------------
 446 sub DESTROY {
 447     my $self = shift;
 448     undef $_ for values %{ $self->{'tables'} };
 449     undef $_ for values %{ $self->{'views'}  };
 450 }
 451
 452 1;
 453
 454 # ----------------------------------------------------------------------
 455
 456 =pod
 457
 458 =head1 AUTHOR
 459
 460 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>
 461
 462 =cut