lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment parse_dbms_version);
  43
  44 use vars qw[ $VERSION $DEBUG $WARN ];
  45
  46 $VERSION = '1.59';
  47 $DEBUG = 0 unless defined $DEBUG;
  48 $WARN = 0 unless defined $WARN;
  49
  50 our $max_id_length    = 30;
  51 my %global_names;
  52
  53 sub produce {
  54     my $translator     = shift;
  55     local $DEBUG       = $translator->debug;
  56     local $WARN        = $translator->show_warnings;
  57     my $no_comments    = $translator->no_comments;
  58     my $add_drop_table = $translator->add_drop_table;
  59     my $schema         = $translator->schema;
  60     my $producer_args  = $translator->producer_args;
  61     my $sqlite_version = parse_dbms_version(
  62         $producer_args->{sqlite_version}, 'perl'
  63     );
  64     my $no_txn         = $producer_args->{no_transaction};
  65
  66     debug("PKG: Beginning production\n");
  67
  68     %global_names = ();   #reset
  69
  70
  71     my $head = (header_comment() . "\n") unless $no_comments;
  72
  73     my @create = ();
  74
  75     push @create, "BEGIN TRANSACTION" unless $no_txn;
  76
  77     for my $table ( $schema->get_tables ) {
  78         push @create, create_table($table, { no_comments => $no_comments,
  79                                              sqlite_version => $sqlite_version,
  80                                           add_drop_table => $add_drop_table,});
  81     }
  82
  83     for my $view ( $schema->get_views ) {
  84       push @create, create_view($view, {
  85         add_drop_view => $add_drop_table,
  86         no_comments   => $no_comments,
  87       });
  88     }
  89
  90     for my $trigger ( $schema->get_triggers ) {
  91       push @create, create_trigger($trigger, {
  92         add_drop_trigger => $add_drop_table,
  93         no_comments   => $no_comments,
  94       });
  95     }
  96
  97     push @create, "COMMIT" unless $no_txn;
  98
  99     if (wantarray) {
 100       return ($head||(), @create);
 101     } else {
 102       return join ('',
 103         $head||(),
 104         join(";\n\n", @create ),
 105         ";\n",
 106       );
 107     }
 108 }
 109
 110 # -------------------------------------------------------------------
 111 sub mk_name {
 112     my ($name, $scope, $critical) = @_;
 113
 114     $scope ||= \%global_names;
 115     if ( my $prev = $scope->{ $name } ) {
 116         my $name_orig = $name;
 117         $name        .= sprintf( "%02d", ++$prev );
 118         substr($name, $max_id_length - 3) = "00"
 119             if length( $name ) > $max_id_length;
 120
 121         warn "The name '$name_orig' has been changed to ",
 122              "'$name' to make it unique.\n" if $WARN;
 123
 124         $scope->{ $name_orig }++;
 125     }
 126
 127     $scope->{ $name }++;
 128     return $name;
 129 }
 130
 131 sub create_view {
 132     my ($view, $options) = @_;
 133     my $add_drop_view = $options->{add_drop_view};
 134
 135     my $view_name = $view->name;
 136     debug("PKG: Looking at view '${view_name}'\n");
 137
 138     # Header.  Should this look like what mysqldump produces?
 139     my $extra = $view->extra;
 140     my $create = '';
 141     $create .= "--\n-- View: ${view_name}\n--\n" unless $options->{no_comments};
 142     $create .= "DROP VIEW IF EXISTS $view_name;\n" if $add_drop_view;
 143     $create .= 'CREATE';
 144     $create .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 145     $create .= ' VIEW';
 146     $create .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 147     $create .= " ${view_name}";
 148
 149     if( my $sql = $view->sql ){
 150       $create .= " AS\n    ${sql}";
 151     }
 152     return $create;
 153 }
 154
 155
 156 sub create_table
 157 {
 158     my ($table, $options) = @_;
 159
 160     my $table_name = $table->name;
 161     my $no_comments = $options->{no_comments};
 162     my $add_drop_table = $options->{add_drop_table};
 163     my $sqlite_version = $options->{sqlite_version} || 0;
 164
 165     debug("PKG: Looking at table '$table_name'\n");
 166
 167     my ( @index_defs, @constraint_defs );
 168     my @fields = $table->get_fields or die "No fields in $table_name";
 169
 170     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 171     #
 172     # Header.
 173     #
 174     my $exists = ($sqlite_version >= 3.003) ? ' IF EXISTS' : '';
 175     my @create;
 176     my ($comment, $create_table) = "";
 177     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 178     if ($add_drop_table) {
 179       push @create, $comment . qq[DROP TABLE$exists $table_name];
 180     } else {
 181       $create_table = $comment;
 182     }
 183
 184     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 185
 186     #
 187     # Comments
 188     #
 189     if ( $table->comments and !$no_comments ){
 190         $create_table .= "-- Comments: \n-- ";
 191         $create_table .= join "\n-- ",  $table->comments;
 192         $create_table .= "\n--\n\n";
 193     }
 194
 195     #
 196     # How many fields in PK?
 197     #
 198     my $pk        = $table->primary_key;
 199     my @pk_fields = $pk ? $pk->fields : ();
 200
 201     #
 202     # Fields
 203     #
 204     my ( @field_defs, $pk_set );
 205     for my $field ( @fields ) {
 206         push @field_defs, create_field($field);
 207     }
 208
 209     if (
 210          scalar @pk_fields > 1
 211          ||
 212          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 213          ) {
 214         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 215     }
 216
 217     #
 218     # Indices
 219     #
 220     my $idx_name_default = 'A';
 221     for my $index ( $table->get_indices ) {
 222         push @index_defs, create_index($index);
 223     }
 224
 225     #
 226     # Constraints
 227     #
 228     my $c_name_default = 'A';
 229     for my $c ( $table->get_constraints ) {
 230         next unless $c->type eq UNIQUE;
 231         push @constraint_defs, create_constraint($c);
 232     }
 233
 234     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 235
 236     return (@create, $create_table, @index_defs, @constraint_defs );
 237 }
 238
 239 sub create_field
 240 {
 241     my ($field, $options) = @_;
 242
 243     my $field_name = $field->name;
 244     debug("PKG: Looking at field '$field_name'\n");
 245     my $field_comments = $field->comments
 246         ? "-- " . $field->comments . "\n  "
 247         : '';
 248
 249     my $field_def = $field_comments.$field_name;
 250
 251     # data type and size
 252     my $size      = $field->size;
 253     my $data_type = $field->data_type;
 254     $data_type    = 'varchar' if lc $data_type eq 'set';
 255     $data_type  = 'blob' if lc $data_type eq 'bytea';
 256
 257     if ( lc $data_type =~ /(text|blob)/i ) {
 258         $size = undef;
 259     }
 260
 261 #             if ( $data_type =~ /timestamp/i ) {
 262 #                 push @trigger_defs,
 263 #                     "CREATE TRIGGER ts_${table_name} ".
 264 #                     "after insert on $table_name\n".
 265 #                     "begin\n".
 266 #                     "  update $table_name set $field_name=timestamp() ".
 267 #                        "where id=new.id;\n".
 268 #                     "end;\n"
 269 #                 ;
 270 #
 271 #            }
 272
 273     #
 274     # SQLite is generally typeless, but newer versions will
 275     # make a field autoincrement if it is declared as (and
 276     # *only* as) INTEGER PRIMARY KEY
 277     #
 278     my $pk        = $field->table->primary_key;
 279     my @pk_fields = $pk ? $pk->fields : ();
 280
 281     if (
 282          $field->is_primary_key &&
 283          scalar @pk_fields == 1 &&
 284          (
 285           $data_type =~ /int(eger)?$/i
 286           ||
 287           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 288           )
 289          ) {
 290         $data_type = 'INTEGER PRIMARY KEY';
 291         $size      = undef;
 292 #        $pk_set    = 1;
 293     }
 294
 295     $field_def .= sprintf " %s%s", $data_type,
 296     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 297
 298     # Null?
 299     $field_def .= ' NOT NULL' unless $field->is_nullable;
 300
 301     # Default?  XXX Need better quoting!
 302     my $default = $field->default_value;
 303     if (defined $default) {
 304         SQL::Translator::Producer->_apply_default_value(
 305             \$field_def,
 306             $default,
 307             [
 308              'NULL'              => \'NULL',
 309              'now()'             => 'now()',
 310              'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 311             ],
 312         );
 313     }
 314
 315     return $field_def;
 316
 317 }
 318
 319 sub create_index
 320 {
 321     my ($index, $options) = @_;
 322
 323     my $name   = $index->name;
 324     $name      = mk_name($name);
 325
 326     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 327
 328     # strip any field size qualifiers as SQLite doesn't like these
 329     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 330     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 331     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 332     my $index_def =
 333     "CREATE ${type}INDEX $name ON " . $index_table_name .
 334         ' (' . join( ', ', @fields ) . ')';
 335
 336     return $index_def;
 337 }
 338
 339 sub create_constraint
 340 {
 341     my ($c, $options) = @_;
 342
 343     my $name   = $c->name;
 344     $name      = mk_name($name);
 345     my @fields = $c->fields;
 346     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 347     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 348
 349     my $c_def =
 350     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 351         ' (' . join( ', ', @fields ) . ')';
 352
 353     return $c_def;
 354 }
 355
 356 sub create_trigger {
 357   my ($trigger, $options) = @_;
 358   my $add_drop = $options->{add_drop_trigger};
 359
 360   my @statements;
 361
 362   my $trigger_name = $trigger->name;
 363   my $events = $trigger->database_events;
 364   for my $evt ( @$events ) {
 365
 366     my $trig_name = $trigger_name;
 367     if (@$events > 1) {
 368       $trig_name .= "_$evt";
 369
 370       warn "Multiple database events supplied for trigger '$trigger_name', ",
 371         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 372     }
 373
 374     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 375
 376
 377     $DB::single = 1;
 378     my $action = "";
 379     if (not ref $trigger->action) {
 380       $action .= "BEGIN " . $trigger->action . " END";
 381     }
 382     else {
 383       $action = $trigger->action->{for_each} . " "
 384         if $trigger->action->{for_each};
 385
 386       $action = $trigger->action->{when} . " "
 387         if $trigger->action->{when};
 388
 389       my $steps = $trigger->action->{steps} || [];
 390
 391       $action .= "BEGIN ";
 392       $action .= $_ . "; " for (@$steps);
 393       $action .= "END";
 394     }
 395
 396     push @statements, sprintf (
 397       'CREATE TRIGGER %s %s %s on %s %s',
 398       $trig_name,
 399       $trigger->perform_action_when,
 400       $evt,
 401       $trigger->on_table,
 402       $action
 403     );
 404   }
 405
 406   return @statements;
 407 }
 408
 409 sub alter_table { } # Noop
 410
 411 sub add_field {
 412   my ($field) = @_;
 413
 414   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 415       $field->table->name, create_field($field))
 416 }
 417
 418 sub alter_create_index {
 419   my ($index) = @_;
 420
 421   # This might cause name collisions
 422   return create_index($index);
 423 }
 424
 425 sub alter_create_constraint {
 426   my ($constraint) = @_;
 427
 428   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 429 }
 430
 431 sub alter_drop_constraint { alter_drop_index(@_) }
 432
 433 sub alter_drop_index {
 434   my ($constraint) = @_;
 435
 436   return sprintf("DROP INDEX %s",
 437       $constraint->name);
 438 }
 439
 440 sub batch_alter_table {
 441   my ($table, $diffs) = @_;
 442
 443   # If we have any of the following
 444   #
 445   #  rename_field
 446   #  alter_field
 447   #  drop_field
 448   #
 449   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 450   #
 451   # BEGIN TRANSACTION;
 452   # CREATE TEMPORARY TABLE t1_backup(a,b);
 453   # INSERT INTO t1_backup SELECT a,b FROM t1;
 454   # DROP TABLE t1;
 455   # CREATE TABLE t1(a,b);
 456   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 457   # DROP TABLE t1_backup;
 458   # COMMIT;
 459   #
 460   # Fun, eh?
 461   #
 462   # If we have rename_field we do similarly.
 463
 464   my $table_name = $table->name;
 465   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 466
 467   if ( @{$diffs->{rename_field}} == 0 &&
 468        @{$diffs->{alter_field}}  == 0 &&
 469        @{$diffs->{drop_field}}   == 0
 470        ) {
 471 #    return join("\n", map {
 472     return map {
 473         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 474         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 475
 476       } grep { @{$diffs->{$_}} }
 477     qw/rename_table
 478        alter_drop_constraint
 479        alter_drop_index
 480        drop_field
 481        add_field
 482        alter_field
 483        rename_field
 484        alter_create_index
 485        alter_create_constraint
 486        alter_table/;
 487   }
 488
 489
 490   my @sql;
 491   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 492
 493   do {
 494     local $table->{name} = $table_name . '_temp_alter';
 495     # We only want the table - dont care about indexes on tmp table
 496     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 497     push @sql,$table_sql;
 498   };
 499
 500   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 501              "DROP TABLE @{[$old_table]}",
 502              create_table($table, { no_comments => 1 }),
 503              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 504              "DROP TABLE @{[$table_name]}_temp_alter";
 505
 506   return @sql;
 507 #  return join("", @sql, "");
 508 }
 509
 510 sub drop_table {
 511   my ($table) = @_;
 512   return "DROP TABLE $table";
 513 }
 514
 515 sub rename_table {
 516   my ($old_table, $new_table, $options) = @_;
 517
 518   my $qt = $options->{quote_table_names} || '';
 519
 520   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 521
 522 }
 523
 524 # No-op. Just here to signify that we are a new style parser.
 525 sub preproces_schema { }
 526
 527 1;
 528
 529 =pod
 530
 531 =head1 SEE ALSO
 532
 533 SQL::Translator, http://www.sqlite.org/.
 534
 535 =head1 AUTHOR
 536
 537 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 538
 539 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 540
 541 =cut