lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: SQLite.pm,v 1.15 2006-08-26 11:35:31 schiffbruechige Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator;
  30
  31   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  32   $t->translate;
  33
  34 =head1 DESCRIPTION
  35
  36 This module will produce text output of the schema suitable for SQLite.
  37
  38 =cut
  39
  40 use strict;
  41 use Data::Dumper;
  42 use SQL::Translator::Schema::Constants;
  43 use SQL::Translator::Utils qw(debug header_comment);
  44
  45 use vars qw[ $VERSION $DEBUG $WARN ];
  46
  47 $VERSION = sprintf "%d.%02d", q$Revision: 1.15 $ =~ /(\d+)\.(\d+)/;
  48 $DEBUG = 0 unless defined $DEBUG;
  49 $WARN = 0 unless defined $WARN;
  50
  51 my %used_identifiers = ();
  52 my $max_id_length    = 30;
  53 my %global_names;
  54 my %truncated;
  55
  56 sub produce {
  57     my $translator     = shift;
  58     local $DEBUG       = $translator->debug;
  59     local $WARN        = $translator->show_warnings;
  60     my $no_comments    = $translator->no_comments;
  61     my $add_drop_table = $translator->add_drop_table;
  62     my $schema         = $translator->schema;
  63
  64     debug("PKG: Beginning production\n");
  65
  66     my @create = ();
  67     push @create, header_comment unless ($no_comments);
  68     push @create, 'BEGIN TRANSACTION';
  69
  70     for my $table ( $schema->get_tables ) {
  71         push @create, create_table($table, { no_comments => $no_comments,
  72                                           add_drop_table => $add_drop_table,});
  73     }
  74
  75     for my $view ( $schema->get_views ) {
  76       push @create, create_view($view, {
  77         add_drop_view => $add_drop_table,
  78         no_comments   => $no_comments,
  79       });
  80     }
  81
  82     return wantarray ? (@create, "COMMIT") : join(";\n\n", (@create, "COMMIT;\n"));
  83 }
  84
  85 # -------------------------------------------------------------------
  86 sub mk_name {
  87     my ($basename, $type, $scope, $critical) = @_;
  88     my $basename_orig = $basename;
  89     my $max_name      = $type
  90                         ? $max_id_length - (length($type) + 1)
  91                         : $max_id_length;
  92     $basename         = substr( $basename, 0, $max_name )
  93                         if length( $basename ) > $max_name;
  94     $basename         =~ s/\./_/g;
  95     my $name          = $type ? "${type}_$basename" : $basename;
  96
  97     if ( $basename ne $basename_orig and $critical ) {
  98         my $show_type = $type ? "+'$type'" : "";
  99         warn "Truncating '$basename_orig'$show_type to $max_id_length ",
 100             "character limit to make '$name'\n" if $WARN;
 101         $truncated{ $basename_orig } = $name;
 102     }
 103
 104     $scope ||= \%global_names;
 105     if ( my $prev = $scope->{ $name } ) {
 106         my $name_orig = $name;
 107         $name        .= sprintf( "%02d", ++$prev );
 108         substr($name, $max_id_length - 3) = "00"
 109             if length( $name ) > $max_id_length;
 110
 111         warn "The name '$name_orig' has been changed to ",
 112              "'$name' to make it unique.\n" if $WARN;
 113
 114         $scope->{ $name_orig }++;
 115     }
 116
 117     $scope->{ $name }++;
 118     return $name;
 119 }
 120
 121 sub create_view {
 122     my ($view, $options) = @_;
 123     my $add_drop_view = $options->{add_drop_view};
 124
 125     my $view_name = $view->name;
 126     debug("PKG: Looking at view '${view_name}'\n");
 127
 128     # Header.  Should this look like what mysqldump produces?
 129     my $extra = $view->extra;
 130     my $create = '';
 131     $create .= "--\n-- View: ${view_name}\n--\n" unless $options->{no_comments};
 132     $create .= "DROP VIEW IF EXISTS $view_name;\n" if $add_drop_view;
 133     $create .= 'CREATE';
 134     $create .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 135     $create .= ' VIEW';
 136     $create .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 137     $create .= " ${view_name}";
 138
 139     if( my $sql = $view->sql ){
 140       $create .= " AS\n    ${sql}";
 141     }
 142     return $create;
 143 }
 144
 145
 146 sub create_table
 147 {
 148     my ($table, $options) = @_;
 149
 150     my $table_name = $table->name;
 151     my $no_comments = $options->{no_comments};
 152     my $add_drop_table = $options->{add_drop_table};
 153
 154     debug("PKG: Looking at table '$table_name'\n");
 155
 156     my ( @index_defs, @constraint_defs, @trigger_defs );
 157     my @fields = $table->get_fields or die "No fields in $table_name";
 158
 159     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 160     #
 161     # Header.
 162     #
 163     my @create;
 164     push @create, "--\n-- Table: $table_name\n--\n" unless $no_comments;
 165     push @create, qq[DROP TABLE $table_name] if $add_drop_table;
 166     my $create_table = "CREATE ${temp}TABLE $table_name (\n";
 167
 168     #
 169     # Comments
 170     #
 171     if ( $table->comments and !$no_comments ){
 172         $create_table .= "-- Comments: \n-- ";
 173         $create_table .= join "\n-- ",  $table->comments;
 174         $create_table .= "\n--\n\n";
 175     }
 176
 177     #
 178     # How many fields in PK?
 179     #
 180     my $pk        = $table->primary_key;
 181     my @pk_fields = $pk ? $pk->fields : ();
 182
 183     #
 184     # Fields
 185     #
 186     my ( @field_defs, $pk_set );
 187     for my $field ( @fields ) {
 188         push @field_defs, create_field($field);
 189     }
 190
 191     if (
 192          scalar @pk_fields > 1
 193          ||
 194          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 195          ) {
 196         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 197     }
 198
 199     #
 200     # Indices
 201     #
 202     my $idx_name_default = 'A';
 203     for my $index ( $table->get_indices ) {
 204         push @index_defs, create_index($index);
 205     }
 206
 207     #
 208     # Constraints
 209     #
 210     my $c_name_default = 'A';
 211     for my $c ( $table->get_constraints ) {
 212         next unless $c->type eq UNIQUE;
 213         push @constraint_defs, create_constraint($c);
 214     }
 215
 216     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 217
 218     return (@create, $create_table, @index_defs, @constraint_defs, @trigger_defs );
 219 }
 220
 221 sub create_field
 222 {
 223     my ($field, $options) = @_;
 224
 225     my $field_name = $field->name;
 226     debug("PKG: Looking at field '$field_name'\n");
 227     my $field_comments = $field->comments
 228         ? "-- " . $field->comments . "\n  "
 229         : '';
 230
 231     my $field_def = $field_comments.$field_name;
 232
 233     # data type and size
 234     my $size      = $field->size;
 235     my $data_type = $field->data_type;
 236     $data_type    = 'varchar' if lc $data_type eq 'set';
 237     $data_type  = 'blob' if lc $data_type eq 'bytea';
 238
 239     if ( lc $data_type =~ /(text|blob)/i ) {
 240         $size = undef;
 241     }
 242
 243 #             if ( $data_type =~ /timestamp/i ) {
 244 #                 push @trigger_defs,
 245 #                     "CREATE TRIGGER ts_${table_name} ".
 246 #                     "after insert on $table_name\n".
 247 #                     "begin\n".
 248 #                     "  update $table_name set $field_name=timestamp() ".
 249 #                        "where id=new.id;\n".
 250 #                     "end;\n"
 251 #                 ;
 252 #
 253 #            }
 254
 255     #
 256     # SQLite is generally typeless, but newer versions will
 257     # make a field autoincrement if it is declared as (and
 258     # *only* as) INTEGER PRIMARY KEY
 259     #
 260     my $pk        = $field->table->primary_key;
 261     my @pk_fields = $pk ? $pk->fields : ();
 262
 263     if (
 264          $field->is_primary_key &&
 265          scalar @pk_fields == 1 &&
 266          (
 267           $data_type =~ /int(eger)?$/i
 268           ||
 269           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 270           )
 271          ) {
 272         $data_type = 'INTEGER PRIMARY KEY';
 273         $size      = undef;
 274 #        $pk_set    = 1;
 275     }
 276
 277     $field_def .= sprintf " %s%s", $data_type,
 278     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 279
 280     # Null?
 281     $field_def .= ' NOT NULL' unless $field->is_nullable;
 282
 283     # Default?  XXX Need better quoting!
 284     my $default = $field->default_value;
 285     if ( defined $default ) {
 286         if ( uc $default eq 'NULL') {
 287             $field_def .= ' DEFAULT NULL';
 288         } elsif ( $default eq 'now()' ||
 289                   $default eq 'CURRENT_TIMESTAMP' ) {
 290             $field_def .= ' DEFAULT CURRENT_TIMESTAMP';
 291         } elsif ( $default =~ /val\(/ ) {
 292             next;
 293         } else {
 294             $field_def .= " DEFAULT '$default'";
 295         }
 296     }
 297
 298     return $field_def;
 299
 300 }
 301
 302 sub create_index
 303 {
 304     my ($index, $options) = @_;
 305
 306     my $name   = $index->name;
 307     $name      = mk_name($index->table->name, $name);
 308
 309     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 310
 311     # strip any field size qualifiers as SQLite doesn't like these
 312     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 313     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 314     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 315     my $index_def =
 316     "CREATE ${type}INDEX $name ON " . $index_table_name .
 317         ' (' . join( ', ', @fields ) . ')';
 318
 319     return $index_def;
 320 }
 321
 322 sub create_constraint
 323 {
 324     my ($c, $options) = @_;
 325
 326     my $name   = $c->name;
 327     $name      = mk_name($c->table->name, $name);
 328     my @fields = $c->fields;
 329     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 330     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 331
 332     my $c_def =
 333     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 334         ' (' . join( ', ', @fields ) . ')';
 335
 336     return $c_def;
 337 }
 338
 339 sub alter_table { } # Noop
 340
 341 sub add_field {
 342   my ($field) = @_;
 343
 344   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 345       $field->table->name, create_field($field))
 346 }
 347
 348 sub alter_create_index {
 349   my ($index) = @_;
 350
 351   # This might cause name collisions
 352   return create_index($index);
 353 }
 354
 355 sub alter_create_constraint {
 356   my ($constraint) = @_;
 357
 358   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 359 }
 360
 361 sub alter_drop_constraint { alter_drop_index(@_) }
 362
 363 sub alter_drop_index {
 364   my ($constraint) = @_;
 365
 366   return sprintf("DROP INDEX %s",
 367       $constraint->name);
 368 }
 369
 370 sub batch_alter_table {
 371   my ($table, $diffs) = @_;
 372
 373   # If we have any of the following
 374   #
 375   #  rename_field
 376   #  alter_field
 377   #  drop_field
 378   #
 379   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 380   #
 381   # BEGIN TRANSACTION;
 382   # CREATE TEMPORARY TABLE t1_backup(a,b);
 383   # INSERT INTO t1_backup SELECT a,b FROM t1;
 384   # DROP TABLE t1;
 385   # CREATE TABLE t1(a,b);
 386   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 387   # DROP TABLE t1_backup;
 388   # COMMIT;
 389   #
 390   # Fun, eh?
 391   #
 392   # If we have rename_field we do similarly.
 393
 394   my $table_name = $table->name;
 395   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 396
 397   if ( @{$diffs->{rename_field}} == 0 &&
 398        @{$diffs->{alter_field}}  == 0 &&
 399        @{$diffs->{drop_field}}   == 0
 400        ) {
 401 #    return join("\n", map {
 402     return map {
 403         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 404         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 405
 406       } grep { @{$diffs->{$_}} }
 407     qw/rename_table
 408        alter_drop_constraint
 409        alter_drop_index
 410        drop_field
 411        add_field
 412        alter_field
 413        rename_field
 414        alter_create_index
 415        alter_create_constraint
 416        alter_table/;
 417   }
 418
 419
 420   my @sql;
 421   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 422
 423   do {
 424     local $table->{name} = $table_name . '_temp_alter';
 425     # We only want the table - dont care about indexes on tmp table
 426     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 427     push @sql,$table_sql;
 428   };
 429
 430   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 431              "DROP TABLE @{[$old_table]}",
 432              create_table($table, { no_comments => 1 }),
 433              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 434              "DROP TABLE @{[$table_name]}_temp_alter";
 435
 436   return @sql;
 437 #  return join("", @sql, "");
 438 }
 439
 440 sub drop_table {
 441   my ($table) = @_;
 442   return "DROP TABLE $table";
 443 }
 444
 445 sub rename_table {
 446   my ($old_table, $new_table, $options) = @_;
 447
 448   my $qt = $options->{quote_table_names} || '';
 449
 450   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 451
 452 }
 453
 454 # No-op. Just here to signify that we are a new style parser.
 455 sub preproces_schema { }
 456
 457 1;
 458
 459 =pod
 460
 461 =head1 SEE ALSO
 462
 463 SQL::Translator, http://www.sqlite.org/.
 464
 465 =head1 AUTHOR
 466
 467 Ken Y. Clark C<< <kclark@cpan.orgE> >>.
 468
 469 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 470
 471 =cut