lib/SQL/Translator/Parser/PostgreSQL.pm

   1 package SQL::Translator::Parser::PostgreSQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: PostgreSQL.pm,v 1.42 2004-10-23 19:58:19 cmungall Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Parser::PostgreSQL - parser for PostgreSQL
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator;
  30   use SQL::Translator::Parser::PostgreSQL;
  31
  32   my $translator = SQL::Translator->new;
  33   $translator->parser("SQL::Translator::Parser::PostgreSQL");
  34
  35 =head1 DESCRIPTION
  36
  37 The grammar was started from the MySQL parsers.  Here is the description
  38 from PostgreSQL:
  39
  40 Table:
  41 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createtable.html)
  42
  43   CREATE [ [ LOCAL ] { TEMPORARY | TEMP } ] TABLE table_name (
  44       { column_name data_type [ DEFAULT default_expr ]
  45          [ column_constraint [, ... ] ]
  46       | table_constraint }  [, ... ]
  47   )
  48   [ INHERITS ( parent_table [, ... ] ) ]
  49   [ WITH OIDS | WITHOUT OIDS ]
  50
  51   where column_constraint is:
  52
  53   [ CONSTRAINT constraint_name ]
  54   { NOT NULL | NULL | UNIQUE | PRIMARY KEY |
  55     CHECK (expression) |
  56     REFERENCES reftable [ ( refcolumn ) ] [ MATCH FULL | MATCH PARTIAL ]
  57       [ ON DELETE action ] [ ON UPDATE action ] }
  58   [ DEFERRABLE | NOT DEFERRABLE ]
  59   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  60
  61   and table_constraint is:
  62
  63   [ CONSTRAINT constraint_name ]
  64   { UNIQUE ( column_name [, ... ] ) |
  65     PRIMARY KEY ( column_name [, ... ] ) |
  66     CHECK ( expression ) |
  67     FOREIGN KEY ( column_name [, ... ] )
  68      REFERENCES reftable [ ( refcolumn [, ... ] ) ]
  69       [ MATCH FULL | MATCH PARTIAL ]
  70       [ ON DELETE action ] [ ON UPDATE action ] }
  71   [ DEFERRABLE | NOT DEFERRABLE ]
  72   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  73
  74 Index:
  75 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createindex.html)
  76
  77   CREATE [ UNIQUE ] INDEX index_name ON table
  78       [ USING acc_method ] ( column [ ops_name ] [, ...] )
  79       [ WHERE predicate ]
  80   CREATE [ UNIQUE ] INDEX index_name ON table
  81       [ USING acc_method ] ( func_name( column [, ... ]) [ ops_name ] )
  82       [ WHERE predicate ]
  83
  84 Alter table:
  85
  86   ALTER TABLE [ ONLY ] table [ * ]
  87       ADD [ COLUMN ] column type [ column_constraint [ ... ] ]
  88   ALTER TABLE [ ONLY ] table [ * ]
  89       ALTER [ COLUMN ] column { SET DEFAULT value | DROP DEFAULT }
  90   ALTER TABLE [ ONLY ] table [ * ]
  91       ALTER [ COLUMN ] column SET STATISTICS integer
  92   ALTER TABLE [ ONLY ] table [ * ]
  93       RENAME [ COLUMN ] column TO newcolumn
  94   ALTER TABLE table
  95       RENAME TO new_table
  96   ALTER TABLE table
  97       ADD table_constraint_definition
  98   ALTER TABLE [ ONLY ] table
  99           DROP CONSTRAINT constraint { RESTRICT | CASCADE }
 100   ALTER TABLE table
 101           OWNER TO new_owner
 102
 103 View table:
 104
 105     CREATE [ OR REPLACE ] VIEW view [ ( column name list ) ] AS SELECT query
 106
 107 =cut
 108
 109 use strict;
 110 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
 111 $VERSION = sprintf "%d.%02d", q$Revision: 1.42 $ =~ /(\d+)\.(\d+)/;
 112 $DEBUG   = 0 unless defined $DEBUG;
 113
 114 use Data::Dumper;
 115 use Parse::RecDescent;
 116 use Exporter;
 117 use base qw(Exporter);
 118
 119 @EXPORT_OK = qw(parse);
 120
 121 # Enable warnings within the Parse::RecDescent module.
 122 $::RD_ERRORS = 1; # Make sure the parser dies when it encounters an error
 123 $::RD_WARN   = 1; # Enable warnings. This will warn on unused rules &c.
 124 $::RD_HINT   = 1; # Give out hints to help fix problems.
 125
 126 my $parser; # should we do this?  There's no programmic way to
 127             # change the grammar, so I think this is safe.
 128
 129 $GRAMMAR = q!
 130
 131 { my ( %tables, $table_order, $field_order, @table_comments) }
 132
 133 #
 134 # The "eofile" rule makes the parser fail if any "statement" rule
 135 # fails.  Otherwise, the first successful match by a "statement"
 136 # won't cause the failure needed to know that the parse, as a whole,
 137 # failed. -ky
 138 #
 139 startrule : statement(s) eofile { \%tables }
 140
 141 eofile : /^\Z/
 142
 143
 144 statement : create
 145   | comment_on_table
 146   | comment_on_column
 147   | comment_on_other
 148   | comment
 149   | alter
 150   | grant
 151   | revoke
 152   | drop
 153   | insert
 154   | connect
 155   | update
 156   | set
 157   | <error>
 158
 159 connect : /^\s*\\\connect.*\n/
 160
 161 set : /set/i /[^;]*/ ';'
 162
 163 revoke : /revoke/i WORD(s /,/) /on/i TABLE(?) table_name /from/i name_with_opt_quotes(s /,/) ';'
 164     {
 165         my $table_name = $item{'table_name'};
 166         push @{ $tables{ $table_name }{'permissions'} }, {
 167             type       => 'revoke',
 168             actions    => $item[2],
 169             users      => $item[7],
 170         }
 171     }
 172
 173 grant : /grant/i WORD(s /,/) /on/i TABLE(?) table_name /to/i name_with_opt_quotes(s /,/) ';'
 174     {
 175         my $table_name = $item{'table_name'};
 176         push @{ $tables{ $table_name }{'permissions'} }, {
 177             type       => 'grant',
 178             actions    => $item[2],
 179             users      => $item[7],
 180         }
 181     }
 182
 183 drop : /drop/i /[^;]*/ ';'
 184
 185 insert : /insert/i /[^;]*/ ';'
 186
 187 update : /update/i /[^;]*/ ';'
 188
 189 #
 190 # Create table.
 191 #
 192 create : create_table table_name '(' create_definition(s /,/) ')' table_option(s?) ';'
 193     {
 194         my $table_name                       = $item{'table_name'};
 195         $tables{ $table_name }{'order'}      = ++$table_order;
 196         $tables{ $table_name }{'table_name'} = $table_name;
 197
 198         if ( @table_comments ) {
 199             $tables{ $table_name }{'comments'} = [ @table_comments ];
 200             @table_comments = ();
 201         }
 202
 203         my @constraints;
 204         for my $definition ( @{ $item[4] } ) {
 205             if ( $definition->{'supertype'} eq 'field' ) {
 206                 my $field_name = $definition->{'name'};
 207                 $tables{ $table_name }{'fields'}{ $field_name } =
 208                     { %$definition, order => $field_order++ };
 209
 210                 for my $constraint ( @{ $definition->{'constraints'} || [] } ) {
 211                     $constraint->{'fields'} = [ $field_name ];
 212                     push @{ $tables{ $table_name }{'constraints'} },
 213                         $constraint;
 214                 }
 215             }
 216             elsif ( $definition->{'supertype'} eq 'constraint' ) {
 217                 push @{ $tables{ $table_name }{'constraints'} }, $definition;
 218             }
 219             elsif ( $definition->{'supertype'} eq 'index' ) {
 220                 push @{ $tables{ $table_name }{'indices'} }, $definition;
 221             }
 222         }
 223
 224         for my $option ( @{ $item[6] } ) {
 225             $tables{ $table_name }{'table_options(s?)'}{ $option->{'type'} } =
 226                 $option;
 227         }
 228
 229         1;
 230     }
 231
 232 create : CREATE unique(?) /(index|key)/i index_name /on/i table_name using_method(?) '(' field_name(s /,/) ')' where_predicate(?) ';'
 233     {
 234         push @{ $tables{ $item{'table_name'} }{'indices'} },
 235             {
 236                 name      => $item{'index_name'},
 237                 supertype => $item{'unique'}[0] ? 'constraint' : 'index',
 238                 type      => $item{'unique'}[0] ? 'unique'     : 'normal',
 239                 fields    => $item[9],
 240                 method    => $item{'using_method'}[0],
 241             }
 242         ;
 243
 244     }
 245
 246 #
 247 # Create anything else (e.g., domain, etc.)
 248 #
 249 create : CREATE WORD /[^;]+/ ';'
 250     { @table_comments = (); }
 251
 252 using_method : /using/i WORD { $item[2] }
 253
 254 where_predicate : /where/i /[^;]+/
 255
 256 create_definition : field
 257     | table_constraint
 258     | <error>
 259
 260 comment : /^\s*(?:#|-{2})(.*)\n/
 261     {
 262         my $comment =  $item[1];
 263         $comment    =~ s/^\s*(#|-*)\s*//;
 264         $comment    =~ s/\s*$//;
 265         $return     = $comment;
 266         push @table_comments, $comment;
 267     }
 268
 269 comment_on_table : /comment/i /on/i /table/i table_name /is/i comment_phrase ';'
 270     {
 271         push @{ $tables{ $item{'table_name'} }{'comments'} }, $item{'comment_phrase'};
 272     }
 273
 274 comment_on_column : /comment/i /on/i /column/i column_name /is/i comment_phrase ';'
 275     {
 276         my $table_name = $item[4]->{'table'};
 277         my $field_name = $item[4]->{'field'};
 278         push @{ $tables{ $table_name }{'fields'}{ $field_name }{'comments'} },
 279             $item{'comment_phrase'};
 280     }
 281
 282 comment_on_other : /comment/i /on/i /\w+/ /\w+/ /is/i comment_phrase ';'
 283     {
 284         push(@table_comments, $item{'comment_phrase'});
 285     }
 286
 287 # [added by cjm 20041019]
 288 # [TODO: other comment-on types]
 289 # for now we just have a general mechanism for handling other
 290 # kinds of comments than table/column; I'm not sure of the best
 291 # way to incorporate these into the datamodel
 292 #
 293 # this is the exhaustive list of types of comment:
 294 #COMMENT ON DATABASE my_database IS 'Development Database';
 295 #COMMENT ON INDEX my_index IS 'Enforces uniqueness on employee id';
 296 #COMMENT ON RULE my_rule IS 'Logs UPDATES of employee records';
 297 #COMMENT ON SEQUENCE my_sequence IS 'Used to generate primary keys';
 298 #COMMENT ON TABLE my_table IS 'Employee Information';
 299 #COMMENT ON TYPE my_type IS 'Complex Number support';
 300 #COMMENT ON VIEW my_view IS 'View of departmental costs';
 301 #COMMENT ON COLUMN my_table.my_field IS 'Employee ID number';
 302 #COMMENT ON TRIGGER my_trigger ON my_table IS 'Used for R.I.';
 303 #
 304 # this is tested by test 08
 305
 306 column_name : NAME '.' NAME
 307     { $return = { table => $item[1], field => $item[3] } }
 308
 309 comment_phrase : /null/i
 310     { $return = 'NULL' }
 311
 312 comment_phrase : /'/ comment_phrase_unquoted(s) /'/
 313     { my $phrase = join(' ', @{ $item[2] });
 314       $return = $phrase}
 315
 316 # [cjm TODO: double-single quotes in a comment_phrase]
 317 comment_phrase_unquoted : /[^\']*/
 318     { $return = $item[1] }
 319
 320
 321 xxxcomment_phrase : /'.*?'|NULL/
 322     {
 323         my $val = $item[1] || '';
 324         $val =~ s/^'|'$//g;
 325         $return = $val;
 326     }
 327
 328 field : field_comment(s?) field_name data_type field_meta(s?) field_comment(s?)
 329     {
 330         my ( $default, @constraints, $is_pk );
 331         my $is_nullable = 1;
 332         for my $meta ( @{ $item[4] } ) {
 333             if ( $meta->{'type'} eq 'default' ) {
 334                 $default = $meta;
 335                 next;
 336             }
 337             elsif ( $meta->{'type'} eq 'not_null' ) {
 338                 $is_nullable = 0;
 339             }
 340             elsif ( $meta->{'type'} eq 'primary_key' ) {
 341                 $is_pk = 1;
 342             }
 343
 344             push @constraints, $meta if $meta->{'supertype'} eq 'constraint';
 345         }
 346
 347         my @comments = ( @{ $item[1] }, @{ $item[5] } );
 348
 349         $return = {
 350             supertype         => 'field',
 351             name              => $item{'field_name'},
 352             data_type         => $item{'data_type'}{'type'},
 353             size              => $item{'data_type'}{'size'},
 354             is_nullable       => $is_nullable,
 355             default           => $default->{'value'},
 356             constraints       => [ @constraints ],
 357             comments          => [ @comments ],
 358             is_primary_key    => $is_pk || 0,
 359             is_auto_increment => $item{'data_type'}{'is_auto_increment'},
 360         }
 361     }
 362     | <error>
 363
 364 field_comment : /^\s*(?:#|-{2})(.*)\n/
 365     {
 366         my $comment =  $item[1];
 367         $comment    =~ s/^\s*(#|-*)\s*//;
 368         $comment    =~ s/\s*$//;
 369         $return     = $comment;
 370     }
 371
 372 field_meta : default_val
 373     | column_constraint
 374
 375 column_constraint : constraint_name(?) column_constraint_type deferrable(?) deferred(?)
 376     {
 377         my $desc       = $item{'column_constraint_type'};
 378         my $type       = $desc->{'type'};
 379         my $fields     = $desc->{'fields'}     || [];
 380         my $expression = $desc->{'expression'} || '';
 381
 382         $return              =  {
 383             supertype        => 'constraint',
 384             name             => $item{'constraint_name'}[0] || '',
 385             type             => $type,
 386             expression       => $type eq 'check' ? $expression : '',
 387             deferrable       => $item{'deferrable'},
 388             deferred         => $item{'deferred'},
 389             reference_table  => $desc->{'reference_table'},
 390             reference_fields => $desc->{'reference_fields'},
 391             match_type       => $desc->{'match_type'},
 392             on_delete_do     => $desc->{'on_delete_do'},
 393             on_update_do     => $desc->{'on_update_do'},
 394         }
 395     }
 396
 397 constraint_name : /constraint/i name_with_opt_quotes { $item[2] }
 398
 399 column_constraint_type : /not null/i { $return = { type => 'not_null' } }
 400     |
 401     /null/i
 402         { $return = { type => 'null' } }
 403     |
 404     /unique/i
 405         { $return = { type => 'unique' } }
 406     |
 407     /primary key/i
 408         { $return = { type => 'primary_key' } }
 409     |
 410     /check/i '(' /[^)]+/ ')'
 411         { $return = { type => 'check', expression => $item[3] } }
 412     |
 413     /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 414     {
 415         my ( $on_delete, $on_update );
 416         for my $action ( @{ $item[5] || [] } ) {
 417             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 418             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 419         }
 420
 421         $return              =  {
 422             type             => 'foreign_key',
 423             reference_table  => $item[2],
 424             reference_fields => $item[3][0],
 425             match_type       => $item[4][0],
 426             on_delete_do     => $on_delete,
 427             on_update_do     => $on_update,
 428         }
 429     }
 430
 431 table_name : name_with_opt_quotes
 432
 433 field_name : name_with_opt_quotes
 434
 435 name_with_opt_quotes : double_quote(?) NAME double_quote(?) { $item[2] }
 436
 437 double_quote: /"/
 438
 439 index_name : WORD
 440
 441 data_type : pg_data_type parens_value_list(?)
 442     {
 443         my $data_type = $item[1];
 444
 445         #
 446         # We can deduce some sizes from the data type's name.
 447         #
 448         if ( my $size = $item[2][0] ) {
 449             $data_type->{'size'} = $size;
 450         }
 451
 452         $return  = $data_type;
 453     }
 454
 455 pg_data_type :
 456     /(bigint|int8)/i
 457         {
 458             $return = {
 459                 type => 'integer',
 460                 size => 20,
 461             };
 462         }
 463     |
 464     /(smallint|int2)/i
 465         {
 466             $return = {
 467                 type => 'integer',
 468                 size => 5,
 469             };
 470         }
 471     |
 472     /interval/i
 473         {
 474             $return = { type => 'interval' };
 475         }
 476     |
 477     /(integer|int4?)/i # interval must come before this
 478         {
 479             $return = {
 480                 type => 'integer',
 481                 size => 10,
 482             };
 483         }
 484     |
 485     /(real|float4)/i
 486         {
 487             $return = {
 488                 type => 'real',
 489                 size => 10,
 490             };
 491         }
 492     |
 493     /(double precision|float8?)/i
 494         {
 495             $return = {
 496                 type => 'float',
 497                 size => 20,
 498             };
 499         }
 500     |
 501     /(bigserial|serial8)/i
 502         {
 503             $return = {
 504                 type              => 'integer',
 505                 size              => 20,
 506                 is_auto_increment => 1,
 507             };
 508         }
 509     |
 510     /serial4?/i
 511         {
 512             $return = {
 513                 type              => 'integer',
 514                 size              => 11,
 515                 is_auto_increment => 1,
 516             };
 517         }
 518     |
 519     /(bit varying|varbit)/i
 520         {
 521             $return = { type => 'varbit' };
 522         }
 523     |
 524     /character varying/i
 525         {
 526             $return = { type => 'varchar' };
 527         }
 528     |
 529     /char(acter)?/i
 530         {
 531             $return = { type => 'char' };
 532         }
 533     |
 534     /bool(ean)?/i
 535         {
 536             $return = { type => 'boolean' };
 537         }
 538     |
 539     /bytea/i
 540         {
 541             $return = { type => 'bytea' };
 542         }
 543     |
 544     /(timestamptz|timestamp)( with time zone)?/i
 545         {
 546             $return = { type => 'timestamp' };
 547         }
 548     |
 549     /(timestamptz|timestamp)( without time zone)?/i
 550         {
 551             $return = { type => 'timestamp' };
 552         }
 553     |
 554     /text/i
 555         {
 556             $return = {
 557                 type => 'text',
 558                 size => 64_000,
 559             };
 560         }
 561     |
 562     /(bit|box|cidr|circle|date|inet|line|lseg|macaddr|money|numeric|decimal|path|point|polygon|timetz|time|varchar)/i
 563         {
 564             $return = { type => $item[1] };
 565         }
 566
 567 parens_value_list : '(' VALUE(s /,/) ')'
 568     { $item[2] }
 569
 570 parens_word_list : '(' WORD(s /,/) ')'
 571     { $item[2] }
 572
 573 field_size : '(' num_range ')' { $item{'num_range'} }
 574
 575 num_range : DIGITS ',' DIGITS
 576     { $return = $item[1].','.$item[3] }
 577     | DIGITS
 578     { $return = $item[1] }
 579
 580 table_constraint : comment(s?) constraint_name(?) table_constraint_type deferrable(?) deferred(?) comment(s?)
 581     {
 582         my $desc       = $item{'table_constraint_type'};
 583         my $type       = $desc->{'type'};
 584         my $fields     = $desc->{'fields'};
 585         my $expression = $desc->{'expression'};
 586         my @comments   = ( @{ $item[1] }, @{ $item[-1] } );
 587
 588         $return              =  {
 589             name             => $item{'constraint_name'}[0] || '',
 590             supertype        => 'constraint',
 591             type             => $type,
 592             fields           => $type ne 'check' ? $fields : [],
 593             expression       => $type eq 'check' ? $expression : '',
 594             deferrable       => $item{'deferrable'},
 595             deferred         => $item{'deferred'},
 596             reference_table  => $desc->{'reference_table'},
 597             reference_fields => $desc->{'reference_fields'},
 598             match_type       => $desc->{'match_type'}[0],
 599             on_delete_do     => $desc->{'on_delete_do'},
 600             on_update_do     => $desc->{'on_update_do'},
 601             comments         => [ @comments ],
 602         }
 603     }
 604
 605 table_constraint_type : /primary key/i '(' name_with_opt_quotes(s /,/) ')'
 606     {
 607         $return = {
 608             type   => 'primary_key',
 609             fields => $item[3],
 610         }
 611     }
 612     |
 613     /unique/i '(' name_with_opt_quotes(s /,/) ')'
 614     {
 615         $return    =  {
 616             type   => 'unique',
 617             fields => $item[3],
 618         }
 619     }
 620     |
 621     /check/i '(' /[^)]+/ ')'
 622     {
 623         $return        =  {
 624             type       => 'check',
 625             expression => $item[3],
 626         }
 627     }
 628     |
 629     /foreign key/i '(' name_with_opt_quotes(s /,/) ')' /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 630     {
 631         my ( $on_delete, $on_update );
 632         for my $action ( @{ $item[9] || [] } ) {
 633             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 634             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 635         }
 636
 637         $return              =  {
 638             supertype        => 'constraint',
 639             type             => 'foreign_key',
 640             fields           => $item[3],
 641             reference_table  => $item[6],
 642             reference_fields => $item[7][0],
 643             match_type       => $item[8][0],
 644             on_delete_do     => $on_delete || '',
 645             on_update_do     => $on_update || '',
 646         }
 647     }
 648
 649 deferrable : /not/i /deferrable/i
 650     {
 651         $return = ( $item[1] =~ /not/i ) ? 0 : 1;
 652     }
 653
 654 deferred : /initially/i /(deferred|immediate)/i { $item[2] }
 655
 656 match_type : /match full/i { 'match_full' }
 657     |
 658     /match partial/i { 'match_partial' }
 659
 660 key_action : key_delete
 661     |
 662     key_update
 663
 664 key_delete : /on delete/i key_mutation
 665     {
 666         $return = {
 667             type   => 'delete',
 668             action => $item[2],
 669         };
 670     }
 671
 672 key_update : /on update/i key_mutation
 673     {
 674         $return = {
 675             type   => 'update',
 676             action => $item[2],
 677         };
 678     }
 679
 680 key_mutation : /no action/i { $return = 'no_action' }
 681     |
 682     /restrict/i { $return = 'restrict' }
 683     |
 684     /cascade/i { $return = 'cascade' }
 685     |
 686     /set null/i { $return = 'set null' }
 687     |
 688     /set default/i { $return = 'set default' }
 689
 690 alter : alter_table table_name add_column field ';'
 691     {
 692         my $field_def = $item[4];
 693         $tables{ $item[2] }{'fields'}{ $field_def->{'name'} } = {
 694             %$field_def, order => $field_order++
 695         };
 696         1;
 697     }
 698
 699 alter : alter_table table_name ADD table_constraint ';'
 700     {
 701         my $table_name = $item[2];
 702         my $constraint = $item[4];
 703         push @{ $tables{ $table_name }{'constraints'} }, $constraint;
 704         1;
 705     }
 706
 707 alter : alter_table table_name drop_column NAME restrict_or_cascade(?) ';'
 708     {
 709         $tables{ $item[2] }{'fields'}{ $item[4] }{'drop'} = 1;
 710         1;
 711     }
 712
 713 alter : alter_table table_name alter_column NAME alter_default_val ';'
 714     {
 715         $tables{ $item[2] }{'fields'}{ $item[4] }{'default'} =
 716             $item[5]->{'value'};
 717         1;
 718     }
 719
 720 #
 721 # These will just parse for now but won't affect the structure. - ky
 722 #
 723 alter : alter_table table_name /rename/i /to/i NAME ';'
 724     { 1 }
 725
 726 alter : alter_table table_name alter_column NAME SET /statistics/i INTEGER ';'
 727     { 1 }
 728
 729 alter : alter_table table_name alter_column NAME SET /storage/i storage_type ';'
 730     { 1 }
 731
 732 alter : alter_table table_name rename_column NAME /to/i NAME ';'
 733     { 1 }
 734
 735 alter : alter_table table_name DROP /constraint/i NAME restrict_or_cascade ';'
 736     { 1 }
 737
 738 alter : alter_table table_name /owner/i /to/i NAME ';'
 739     { 1 }
 740
 741 storage_type : /(plain|external|extended|main)/i
 742
 743 alter_default_val : SET default_val
 744     {
 745         $return = { value => $item[2]->{'value'} }
 746     }
 747     | DROP DEFAULT
 748     {
 749         $return = { value => undef }
 750     }
 751
 752 #
 753 # This is a little tricky to get right, at least WRT to making the
 754 # tests pass.  The problem is that the constraints are stored just as
 755 # a list (no name access), and the tests expect the constraints in a
 756 # particular order.  I'm going to leave the rule but disable the code
 757 # for now. - ky
 758 #
 759 alter : alter_table table_name alter_column NAME alter_nullable ';'
 760     {
 761 #        my $table_name  = $item[2];
 762 #        my $field_name  = $item[4];
 763 #        my $is_nullable = $item[5]->{'is_nullable'};
 764 #
 765 #        $tables{ $table_name }{'fields'}{ $field_name }{'is_nullable'} =
 766 #            $is_nullable;
 767 #
 768 #        if ( $is_nullable ) {
 769 #            1;
 770 #            push @{ $tables{ $table_name }{'constraints'} }, {
 771 #                type   => 'not_null',
 772 #                fields => [ $field_name ],
 773 #            };
 774 #        }
 775 #        else {
 776 #            for my $i (
 777 #                0 .. $#{ $tables{ $table_name }{'constraints'} || [] }
 778 #            ) {
 779 #                my $c = $tables{ $table_name }{'constraints'}[ $i ] or next;
 780 #                my $fields = join( '', @{ $c->{'fields'} || [] } ) or next;
 781 #                if ( $c->{'type'} eq 'not_null' && $fields eq $field_name ) {
 782 #                    delete $tables{ $table_name }{'constraints'}[ $i ];
 783 #                    last;
 784 #                }
 785 #            }
 786 #        }
 787
 788         1;
 789     }
 790
 791 alter_nullable : SET not_null
 792     {
 793         $return = { is_nullable => 0 }
 794     }
 795     | DROP not_null
 796     {
 797         $return = { is_nullable => 1 }
 798     }
 799
 800 not_null : /not/i /null/i
 801
 802 add_column : ADD COLUMN(?)
 803
 804 alter_table : ALTER TABLE ONLY(?)
 805
 806 drop_column : DROP COLUMN(?)
 807
 808 alter_column : ALTER COLUMN(?)
 809
 810 rename_column : /rename/i COLUMN(?)
 811
 812 restrict_or_cascade : /restrict/i |
 813     /cascade/i
 814
 815 #
 816 # End basically useless stuff. - ky
 817 #
 818
 819 create_table : CREATE TABLE
 820
 821 create_index : CREATE /index/i
 822
 823 default_val  : DEFAULT /(\d+|'[^']*'|\w+\(.*?\))|\w+/
 824     {
 825         my $val =  defined $item[2] ? $item[2] : '';
 826         $val    =~ s/^'|'$//g;
 827         $return =  {
 828             supertype => 'constraint',
 829             type      => 'default',
 830             value     => $val,
 831         }
 832     }
 833     | /null/i
 834     {
 835         $return =  {
 836             supertype => 'constraint',
 837             type      => 'default',
 838             value     => 'NULL',
 839         }
 840     }
 841
 842 name_with_opt_paren : NAME parens_value_list(s?)
 843     { $item[2][0] ? "$item[1]($item[2][0][0])" : $item[1] }
 844
 845 unique : /unique/i { 1 }
 846
 847 key : /key/i | /index/i
 848
 849 table_option : /inherits/i '(' name_with_opt_quotes(s /,/) ')'
 850     {
 851         $return = { type => 'inherits', table_name => $item[3] }
 852     }
 853     |
 854     /with(out)? oids/i
 855     {
 856         $return = { type => $item[1] =~ /out/i ? 'without_oids' : 'with_oids' }
 857     }
 858
 859 ADD : /add/i
 860
 861 ALTER : /alter/i
 862
 863 CREATE : /create/i
 864
 865 ONLY : /only/i
 866
 867 DEFAULT : /default/i
 868
 869 DROP : /drop/i
 870
 871 COLUMN : /column/i
 872
 873 TABLE : /table/i
 874
 875 SEMICOLON : /\s*;\n?/
 876
 877 INTEGER : /\d+/
 878
 879 WORD : /\w+/
 880
 881 DIGITS : /\d+/
 882
 883 COMMA : ','
 884
 885 SET : /set/i
 886
 887 NAME    : "`" /\w+/ "`"
 888     { $item[2] }
 889     | /\w+/
 890     { $item[1] }
 891     | /[\$\w]+/
 892     { $item[1] }
 893
 894 VALUE   : /[-+]?\.?\d+(?:[eE]\d+)?/
 895     { $item[1] }
 896     | /'.*?'/   # XXX doesn't handle embedded quotes
 897     { $item[1] }
 898     | /null/i
 899     { 'NULL' }
 900
 901 !;
 902
 903 # -------------------------------------------------------------------
 904 sub parse {
 905     my ( $translator, $data ) = @_;
 906     $parser ||= Parse::RecDescent->new($GRAMMAR);
 907
 908     $::RD_TRACE  = $translator->trace ? 1 : undef;
 909     $DEBUG       = $translator->debug;
 910
 911     unless (defined $parser) {
 912         return $translator->error("Error instantiating Parse::RecDescent ".
 913             "instance: Bad grammer");
 914     }
 915
 916     my $result = $parser->startrule($data);
 917     die "Parse failed.\n" unless defined $result;
 918     warn Dumper($result) if $DEBUG;
 919
 920     my $schema = $translator->schema;
 921     my @tables = sort {
 922         ( $result->{ $a }{'order'} || 0 ) <=> ( $result->{ $b }{'order'} || 0 )
 923     } keys %{ $result };
 924
 925     for my $table_name ( @tables ) {
 926         my $tdata =  $result->{ $table_name };
 927         my $table =  $schema->add_table(
 928             name  => $tdata->{'table_name'},
 929         ) or die "Couldn't create table '$table_name': " . $schema->error;
 930
 931         $table->comments( $tdata->{'comments'} );
 932
 933         my @fields = sort {
 934             $tdata->{'fields'}{ $a }{'order'}
 935             <=>
 936             $tdata->{'fields'}{ $b }{'order'}
 937         } keys %{ $tdata->{'fields'} };
 938
 939         for my $fname ( @fields ) {
 940             my $fdata = $tdata->{'fields'}{ $fname };
 941             next if $fdata->{'drop'};
 942             my $field = $table->add_field(
 943                 name              => $fdata->{'name'},
 944                 data_type         => $fdata->{'data_type'},
 945                 size              => $fdata->{'size'},
 946                 default_value     => $fdata->{'default'},
 947                 is_auto_increment => $fdata->{'is_auto_increment'},
 948                 is_nullable       => $fdata->{'is_nullable'},
 949                 comments          => $fdata->{'comments'},
 950             ) or die $table->error;
 951
 952             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 953
 954             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 955                 next unless $cdata->{'type'} eq 'foreign_key';
 956                 $cdata->{'fields'} ||= [ $field->name ];
 957                 push @{ $tdata->{'constraints'} }, $cdata;
 958             }
 959         }
 960
 961         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 962             my $index  =  $table->add_index(
 963                 name   => $idata->{'name'},
 964                 type   => uc $idata->{'type'},
 965                 fields => $idata->{'fields'},
 966             ) or die $table->error;
 967         }
 968
 969         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 970             my $constraint       =  $table->add_constraint(
 971                 name             => $cdata->{'name'},
 972                 type             => $cdata->{'type'},
 973                 fields           => $cdata->{'fields'},
 974                 reference_table  => $cdata->{'reference_table'},
 975                 reference_fields => $cdata->{'reference_fields'},
 976                 match_type       => $cdata->{'match_type'} || '',
 977                 on_delete        => $cdata->{'on_delete_do'},
 978                 on_update        => $cdata->{'on_update_do'},
 979                 expression       => $cdata->{'expression'},
 980             ) or die "Can't add constraint of type '" .
 981                 $cdata->{'type'} .  "' to table '" . $table->name .
 982                 "': " . $table->error;
 983         }
 984     }
 985
 986     return 1;
 987 }
 988
 989 1;
 990
 991 # -------------------------------------------------------------------
 992 # Rescue the drowning and tie your shoestrings.
 993 # Henry David Thoreau
 994 # -------------------------------------------------------------------
 995
 996 =pod
 997
 998 =head1 AUTHORS
 999
1000 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>,
1001 Allen Day E<lt>allenday@ucla.eduE<gt>.
1002
1003 =head1 SEE ALSO
1004
1005 perl(1), Parse::RecDescent.
1006
1007 =cut