lib/SQL/Translator/Parser/xSV.pm

   1 package SQL::Translator::Parser::xSV;
   2
   3 =head1 NAME
   4
   5 SQL::Translator::Parser::xSV - parser for arbitrarily delimited text files
   6
   7 =head1 SYNOPSIS
   8
   9   use SQL::Translator;
  10   use SQL::Translator::Parser::xSV;
  11
  12   my $translator  =  SQL::Translator->new(
  13       parser      => 'xSV',
  14       parser_args => { field_separator => "\t" },
  15   );
  16
  17 =head1 DESCRIPTION
  18
  19 Parses arbitrarily delimited text files.  See the
  20 Text::RecordParser manpage for arguments on how to parse the file
  21 (e.g., C<field_separator>, C<record_separator>).  Other arguments
  22 include:
  23
  24 =head1 OPTIONS
  25
  26 =over
  27
  28 =item * scan_fields
  29
  30 Indicates that the columns should be scanned to determine data types
  31 and field sizes.  True by default.
  32
  33 =item * trim_fields
  34
  35 A shortcut to sending filters to Text::RecordParser, will create
  36 callbacks that trim leading and trailing spaces from fields and headers.
  37 True by default.
  38
  39 =back
  40
  41 Field names will automatically be normalized by
  42 C<SQL::Translator::Utils::normalize_name>.
  43
  44 =cut
  45
  46 use strict;
  47 use vars qw($VERSION @EXPORT);
  48 $VERSION = '1.59';
  49
  50 use Exporter;
  51 use Text::ParseWords qw(quotewords);
  52 use Text::RecordParser;
  53 use SQL::Translator::Utils qw(debug normalize_name);
  54
  55 use base qw(Exporter);
  56 @EXPORT = qw(parse);
  57
  58 #
  59 # Passed a SQL::Translator instance and a string containing the data
  60 #
  61 sub parse {
  62     my ( $tr, $data )    = @_;
  63     my $args             = $tr->parser_args;
  64     my $parser           = Text::RecordParser->new(
  65         field_separator  => $args->{'field_separator'}  || ',',
  66         record_separator => $args->{'record_separator'} || "\n",
  67         data             => $data,
  68         header_filter    => \&normalize_name,
  69     );
  70
  71     $parser->field_filter( sub { $_ = shift || ''; s/^\s+|\s+$//g; $_ } )
  72         unless defined $args->{'trim_fields'} && $args->{'trim_fields'} == 0;
  73
  74     my $schema = $tr->schema;
  75     my $table = $schema->add_table( name => 'table1' );
  76
  77     #
  78     # Get the field names from the first row.
  79     #
  80     $parser->bind_header;
  81     my @field_names = $parser->field_list;
  82
  83     for ( my $i = 0; $i < @field_names; $i++ ) {
  84         my $field = $table->add_field(
  85             name              => $field_names[$i],
  86             data_type         => 'char',
  87             default_value     => '',
  88             size              => 255,
  89             is_nullable       => 1,
  90             is_auto_increment => undef,
  91         ) or die $table->error;
  92
  93         if ( $i == 0 ) {
  94             $table->primary_key( $field->name );
  95             $field->is_primary_key(1);
  96         }
  97     }
  98
  99     #
 100     # If directed, look at every field's values to guess size and type.
 101     #
 102     unless (
 103         defined $args->{'scan_fields'} &&
 104         $args->{'scan_fields'} == 0
 105     ) {
 106         my %field_info = map { $_, {} } @field_names;
 107         while ( my $rec = $parser->fetchrow_hashref ) {
 108             for my $field ( @field_names ) {
 109                 my $data = defined $rec->{ $field } ? $rec->{ $field } : '';
 110                 my $size = [ length $data ];
 111                 my $type;
 112
 113                 if ( $data =~ /^-?\d+$/ ) {
 114                     $type = 'integer';
 115                 }
 116                 elsif (
 117                     $data =~ /^-?[,\d]+\.[\d+]?$/
 118                     ||
 119                     $data =~ /^-?[,\d]+?\.\d+$/
 120                     ||
 121                     $data =~ /^-?\.\d+$/
 122                 ) {
 123                     $type = 'float';
 124                     my ( $w, $d ) =
 125                         map { s/,//g; length $_ || 1 } split( /\./, $data );
 126                     $size = [ $w + $d, $d ];
 127                 }
 128                 else {
 129                     $type = 'char';
 130                 }
 131
 132                 for my $i ( 0, 1 ) {
 133                     next unless defined $size->[ $i ];
 134                     my $fsize = $field_info{ $field }{'size'}[ $i ] || 0;
 135                     if ( $size->[ $i ] > $fsize ) {
 136                         $field_info{ $field }{'size'}[ $i ] = $size->[ $i ];
 137                     }
 138                 }
 139
 140                 $field_info{ $field }{ $type }++;
 141             }
 142         }
 143
 144         for my $field ( keys %field_info ) {
 145             my $size      = $field_info{ $field }{'size'} || [ 1 ];
 146             my $data_type =
 147                 $field_info{ $field }{'char'}    ? 'char'  :
 148                 $field_info{ $field }{'float'}   ? 'float' :
 149                 $field_info{ $field }{'integer'} ? 'integer' : 'char';
 150
 151             if ( $data_type eq 'char' && scalar @$size == 2 ) {
 152                 $size = [ $size->[0] + $size->[1] ];
 153             }
 154
 155             my $field = $table->get_field( $field );
 156             $field->size( $size );
 157             $field->data_type( $data_type );
 158         }
 159     }
 160
 161     return 1;
 162 }
 163
 164 1;
 165
 166 =pod
 167
 168 =head1 AUTHORS
 169
 170 Darren Chamberlain E<lt>darren@cpan.orgE<gt>,
 171 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 172
 173 =head1 SEE ALSO
 174
 175 Text::RecordParser, SQL::Translator.
 176
 177 =cut