lib/SQL/Translator/Parser/Sybase.pm

   1 package SQL::Translator::Parser::Sybase;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: Sybase.pm,v 1.8 2003-11-05 23:27:09 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>,
   7 #                    darren chamberlain <darren@cpan.org>,
   8 #                    Chris Mungall <cjm@fruitfly.org>
   9 #
  10 # This program is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU General Public License as
  12 # published by the Free Software Foundation; version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  22 # 02111-1307  USA
  23 # -------------------------------------------------------------------
  24
  25 =head1 NAME
  26
  27 SQL::Translator::Parser::Sybase - parser for Sybase
  28
  29 =head1 SYNOPSIS
  30
  31   use SQL::Translator::Parser::Sybase;
  32
  33 =head1 DESCRIPTION
  34
  35 Mostly parses the output of "dbschema.pl," a Perl script freely
  36 available from http://www.midsomer.org.  The parsing is not complete,
  37 however, and you would probably have much better luck using the
  38 DBI-Sybase parser included with SQL::Translator.
  39
  40 =cut
  41
  42 use strict;
  43
  44 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  45 $VERSION = sprintf "%d.%02d", q$Revision: 1.8 $ =~ /(\d+)\.(\d+)/;
  46 $DEBUG   = 0 unless defined $DEBUG;
  47
  48 use Data::Dumper;
  49 use Parse::RecDescent;
  50 use Exporter;
  51 use base qw(Exporter);
  52
  53 @EXPORT_OK = qw(parse);
  54
  55 $::RD_ERRORS = 1;
  56 $::RD_WARN   = 1;
  57 $::RD_HINT   = 1;
  58
  59 $GRAMMAR = q{
  60
  61 {
  62     my ( %tables, @table_comments, $table_order );
  63 }
  64
  65 startrule : statement(s) eofile { \%tables }
  66
  67 eofile : /^\Z/
  68
  69 statement : create_table
  70     | create_procedure
  71     | create_index
  72     | create_constraint
  73     | comment
  74     | use
  75     | setuser
  76     | if
  77     | print
  78     | grant
  79     | exec
  80     | <error>
  81
  82 use : /use/i WORD GO
  83     { @table_comments = () }
  84
  85 setuser : /setuser/i NAME GO
  86
  87 if : /if/i object_not_null begin if_command end GO
  88
  89 if_command : grant
  90     | create_index
  91     | create_constraint
  92
  93 object_not_null : /object_id/i '(' ident ')' /is not null/i
  94
  95 print : /\s*/ /print/i /.*/
  96
  97 else : /else/i /.*/
  98
  99 begin : /begin/i
 100
 101 end : /end/i
 102
 103 grant : /grant/i /[^\n]*/
 104
 105 exec : exec_statement(s) GO
 106
 107 exec_statement : /exec/i /[^\n]+/
 108
 109 comment : comment_start comment_middle comment_end
 110     {
 111         my $comment = $item[2];
 112         $comment =~ s/^\s*|\s*$//mg;
 113         $comment =~ s/^\**\s*//mg;
 114         push @table_comments, $comment;
 115     }
 116
 117 comment_start : /^\s*\/\*/
 118
 119 comment_end : /\s*\*\//
 120
 121 comment_middle : m{([^*]+|\*(?!/))*}
 122
 123 #
 124 # Create table.
 125 #
 126 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) GO
 127     {
 128         my $table_owner = $item[3]{'owner'};
 129         my $table_name  = $item[3]{'name'};
 130
 131         if ( @table_comments ) {
 132             $tables{ $table_name }{'comments'} = [ @table_comments ];
 133             @table_comments = ();
 134         }
 135
 136         $tables{ $table_name }{'order'}  = ++$table_order;
 137         $tables{ $table_name }{'name'}   = $table_name;
 138         $tables{ $table_name }{'owner'}  = $table_owner;
 139         $tables{ $table_name }{'system'} = $item[7];
 140
 141         my $i = 0;
 142         for my $def ( @{ $item[5] } ) {
 143             if ( $def->{'supertype'} eq 'field' ) {
 144                 my $field_name = $def->{'name'};
 145                 $tables{ $table_name }{'fields'}{ $field_name } =
 146                     { %$def, order => $i };
 147                 $i++;
 148
 149                 if ( $def->{'is_primary_key'} ) {
 150                     push @{ $tables{ $table_name }{'constraints'} }, {
 151                         type   => 'primary_key',
 152                         fields => [ $field_name ],
 153                     };
 154                 }
 155             }
 156             elsif ( $def->{'supertype'} eq 'constraint' ) {
 157                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 158             }
 159             else {
 160                 push @{ $tables{ $table_name }{'indices'} }, $def;
 161             }
 162         }
 163     }
 164
 165 create_constraint : /create/i constraint
 166     {
 167         @table_comments = ();
 168         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 169     }
 170
 171 create_index : /create/i index
 172     {
 173         @table_comments = ();
 174         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 175     }
 176
 177 create_procedure : /create/i /procedure/i procedure_body GO
 178     {
 179         @table_comments = ();
 180     }
 181
 182 procedure_body : not_go(s)
 183
 184 not_go : /((?!go).)*/
 185
 186 create_def : field
 187     | index
 188     | constraint
 189
 190 blank : /\s*/
 191
 192 field : field_name data_type nullable(?)
 193     {
 194         $return = {
 195             supertype      => 'field',
 196             name           => $item{'field_name'},
 197             data_type      => $item{'data_type'}{'type'},
 198             size           => $item{'data_type'}{'size'},
 199             nullable       => $item[3][0],
 200 #            default        => $item{'default_val'}[0],
 201 #            is_auto_inc    => $item{'auto_inc'}[0],
 202 #            is_primary_key => $item{'primary_key'}[0],
 203         }
 204     }
 205
 206 constraint : primary_key_constraint
 207     | unique_constraint
 208
 209 field_name : WORD
 210
 211 index_name : WORD
 212
 213 table_name : WORD
 214
 215 data_type : WORD field_size(?)
 216     {
 217         $return = {
 218             type => $item[1],
 219             size => $item[2][0]
 220         }
 221     }
 222
 223 lock : /lock/i /datarows/i
 224
 225 field_type : WORD
 226
 227 field_size : '(' num_range ')' { $item{'num_range'} }
 228
 229 num_range : DIGITS ',' DIGITS
 230     { $return = $item[1].','.$item[3] }
 231                | DIGITS
 232     { $return = $item[1] }
 233
 234
 235 nullable : /not/i /null/i
 236     { $return = 0 }
 237     | /null/i
 238     { $return = 1 }
 239
 240 default_val : /default/i /(?:')?[\w\d.-]*(?:')?/
 241     { $item[2]=~s/'//g; $return=$item[2] }
 242
 243 auto_inc : /auto_increment/i { 1 }
 244
 245 primary_key_constraint : /primary/i /key/i index_name(?) parens_field_list
 246     {
 247         $return = {
 248             supertype => 'constraint',
 249             name      => $item{'index_name'}[0],
 250             type      => 'primary_key',
 251             fields    => $item[4],
 252         }
 253     }
 254
 255 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list
 256     {
 257         $return = {
 258             supertype => 'constraint',
 259             type      => 'unique',
 260             clustered => $item[2][0],
 261             name      => $item[4][0],
 262             table     => $item[5][0],
 263             fields    => $item[6],
 264         }
 265     }
 266
 267 clustered : /clustered/i
 268     { $return = 1 }
 269     | /nonclustered/i
 270     { $return = 0 }
 271
 272 INDEX : /index/i
 273
 274 on_table : /on/i table_name
 275     { $return = $item[2] }
 276
 277 on_system : /on/i /system/i
 278     { $return = 1 }
 279
 280 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list
 281     {
 282         $return = {
 283             supertype => 'index',
 284             type      => 'normal',
 285             clustered => $item[1][0],
 286             name      => $item[3][0],
 287             table     => $item[4][0],
 288             fields    => $item[5],
 289         }
 290     }
 291
 292 parens_field_list : '(' field_name(s /,/) ')'
 293     { $item[2] }
 294
 295 ident : QUOTE(?) WORD '.' WORD QUOTE(?)
 296     { $return = { owner => $item[2], name => $item[4] } }
 297     | WORD
 298     { $return = { name  => $item[2] } }
 299
 300 GO : /^go/i
 301
 302 NAME : QUOTE(?) /\w+/ QUOTE(?)
 303     { $item[2] }
 304
 305 WORD : /[\w#]+/
 306
 307 DIGITS : /\d+/
 308
 309 COMMA : ','
 310
 311 QUOTE : /'/
 312
 313 };
 314
 315 # -------------------------------------------------------------------
 316 sub parse {
 317     my ( $translator, $data ) = @_;
 318     my $parser = Parse::RecDescent->new($GRAMMAR);
 319
 320     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 321     local $DEBUG       = $translator->debug;
 322
 323     unless (defined $parser) {
 324         return $translator->error("Error instantiating Parse::RecDescent ".
 325             "instance: Bad grammer");
 326     }
 327
 328     my $result = $parser->startrule($data);
 329     return $translator->error( "Parse failed." ) unless defined $result;
 330     warn Dumper( $result ) if $DEBUG;
 331
 332     my $schema = $translator->schema;
 333     my @tables = sort {
 334         $result->{ $a }->{'order'} <=> $result->{ $b }->{'order'}
 335     } keys %{ $result };
 336
 337     for my $table_name ( @tables ) {
 338         my $tdata = $result->{ $table_name };
 339         my $table = $schema->add_table( name => $tdata->{'name'} )
 340                     or die "Can't create table '$table_name': ", $schema->error;
 341
 342         $table->comments( $tdata->{'comments'} );
 343
 344         my @fields = sort {
 345             $tdata->{'fields'}->{$a}->{'order'}
 346             <=>
 347             $tdata->{'fields'}->{$b}->{'order'}
 348         } keys %{ $tdata->{'fields'} };
 349
 350         for my $fname ( @fields ) {
 351             my $fdata = $tdata->{'fields'}{ $fname };
 352             my $field = $table->add_field(
 353                 name              => $fdata->{'name'},
 354                 data_type         => $fdata->{'data_type'},
 355                 size              => $fdata->{'size'},
 356                 default_value     => $fdata->{'default'},
 357                 is_auto_increment => $fdata->{'is_auto_inc'},
 358                 is_nullable       => $fdata->{'nullable'},
 359                 comments          => $fdata->{'comments'},
 360             ) or die $table->error;
 361
 362             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 363
 364             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 365                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 366                     next if ref $val eq 'ARRAY' && !@$val;
 367                     $field->extra( $qual, $val );
 368                 }
 369             }
 370
 371             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 372                 my %extra = $field->extra;
 373                 my $longest = 0;
 374                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 375                     $longest = $len if $len > $longest;
 376                 }
 377                 $field->size( $longest ) if $longest;
 378             }
 379
 380             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 381                 next unless $cdata->{'type'} eq 'foreign_key';
 382                 $cdata->{'fields'} ||= [ $field->name ];
 383                 push @{ $tdata->{'constraints'} }, $cdata;
 384             }
 385         }
 386
 387         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 388             my $index  =  $table->add_index(
 389                 name   => $idata->{'name'},
 390                 type   => uc $idata->{'type'},
 391                 fields => $idata->{'fields'},
 392             ) or die $table->error;
 393         }
 394
 395         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 396             my $constraint       =  $table->add_constraint(
 397                 name             => $cdata->{'name'},
 398                 type             => $cdata->{'type'},
 399                 fields           => $cdata->{'fields'},
 400                 reference_table  => $cdata->{'reference_table'},
 401                 reference_fields => $cdata->{'reference_fields'},
 402                 match_type       => $cdata->{'match_type'} || '',
 403                 on_delete        => $cdata->{'on_delete_do'},
 404                 on_update        => $cdata->{'on_update_do'},
 405             ) or die $table->error;
 406         }
 407     }
 408
 409     return 1;
 410 }
 411
 412 1;
 413
 414 # -------------------------------------------------------------------
 415 # Every hero becomes a bore at last.
 416 # Ralph Waldo Emerson
 417 # -------------------------------------------------------------------
 418
 419 =pod
 420
 421 =head1 AUTHOR
 422
 423 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 424
 425 =head1 SEE ALSO
 426
 427 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 428
 429 =cut