lib/SQL/Translator/Parser/Sybase.pm

   1 package SQL::Translator::Parser::Sybase;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: Sybase.pm,v 1.7 2003-10-15 18:35:09 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>,
   7 #                    darren chamberlain <darren@cpan.org>,
   8 #                    Chris Mungall <cjm@fruitfly.org>
   9 #
  10 # This program is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU General Public License as
  12 # published by the Free Software Foundation; version 2.
  13 #
  14 # This program is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  22 # 02111-1307  USA
  23 # -------------------------------------------------------------------
  24
  25 =head1 NAME
  26
  27 SQL::Translator::Parser::Sybase - parser for Sybase
  28
  29 =head1 SYNOPSIS
  30
  31   use SQL::Translator::Parser::Sybase;
  32
  33 =head1 DESCRIPTION
  34
  35 Mostly parses the output of "dbschema.pl," a Perl script freely
  36 available from http://www.midsomer.org.  The parsing is not complete,
  37 however, and you would probably have much better luck using the
  38 DBI-Sybase parser included with SQL::Translator.
  39
  40 =cut
  41
  42 use strict;
  43
  44 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  45 $VERSION = sprintf "%d.%02d", q$Revision: 1.7 $ =~ /(\d+)\.(\d+)/;
  46 $DEBUG   = 0 unless defined $DEBUG;
  47
  48 use Data::Dumper;
  49 use Parse::RecDescent;
  50 use Exporter;
  51 use base qw(Exporter);
  52
  53 @EXPORT_OK = qw(parse);
  54
  55 $::RD_ERRORS = 1;
  56 $::RD_WARN   = 1;
  57 $::RD_HINT   = 1;
  58
  59 $GRAMMAR = q{
  60
  61 {
  62     my ( %tables, @table_comments );
  63 }
  64
  65 startrule : statement(s) eofile { \%tables }
  66
  67 eofile : /^\Z/
  68
  69 statement : create_table
  70     | create_procedure
  71     | create_index
  72     | create_constraint
  73     | comment
  74     | use
  75     | setuser
  76     | if
  77     | print
  78     | grant
  79     | exec
  80     | <error>
  81
  82 use : /use/i WORD GO
  83     { @table_comments = () }
  84
  85 setuser : /setuser/i NAME GO
  86
  87 if : /if/i object_not_null begin if_command end GO
  88
  89 if_command : grant
  90     | create_index
  91     | create_constraint
  92
  93 object_not_null : /object_id/i '(' ident ')' /is not null/i
  94
  95 print : /\s*/ /print/i /.*/
  96
  97 else : /else/i /.*/
  98
  99 begin : /begin/i
 100
 101 end : /end/i
 102
 103 grant : /grant/i /[^\n]*/
 104
 105 exec : exec_statement(s) GO
 106
 107 exec_statement : /exec/i /[^\n]+/
 108
 109 comment : comment_start comment_middle comment_end
 110     {
 111         my $comment = $item[2];
 112         $comment =~ s/^\s*|\s*$//mg;
 113         $comment =~ s/^\**\s*//mg;
 114         push @table_comments, $comment;
 115     }
 116
 117 comment_start : /^\s*\/\*/
 118
 119 comment_end : /\s*\*\//
 120
 121 comment_middle : m{([^*]+|\*(?!/))*}
 122
 123 #
 124 # Create table.
 125 #
 126 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) GO
 127     {
 128         my $table_owner = $item[3]{'owner'};
 129         my $table_name  = $item[3]{'name'};
 130
 131         if ( @table_comments ) {
 132             $tables{ $table_name }{'comments'} = [ @table_comments ];
 133             @table_comments = ();
 134         }
 135
 136         $tables{ $table_name }{'name'}   = $table_name;
 137         $tables{ $table_name }{'owner'}  = $table_owner;
 138         $tables{ $table_name }{'system'} = $item[7];
 139
 140         my $i = 0;
 141         for my $def ( @{ $item[5] } ) {
 142             if ( $def->{'supertype'} eq 'field' ) {
 143                 my $field_name = $def->{'name'};
 144                 $tables{ $table_name }{'fields'}{ $field_name } =
 145                     { %$def, order => $i };
 146                 $i++;
 147
 148                 if ( $def->{'is_primary_key'} ) {
 149                     push @{ $tables{ $table_name }{'constraints'} }, {
 150                         type   => 'primary_key',
 151                         fields => [ $field_name ],
 152                     };
 153                 }
 154             }
 155             elsif ( $def->{'supertype'} eq 'constraint' ) {
 156                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 157             }
 158             else {
 159                 push @{ $tables{ $table_name }{'indices'} }, $def;
 160             }
 161         }
 162     }
 163
 164 create_constraint : /create/i constraint
 165     {
 166         @table_comments = ();
 167         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 168     }
 169
 170 create_index : /create/i index
 171     {
 172         @table_comments = ();
 173         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 174     }
 175
 176 create_procedure : /create/i /procedure/i procedure_body GO
 177     {
 178         @table_comments = ();
 179     }
 180
 181 procedure_body : not_go(s)
 182
 183 not_go : /((?!go).)*/
 184
 185 create_def : field
 186     | index
 187     | constraint
 188
 189 blank : /\s*/
 190
 191 field : field_name data_type nullable(?)
 192     {
 193         $return = {
 194             supertype      => 'field',
 195             name           => $item{'field_name'},
 196             data_type      => $item{'data_type'}{'type'},
 197             size           => $item{'data_type'}{'size'},
 198             nullable       => $item[3][0],
 199 #            default        => $item{'default_val'}[0],
 200 #            is_auto_inc    => $item{'auto_inc'}[0],
 201 #            is_primary_key => $item{'primary_key'}[0],
 202         }
 203     }
 204
 205 constraint : primary_key_constraint
 206     | unique_constraint
 207
 208 field_name : WORD
 209
 210 index_name : WORD
 211
 212 table_name : WORD
 213
 214 data_type : WORD field_size(?)
 215     {
 216         $return = {
 217             type => $item[1],
 218             size => $item[2][0]
 219         }
 220     }
 221
 222 lock : /lock/i /datarows/i
 223
 224 field_type : WORD
 225
 226 field_size : '(' num_range ')' { $item{'num_range'} }
 227
 228 num_range : DIGITS ',' DIGITS
 229     { $return = $item[1].','.$item[3] }
 230                | DIGITS
 231     { $return = $item[1] }
 232
 233
 234 nullable : /not/i /null/i
 235     { $return = 0 }
 236     | /null/i
 237     { $return = 1 }
 238
 239 default_val : /default/i /(?:')?[\w\d.-]*(?:')?/
 240     { $item[2]=~s/'//g; $return=$item[2] }
 241
 242 auto_inc : /auto_increment/i { 1 }
 243
 244 primary_key_constraint : /primary/i /key/i index_name(?) parens_field_list
 245     {
 246         $return = {
 247             supertype => 'constraint',
 248             name      => $item{'index_name'}[0],
 249             type      => 'primary_key',
 250             fields    => $item[4],
 251         }
 252     }
 253
 254 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list
 255     {
 256         $return = {
 257             supertype => 'constraint',
 258             type      => 'unique',
 259             clustered => $item[2][0],
 260             name      => $item[4][0],
 261             table     => $item[5][0],
 262             fields    => $item[6],
 263         }
 264     }
 265
 266 clustered : /clustered/i
 267     { $return = 1 }
 268     | /nonclustered/i
 269     { $return = 0 }
 270
 271 INDEX : /index/i
 272
 273 on_table : /on/i table_name
 274     { $return = $item[2] }
 275
 276 on_system : /on/i /system/i
 277     { $return = 1 }
 278
 279 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list
 280     {
 281         $return = {
 282             supertype => 'index',
 283             type      => 'normal',
 284             clustered => $item[1][0],
 285             name      => $item[3][0],
 286             table     => $item[4][0],
 287             fields    => $item[5],
 288         }
 289     }
 290
 291 parens_field_list : '(' field_name(s /,/) ')'
 292     { $item[2] }
 293
 294 ident : QUOTE(?) WORD '.' WORD QUOTE(?)
 295     { $return = { owner => $item[2], name => $item[4] } }
 296     | WORD
 297     { $return = { name  => $item[2] } }
 298
 299 GO : /^go/i
 300
 301 NAME : QUOTE(?) /\w+/ QUOTE(?)
 302     { $item[2] }
 303
 304 WORD : /[\w#]+/
 305
 306 DIGITS : /\d+/
 307
 308 COMMA : ','
 309
 310 QUOTE : /'/
 311
 312 };
 313
 314 # -------------------------------------------------------------------
 315 sub parse {
 316     my ( $translator, $data ) = @_;
 317     my $parser = Parse::RecDescent->new($GRAMMAR);
 318
 319     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 320     local $DEBUG       = $translator->debug;
 321
 322     unless (defined $parser) {
 323         return $translator->error("Error instantiating Parse::RecDescent ".
 324             "instance: Bad grammer");
 325     }
 326
 327     my $result = $parser->startrule($data);
 328     return $translator->error( "Parse failed." ) unless defined $result;
 329     warn Dumper( $result ) if $DEBUG;
 330
 331     my $schema = $translator->schema;
 332     my @tables = sort {
 333         $result->{ $a }->{'order'} <=> $result->{ $b }->{'order'}
 334     } keys %{ $result };
 335
 336     for my $table_name ( @tables ) {
 337         my $tdata = $result->{ $table_name };
 338         my $table = $schema->add_table( name => $tdata->{'name'} )
 339                     or die "Can't create table '$table_name': ", $schema->error;
 340
 341         $table->comments( $tdata->{'comments'} );
 342
 343         my @fields = sort {
 344             $tdata->{'fields'}->{$a}->{'order'}
 345             <=>
 346             $tdata->{'fields'}->{$b}->{'order'}
 347         } keys %{ $tdata->{'fields'} };
 348
 349         for my $fname ( @fields ) {
 350             my $fdata = $tdata->{'fields'}{ $fname };
 351             my $field = $table->add_field(
 352                 name              => $fdata->{'name'},
 353                 data_type         => $fdata->{'data_type'},
 354                 size              => $fdata->{'size'},
 355                 default_value     => $fdata->{'default'},
 356                 is_auto_increment => $fdata->{'is_auto_inc'},
 357                 is_nullable       => $fdata->{'nullable'},
 358                 comments          => $fdata->{'comments'},
 359             ) or die $table->error;
 360
 361             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 362
 363             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 364                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 365                     next if ref $val eq 'ARRAY' && !@$val;
 366                     $field->extra( $qual, $val );
 367                 }
 368             }
 369
 370             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 371                 my %extra = $field->extra;
 372                 my $longest = 0;
 373                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 374                     $longest = $len if $len > $longest;
 375                 }
 376                 $field->size( $longest ) if $longest;
 377             }
 378
 379             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 380                 next unless $cdata->{'type'} eq 'foreign_key';
 381                 $cdata->{'fields'} ||= [ $field->name ];
 382                 push @{ $tdata->{'constraints'} }, $cdata;
 383             }
 384         }
 385
 386         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 387             my $index  =  $table->add_index(
 388                 name   => $idata->{'name'},
 389                 type   => uc $idata->{'type'},
 390                 fields => $idata->{'fields'},
 391             ) or die $table->error;
 392         }
 393
 394         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 395             my $constraint       =  $table->add_constraint(
 396                 name             => $cdata->{'name'},
 397                 type             => $cdata->{'type'},
 398                 fields           => $cdata->{'fields'},
 399                 reference_table  => $cdata->{'reference_table'},
 400                 reference_fields => $cdata->{'reference_fields'},
 401                 match_type       => $cdata->{'match_type'} || '',
 402                 on_delete        => $cdata->{'on_delete_do'},
 403                 on_update        => $cdata->{'on_update_do'},
 404             ) or die $table->error;
 405         }
 406     }
 407
 408     return 1;
 409 }
 410
 411 1;
 412
 413 # -------------------------------------------------------------------
 414 # Every hero becomes a bore at last.
 415 # Ralph Waldo Emerson
 416 # -------------------------------------------------------------------
 417
 418 =pod
 419
 420 =head1 AUTHOR
 421
 422 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 423
 424 =head1 SEE ALSO
 425
 426 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 427
 428 =cut