lib/SQL/Translator/Parser/YAML.pm

   1 package SQL::Translator::Parser::YAML;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: YAML.pm,v 1.3 2003-10-09 21:48:55 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 darren chamberlain <darren@cpan.org>,
   7 #   Ken Y. Clark <kclark@cpan.org>.
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License as
  11 # published by the Free Software Foundation; version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21 # 02111-1307  USA
  22 # -------------------------------------------------------------------
  23
  24 use strict;
  25 use vars qw($VERSION);
  26 $VERSION = sprintf "%d.%02d", q$Revision: 1.3 $ =~ /(\d+)\.(\d+)/;
  27
  28 use SQL::Translator::Schema;
  29 use SQL::Translator::Utils qw(header_comment);
  30 use Data::Dumper;
  31 use YAML qw(Load);
  32
  33 sub parse {
  34     my ($translator, $data) = @_;
  35     $data = Load($data);
  36     $data = $data->{'schema'};
  37
  38     warn Dumper( $data ) if $translator->debug;
  39
  40     my $schema = $translator->schema;
  41
  42     #
  43     # Tables
  44     #
  45     my @tables =
  46         map   { $data->{'tables'}{ $_->[1] } }
  47         sort  { $a->[0] <=> $b->[0] }
  48         map   { [ $data->{'tables'}{ $_ }{'order'}, $_ ] }
  49         keys %{ $data->{'tables'} }
  50     ;
  51
  52     for my $tdata ( @tables ) {
  53         my $table = $schema->add_table(
  54             name  => $tdata->{'name'},
  55         ) or die $schema->error;
  56
  57         my @fields =
  58             map   { $tdata->{'fields'}{ $_->[1] } }
  59             sort  { $a->[0] <=> $b->[0] }
  60             map   { [ $tdata->{'fields'}{ $_ }{'order'}, $_ ] }
  61             keys %{ $tdata->{'fields'} }
  62         ;
  63
  64         for my $fdata ( @fields ) {
  65             $table->add_field( %$fdata ) or die $table->error;
  66             $table->primary_key( $fdata->{'name'} )
  67                 if $fdata->{'is_primary_key'};
  68         }
  69     }
  70
  71     #
  72     # Views
  73     #
  74     my @views =
  75         map   { $data->{'views'}{ $_->[1] } }
  76         sort  { $a->[0] <=> $b->[0] }
  77         map   { [ $data->{'views'}{ $_ }{'order'}, $_ ] }
  78         keys %{ $data->{'views'} }
  79     ;
  80
  81     for my $vdata ( @views ) {
  82         $schema->add_view( %$vdata ) or die $schema->error;
  83     }
  84
  85     #
  86     # Triggers
  87     #
  88     my @triggers =
  89         map   { $data->{'triggers'}{ $_->[1] } }
  90         sort  { $a->[0] <=> $b->[0] }
  91         map   { [ $data->{'triggers'}{ $_ }{'order'}, $_ ] }
  92         keys %{ $data->{'triggers'} }
  93     ;
  94
  95     for my $tdata ( @triggers ) {
  96         $schema->add_trigger( %$tdata ) or die $schema->error;
  97     }
  98
  99     #
 100     # Procedures
 101     #
 102     my @procedures =
 103         map   { $data->{'procedures'}{ $_->[1] } }
 104         sort  { $a->[0] <=> $b->[0] }
 105         map   { [ $data->{'procedures'}{ $_ }{'order'}, $_ ] }
 106         keys %{ $data->{'procedures'} }
 107     ;
 108
 109     for my $tdata ( @procedures ) {
 110         $schema->add_procedure( %$tdata ) or die $schema->error;
 111     }
 112
 113     return 1;
 114 }
 115
 116 1;
 117
 118 __END__
 119
 120 =head1 NAME
 121
 122 SQL::Translator::Parser::YAML - Parse a YAML representation of a schema
 123
 124 =head1 SYNOPSIS
 125
 126     use SQL::Translator;
 127
 128     my $translator = SQL::Translator->new(parser => "YAML");
 129
 130 =head1 DESCRIPTION
 131
 132 C<SQL::Translator::Parser::YAML> parses a schema serialized with YAML.
 133
 134 =head1 AUTHOR
 135
 136 Darren Chamberlain E<lt>darren@cpan.orgE<gt>,
 137 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.