lib/SQL/Translator/Producer/MySQL.pm

   1 package SQL::Translator::Producer::MySQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: MySQL.pm,v 1.7 2003-02-26 05:17:49 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>,
   7 #                    darren chamberlain <darren@cpan.org>,
   8 #                    Chris Mungall <cjm@fruitfly.org>
   9 #
  10 # This program is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU General Public License as
  12 # published by the Free Software Foundation; version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  22 # 02111-1307  USA
  23 # -------------------------------------------------------------------
  24
  25 use strict;
  26 use vars qw[ $VERSION $DEBUG ];
  27 $VERSION = sprintf "%d.%02d", q$Revision: 1.7 $ =~ /(\d+)\.(\d+)/;
  28 $DEBUG   = 1 unless defined $DEBUG;
  29
  30 use Data::Dumper;
  31
  32 sub import {
  33     warn "loading " . __PACKAGE__ . "...\n";
  34 }
  35
  36 sub produce {
  37     my ($translator, $data) = @_;
  38     $DEBUG                  = $translator->debug;
  39     my $no_comments         = $translator->no_comments;
  40
  41     debug("Beginning production\n");
  42
  43     my $create;
  44     unless ( $no_comments ) {
  45         $create .= sprintf "--\n-- Created by %s\n-- Created on %s\n--\n\n",
  46             __PACKAGE__, scalar localtime;
  47     }
  48
  49     for my $table (keys %{$data}) {
  50         debug("Looking at table '$table'\n");
  51         my $table_data = $data->{$table};
  52         my @fields = sort {
  53             $table_data->{'fields'}->{$a}->{'order'}
  54             <=>
  55             $table_data->{'fields'}->{$b}->{'order'}
  56         } keys %{$table_data->{'fields'}};
  57
  58         #
  59         # Header.  Should this look like what mysqldump produces?
  60         #
  61         $create .= "--\n-- Table: $table\n--\n" unless $no_comments;
  62         $create .= "CREATE TABLE $table (";
  63
  64         #
  65         # Fields
  66         #
  67         for (my $i = 0; $i <= $#fields; $i++) {
  68             my $field = $fields[$i];
  69             debug("Looking at field '$field'\n");
  70             my $field_data = $table_data->{'fields'}->{$field};
  71             my @fdata = ("", $field);
  72             $create .= "\n";
  73
  74             # data type and size
  75             my $attr = uc $field_data->{'data_type'} eq 'SET' ? 'list' : 'size';
  76             my @values = @{ $field_data->{ $attr } || [] };
  77             push @fdata, sprintf "%s%s",
  78                 $field_data->{'data_type'},
  79                 ( @values )
  80                     ? '('.join(', ', @values).')'
  81                     : '';
  82
  83             # MySQL qualifiers
  84             for my $qual ( qw[ binary unsigned zerofill ] ) {
  85                 push @fdata, $qual
  86                     if $field_data->{ $qual } ||
  87                        $field_data->{ uc $qual };
  88             }
  89
  90             # Null?
  91             push @fdata, "NOT NULL" unless $field_data->{'null'};
  92
  93             # Default?  XXX Need better quoting!
  94             my $default = $field_data->{'default'};
  95             if ( defined $default ) {
  96                 if ( uc $default eq 'NULL') {
  97                     push @fdata, "DEFAULT NULL";
  98                 } else {
  99                     push @fdata, "DEFAULT '$default'";
 100                 }
 101             }
 102
 103             # auto_increment?
 104             push @fdata, "auto_increment" if $field_data->{'is_auto_inc'};
 105
 106             # primary key?
 107             # This is taken care of in the indices, could be duplicated here
 108             # push @fdata, "PRIMARY KEY" if $field_data->{'is_primary_key'};
 109
 110
 111             $create .= (join " ", '', @fdata);
 112             $create .= "," unless ($i == $#fields);
 113         }
 114
 115         #
 116         # Indices
 117         #
 118         my @index_creates;
 119         my @indices = @{ $table_data->{'indices'} || [] };
 120         for (my $i = 0; $i <= $#indices; $i++) {
 121             my $key  = $indices[$i];
 122             my ($name, $type, $fields) = @{ $key }{ qw[ name type fields ] };
 123             $name ||= '';
 124             my $index_type =
 125                 $type eq 'primary_key' ? 'PRIMARY KEY' :
 126                 $type eq 'unique'      ? 'UNIQUE KEY'  : 'KEY';
 127             push @index_creates,
 128                 "  $index_type $name (" . join( ', ', @$fields ) . ')';
 129         }
 130
 131         if ( @index_creates ) {
 132             $create .= join(",\n", '', @index_creates);
 133         }
 134
 135         #
 136         # Constraints -- need to handle more than just FK. -ky
 137         #
 138         my @constraints;
 139         for my $constraint ( @{ $table_data->{'constraints'} } ) {
 140             my $name       = $constraint->{'name'} || '';
 141             my $type       = $constraint->{'type'};
 142             my $fields     = $constraint->{'fields'};
 143             my $ref_table  = $constraint->{'reference_table'};
 144             my $ref_fields = $constraint->{'reference_fields'};
 145             my $match_type = $constraint->{'match_type'} || '';
 146             my $on_delete  = $constraint->{'on_delete_do'};
 147             my $on_update  = $constraint->{'on_update_do'};
 148
 149             if ( $type eq 'foreign_key' ) {
 150                 my $def = join(' ', map { $_ || () } '  FOREIGN KEY', $name );
 151                 if ( @$fields ) {
 152                     $def .= ' (' . join( ', ', @$fields ) . ')';
 153                 }
 154                 $def .= " REFERENCES $ref_table";
 155
 156                 if ( @$ref_fields ) {
 157                     $def .= ' (' . join( ', ', @$ref_fields ) . ')';
 158                 }
 159
 160                 if ( $match_type ) {
 161                     $def .= ' MATCH ' .
 162                         ( $match_type =~ /full/i ) ? 'FULL' : 'PARTIAL';
 163                 }
 164
 165                 if ( @{ $on_delete || [] } ) {
 166                     $def .= ' ON DELETE '.join(' ', @$on_delete);
 167                 }
 168
 169                 if ( @{ $on_update || [] } ) {
 170                     $def .= ' ON UPDATE '.join(' ', @$on_update);
 171                 }
 172
 173                 push @constraints, $def;
 174             }
 175         }
 176
 177         $create .= join(",\n", '', @constraints) if @constraints;
 178
 179         #
 180         # Footer
 181         #
 182         $create .= "\n)";
 183         while ( my ( $key, $val ) = each %{ $table_data->{'table_options'} } ) {
 184             $create .= " $key=$val"
 185         }
 186         $create .= ";\n\n";
 187     }
 188
 189     return $create;
 190 }
 191
 192 sub debug {
 193     if ($DEBUG) {
 194         map { warn "[" . __PACKAGE__ . "] $_" } @_;
 195     }
 196 }
 197
 198 1;
 199 __END__
 200
 201 =head1 NAME
 202
 203 SQL::Translator::Producer::MySQL - mysql-specific producer for SQL::Translator
 204
 205 =head1 AUTHOR
 206
 207 darren chamberlain E<lt>darren@cpan.orgE<gt>