lib/SQL/Translator/Producer/MySQL.pm

   1 package SQL::Translator::Producer::MySQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: MySQL.pm,v 1.9 2003-03-12 14:17:11 dlc Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>,
   7 #                    darren chamberlain <darren@cpan.org>,
   8 #                    Chris Mungall <cjm@fruitfly.org>
   9 #
  10 # This program is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU General Public License as
  12 # published by the Free Software Foundation; version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  22 # 02111-1307  USA
  23 # -------------------------------------------------------------------
  24
  25 use strict;
  26 use vars qw[ $VERSION $DEBUG ];
  27 $VERSION = sprintf "%d.%02d", q$Revision: 1.9 $ =~ /(\d+)\.(\d+)/;
  28 $DEBUG   = 1 unless defined $DEBUG;
  29
  30 use Data::Dumper;
  31 use SQL::Translator::Utils qw(debug);
  32
  33 sub import {
  34     warn "loading " . __PACKAGE__ . "...\n";
  35 }
  36
  37 sub produce {
  38     my ($translator, $data) = @_;
  39     $DEBUG                  = $translator->debug;
  40     my $no_comments         = $translator->no_comments;
  41     my $add_drop_table      = $translator->add_drop_table;
  42
  43     debug("PKG: Beginning production\n");
  44
  45     my $create;
  46     unless ( $no_comments ) {
  47         $create .= sprintf "--\n-- Created by %s\n-- Created on %s\n--\n\n",
  48             __PACKAGE__, scalar localtime;
  49     }
  50
  51     for my $table ( keys %{ $data } ) {
  52         debug("PKG: Looking at table '$table'\n");
  53         my $table_data = $data->{$table};
  54         my @fields = sort {
  55             $table_data->{'fields'}->{$a}->{'order'}
  56             <=>
  57             $table_data->{'fields'}->{$b}->{'order'}
  58         } keys %{$table_data->{'fields'}};
  59
  60         #
  61         # Header.  Should this look like what mysqldump produces?
  62         #
  63         $create .= "--\n-- Table: $table\n--\n" unless $no_comments;
  64         $create .= qq[DROP TABLE $table;\n] if $add_drop_table;
  65         $create .= "CREATE TABLE $table (";
  66
  67         #
  68         # Fields
  69         #
  70         for (my $i = 0; $i <= $#fields; $i++) {
  71             my $field = $fields[$i];
  72             debug("PKG: Looking at field '$field'\n");
  73             my $field_data = $table_data->{'fields'}->{$field};
  74             my @fdata = ("", $field);
  75             $create .= "\n";
  76
  77             # data type and size
  78             my $attr = uc $field_data->{'data_type'} eq 'SET' ? 'list' : 'size';
  79             my @values = @{ $field_data->{ $attr } || [] };
  80             push @fdata, sprintf "%s%s",
  81                 $field_data->{'data_type'},
  82                 ( @values )
  83                     ? '('.join(', ', @values).')'
  84                     : '';
  85
  86             # MySQL qualifiers
  87             for my $qual ( qw[ binary unsigned zerofill ] ) {
  88                 push @fdata, $qual
  89                     if $field_data->{ $qual } ||
  90                        $field_data->{ uc $qual };
  91             }
  92
  93             # Null?
  94             push @fdata, "NOT NULL" unless $field_data->{'null'};
  95
  96             # Default?  XXX Need better quoting!
  97             my $default = $field_data->{'default'};
  98             if ( defined $default ) {
  99                 if ( uc $default eq 'NULL') {
 100                     push @fdata, "DEFAULT NULL";
 101                 } else {
 102                     push @fdata, "DEFAULT '$default'";
 103                 }
 104             }
 105
 106             # auto_increment?
 107             push @fdata, "auto_increment" if $field_data->{'is_auto_inc'};
 108
 109             # primary key?
 110             # This is taken care of in the indices, could be duplicated here
 111             # push @fdata, "PRIMARY KEY" if $field_data->{'is_primary_key'};
 112
 113
 114             $create .= (join " ", '', @fdata);
 115             $create .= "," unless ($i == $#fields);
 116         }
 117
 118         #
 119         # Indices
 120         #
 121         my @index_creates;
 122         my @indices = @{ $table_data->{'indices'} || [] };
 123         for (my $i = 0; $i <= $#indices; $i++) {
 124             my $key  = $indices[$i];
 125             my ($name, $type, $fields) = @{ $key }{ qw[ name type fields ] };
 126             $name ||= '';
 127             my $index_type =
 128                 $type eq 'primary_key' ? 'PRIMARY KEY' :
 129                 $type eq 'unique'      ? 'UNIQUE KEY'  : 'KEY';
 130             push @index_creates,
 131                 "  $index_type $name (" . join( ', ', @$fields ) . ')';
 132         }
 133
 134         if ( @index_creates ) {
 135             $create .= join(",\n", '', @index_creates);
 136         }
 137
 138         #
 139         # Constraints -- need to handle more than just FK. -ky
 140         #
 141         my @constraints;
 142         for my $constraint ( @{ $table_data->{'constraints'} } ) {
 143             my $name       = $constraint->{'name'} || '';
 144             my $type       = $constraint->{'type'};
 145             my $fields     = $constraint->{'fields'};
 146             my $ref_table  = $constraint->{'reference_table'};
 147             my $ref_fields = $constraint->{'reference_fields'};
 148             my $match_type = $constraint->{'match_type'} || '';
 149             my $on_delete  = $constraint->{'on_delete_do'};
 150             my $on_update  = $constraint->{'on_update_do'};
 151
 152             if ( $type eq 'foreign_key' ) {
 153                 my $def = join(' ', map { $_ || () } '  FOREIGN KEY', $name );
 154                 if ( @$fields ) {
 155                     $def .= ' (' . join( ', ', @$fields ) . ')';
 156                 }
 157                 $def .= " REFERENCES $ref_table";
 158
 159                 if ( @$ref_fields ) {
 160                     $def .= ' (' . join( ', ', @$ref_fields ) . ')';
 161                 }
 162
 163                 if ( $match_type ) {
 164                     $def .= ' MATCH ' .
 165                         ( $match_type =~ /full/i ) ? 'FULL' : 'PARTIAL';
 166                 }
 167
 168                 if ( @{ $on_delete || [] } ) {
 169                     $def .= ' ON DELETE '.join(' ', @$on_delete);
 170                 }
 171
 172                 if ( @{ $on_update || [] } ) {
 173                     $def .= ' ON UPDATE '.join(' ', @$on_update);
 174                 }
 175
 176                 push @constraints, $def;
 177             }
 178         }
 179
 180         $create .= join(",\n", '', @constraints) if @constraints;
 181
 182         #
 183         # Footer
 184         #
 185         $create .= "\n)";
 186         while ( my ( $key, $val ) = each %{ $table_data->{'table_options'} } ) {
 187             $create .= " $key=$val"
 188         }
 189         $create .= ";\n\n";
 190     }
 191
 192     return $create;
 193 }
 194
 195 1;
 196 __END__
 197
 198 =head1 NAME
 199
 200 SQL::Translator::Producer::MySQL - MySQL-specific producer for SQL::Translator
 201
 202 =head1 AUTHOR
 203
 204 darren chamberlain E<lt>darren@cpan.orgE<gt>,
 205 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>