lib/SQL/Translator/Schema/Index.pm

   1 package SQL::Translator::Schema::Index;
   2
   3 =pod
   4
   5 =head1 NAME
   6
   7 SQL::Translator::Schema::Index - SQL::Translator index object
   8
   9 =head1 SYNOPSIS
  10
  11   use SQL::Translator::Schema::Index;
  12   my $index = SQL::Translator::Schema::Index->new(
  13       name   => 'foo',
  14       fields => [ id ],
  15       type   => 'unique',
  16   );
  17
  18 =head1 DESCRIPTION
  19
  20 C<SQL::Translator::Schema::Index> is the index object.
  21
  22 Primary and unique keys are table constraints, not indices.
  23
  24 =head1 METHODS
  25
  26 =cut
  27
  28 use Moo;
  29 use SQL::Translator::Schema::Constants;
  30 use SQL::Translator::Utils qw(parse_list_arg ex2err throw);
  31 use SQL::Translator::Types qw(schema_obj);
  32 use List::MoreUtils qw(uniq);
  33
  34 extends 'SQL::Translator::Schema::Object';
  35
  36 our $VERSION = '1.59';
  37
  38 my %VALID_INDEX_TYPE = (
  39   UNIQUE         => 1,
  40   NORMAL         => 1,
  41   FULLTEXT       => 1, # MySQL only (?)
  42   FULL_TEXT      => 1, # MySQL only (?)
  43   SPATIAL        => 1, # MySQL only (?)
  44 );
  45
  46 =head2 new
  47
  48 Object constructor.
  49
  50   my $schema = SQL::Translator::Schema::Index->new;
  51
  52 =head2 fields
  53
  54 Gets and set the fields the index is on.  Accepts a string, list or
  55 arrayref; returns an array or array reference.  Will unique the field
  56 names and keep them in order by the first occurrence of a field name.
  57
  58   $index->fields('id');
  59   $index->fields('id', 'name');
  60   $index->fields( 'id, name' );
  61   $index->fields( [ 'id', 'name' ] );
  62   $index->fields( qw[ id name ] );
  63
  64   my @fields = $index->fields;
  65
  66 =cut
  67
  68 has fields => (
  69     is => 'rw',
  70     default => sub { [] },
  71     coerce => sub { [uniq @{parse_list_arg($_[0])}] },
  72 );
  73
  74 around fields => sub {
  75     my $orig   = shift;
  76     my $self   = shift;
  77     my $fields = parse_list_arg( @_ );
  78     $self->$orig($fields) if @$fields;
  79
  80     return wantarray ? @{ $self->$orig } : $self->$orig;
  81 };
  82
  83 sub is_valid {
  84
  85 =pod
  86
  87 =head2 is_valid
  88
  89 Determine whether the index is valid or not.
  90
  91   my $ok = $index->is_valid;
  92
  93 =cut
  94
  95     my $self   = shift;
  96     my $table  = $self->table  or return $self->error('No table');
  97     my @fields = $self->fields or return $self->error('No fields');
  98
  99     for my $field ( @fields ) {
 100         return $self->error(
 101             "Field '$field' does not exist in table '", $table->name, "'"
 102         ) unless $table->get_field( $field );
 103     }
 104
 105     return 1;
 106 }
 107
 108 =head2 name
 109
 110 Get or set the index's name.
 111
 112   my $name = $index->name('foo');
 113
 114 =cut
 115
 116 has name => ( is => 'rw', coerce => sub { defined $_[0] ? $_[0] : '' }, default => sub { '' } );
 117
 118 =head2 options
 119
 120 Get or set the index's options (e.g., "using" or "where" for PG).  Returns
 121 an array or array reference.
 122
 123   my @options = $index->options;
 124
 125 =cut
 126
 127 has options => (
 128     is => 'rw',
 129     default => sub { [] },
 130     coerce => \&parse_list_arg,
 131 );
 132
 133 around options => sub {
 134     my $orig    = shift;
 135     my $self    = shift;
 136     my $options = parse_list_arg( @_ );
 137
 138     push @{ $self->$orig }, @$options;
 139
 140     return wantarray ? @{ $self->$orig } : $self->$orig;
 141 };
 142
 143 =head2 table
 144
 145 Get or set the index's table object.
 146
 147   my $table = $index->table;
 148
 149 =cut
 150
 151 has table => ( is => 'rw', isa => schema_obj('Table'), weak_ref => 1 );
 152
 153 around table => \&ex2err;
 154
 155 =head2 type
 156
 157 Get or set the index's type.
 158
 159   my $type = $index->type('unique');
 160
 161 Get or set the index's type.
 162
 163 Currently there are only four acceptable types: UNIQUE, NORMAL, FULL_TEXT,
 164 and SPATIAL. The latter two might be MySQL-specific. While both lowercase
 165 and uppercase types are acceptable input, this method returns the type in
 166 uppercase.
 167
 168 =cut
 169
 170 has type => (
 171     is => 'rw',
 172     isa => sub {
 173         my $type = uc $_[0] or return;
 174         throw("Invalid index type: $type") unless $VALID_INDEX_TYPE{$type};
 175     },
 176     coerce => sub { uc $_[0] },
 177     default => sub { 'NORMAL' },
 178 );
 179
 180 around type => \&ex2err;
 181
 182 =head2 equals
 183
 184 Determines if this index is the same as another
 185
 186   my $isIdentical = $index1->equals( $index2 );
 187
 188 =cut
 189
 190 around equals => sub {
 191     my $orig = shift;
 192     my $self = shift;
 193     my $other = shift;
 194     my $case_insensitive = shift;
 195     my $ignore_index_names = shift;
 196
 197     return 0 unless $self->$orig($other);
 198
 199     unless ($ignore_index_names) {
 200       unless ((!$self->name && ($other->name eq $other->fields->[0])) ||
 201         (!$other->name && ($self->name eq $self->fields->[0]))) {
 202         return 0 unless $case_insensitive ? uc($self->name) eq uc($other->name) : $self->name eq $other->name;
 203       }
 204     }
 205     #return 0 unless $self->is_valid eq $other->is_valid;
 206     return 0 unless $self->type eq $other->type;
 207
 208     # Check fields, regardless of order
 209     my %otherFields = ();  # create a hash of the other fields
 210     foreach my $otherField ($other->fields) {
 211       $otherField = uc($otherField) if $case_insensitive;
 212       $otherFields{$otherField} = 1;
 213     }
 214     foreach my $selfField ($self->fields) { # check for self fields in hash
 215       $selfField = uc($selfField) if $case_insensitive;
 216       return 0 unless $otherFields{$selfField};
 217       delete $otherFields{$selfField};
 218     }
 219     # Check all other fields were accounted for
 220     return 0 unless keys %otherFields == 0;
 221
 222     return 0 unless $self->_compare_objects(scalar $self->options, scalar $other->options);
 223     return 0 unless $self->_compare_objects(scalar $self->extra, scalar $other->extra);
 224     return 1;
 225 };
 226
 227 # Must come after all 'has' declarations
 228 around new => \&ex2err;
 229
 230 1;
 231
 232 =pod
 233
 234 =head1 AUTHOR
 235
 236 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>.
 237
 238 =cut