lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 =head1 NAME
   4
   5 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
   6
   7 =head1 SYNOPSIS
   8
   9   use SQL::Translator;
  10
  11   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  12   $t->translate;
  13
  14 =head1 DESCRIPTION
  15
  16 This module will produce text output of the schema suitable for SQLite.
  17
  18 =cut
  19
  20 use strict;
  21 use warnings;
  22 use Data::Dumper;
  23 use SQL::Translator::Schema::Constants;
  24 use SQL::Translator::Utils qw(debug header_comment parse_dbms_version);
  25
  26 use vars qw[ $VERSION $DEBUG $WARN ];
  27
  28 $VERSION = '1.59';
  29 $DEBUG = 0 unless defined $DEBUG;
  30 $WARN = 0 unless defined $WARN;
  31
  32 our $max_id_length    = 30;
  33 my %global_names;
  34
  35 sub produce {
  36     my $translator     = shift;
  37     local $DEBUG       = $translator->debug;
  38     local $WARN        = $translator->show_warnings;
  39     my $no_comments    = $translator->no_comments;
  40     my $add_drop_table = $translator->add_drop_table;
  41     my $schema         = $translator->schema;
  42     my $producer_args  = $translator->producer_args;
  43     my $sqlite_version = parse_dbms_version(
  44         $producer_args->{sqlite_version}, 'perl'
  45     );
  46     my $no_txn         = $producer_args->{no_transaction};
  47
  48     debug("PKG: Beginning production\n");
  49
  50     %global_names = ();   #reset
  51
  52
  53     my $head = (header_comment() . "\n") unless $no_comments;
  54
  55     my @create = ();
  56
  57     push @create, "BEGIN TRANSACTION" unless $no_txn;
  58
  59     for my $table ( $schema->get_tables ) {
  60         push @create, create_table($table, { no_comments => $no_comments,
  61                                              sqlite_version => $sqlite_version,
  62                                           add_drop_table => $add_drop_table,});
  63     }
  64
  65     for my $view ( $schema->get_views ) {
  66       push @create, create_view($view, {
  67         add_drop_view => $add_drop_table,
  68         no_comments   => $no_comments,
  69       });
  70     }
  71
  72     for my $trigger ( $schema->get_triggers ) {
  73       push @create, create_trigger($trigger, {
  74         add_drop_trigger => $add_drop_table,
  75         no_comments   => $no_comments,
  76       });
  77     }
  78
  79     push @create, "COMMIT" unless $no_txn;
  80
  81     if (wantarray) {
  82       return ($head||(), @create);
  83     } else {
  84       return join ('',
  85         $head||(),
  86         join(";\n\n", @create ),
  87         ";\n",
  88       );
  89     }
  90 }
  91
  92 sub mk_name {
  93     my ($name, $scope, $critical) = @_;
  94
  95     $scope ||= \%global_names;
  96     if ( my $prev = $scope->{ $name } ) {
  97         my $name_orig = $name;
  98         $name        .= sprintf( "%02d", ++$prev );
  99         substr($name, $max_id_length - 3) = "00"
 100             if length( $name ) > $max_id_length;
 101
 102         warn "The name '$name_orig' has been changed to ",
 103              "'$name' to make it unique.\n" if $WARN;
 104
 105         $scope->{ $name_orig }++;
 106     }
 107
 108     $scope->{ $name }++;
 109     return $name;
 110 }
 111
 112 sub create_view {
 113     my ($view, $options) = @_;
 114     my $add_drop_view = $options->{add_drop_view};
 115
 116     my $view_name = $view->name;
 117     $global_names{$view_name} = 1;
 118
 119     debug("PKG: Looking at view '${view_name}'\n");
 120
 121     # Header.  Should this look like what mysqldump produces?
 122     my $extra = $view->extra;
 123     my @create;
 124     push @create, "DROP VIEW IF EXISTS $view_name" if $add_drop_view;
 125
 126     my $create_view = 'CREATE';
 127     $create_view .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 128     $create_view .= ' VIEW';
 129     $create_view .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 130     $create_view .= " ${view_name}";
 131
 132     if( my $sql = $view->sql ){
 133       $create_view .= " AS\n    ${sql}";
 134     }
 135     push @create, $create_view;
 136
 137     # Tack the comment onto the first statement.
 138     unless ($options->{no_comments}) {
 139       $create[0] = "--\n-- View: ${view_name}\n--\n" . $create[0];
 140     }
 141
 142     return @create;
 143 }
 144
 145
 146 sub create_table
 147 {
 148     my ($table, $options) = @_;
 149
 150     my $table_name = $table->name;
 151     $global_names{$table_name} = 1;
 152
 153     my $no_comments = $options->{no_comments};
 154     my $add_drop_table = $options->{add_drop_table};
 155     my $sqlite_version = $options->{sqlite_version} || 0;
 156
 157     debug("PKG: Looking at table '$table_name'\n");
 158
 159     my ( @index_defs, @constraint_defs );
 160     my @fields = $table->get_fields or die "No fields in $table_name";
 161
 162     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 163     #
 164     # Header.
 165     #
 166     my $exists = ($sqlite_version >= 3.003) ? ' IF EXISTS' : '';
 167     my @create;
 168     my ($comment, $create_table) = "";
 169     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 170     if ($add_drop_table) {
 171       push @create, $comment . qq[DROP TABLE$exists $table_name];
 172     } else {
 173       $create_table = $comment;
 174     }
 175
 176     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 177
 178     #
 179     # Comments
 180     #
 181     if ( $table->comments and !$no_comments ){
 182         $create_table .= "-- Comments: \n-- ";
 183         $create_table .= join "\n-- ",  $table->comments;
 184         $create_table .= "\n--\n\n";
 185     }
 186
 187     #
 188     # How many fields in PK?
 189     #
 190     my $pk        = $table->primary_key;
 191     my @pk_fields = $pk ? $pk->fields : ();
 192
 193     #
 194     # Fields
 195     #
 196     my ( @field_defs, $pk_set );
 197     for my $field ( @fields ) {
 198         push @field_defs, create_field($field);
 199     }
 200
 201     if (
 202          scalar @pk_fields > 1
 203          ||
 204          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 205          ) {
 206         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 207     }
 208
 209     #
 210     # Indices
 211     #
 212     my $idx_name_default = 'A';
 213     for my $index ( $table->get_indices ) {
 214         push @index_defs, create_index($index);
 215     }
 216
 217     #
 218     # Constraints
 219     #
 220     my $c_name_default = 'A';
 221     for my $c ( $table->get_constraints ) {
 222         if ($c->type eq "FOREIGN KEY") {
 223             push @field_defs, create_foreignkey($c);
 224         }
 225         next unless $c->type eq UNIQUE;
 226         push @constraint_defs, create_constraint($c);
 227     }
 228
 229     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 230
 231     return (@create, $create_table, @index_defs, @constraint_defs );
 232 }
 233
 234 sub create_foreignkey {
 235     my $c = shift;
 236
 237     my $fk_sql = "FOREIGN KEY($c->{fields}[0]) REFERENCES ";
 238     $fk_sql .= ( $c->{reference_table} || '' )."(".( $c->{reference_fields}[0] || '' ).")";
 239
 240     return $fk_sql;
 241 }
 242
 243 sub create_field
 244 {
 245     my ($field, $options) = @_;
 246
 247     my $field_name = $field->name;
 248     debug("PKG: Looking at field '$field_name'\n");
 249     my $field_comments = $field->comments
 250         ? "-- " . $field->comments . "\n  "
 251         : '';
 252
 253     my $field_def = $field_comments.$field_name;
 254
 255     # data type and size
 256     my $size      = $field->size;
 257     my $data_type = $field->data_type;
 258     $data_type    = 'varchar' if lc $data_type eq 'set';
 259     $data_type  = 'blob' if lc $data_type eq 'bytea';
 260
 261     if ( lc $data_type =~ /(text|blob)/i ) {
 262         $size = undef;
 263     }
 264
 265 #             if ( $data_type =~ /timestamp/i ) {
 266 #                 push @trigger_defs,
 267 #                     "CREATE TRIGGER ts_${table_name} ".
 268 #                     "after insert on $table_name\n".
 269 #                     "begin\n".
 270 #                     "  update $table_name set $field_name=timestamp() ".
 271 #                        "where id=new.id;\n".
 272 #                     "end;\n"
 273 #                 ;
 274 #
 275 #            }
 276
 277     #
 278     # SQLite is generally typeless, but newer versions will
 279     # make a field autoincrement if it is declared as (and
 280     # *only* as) INTEGER PRIMARY KEY
 281     #
 282     my $pk        = $field->table->primary_key;
 283     my @pk_fields = $pk ? $pk->fields : ();
 284
 285     if (
 286          $field->is_primary_key &&
 287          scalar @pk_fields == 1 &&
 288          (
 289           $data_type =~ /int(eger)?$/i
 290           ||
 291           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 292           )
 293          ) {
 294         $data_type = 'INTEGER PRIMARY KEY';
 295         $size      = undef;
 296 #        $pk_set    = 1;
 297     }
 298
 299     $field_def .= sprintf " %s%s", $data_type,
 300     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 301
 302     # Null?
 303     $field_def .= ' NOT NULL' unless $field->is_nullable;
 304
 305     # Default?
 306     SQL::Translator::Producer->_apply_default_value(
 307         $field,
 308         \$field_def,
 309         [
 310          'NULL'              => \'NULL',
 311          'now()'             => 'now()',
 312          'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 313         ],
 314     );
 315
 316     return $field_def;
 317
 318 }
 319
 320 sub create_index
 321 {
 322     my ($index, $options) = @_;
 323
 324     my $name   = $index->name;
 325     $name      = mk_name($name);
 326
 327     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 328
 329     # strip any field size qualifiers as SQLite doesn't like these
 330     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 331     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 332     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 333     my $index_def =
 334     "CREATE ${type}INDEX $name ON " . $index_table_name .
 335         ' (' . join( ', ', @fields ) . ')';
 336
 337     return $index_def;
 338 }
 339
 340 sub create_constraint
 341 {
 342     my ($c, $options) = @_;
 343
 344     my $name   = $c->name;
 345     $name      = mk_name($name);
 346     my @fields = $c->fields;
 347     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 348     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 349
 350     my $c_def =
 351     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 352         ' (' . join( ', ', @fields ) . ')';
 353
 354     return $c_def;
 355 }
 356
 357 sub create_trigger {
 358   my ($trigger, $options) = @_;
 359   my $add_drop = $options->{add_drop_trigger};
 360
 361   my @statements;
 362
 363   my $trigger_name = $trigger->name;
 364   $global_names{$trigger_name} = 1;
 365
 366   my $events = $trigger->database_events;
 367   for my $evt ( @$events ) {
 368
 369     my $trig_name = $trigger_name;
 370     if (@$events > 1) {
 371       $trig_name .= "_$evt";
 372
 373       warn "Multiple database events supplied for trigger '$trigger_name', ",
 374         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 375     }
 376
 377     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 378
 379
 380     $DB::single = 1;
 381     my $action = "";
 382     if (not ref $trigger->action) {
 383       $action .= "BEGIN " . $trigger->action . " END";
 384     }
 385     else {
 386       $action = $trigger->action->{for_each} . " "
 387         if $trigger->action->{for_each};
 388
 389       $action = $trigger->action->{when} . " "
 390         if $trigger->action->{when};
 391
 392       my $steps = $trigger->action->{steps} || [];
 393
 394       $action .= "BEGIN ";
 395       $action .= $_ . "; " for (@$steps);
 396       $action .= "END";
 397     }
 398
 399     push @statements, sprintf (
 400       'CREATE TRIGGER %s %s %s on %s %s',
 401       $trig_name,
 402       $trigger->perform_action_when,
 403       $evt,
 404       $trigger->on_table,
 405       $action
 406     );
 407   }
 408
 409   return @statements;
 410 }
 411
 412 sub alter_table { } # Noop
 413
 414 sub add_field {
 415   my ($field) = @_;
 416
 417   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 418       $field->table->name, create_field($field))
 419 }
 420
 421 sub alter_create_index {
 422   my ($index) = @_;
 423
 424   # This might cause name collisions
 425   return create_index($index);
 426 }
 427
 428 sub alter_create_constraint {
 429   my ($constraint) = @_;
 430
 431   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 432 }
 433
 434 sub alter_drop_constraint { alter_drop_index(@_) }
 435
 436 sub alter_drop_index {
 437   my ($constraint) = @_;
 438
 439   return sprintf("DROP INDEX %s",
 440       $constraint->name);
 441 }
 442
 443 sub batch_alter_table {
 444   my ($table, $diffs) = @_;
 445
 446   # If we have any of the following
 447   #
 448   #  rename_field
 449   #  alter_field
 450   #  drop_field
 451   #
 452   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 453   #
 454   # BEGIN TRANSACTION;
 455   # CREATE TEMPORARY TABLE t1_backup(a,b);
 456   # INSERT INTO t1_backup SELECT a,b FROM t1;
 457   # DROP TABLE t1;
 458   # CREATE TABLE t1(a,b);
 459   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 460   # DROP TABLE t1_backup;
 461   # COMMIT;
 462   #
 463   # Fun, eh?
 464   #
 465   # If we have rename_field we do similarly.
 466
 467   my $table_name = $table->name;
 468   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 469
 470   if ( @{$diffs->{rename_field}} == 0 &&
 471        @{$diffs->{alter_field}}  == 0 &&
 472        @{$diffs->{drop_field}}   == 0
 473        ) {
 474 #    return join("\n", map {
 475     return map {
 476         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 477         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 478
 479       } grep { @{$diffs->{$_}} }
 480     qw/rename_table
 481        alter_drop_constraint
 482        alter_drop_index
 483        drop_field
 484        add_field
 485        alter_field
 486        rename_field
 487        alter_create_index
 488        alter_create_constraint
 489        alter_table/;
 490   }
 491
 492
 493   my @sql;
 494   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 495
 496   do {
 497     local $table->{name} = $table_name . '_temp_alter';
 498     # We only want the table - dont care about indexes on tmp table
 499     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 500     push @sql,$table_sql;
 501   };
 502
 503   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 504              "DROP TABLE @{[$old_table]}",
 505              create_table($table, { no_comments => 1 }),
 506              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 507              "DROP TABLE @{[$table_name]}_temp_alter";
 508
 509   return @sql;
 510 #  return join("", @sql, "");
 511 }
 512
 513 sub drop_table {
 514   my ($table) = @_;
 515   return "DROP TABLE $table";
 516 }
 517
 518 sub rename_table {
 519   my ($old_table, $new_table, $options) = @_;
 520
 521   my $qt = $options->{quote_table_names} || '';
 522
 523   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 524
 525 }
 526
 527 # No-op. Just here to signify that we are a new style parser.
 528 sub preproces_schema { }
 529
 530 1;
 531
 532 =pod
 533
 534 =head1 SEE ALSO
 535
 536 SQL::Translator, http://www.sqlite.org/.
 537
 538 =head1 AUTHOR
 539
 540 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 541
 542 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 543
 544 =cut