lib/SQL/Translator/Producer/Diagram.pm

   1 package SQL::Translator::Producer::Diagram;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: Diagram.pm,v 1.6 2003-08-21 20:27:39 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 use strict;
  24 use GD;
  25 use Data::Dumper;
  26 use SQL::Translator::Schema::Constants;
  27 use SQL::Translator::Utils qw(debug);
  28
  29 use vars qw[ $VERSION $DEBUG ];
  30 $VERSION = sprintf "%d.%02d", q$Revision: 1.6 $ =~ /(\d+)\.(\d+)/;
  31 $DEBUG   = 0 unless defined $DEBUG;
  32
  33 use constant VALID_FONT_SIZE => {
  34     small  => 1,
  35     medium => 1,
  36     large  => 1,
  37     huge   => 1,
  38 };
  39
  40 use constant VALID_IMAGE_TYPE => {
  41     png  => 1,
  42     jpeg => 1,
  43 };
  44
  45 sub produce {
  46     my $t          = shift;
  47     my $schema     = $t->schema;
  48     my $args       = $t->producer_args;
  49     local $DEBUG   = $t->debug;
  50     debug("Schema =\n", Dumper( $schema ));
  51     debug("Producer args =\n", Dumper( $args ));
  52
  53     my $out_file     = $args->{'out_file'}     || '';
  54     my $image_type   = $args->{'image_type'}   || 'png';
  55     my $title        = $args->{'title'}        || $t->filename;
  56     my $font_size    = $args->{'font_size'}    || 'medium';
  57     my $imap_file    = $args->{'imap_file'}    || '';
  58     my $imap_url     = $args->{'imap_url'}     || '';
  59     my $no_columns   = $args->{'no_columns'};
  60     my $no_lines     = $args->{'no_lines'};
  61     my $add_color    = $args->{'add_color'};
  62     my $show_fk_only = $args->{'show_fk_only'};
  63     my $join_pk_only = $args->{'join_pk_only'};
  64     my $natural_join = $args->{'natural_join'} || $join_pk_only;
  65     my $skip_fields  = $args->{'skip_fields'};
  66     my %skip         = map { s/^\s+|\s+$//g; $_,1 } split (/,/, $skip_fields);
  67
  68     $schema->make_natural_joins(
  69         join_pk_only => $join_pk_only,
  70         skip_fields  => $args->{'skip_fields'},
  71     ) if $natural_join;
  72
  73     die "Invalid image type '$image_type'"
  74         unless VALID_IMAGE_TYPE ->{ $image_type  };
  75     die "Invalid font size '$font_size'"
  76         unless VALID_FONT_SIZE->{ $font_size };
  77
  78     #
  79     # Layout the image.
  80     #
  81     my $font         =
  82         $font_size eq 'small'  ? gdTinyFont  :
  83         $font_size eq 'medium' ? gdSmallFont :
  84         $font_size eq 'large'  ? gdLargeFont : gdGiantFont;
  85     my @tables       = $schema->get_tables;
  86     my $no_tables    = scalar @tables;
  87     $no_columns      = 0 unless $no_columns =~ /^\d+$/;
  88     $no_columns    ||= sprintf( "%.0f", sqrt( $no_tables ) + .5 );
  89     $no_columns    ||= .5;
  90     my $no_per_col   = sprintf( "%.0f", $no_tables/$no_columns + .5 );
  91
  92     my @shapes;
  93     my ( $max_x, $max_y );          # the furthest x and y used
  94     my $orig_y      = 40;           # used to reset y for each column
  95     my ( $x, $y )   = (30,$orig_y); # where to start
  96     my $cur_col     = 1;            # the current column
  97     my $no_this_col = 0;            # number of tables in current column
  98     my $this_col_x  = $x;           # current column's x
  99     my $gutter      = 30;           # distance b/w columns
 100     my %nj_registry;                # for locations of fields for natural joins
 101     my @fk_registry;                # for locations of fields for foreign keys
 102     my %table_x;                    # for max x of each table
 103     my $field_no;                   # counter to give distinct no. to each field
 104     my %coords;                     # holds fields coordinates
 105     my @imap_coords;                # for making clickable image map
 106     my %legend;
 107
 108     for my $table ( @tables ) {
 109         my $table_name = $table->name;
 110         my $top        = $y;
 111         push @shapes,
 112             [ 'string', $font, $this_col_x, $y, $table_name, 'black' ];
 113         $y                   += $font->height + 2;
 114         my $below_table_name  = $y;
 115         $y                   += 2;
 116         my $this_max_x        =
 117             $this_col_x + ($font->width * length($table_name));
 118
 119         debug("Processing table '$table_name'");
 120
 121         my @fields = $table->get_fields;
 122         debug("Fields = ", join(', ', map { $_->name } @fields));
 123
 124         my ( @fld_desc, $max_name );
 125         for my $f ( @fields ) {
 126             my $name  = $f->name or next;
 127             my $is_pk = $f->is_primary_key;
 128
 129             #
 130             # Decide if we should skip this field.
 131             #
 132             if ( $show_fk_only ) {
 133                 next unless $is_pk || $f->is_foreign_key;
 134             }
 135
 136             if ( $is_pk ) {
 137                 $name .= ' *';
 138                 $legend{'Primary key'} = '*';
 139             }
 140
 141             if ( $f->is_unique ) {
 142                 $name .= ' [U]';
 143                 $legend{'Unique constraint'} = '[U]';
 144             }
 145
 146             my $desc = $f->data_type;
 147             $desc   .= '('.$f->size.')' if $f->size;
 148
 149             my $nlen  = length $name;
 150             $max_name = $nlen if $nlen > $max_name;
 151             push @fld_desc, [ $name, $desc, $f->{'name'}, $is_pk ];
 152         }
 153
 154         $max_name += 4;
 155         for my $fld_desc ( @fld_desc ) {
 156             my ( $name, $desc, $orig_name, $is_pk ) = @$fld_desc;
 157             my $diff = $max_name - length $name;
 158             $name   .= ' ' x $diff;
 159             $desc    = $name . $desc;
 160
 161             push @shapes, [ 'string', $font, $this_col_x, $y, $desc, 'black' ];
 162             $y         += $font->height + 2;
 163             my $length  = $this_col_x + ( $font->width * length( $desc ) );
 164             $this_max_x = $length if $length > $this_max_x;
 165
 166             my $constraints = $table->{'fields'}{ $orig_name }{'constraints'};
 167
 168             if ( $natural_join && !$skip{ $orig_name } ) {
 169                 push @{ $nj_registry{ $orig_name } }, $table_name;
 170             }
 171
 172             my $y_link = $y - $font->height/2;
 173             $coords{ $table_name }{ $orig_name }{'coords'} = {
 174                 left     => [ $this_col_x - 6, $y_link ],
 175                 right    => [ $length + 2    , $y_link ],
 176                 table    => $table_name,
 177                 field_no => ++$field_no,
 178                 is_pk    => $is_pk,
 179                 fld_name => $orig_name,
 180             };
 181
 182             push @imap_coords, [
 183                 $imap_url."#$table_name-$orig_name",
 184                 $this_col_x, $y - $font->height, $length, $y_link,
 185             ];
 186         }
 187
 188         unless ( $natural_join ) {
 189             for my $c ( $table->get_constraints ) {
 190                 next unless $c->type eq FOREIGN_KEY;
 191                 my $fk_table = $c->reference_table or next;
 192
 193                 for my $field_name ( $c->fields ) {
 194                     for my $fk_field ( $c->reference_fields ) {
 195                         next unless defined $schema->get_table( $fk_table );
 196                         push @fk_registry, [
 197                             [ $fk_table  , $fk_field  ],
 198                             [ $table_name, $field_name ],
 199                         ];
 200                     }
 201                 }
 202             }
 203         }
 204
 205         $this_max_x += 5;
 206         $table_x{ $table_name } = $this_max_x + 5;
 207         push @shapes, [ 'line', $this_col_x - 5, $below_table_name,
 208             $this_max_x, $below_table_name, 'black' ];
 209         my @bounds = ( $this_col_x - 5, $top - 5, $this_max_x, $y + 5 );
 210         if ( $add_color ) {
 211             unshift @shapes, [
 212                 'filledRectangle',
 213                 $bounds[0], $bounds[1],
 214                 $this_max_x, $below_table_name,
 215                 'khaki'
 216             ];
 217             unshift @shapes, [ 'filledRectangle', @bounds, 'white' ];
 218         }
 219
 220         push @imap_coords, [
 221             $imap_url."#$table_name",
 222             $bounds[0], $bounds[1], $this_max_x, $below_table_name,
 223         ];
 224
 225         push @shapes, [ 'rectangle', @bounds, 'black' ];
 226         $max_x = $this_max_x if $this_max_x > $max_x;
 227         $y    += 25;
 228
 229         if ( ++$no_this_col == $no_per_col ) {# if we've filled up this column
 230             $cur_col++;                       # up the column number
 231             $no_this_col = 0;                 # reset the number of tables
 232             $max_x      += $gutter;           # push the x over for next column
 233             $this_col_x  = $max_x;            # remember the max x for this col
 234             $max_y       = $y if $y > $max_y; # note the max y
 235             $y           = $orig_y;           # reset the y for next column
 236         }
 237     }
 238
 239     #
 240     # Connect the lines.
 241     #
 242     my %horz_taken;
 243     my %done;
 244     unless ( $no_lines ) {
 245         my @position_bunches;
 246
 247         if ( $natural_join ) {
 248             for my $field_name ( keys %nj_registry ) {
 249                 my @positions;
 250                 my @table_names =
 251                     @{ $nj_registry{ $field_name } || [] } or next;
 252                 next if scalar @table_names == 1;
 253
 254                 for my $table_name ( @table_names ) {
 255                     push @positions,
 256                         $coords{ $table_name }{ $field_name }{'coords'};
 257                 }
 258
 259                 push @position_bunches, [ @positions ];
 260             }
 261         }
 262         else {
 263             for my $pair ( @fk_registry ) {
 264                 push @position_bunches, [
 265                     $coords{$pair->[0][0]}{ $pair->[0][1] }{'coords'},
 266                     $coords{$pair->[1][0]}{ $pair->[1][1] }{'coords'},
 267                 ];
 268             }
 269         }
 270
 271         my $is_directed = $natural_join ? 0 : 1;
 272
 273         for my $bunch ( @position_bunches ) {
 274             my @positions = @$bunch;
 275
 276             for my $i ( 0 .. $#positions ) {
 277                 my $pos1        = $positions[ $i ];
 278                 my ( $ax, $ay ) = @{ $pos1->{'left'}  || [] } or next;
 279                 my ( $bx, $by ) = @{ $pos1->{'right'} || [] } or next;
 280                 my $table1      = $pos1->{'table'};
 281                 my $fno1        = $pos1->{'field_no'};
 282                 my $is_pk       = $pos1->{'is_pk'};
 283                 next if $join_pk_only and !$is_pk;
 284
 285                 for my $j ( 0 .. $#positions ) {
 286                     my $pos2        = $positions[ $j ];
 287                     my ( $cx, $cy ) = @{ $pos2->{'left'}  || [] } or next;
 288                     my ( $dx, $dy ) = @{ $pos2->{'right'} || [] } or next;
 289                     my $table2      = $pos2->{'table'};
 290                     my $fno2        = $pos2->{'field_no'};
 291                     next if $table1 eq $table2;
 292                     next if $done{ $fno1 }{ $fno2 };
 293                     next if $fno1 == $fno2;
 294
 295                     my @distances = ();
 296                     push @distances, [
 297                         abs ( $ax - $cx ) + abs ( $ay - $cy ),
 298                         [ $ax, $ay, $cx, $cy ],
 299                         [ 'left', 'left' ]
 300                     ];
 301                     push @distances, [
 302                         abs ( $ax - $dx ) + abs ( $ay - $dy ),
 303                         [ $ax, $ay, $dx, $dy ],
 304                         [ 'left', 'right' ],
 305                     ];
 306                     push @distances, [
 307                         abs ( $bx - $cx ) + abs ( $by - $cy ),
 308                         [ $bx, $by, $cx, $cy ],
 309                         [ 'right', 'left' ],
 310                     ];
 311                     push @distances, [
 312                         abs ( $bx - $dx ) + abs ( $by - $dy ),
 313                         [ $bx, $by, $dx, $dy ],
 314                         [ 'right', 'right' ],
 315                     ];
 316                     @distances   = sort { $a->[0] <=> $b->[0] } @distances;
 317                     my $shortest = $distances[0];
 318                     my ( $x1, $y1, $x2, $y2 ) = @{ $shortest->[1] };
 319                     my ( $side1, $side2     ) = @{ $shortest->[2] };
 320                     my ( $start, $end );
 321                     my $offset     = 9;
 322                     my $col1_right = $table_x{ $table1 };
 323                     my $col2_right = $table_x{ $table2 };
 324
 325                     my $diff = 0;
 326                     if ( $x1 == $x2 ) {
 327                         while ( $horz_taken{ $x1 + $diff } ) {
 328                             $diff = $side1 eq 'left' ? $diff - 2 : $diff + 2;
 329                         }
 330                         $horz_taken{ $x1 + $diff } = 1;
 331                     }
 332
 333                     if ( $side1 eq 'left' ) {
 334                         $start = $x1 - $offset + $diff;
 335                     }
 336                     else {
 337                         $start = $col1_right + $diff;
 338                     }
 339
 340                     if ( $side2 eq 'left' ) {
 341                         $end = $x2 - $offset + $diff;
 342                     }
 343                     else {
 344                         $end = $col2_right + $diff;
 345                     }
 346
 347                     push @shapes,
 348                         [ 'line', $x1,    $y1, $start, $y1, 'cadetblue' ];
 349                     push @shapes,
 350                         [ 'line', $start, $y1, $end,   $y2, 'cadetblue' ];
 351                     push @shapes,
 352                         [ 'line', $end,   $y2, $x2,    $y2, 'cadetblue' ];
 353
 354                     if ( $is_directed ) {
 355                         if (
 356                             $side1 eq 'right' && $side2 eq 'left'
 357                             ||
 358                             $side1 eq 'left' && $side2 eq 'left'
 359                         ) {
 360                             push @shapes, [
 361                                 'line', $x2 - 3, $y2 - 3, $x2, $y2, 'cadetblue'
 362                             ];
 363                             push @shapes, [
 364                                 'line', $x2 - 3, $y2 + 3, $x2, $y2, 'cadetblue'
 365                             ];
 366                             push @shapes, [
 367                                 'line', $x2 - 3, $y2 - 3, $x2 - 3, $y2 +3,
 368                                 'cadetblue'
 369                             ];
 370                         }
 371                         else {
 372                             push @shapes, [
 373                                 'line', $x2 + 3, $y2 - 3, $x2, $y2, 'cadetblue'
 374                             ];
 375                             push @shapes, [
 376                                 'line', $x2 + 3, $y2 + 3, $x2, $y2, 'cadetblue'
 377                             ];
 378                             push @shapes, [
 379                                 'line', $x2 + 3, $y2 - 3, $x2 + 3, $y2 +3,
 380                                 'cadetblue'
 381                             ];
 382                         }
 383                     }
 384
 385                     $done{ $fno1 }{ $fno2 } = 1;
 386                     $done{ $fno2 }{ $fno1 } = 1;
 387                 }
 388             }
 389         }
 390     }
 391
 392     #
 393     # Add the title, legend and signature.
 394     #
 395     my $large_font = gdLargeFont;
 396     my $title_len  = $large_font->width * length $title;
 397     push @shapes, [
 398         'string', $large_font, $max_x/2 - $title_len/2, 10, $title, 'black'
 399     ];
 400
 401     if ( %legend ) {
 402         $max_y += 5;
 403         push @shapes, [
 404             'string', $font, $x, $max_y - $font->height - 4, 'Legend', 'black'
 405         ];
 406         $max_y += $font->height + 4;
 407
 408         my $longest;
 409         for my $len ( map { length $_ } values %legend ) {
 410             $longest = $len if $len > $longest;
 411         }
 412         $longest += 2;
 413
 414         while ( my ( $key, $shape ) = each %legend ) {
 415             my $space = $longest - length $shape;
 416             push @shapes, [
 417                 'string', $font, $x, $max_y - $font->height - 4,
 418                 join( '', $shape, ' ' x $space, $key ), 'black'
 419             ];
 420
 421             $max_y += $font->height + 4;
 422         }
 423     }
 424
 425     my $sig     = __PACKAGE__." $VERSION";
 426     my $sig_len = $font->width * length $sig;
 427     push @shapes, [
 428         'string', $font, $max_x - $sig_len, $max_y - $font->height - 4,
 429         $sig, 'black'
 430     ];
 431
 432     #
 433     # Render the image.
 434     #
 435     my $gd = GD::Image->new( $max_x + 30, $max_y );
 436     unless ( $gd->can( $image_type ) ) {
 437         die "GD can't create images of type '$image_type'\n";
 438     }
 439     my %colors = map { $_->[0], $gd->colorAllocate( @{$_->[1]} ) } (
 440         [ white                => [ 255, 255, 255 ] ],
 441         [ beige                => [ 245, 245, 220 ] ],
 442         [ black                => [   0,   0,   0 ] ],
 443         [ lightblue            => [ 173, 216, 230 ] ],
 444         [ cadetblue            => [  95, 158, 160 ] ],
 445         [ lightgoldenrodyellow => [ 250, 250, 210 ] ],
 446         [ khaki                => [ 240, 230, 140 ] ],
 447         [ red                  => [ 255,   0,   0 ] ],
 448     );
 449     $gd->interlaced( 'true' );
 450     my $background_color = $add_color ? 'lightgoldenrodyellow' : 'white';
 451     $gd->fill( 0, 0, $colors{ $background_color } );
 452     for my $shape ( @shapes ) {
 453         my $method = shift @$shape;
 454         my $color  = pop   @$shape;
 455         $gd->$method( @$shape, $colors{ $color } );
 456     }
 457
 458     #
 459     # Make image map.
 460     #
 461     debug("imap file = '$imap_file'");
 462     if ( $imap_file && @imap_coords ) {
 463         open my $fh, ">$imap_file" or die "Can't write '$imap_file': $!\n";
 464         print $fh qq[<html><body><img src="" usemap="#imap" border="0">\n].
 465             qq[<map name="imap">\n];
 466         for my $rec ( @imap_coords ) {
 467             my $href = shift @$rec;
 468             print $fh q[<area coords="].join(',', @$rec).qq[" href="$href">\n];
 469         }
 470         print $fh qq[</body></html>];
 471         close $fh;
 472     }
 473
 474     #
 475     # Print the image.
 476     #
 477     if ( $out_file ) {
 478         open my $fh, ">$out_file" or die "Can't write '$out_file': $!\n";
 479         print $fh $gd->$image_type;
 480         close $fh;
 481     }
 482     else {
 483         return $gd->$image_type;
 484     }
 485 }
 486
 487 1;
 488
 489 =pod
 490
 491 =head1 NAME
 492
 493 SQL::Translator::Producer::Diagram - ER diagram producer for SQL::Translator
 494
 495 =head1 AUTHOR
 496
 497 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>
 498
 499 =cut