lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment);
  43
  44 use vars qw[ $VERSION $DEBUG $WARN ];
  45
  46 $VERSION = '1.59';
  47 $DEBUG = 0 unless defined $DEBUG;
  48 $WARN = 0 unless defined $WARN;
  49
  50 our $max_id_length    = 30;
  51 my %global_names;
  52
  53 sub produce {
  54     my $translator     = shift;
  55     local $DEBUG       = $translator->debug;
  56     local $WARN        = $translator->show_warnings;
  57     my $no_comments    = $translator->no_comments;
  58     my $add_drop_table = $translator->add_drop_table;
  59     my $schema         = $translator->schema;
  60     my $producer_args  = $translator->producer_args;
  61     my $sqlite_version = $producer_args->{sqlite_version} || 0;
  62     my $no_txn         = $producer_args->{no_transaction};
  63
  64     debug("PKG: Beginning production\n");
  65
  66     %global_names = ();   #reset
  67
  68
  69     my $head = (header_comment() . "\n") unless $no_comments;
  70
  71     my @create = ();
  72
  73     push @create, "BEGIN TRANSACTION" unless $no_txn;
  74
  75     for my $table ( $schema->get_tables ) {
  76         push @create, create_table($table, { no_comments => $no_comments,
  77                                              sqlite_version => $sqlite_version,
  78                                           add_drop_table => $add_drop_table,});
  79     }
  80
  81     for my $view ( $schema->get_views ) {
  82       push @create, create_view($view, {
  83         add_drop_view => $add_drop_table,
  84         no_comments   => $no_comments,
  85       });
  86     }
  87
  88     for my $trigger ( $schema->get_triggers ) {
  89       push @create, create_trigger($trigger, {
  90         add_drop_trigger => $add_drop_table,
  91         no_comments   => $no_comments,
  92       });
  93     }
  94
  95     push @create, "COMMIT" unless $no_txn;
  96
  97     if (wantarray) {
  98       return ($head||(), @create);
  99     } else {
 100       return join ('',
 101         $head||(),
 102         join(";\n\n", @create ),
 103         ";\n",
 104       );
 105     }
 106 }
 107
 108 # -------------------------------------------------------------------
 109 sub mk_name {
 110     my ($name, $scope, $critical) = @_;
 111
 112     $scope ||= \%global_names;
 113     if ( my $prev = $scope->{ $name } ) {
 114         my $name_orig = $name;
 115         $name        .= sprintf( "%02d", ++$prev );
 116         substr($name, $max_id_length - 3) = "00"
 117             if length( $name ) > $max_id_length;
 118
 119         warn "The name '$name_orig' has been changed to ",
 120              "'$name' to make it unique.\n" if $WARN;
 121
 122         $scope->{ $name_orig }++;
 123     }
 124
 125     $scope->{ $name }++;
 126     return $name;
 127 }
 128
 129 sub create_view {
 130     my ($view, $options) = @_;
 131     my $add_drop_view = $options->{add_drop_view};
 132
 133     my $view_name = $view->name;
 134     debug("PKG: Looking at view '${view_name}'\n");
 135
 136     # Header.  Should this look like what mysqldump produces?
 137     my $extra = $view->extra;
 138     my $create = '';
 139     $create .= "--\n-- View: ${view_name}\n--\n" unless $options->{no_comments};
 140     $create .= "DROP VIEW IF EXISTS $view_name;\n" if $add_drop_view;
 141     $create .= 'CREATE';
 142     $create .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 143     $create .= ' VIEW';
 144     $create .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 145     $create .= " ${view_name}";
 146
 147     if( my $sql = $view->sql ){
 148       $create .= " AS\n    ${sql}";
 149     }
 150     return $create;
 151 }
 152
 153
 154 sub create_table
 155 {
 156     my ($table, $options) = @_;
 157
 158     my $table_name = $table->name;
 159     my $no_comments = $options->{no_comments};
 160     my $add_drop_table = $options->{add_drop_table};
 161     my $sqlite_version = $options->{sqlite_version} || 0;
 162
 163     debug("PKG: Looking at table '$table_name'\n");
 164
 165     my ( @index_defs, @constraint_defs );
 166     my @fields = $table->get_fields or die "No fields in $table_name";
 167
 168     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 169     #
 170     # Header.
 171     #
 172     my $exists = ($sqlite_version >= 3.3) ? ' IF EXISTS' : '';
 173     my @create;
 174     my ($comment, $create_table) = "";
 175     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 176     if ($add_drop_table) {
 177       push @create, $comment . qq[DROP TABLE$exists $table_name];
 178     } else {
 179       $create_table = $comment;
 180     }
 181
 182     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 183
 184     #
 185     # Comments
 186     #
 187     if ( $table->comments and !$no_comments ){
 188         $create_table .= "-- Comments: \n-- ";
 189         $create_table .= join "\n-- ",  $table->comments;
 190         $create_table .= "\n--\n\n";
 191     }
 192
 193     #
 194     # How many fields in PK?
 195     #
 196     my $pk        = $table->primary_key;
 197     my @pk_fields = $pk ? $pk->fields : ();
 198
 199     #
 200     # Fields
 201     #
 202     my ( @field_defs, $pk_set );
 203     for my $field ( @fields ) {
 204         push @field_defs, create_field($field);
 205     }
 206
 207     if (
 208          scalar @pk_fields > 1
 209          ||
 210          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 211          ) {
 212         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 213     }
 214
 215     #
 216     # Indices
 217     #
 218     my $idx_name_default = 'A';
 219     for my $index ( $table->get_indices ) {
 220         push @index_defs, create_index($index);
 221     }
 222
 223     #
 224     # Constraints
 225     #
 226     my $c_name_default = 'A';
 227     for my $c ( $table->get_constraints ) {
 228         next unless $c->type eq UNIQUE;
 229         push @constraint_defs, create_constraint($c);
 230     }
 231
 232     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 233
 234     return (@create, $create_table, @index_defs, @constraint_defs );
 235 }
 236
 237 sub create_field
 238 {
 239     my ($field, $options) = @_;
 240
 241     my $field_name = $field->name;
 242     debug("PKG: Looking at field '$field_name'\n");
 243     my $field_comments = $field->comments
 244         ? "-- " . $field->comments . "\n  "
 245         : '';
 246
 247     my $field_def = $field_comments.$field_name;
 248
 249     # data type and size
 250     my $size      = $field->size;
 251     my $data_type = $field->data_type;
 252     $data_type    = 'varchar' if lc $data_type eq 'set';
 253     $data_type  = 'blob' if lc $data_type eq 'bytea';
 254
 255     if ( lc $data_type =~ /(text|blob)/i ) {
 256         $size = undef;
 257     }
 258
 259 #             if ( $data_type =~ /timestamp/i ) {
 260 #                 push @trigger_defs,
 261 #                     "CREATE TRIGGER ts_${table_name} ".
 262 #                     "after insert on $table_name\n".
 263 #                     "begin\n".
 264 #                     "  update $table_name set $field_name=timestamp() ".
 265 #                        "where id=new.id;\n".
 266 #                     "end;\n"
 267 #                 ;
 268 #
 269 #            }
 270
 271     #
 272     # SQLite is generally typeless, but newer versions will
 273     # make a field autoincrement if it is declared as (and
 274     # *only* as) INTEGER PRIMARY KEY
 275     #
 276     my $pk        = $field->table->primary_key;
 277     my @pk_fields = $pk ? $pk->fields : ();
 278
 279     if (
 280          $field->is_primary_key &&
 281          scalar @pk_fields == 1 &&
 282          (
 283           $data_type =~ /int(eger)?$/i
 284           ||
 285           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 286           )
 287          ) {
 288         $data_type = 'INTEGER PRIMARY KEY';
 289         $size      = undef;
 290 #        $pk_set    = 1;
 291     }
 292
 293     $field_def .= sprintf " %s%s", $data_type,
 294     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 295
 296     # Null?
 297     $field_def .= ' NOT NULL' unless $field->is_nullable;
 298
 299     # Default?  XXX Need better quoting!
 300     my $default = $field->default_value;
 301     if (defined $default) {
 302         SQL::Translator::Producer->_apply_default_value(
 303             \$field_def,
 304             $default,
 305             [
 306              'NULL'              => \'NULL',
 307              'now()'             => 'now()',
 308              'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 309             ],
 310         );
 311     }
 312
 313     return $field_def;
 314
 315 }
 316
 317 sub create_index
 318 {
 319     my ($index, $options) = @_;
 320
 321     my $name   = $index->name;
 322     $name      = mk_name($name);
 323
 324     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 325
 326     # strip any field size qualifiers as SQLite doesn't like these
 327     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 328     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 329     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 330     my $index_def =
 331     "CREATE ${type}INDEX $name ON " . $index_table_name .
 332         ' (' . join( ', ', @fields ) . ')';
 333
 334     return $index_def;
 335 }
 336
 337 sub create_constraint
 338 {
 339     my ($c, $options) = @_;
 340
 341     my $name   = $c->name;
 342     $name      = mk_name($name);
 343     my @fields = $c->fields;
 344     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 345     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 346
 347     my $c_def =
 348     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 349         ' (' . join( ', ', @fields ) . ')';
 350
 351     return $c_def;
 352 }
 353
 354 sub create_trigger {
 355   my ($trigger, $options) = @_;
 356   my $add_drop = $options->{add_drop_trigger};
 357
 358   my @statements;
 359
 360   my $trigger_name = $trigger->name;
 361   my $events = $trigger->database_events;
 362   for my $evt ( @$events ) {
 363
 364     my $trig_name = $trigger_name;
 365     if (@$events > 1) {
 366       $trig_name .= "_$evt";
 367
 368       warn "Multiple database events supplied for trigger '$trigger_name', ",
 369         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 370     }
 371
 372     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 373
 374
 375     $DB::single = 1;
 376     my $action = "";
 377     if (not ref $trigger->action) {
 378       $action .= "BEGIN " . $trigger->action . " END";
 379     }
 380     else {
 381       $action = $trigger->action->{for_each} . " "
 382         if $trigger->action->{for_each};
 383
 384       $action = $trigger->action->{when} . " "
 385         if $trigger->action->{when};
 386
 387       my $steps = $trigger->action->{steps} || [];
 388
 389       $action .= "BEGIN ";
 390       $action .= $_ . "; " for (@$steps);
 391       $action .= "END";
 392     }
 393
 394     push @statements, sprintf (
 395       'CREATE TRIGGER %s %s %s on %s %s',
 396       $trig_name,
 397       $trigger->perform_action_when,
 398       $evt,
 399       $trigger->on_table,
 400       $action
 401     );
 402   }
 403
 404   return @statements;
 405 }
 406
 407 sub alter_table { } # Noop
 408
 409 sub add_field {
 410   my ($field) = @_;
 411
 412   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 413       $field->table->name, create_field($field))
 414 }
 415
 416 sub alter_create_index {
 417   my ($index) = @_;
 418
 419   # This might cause name collisions
 420   return create_index($index);
 421 }
 422
 423 sub alter_create_constraint {
 424   my ($constraint) = @_;
 425
 426   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 427 }
 428
 429 sub alter_drop_constraint { alter_drop_index(@_) }
 430
 431 sub alter_drop_index {
 432   my ($constraint) = @_;
 433
 434   return sprintf("DROP INDEX %s",
 435       $constraint->name);
 436 }
 437
 438 sub batch_alter_table {
 439   my ($table, $diffs) = @_;
 440
 441   # If we have any of the following
 442   #
 443   #  rename_field
 444   #  alter_field
 445   #  drop_field
 446   #
 447   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 448   #
 449   # BEGIN TRANSACTION;
 450   # CREATE TEMPORARY TABLE t1_backup(a,b);
 451   # INSERT INTO t1_backup SELECT a,b FROM t1;
 452   # DROP TABLE t1;
 453   # CREATE TABLE t1(a,b);
 454   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 455   # DROP TABLE t1_backup;
 456   # COMMIT;
 457   #
 458   # Fun, eh?
 459   #
 460   # If we have rename_field we do similarly.
 461
 462   my $table_name = $table->name;
 463   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 464
 465   if ( @{$diffs->{rename_field}} == 0 &&
 466        @{$diffs->{alter_field}}  == 0 &&
 467        @{$diffs->{drop_field}}   == 0
 468        ) {
 469 #    return join("\n", map {
 470     return map {
 471         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 472         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 473
 474       } grep { @{$diffs->{$_}} }
 475     qw/rename_table
 476        alter_drop_constraint
 477        alter_drop_index
 478        drop_field
 479        add_field
 480        alter_field
 481        rename_field
 482        alter_create_index
 483        alter_create_constraint
 484        alter_table/;
 485   }
 486
 487
 488   my @sql;
 489   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 490
 491   do {
 492     local $table->{name} = $table_name . '_temp_alter';
 493     # We only want the table - dont care about indexes on tmp table
 494     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 495     push @sql,$table_sql;
 496   };
 497
 498   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 499              "DROP TABLE @{[$old_table]}",
 500              create_table($table, { no_comments => 1 }),
 501              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 502              "DROP TABLE @{[$table_name]}_temp_alter";
 503
 504   return @sql;
 505 #  return join("", @sql, "");
 506 }
 507
 508 sub drop_table {
 509   my ($table) = @_;
 510   return "DROP TABLE $table";
 511 }
 512
 513 sub rename_table {
 514   my ($old_table, $new_table, $options) = @_;
 515
 516   my $qt = $options->{quote_table_names} || '';
 517
 518   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 519
 520 }
 521
 522 # No-op. Just here to signify that we are a new style parser.
 523 sub preproces_schema { }
 524
 525 1;
 526
 527 =pod
 528
 529 =head1 SEE ALSO
 530
 531 SQL::Translator, http://www.sqlite.org/.
 532
 533 =head1 AUTHOR
 534
 535 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 536
 537 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 538
 539 =cut