lib/SQL/Translator/Schema/Index.pm

   1 package SQL::Translator::Schema::Index;
   2
   3 =pod
   4
   5 =head1 NAME
   6
   7 SQL::Translator::Schema::Index - SQL::Translator index object
   8
   9 =head1 SYNOPSIS
  10
  11   use SQL::Translator::Schema::Index;
  12   my $index = SQL::Translator::Schema::Index->new(
  13       name   => 'foo',
  14       fields => [ id ],
  15       type   => 'unique',
  16   );
  17
  18 =head1 DESCRIPTION
  19
  20 C<SQL::Translator::Schema::Index> is the index object.
  21
  22 Primary and unique keys are table constraints, not indices.
  23
  24 =head1 METHODS
  25
  26 =cut
  27
  28 use Moo 1.000003;
  29 use SQL::Translator::Schema::Constants;
  30 use SQL::Translator::Utils qw(ex2err throw);
  31 use SQL::Translator::Role::ListAttr;
  32 use SQL::Translator::Types qw(schema_obj);
  33 use Sub::Quote qw(quote_sub);
  34
  35 extends 'SQL::Translator::Schema::Object';
  36
  37 our $VERSION = '1.59';
  38
  39 my %VALID_INDEX_TYPE = (
  40   UNIQUE         => 1,
  41   NORMAL         => 1,
  42   FULLTEXT       => 1, # MySQL only (?)
  43   FULL_TEXT      => 1, # MySQL only (?)
  44   SPATIAL        => 1, # MySQL only (?)
  45 );
  46
  47 =head2 new
  48
  49 Object constructor.
  50
  51   my $schema = SQL::Translator::Schema::Index->new;
  52
  53 =head2 fields
  54
  55 Gets and set the fields the index is on.  Accepts a string, list or
  56 arrayref; returns an array or array reference.  Will unique the field
  57 names and keep them in order by the first occurrence of a field name.
  58
  59   $index->fields('id');
  60   $index->fields('id', 'name');
  61   $index->fields( 'id, name' );
  62   $index->fields( [ 'id', 'name' ] );
  63   $index->fields( qw[ id name ] );
  64
  65   my @fields = $index->fields;
  66
  67 =cut
  68
  69 with ListAttr fields => ( uniq => 1 );
  70
  71 sub is_valid {
  72
  73 =pod
  74
  75 =head2 is_valid
  76
  77 Determine whether the index is valid or not.
  78
  79   my $ok = $index->is_valid;
  80
  81 =cut
  82
  83     my $self   = shift;
  84     my $table  = $self->table  or return $self->error('No table');
  85     my @fields = $self->fields or return $self->error('No fields');
  86
  87     for my $field ( @fields ) {
  88         return $self->error(
  89             "Field '$field' does not exist in table '", $table->name, "'"
  90         ) unless $table->get_field( $field );
  91     }
  92
  93     return 1;
  94 }
  95
  96 =head2 name
  97
  98 Get or set the index's name.
  99
 100   my $name = $index->name('foo');
 101
 102 =cut
 103
 104 has name => (
 105     is => 'rw',
 106     coerce => quote_sub(q{ defined $_[0] ? $_[0] : '' }),
 107     default => quote_sub(q{ '' }),
 108 );
 109
 110 =head2 options
 111
 112 Get or set the index's options (e.g., "using" or "where" for PG).  Returns
 113 an array or array reference.
 114
 115   my @options = $index->options;
 116
 117 =cut
 118
 119 with ListAttr options => ();
 120
 121 =head2 table
 122
 123 Get or set the index's table object.
 124
 125   my $table = $index->table;
 126
 127 =cut
 128
 129 has table => ( is => 'rw', isa => schema_obj('Table'), weak_ref => 1 );
 130
 131 around table => \&ex2err;
 132
 133 =head2 type
 134
 135 Get or set the index's type.
 136
 137   my $type = $index->type('unique');
 138
 139 Get or set the index's type.
 140
 141 Currently there are only four acceptable types: UNIQUE, NORMAL, FULL_TEXT,
 142 and SPATIAL. The latter two might be MySQL-specific. While both lowercase
 143 and uppercase types are acceptable input, this method returns the type in
 144 uppercase.
 145
 146 =cut
 147
 148 has type => (
 149     is => 'rw',
 150     isa => sub {
 151         my $type = uc $_[0] or return;
 152         throw("Invalid index type: $type") unless $VALID_INDEX_TYPE{$type};
 153     },
 154     coerce => quote_sub(q{ uc $_[0] }),
 155     default => quote_sub(q{ 'NORMAL' }),
 156 );
 157
 158 around type => \&ex2err;
 159
 160 =head2 equals
 161
 162 Determines if this index is the same as another
 163
 164   my $isIdentical = $index1->equals( $index2 );
 165
 166 =cut
 167
 168 around equals => sub {
 169     my $orig = shift;
 170     my $self = shift;
 171     my $other = shift;
 172     my $case_insensitive = shift;
 173     my $ignore_index_names = shift;
 174
 175     return 0 unless $self->$orig($other);
 176
 177     unless ($ignore_index_names) {
 178       unless ((!$self->name && ($other->name eq $other->fields->[0])) ||
 179         (!$other->name && ($self->name eq $self->fields->[0]))) {
 180         return 0 unless $case_insensitive ? uc($self->name) eq uc($other->name) : $self->name eq $other->name;
 181       }
 182     }
 183     #return 0 unless $self->is_valid eq $other->is_valid;
 184     return 0 unless $self->type eq $other->type;
 185
 186     # Check fields, regardless of order
 187     my %otherFields = ();  # create a hash of the other fields
 188     foreach my $otherField ($other->fields) {
 189       $otherField = uc($otherField) if $case_insensitive;
 190       $otherFields{$otherField} = 1;
 191     }
 192     foreach my $selfField ($self->fields) { # check for self fields in hash
 193       $selfField = uc($selfField) if $case_insensitive;
 194       return 0 unless $otherFields{$selfField};
 195       delete $otherFields{$selfField};
 196     }
 197     # Check all other fields were accounted for
 198     return 0 unless keys %otherFields == 0;
 199
 200     return 0 unless $self->_compare_objects(scalar $self->options, scalar $other->options);
 201     return 0 unless $self->_compare_objects(scalar $self->extra, scalar $other->extra);
 202     return 1;
 203 };
 204
 205 # Must come after all 'has' declarations
 206 around new => \&ex2err;
 207
 208 1;
 209
 210 =pod
 211
 212 =head1 AUTHOR
 213
 214 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>.
 215
 216 =cut