lib/SQL/Translator/Producer/MySQL.pm

   1 package SQL::Translator::Producer::MySQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: MySQL.pm,v 1.24 2003-08-16 15:56:58 rossta Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>,
   7 #                    darren chamberlain <darren@cpan.org>,
   8 #                    Chris Mungall <cjm@fruitfly.org>
   9 #
  10 # This program is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU General Public License as
  12 # published by the Free Software Foundation; version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  22 # 02111-1307  USA
  23 # -------------------------------------------------------------------
  24
  25 use strict;
  26 use vars qw[ $VERSION $DEBUG ];
  27 $VERSION = sprintf "%d.%02d", q$Revision: 1.24 $ =~ /(\d+)\.(\d+)/;
  28 $DEBUG   = 0 unless defined $DEBUG;
  29
  30 use Data::Dumper;
  31 use SQL::Translator::Schema::Constants;
  32 use SQL::Translator::Utils qw(debug header_comment);
  33
  34 my %translate  = (
  35     #
  36     # Oracle types
  37     #
  38     varchar2   => 'varchar',
  39     long       => 'text',
  40     CLOB       => 'longtext',
  41
  42     #
  43     # Sybase types
  44     #
  45     int        => 'integer',
  46     money      => 'float',
  47     real       => 'double',
  48     comment    => 'text',
  49     bit        => 'tinyint',
  50 );
  51
  52 sub produce {
  53     my $translator     = shift;
  54     local $DEBUG       = $translator->debug;
  55     my $no_comments    = $translator->no_comments;
  56     my $add_drop_table = $translator->add_drop_table;
  57     my $schema         = $translator->schema;
  58
  59     debug("PKG: Beginning production\n");
  60
  61     my $create;
  62     $create .= header_comment unless ($no_comments);
  63     $create .= "SET foreign_key_checks=0;\n\n";
  64
  65     for my $table ( $schema->get_tables ) {
  66         my $table_name = $table->name;
  67         debug("PKG: Looking at table '$table_name'\n");
  68
  69         #
  70         # Header.  Should this look like what mysqldump produces?
  71         #
  72         $create .= "--\n-- Table: $table_name\n--\n" unless $no_comments;
  73         $create .= qq[DROP TABLE IF EXISTS $table_name;\n] if $add_drop_table;
  74         $create .= "CREATE TABLE $table_name (\n";
  75
  76         #
  77         # Fields
  78         #
  79         my @field_defs;
  80         for my $field ( $table->get_fields ) {
  81             my $field_name = $field->name;
  82             debug("PKG: Looking at field '$field_name'\n");
  83             my $field_def = $field_name;
  84
  85             # data type and size
  86             my $data_type = $field->data_type;
  87             my @size      = $field->size;
  88             my %extra     = $field->extra;
  89             my $list      = $extra{'list'} || [];
  90             my $commalist = "'" . join("','", @$list) . "'"; # \todo deal with embedded quotes
  91
  92             #
  93             # Oracle "number" type -- figure best MySQL type
  94             #
  95             if ( lc $data_type eq 'number' ) {
  96                 # not an integer
  97                 if ( scalar @size > 1 ) {
  98                     $data_type = 'double';
  99                 }
 100                 elsif ( $size[0] >= 12 ) {
 101                     $data_type = 'bigint';
 102                 }
 103                 elsif ( $size[0] <= 1 ) {
 104                     $data_type = 'tinyint';
 105                 }
 106                 else {
 107                     $data_type = 'int';
 108                 }
 109             }
 110             elsif ( exists $translate{ $data_type } ) {
 111                 $data_type = $translate{ $data_type };
 112             }
 113
 114             $field_def .= " $data_type";
 115
 116             if ( lc $data_type eq 'enum' ) {
 117                 $field_def .= '(' . $commalist . ')';
 118                         } elsif ( defined $size[0] && $size[0] > 0 ) {
 119                 $field_def .= '(' . join( ', ', @size ) . ')';
 120             }
 121
 122             # MySQL qualifiers
 123             for my $qual ( qw[ binary unsigned zerofill ] ) {
 124                 my $val = $extra{ $qual || uc $qual } or next;
 125                 $field_def .= " $val";
 126             }
 127
 128             # Null?
 129             $field_def .= ' NOT NULL' unless $field->is_nullable;
 130
 131             # Default?  XXX Need better quoting!
 132             my $default = $field->default_value;
 133             if ( defined $default ) {
 134                 if ( uc $default eq 'NULL') {
 135                     $field_def .= ' DEFAULT NULL';
 136                 } else {
 137                     $field_def .= " DEFAULT '$default'";
 138                 }
 139             }
 140
 141             # auto_increment?
 142             $field_def .= " auto_increment" if $field->is_auto_increment;
 143             push @field_defs, $field_def;
 144                 }
 145
 146         #
 147         # Indices
 148         #
 149         my @index_defs;
 150         for my $index ( $table->get_indices ) {
 151             push @index_defs, join( ' ',
 152                 lc $index->type eq 'normal' ? 'INDEX' : $index->type,
 153                 $index->name,
 154                 '(' . join( ', ', $index->fields ) . ')'
 155             );
 156         }
 157
 158         #
 159         # Constraints -- need to handle more than just FK. -ky
 160         #
 161         my @constraint_defs;
 162         for my $c ( $table->get_constraints ) {
 163             my @fields = $c->fields or next;
 164
 165             if ( $c->type eq PRIMARY_KEY ) {
 166                 push @constraint_defs,
 167                     'PRIMARY KEY (' . join(', ', @fields). ')';
 168             }
 169             elsif ( $c->type eq UNIQUE ) {
 170                 push @constraint_defs,
 171                     'UNIQUE (' . join(', ', @fields). ')';
 172             }
 173             elsif ( $c->type eq FOREIGN_KEY ) {
 174                 my $def = join(' ',
 175                     map { $_ || () } 'FOREIGN KEY', $c->name
 176                 );
 177
 178                 $def .= ' (' . join( ', ', @fields ) . ')';
 179
 180                 $def .= ' REFERENCES ' . $c->reference_table;
 181
 182                 if ( my @rfields = $c->reference_fields ) {
 183                     $def .= ' (' . join( ', ', @rfields ) . ')';
 184                 }
 185
 186                 if ( $c->match_type ) {
 187                     $def .= ' MATCH ' .
 188                         ( $c->match_type =~ /full/i ) ? 'FULL' : 'PARTIAL';
 189                 }
 190
 191                 if ( $c->on_delete ) {
 192                     $def .= ' ON DELETE '.join( ' ', $c->on_delete );
 193                 }
 194
 195                 if ( $c->on_update ) {
 196                     $def .= ' ON UPDATE '.join( ' ', $c->on_update );
 197                 }
 198
 199                 push @constraint_defs, $def;
 200             }
 201         }
 202
 203         $create .= join(",\n", map { "  $_" }
 204             @field_defs, @index_defs, @constraint_defs
 205         );
 206
 207         #
 208         # Footer
 209         #
 210         $create .= "\n)";
 211 #        while (
 212 #            my ( $key, $val ) = each %{ $table->options }
 213 #        ) {
 214 #            $create .= " $key=$val"
 215 #        }
 216         $create .= ";\n\n";
 217     }
 218
 219     return $create;
 220 }
 221
 222 1;
 223 __END__
 224
 225 =head1 NAME
 226
 227 SQL::Translator::Producer::MySQL - MySQL-specific producer for SQL::Translator
 228
 229 =head1 AUTHORS
 230
 231 darren chamberlain E<lt>darren@cpan.orgE<gt>,
 232 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>