lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment);
  43
  44 use vars qw[ $VERSION $DEBUG $WARN ];
  45
  46 $VERSION = '1.59';
  47 $DEBUG = 0 unless defined $DEBUG;
  48 $WARN = 0 unless defined $WARN;
  49
  50 our $max_id_length    = 30;
  51 my %global_names;
  52
  53 sub produce {
  54     my $translator     = shift;
  55     local $DEBUG       = $translator->debug;
  56     local $WARN        = $translator->show_warnings;
  57     my $no_comments    = $translator->no_comments;
  58     my $add_drop_table = $translator->add_drop_table;
  59     my $schema         = $translator->schema;
  60     my $producer_args  = $translator->producer_args;
  61     my $sqlite_version = $producer_args->{sqlite_version} || 0;
  62     my $no_txn         = $producer_args->{no_transaction};
  63
  64     debug("PKG: Beginning production\n");
  65
  66     %global_names = ();   #reset
  67
  68     my @create = ();
  69     push @create, header_comment unless ($no_comments);
  70     $create[0] .= "\n\nBEGIN TRANSACTION" unless $no_txn;
  71
  72     for my $table ( $schema->get_tables ) {
  73         push @create, create_table($table, { no_comments => $no_comments,
  74                                              sqlite_version => $sqlite_version,
  75                                           add_drop_table => $add_drop_table,});
  76     }
  77
  78     for my $view ( $schema->get_views ) {
  79       push @create, create_view($view, {
  80         add_drop_view => $add_drop_table,
  81         no_comments   => $no_comments,
  82       });
  83     }
  84
  85     for my $trigger ( $schema->get_triggers ) {
  86       push @create, create_trigger($trigger, {
  87         add_drop_trigger => $add_drop_table,
  88         no_comments   => $no_comments,
  89       });
  90     }
  91
  92     if (wantarray) {
  93       push @create, "COMMIT" unless $no_txn;
  94       return @create;
  95     } else {
  96       push @create, "COMMIT;\n" unless $no_txn;
  97       return join(";\n\n", @create );
  98     }
  99 }
 100
 101 # -------------------------------------------------------------------
 102 sub mk_name {
 103     my ($name, $scope, $critical) = @_;
 104
 105     $scope ||= \%global_names;
 106     if ( my $prev = $scope->{ $name } ) {
 107         my $name_orig = $name;
 108         $name        .= sprintf( "%02d", ++$prev );
 109         substr($name, $max_id_length - 3) = "00"
 110             if length( $name ) > $max_id_length;
 111
 112         warn "The name '$name_orig' has been changed to ",
 113              "'$name' to make it unique.\n" if $WARN;
 114
 115         $scope->{ $name_orig }++;
 116     }
 117
 118     $scope->{ $name }++;
 119     return $name;
 120 }
 121
 122 sub create_view {
 123     my ($view, $options) = @_;
 124     my $add_drop_view = $options->{add_drop_view};
 125
 126     my $view_name = $view->name;
 127     debug("PKG: Looking at view '${view_name}'\n");
 128
 129     # Header.  Should this look like what mysqldump produces?
 130     my $extra = $view->extra;
 131     my $create = '';
 132     $create .= "--\n-- View: ${view_name}\n--\n" unless $options->{no_comments};
 133     $create .= "DROP VIEW IF EXISTS $view_name;\n" if $add_drop_view;
 134     $create .= 'CREATE';
 135     $create .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 136     $create .= ' VIEW';
 137     $create .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 138     $create .= " ${view_name}";
 139
 140     if( my $sql = $view->sql ){
 141       $create .= " AS\n    ${sql}";
 142     }
 143     return $create;
 144 }
 145
 146
 147 sub create_table
 148 {
 149     my ($table, $options) = @_;
 150
 151     my $table_name = $table->name;
 152     my $no_comments = $options->{no_comments};
 153     my $add_drop_table = $options->{add_drop_table};
 154     my $sqlite_version = $options->{sqlite_version} || 0;
 155
 156     debug("PKG: Looking at table '$table_name'\n");
 157
 158     my ( @index_defs, @constraint_defs );
 159     my @fields = $table->get_fields or die "No fields in $table_name";
 160
 161     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 162     #
 163     # Header.
 164     #
 165     my $exists = ($sqlite_version >= 3.3) ? ' IF EXISTS' : '';
 166     my @create;
 167     my ($comment, $create_table) = "";
 168     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 169     if ($add_drop_table) {
 170       push @create, $comment . qq[DROP TABLE$exists $table_name];
 171     } else {
 172       $create_table = $comment;
 173     }
 174
 175     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 176
 177     #
 178     # Comments
 179     #
 180     if ( $table->comments and !$no_comments ){
 181         $create_table .= "-- Comments: \n-- ";
 182         $create_table .= join "\n-- ",  $table->comments;
 183         $create_table .= "\n--\n\n";
 184     }
 185
 186     #
 187     # How many fields in PK?
 188     #
 189     my $pk        = $table->primary_key;
 190     my @pk_fields = $pk ? $pk->fields : ();
 191
 192     #
 193     # Fields
 194     #
 195     my ( @field_defs, $pk_set );
 196     for my $field ( @fields ) {
 197         push @field_defs, create_field($field);
 198     }
 199
 200     if (
 201          scalar @pk_fields > 1
 202          ||
 203          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 204          ) {
 205         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 206     }
 207
 208     #
 209     # Indices
 210     #
 211     my $idx_name_default = 'A';
 212     for my $index ( $table->get_indices ) {
 213         push @index_defs, create_index($index);
 214     }
 215
 216     #
 217     # Constraints
 218     #
 219     my $c_name_default = 'A';
 220     for my $c ( $table->get_constraints ) {
 221         next unless $c->type eq UNIQUE;
 222         push @constraint_defs, create_constraint($c);
 223     }
 224
 225     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 226
 227     return (@create, $create_table, @index_defs, @constraint_defs );
 228 }
 229
 230 sub create_field
 231 {
 232     my ($field, $options) = @_;
 233
 234     my $field_name = $field->name;
 235     debug("PKG: Looking at field '$field_name'\n");
 236     my $field_comments = $field->comments
 237         ? "-- " . $field->comments . "\n  "
 238         : '';
 239
 240     my $field_def = $field_comments.$field_name;
 241
 242     # data type and size
 243     my $size      = $field->size;
 244     my $data_type = $field->data_type;
 245     $data_type    = 'varchar' if lc $data_type eq 'set';
 246     $data_type  = 'blob' if lc $data_type eq 'bytea';
 247
 248     if ( lc $data_type =~ /(text|blob)/i ) {
 249         $size = undef;
 250     }
 251
 252 #             if ( $data_type =~ /timestamp/i ) {
 253 #                 push @trigger_defs,
 254 #                     "CREATE TRIGGER ts_${table_name} ".
 255 #                     "after insert on $table_name\n".
 256 #                     "begin\n".
 257 #                     "  update $table_name set $field_name=timestamp() ".
 258 #                        "where id=new.id;\n".
 259 #                     "end;\n"
 260 #                 ;
 261 #
 262 #            }
 263
 264     #
 265     # SQLite is generally typeless, but newer versions will
 266     # make a field autoincrement if it is declared as (and
 267     # *only* as) INTEGER PRIMARY KEY
 268     #
 269     my $pk        = $field->table->primary_key;
 270     my @pk_fields = $pk ? $pk->fields : ();
 271
 272     if (
 273          $field->is_primary_key &&
 274          scalar @pk_fields == 1 &&
 275          (
 276           $data_type =~ /int(eger)?$/i
 277           ||
 278           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 279           )
 280          ) {
 281         $data_type = 'INTEGER PRIMARY KEY';
 282         $size      = undef;
 283 #        $pk_set    = 1;
 284     }
 285
 286     $field_def .= sprintf " %s%s", $data_type,
 287     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 288
 289     # Null?
 290     $field_def .= ' NOT NULL' unless $field->is_nullable;
 291
 292     # Default?  XXX Need better quoting!
 293     my $default = $field->default_value;
 294     if (defined $default) {
 295         SQL::Translator::Producer->_apply_default_value(
 296             \$field_def,
 297             $default,
 298             [
 299              'NULL'              => \'NULL',
 300              'now()'             => 'now()',
 301              'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 302             ],
 303         );
 304     }
 305
 306     return $field_def;
 307
 308 }
 309
 310 sub create_index
 311 {
 312     my ($index, $options) = @_;
 313
 314     my $name   = $index->name;
 315     $name      = mk_name($name);
 316
 317     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 318
 319     # strip any field size qualifiers as SQLite doesn't like these
 320     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 321     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 322     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 323     my $index_def =
 324     "CREATE ${type}INDEX $name ON " . $index_table_name .
 325         ' (' . join( ', ', @fields ) . ')';
 326
 327     return $index_def;
 328 }
 329
 330 sub create_constraint
 331 {
 332     my ($c, $options) = @_;
 333
 334     my $name   = $c->name;
 335     $name      = mk_name($name);
 336     my @fields = $c->fields;
 337     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 338     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 339
 340     my $c_def =
 341     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 342         ' (' . join( ', ', @fields ) . ')';
 343
 344     return $c_def;
 345 }
 346
 347 sub create_trigger {
 348   my ($trigger, $options) = @_;
 349   my $add_drop = $options->{add_drop_trigger};
 350
 351   my @statements;
 352
 353   my $trigger_name = $trigger->name;
 354   my $events = $trigger->database_events;
 355   for my $evt ( @$events ) {
 356
 357     my $trig_name = $trigger_name;
 358     if (@$events > 1) {
 359       $trig_name .= "_$evt";
 360
 361       warn "Multiple database events supplied for trigger '$trigger_name', ",
 362         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 363     }
 364
 365     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 366
 367
 368     $DB::single = 1;
 369     my $action = "";
 370     if (not ref $trigger->action) {
 371       $action .= "BEGIN " . $trigger->action . " END";
 372     }
 373     else {
 374       $action = $trigger->action->{for_each} . " "
 375         if $trigger->action->{for_each};
 376
 377       $action = $trigger->action->{when} . " "
 378         if $trigger->action->{when};
 379
 380       my $steps = $trigger->action->{steps} || [];
 381
 382       $action .= "BEGIN ";
 383       $action .= $_ . "; " for (@$steps);
 384       $action .= "END";
 385     }
 386
 387     push @statements, sprintf (
 388       'CREATE TRIGGER %s %s %s on %s %s',
 389       $trig_name,
 390       $trigger->perform_action_when,
 391       $evt,
 392       $trigger->on_table,
 393       $action
 394     );
 395   }
 396
 397   return @statements;
 398 }
 399
 400 sub alter_table { } # Noop
 401
 402 sub add_field {
 403   my ($field) = @_;
 404
 405   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 406       $field->table->name, create_field($field))
 407 }
 408
 409 sub alter_create_index {
 410   my ($index) = @_;
 411
 412   # This might cause name collisions
 413   return create_index($index);
 414 }
 415
 416 sub alter_create_constraint {
 417   my ($constraint) = @_;
 418
 419   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 420 }
 421
 422 sub alter_drop_constraint { alter_drop_index(@_) }
 423
 424 sub alter_drop_index {
 425   my ($constraint) = @_;
 426
 427   return sprintf("DROP INDEX %s",
 428       $constraint->name);
 429 }
 430
 431 sub batch_alter_table {
 432   my ($table, $diffs) = @_;
 433
 434   # If we have any of the following
 435   #
 436   #  rename_field
 437   #  alter_field
 438   #  drop_field
 439   #
 440   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 441   #
 442   # BEGIN TRANSACTION;
 443   # CREATE TEMPORARY TABLE t1_backup(a,b);
 444   # INSERT INTO t1_backup SELECT a,b FROM t1;
 445   # DROP TABLE t1;
 446   # CREATE TABLE t1(a,b);
 447   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 448   # DROP TABLE t1_backup;
 449   # COMMIT;
 450   #
 451   # Fun, eh?
 452   #
 453   # If we have rename_field we do similarly.
 454
 455   my $table_name = $table->name;
 456   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 457
 458   if ( @{$diffs->{rename_field}} == 0 &&
 459        @{$diffs->{alter_field}}  == 0 &&
 460        @{$diffs->{drop_field}}   == 0
 461        ) {
 462 #    return join("\n", map {
 463     return map {
 464         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 465         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 466
 467       } grep { @{$diffs->{$_}} }
 468     qw/rename_table
 469        alter_drop_constraint
 470        alter_drop_index
 471        drop_field
 472        add_field
 473        alter_field
 474        rename_field
 475        alter_create_index
 476        alter_create_constraint
 477        alter_table/;
 478   }
 479
 480
 481   my @sql;
 482   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 483
 484   do {
 485     local $table->{name} = $table_name . '_temp_alter';
 486     # We only want the table - dont care about indexes on tmp table
 487     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 488     push @sql,$table_sql;
 489   };
 490
 491   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 492              "DROP TABLE @{[$old_table]}",
 493              create_table($table, { no_comments => 1 }),
 494              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 495              "DROP TABLE @{[$table_name]}_temp_alter";
 496
 497   return @sql;
 498 #  return join("", @sql, "");
 499 }
 500
 501 sub drop_table {
 502   my ($table) = @_;
 503   return "DROP TABLE $table";
 504 }
 505
 506 sub rename_table {
 507   my ($old_table, $new_table, $options) = @_;
 508
 509   my $qt = $options->{quote_table_names} || '';
 510
 511   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 512
 513 }
 514
 515 # No-op. Just here to signify that we are a new style parser.
 516 sub preproces_schema { }
 517
 518 1;
 519
 520 =pod
 521
 522 =head1 SEE ALSO
 523
 524 SQL::Translator, http://www.sqlite.org/.
 525
 526 =head1 AUTHOR
 527
 528 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 529
 530 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 531
 532 =cut