lib/SQL/Translator/Parser/PostgreSQL.pm

   1 package SQL::Translator::Parser::PostgreSQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: PostgreSQL.pm,v 1.37 2004-02-09 22:23:40 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Parser::PostgreSQL - parser for PostgreSQL
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator;
  30   use SQL::Translator::Parser::PostgreSQL;
  31
  32   my $translator = SQL::Translator->new;
  33   $translator->parser("SQL::Translator::Parser::PostgreSQL");
  34
  35 =head1 DESCRIPTION
  36
  37 The grammar was started from the MySQL parsers.  Here is the description
  38 from PostgreSQL:
  39
  40 Table:
  41 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createtable.html)
  42
  43   CREATE [ [ LOCAL ] { TEMPORARY | TEMP } ] TABLE table_name (
  44       { column_name data_type [ DEFAULT default_expr ]
  45          [ column_constraint [, ... ] ]
  46       | table_constraint }  [, ... ]
  47   )
  48   [ INHERITS ( parent_table [, ... ] ) ]
  49   [ WITH OIDS | WITHOUT OIDS ]
  50
  51   where column_constraint is:
  52
  53   [ CONSTRAINT constraint_name ]
  54   { NOT NULL | NULL | UNIQUE | PRIMARY KEY |
  55     CHECK (expression) |
  56     REFERENCES reftable [ ( refcolumn ) ] [ MATCH FULL | MATCH PARTIAL ]
  57       [ ON DELETE action ] [ ON UPDATE action ] }
  58   [ DEFERRABLE | NOT DEFERRABLE ]
  59   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  60
  61   and table_constraint is:
  62
  63   [ CONSTRAINT constraint_name ]
  64   { UNIQUE ( column_name [, ... ] ) |
  65     PRIMARY KEY ( column_name [, ... ] ) |
  66     CHECK ( expression ) |
  67     FOREIGN KEY ( column_name [, ... ] )
  68      REFERENCES reftable [ ( refcolumn [, ... ] ) ]
  69       [ MATCH FULL | MATCH PARTIAL ]
  70       [ ON DELETE action ] [ ON UPDATE action ] }
  71   [ DEFERRABLE | NOT DEFERRABLE ]
  72   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  73
  74 Index:
  75 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createindex.html)
  76
  77   CREATE [ UNIQUE ] INDEX index_name ON table
  78       [ USING acc_method ] ( column [ ops_name ] [, ...] )
  79       [ WHERE predicate ]
  80   CREATE [ UNIQUE ] INDEX index_name ON table
  81       [ USING acc_method ] ( func_name( column [, ... ]) [ ops_name ] )
  82       [ WHERE predicate ]
  83
  84 Alter table:
  85
  86   ALTER TABLE [ ONLY ] table [ * ]
  87       ADD [ COLUMN ] column type [ column_constraint [ ... ] ]
  88   ALTER TABLE [ ONLY ] table [ * ]
  89       ALTER [ COLUMN ] column { SET DEFAULT value | DROP DEFAULT }
  90   ALTER TABLE [ ONLY ] table [ * ]
  91       ALTER [ COLUMN ] column SET STATISTICS integer
  92   ALTER TABLE [ ONLY ] table [ * ]
  93       RENAME [ COLUMN ] column TO newcolumn
  94   ALTER TABLE table
  95       RENAME TO new_table
  96   ALTER TABLE table
  97       ADD table_constraint_definition
  98   ALTER TABLE [ ONLY ] table
  99           DROP CONSTRAINT constraint { RESTRICT | CASCADE }
 100   ALTER TABLE table
 101           OWNER TO new_owner
 102
 103 View table:
 104
 105     CREATE [ OR REPLACE ] VIEW view [ ( column name list ) ] AS SELECT query
 106
 107 =cut
 108
 109 use strict;
 110 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
 111 $VERSION = sprintf "%d.%02d", q$Revision: 1.37 $ =~ /(\d+)\.(\d+)/;
 112 $DEBUG   = 0 unless defined $DEBUG;
 113
 114 use Data::Dumper;
 115 use Parse::RecDescent;
 116 use Exporter;
 117 use base qw(Exporter);
 118
 119 @EXPORT_OK = qw(parse);
 120
 121 # Enable warnings within the Parse::RecDescent module.
 122 $::RD_ERRORS = 1; # Make sure the parser dies when it encounters an error
 123 $::RD_WARN   = 1; # Enable warnings. This will warn on unused rules &c.
 124 $::RD_HINT   = 1; # Give out hints to help fix problems.
 125
 126 my $parser; # should we do this?  There's no programmic way to
 127             # change the grammar, so I think this is safe.
 128
 129 $GRAMMAR = q!
 130
 131 { my ( %tables, $table_order, $field_order, @table_comments) }
 132
 133 #
 134 # The "eofile" rule makes the parser fail if any "statement" rule
 135 # fails.  Otherwise, the first successful match by a "statement"
 136 # won't cause the failure needed to know that the parse, as a whole,
 137 # failed. -ky
 138 #
 139 startrule : statement(s) eofile { \%tables }
 140
 141 eofile : /^\Z/
 142
 143 statement : create
 144   | comment_on_table
 145   | comment_on_column
 146   | comment
 147   | alter
 148   | grant
 149   | revoke
 150   | drop
 151   | insert
 152   | connect
 153   | update
 154   | set
 155   | <error>
 156
 157 connect : /^\s*\\\connect.*\n/
 158
 159 set : /set/i /[^;]*/ ';'
 160
 161 revoke : /revoke/i WORD(s /,/) /on/i TABLE(?) table_name /from/i name_with_opt_quotes(s /,/) ';'
 162     {
 163         my $table_name = $item{'table_name'};
 164         push @{ $tables{ $table_name }{'permissions'} }, {
 165             type       => 'revoke',
 166             actions    => $item[2],
 167             users      => $item[7],
 168         }
 169     }
 170
 171 grant : /grant/i WORD(s /,/) /on/i TABLE(?) table_name /to/i name_with_opt_quotes(s /,/) ';'
 172     {
 173         my $table_name = $item{'table_name'};
 174         push @{ $tables{ $table_name }{'permissions'} }, {
 175             type       => 'grant',
 176             actions    => $item[2],
 177             users      => $item[7],
 178         }
 179     }
 180
 181 drop : /drop/i /[^;]*/ ';'
 182
 183 insert : /insert/i /[^;]*/ ';'
 184
 185 update : /update/i /[^;]*/ ';'
 186
 187 #
 188 # Create table.
 189 #
 190 create : create_table table_name '(' create_definition(s /,/) ')' table_option(s?) ';'
 191     {
 192         my $table_name                       = $item{'table_name'};
 193         $tables{ $table_name }{'order'}      = ++$table_order;
 194         $tables{ $table_name }{'table_name'} = $table_name;
 195
 196         if ( @table_comments ) {
 197             $tables{ $table_name }{'comments'} = [ @table_comments ];
 198             @table_comments = ();
 199         }
 200
 201         my @constraints;
 202         for my $definition ( @{ $item[4] } ) {
 203             if ( $definition->{'supertype'} eq 'field' ) {
 204                 my $field_name = $definition->{'name'};
 205                 $tables{ $table_name }{'fields'}{ $field_name } =
 206                     { %$definition, order => $field_order++ };
 207
 208                 for my $constraint ( @{ $definition->{'constraints'} || [] } ) {
 209                     $constraint->{'fields'} = [ $field_name ];
 210                     push @{ $tables{ $table_name }{'constraints'} },
 211                         $constraint;
 212                 }
 213             }
 214             elsif ( $definition->{'supertype'} eq 'constraint' ) {
 215                 push @{ $tables{ $table_name }{'constraints'} }, $definition;
 216             }
 217             elsif ( $definition->{'supertype'} eq 'index' ) {
 218                 push @{ $tables{ $table_name }{'indices'} }, $definition;
 219             }
 220         }
 221
 222         for my $option ( @{ $item[6] } ) {
 223             $tables{ $table_name }{'table_options(s?)'}{ $option->{'type'} } =
 224                 $option;
 225         }
 226
 227         1;
 228     }
 229
 230 create : CREATE unique(?) /(index|key)/i index_name /on/i table_name using_method(?) '(' field_name(s /,/) ')' where_predicate(?) ';'
 231     {
 232         push @{ $tables{ $item{'table_name'} }{'indices'} },
 233             {
 234                 name      => $item{'index_name'},
 235                 supertype => $item{'unique'}[0] ? 'constraint' : 'index',
 236                 type      => $item{'unique'}[0] ? 'unique'     : 'normal',
 237                 fields    => $item[9],
 238                 method    => $item{'using_method'}[0],
 239             }
 240         ;
 241
 242     }
 243
 244 #
 245 # Create anything else (e.g., domain, etc.)
 246 #
 247 create : CREATE WORD /[^;]+/ ';'
 248     { @table_comments = (); }
 249
 250 using_method : /using/i WORD { $item[2] }
 251
 252 where_predicate : /where/i /[^;]+/
 253
 254 create_definition : field
 255     | table_constraint
 256     | <error>
 257
 258 table_comment : comment
 259     {
 260         my $comment = $item[1];
 261         $return     = $comment;
 262         push @table_comments, $comment;
 263     }
 264
 265 comment : /^\s*(?:#|-{2}).*\n/
 266
 267 comment_on_table : /comment/i /on/i /table/i table_name /is/i comment_phrase ';'
 268     {
 269         push @{ $tables{ $item{'table_name'} }{'comments'} }, $item{'comment_phrase'};
 270     }
 271
 272 comment_on_column : /comment/i /on/i /column/i column_name /is/i comment_phrase ';'
 273     {
 274         my $table_name = $item[4]->{'table'};
 275         my $field_name = $item[4]->{'field'};
 276         push @{ $tables{ $table_name }{'fields'}{ $field_name }{'comments'} },
 277             $item{'comment_phrase'};
 278     }
 279
 280 column_name : NAME '.' NAME
 281     { $return = { table => $item[1], field => $item[3] } }
 282
 283 comment_phrase : /'.*?'|NULL/
 284     {
 285         my $val = $item[1] || '';
 286         $val =~ s/^'|'$//g;
 287         $return = $val;
 288     }
 289
 290 field : comment(s?) field_name data_type field_meta(s?) comment(s?)
 291     {
 292         my ( $default, @constraints, $is_pk );
 293         my $is_nullable = 1;
 294         for my $meta ( @{ $item[4] } ) {
 295             if ( $meta->{'type'} eq 'default' ) {
 296                 $default = $meta;
 297                 next;
 298             }
 299             elsif ( $meta->{'type'} eq 'not_null' ) {
 300                 $is_nullable = 0;
 301             }
 302             elsif ( $meta->{'type'} eq 'primary_key' ) {
 303                 $is_pk = 1;
 304             }
 305
 306             push @constraints, $meta if $meta->{'supertype'} eq 'constraint';
 307         }
 308
 309         my @comments = ( @{ $item[1] }, @{ $item[5] } );
 310
 311         $return = {
 312             supertype         => 'field',
 313             name              => $item{'field_name'},
 314             data_type         => $item{'data_type'}{'type'},
 315             size              => $item{'data_type'}{'size'},
 316             is_nullable       => $is_nullable,
 317             default           => $default->{'value'},
 318             constraints       => [ @constraints ],
 319             comments          => [ @comments ],
 320             is_primary_key    => $is_pk || 0,
 321             is_auto_increment => $item{'data_type'}{'is_auto_increment'},
 322         }
 323     }
 324     | <error>
 325
 326 field_meta : default_val
 327     | column_constraint
 328
 329 column_constraint : constraint_name(?) column_constraint_type deferrable(?) deferred(?)
 330     {
 331         my $desc       = $item{'column_constraint_type'};
 332         my $type       = $desc->{'type'};
 333         my $fields     = $desc->{'fields'}     || [];
 334         my $expression = $desc->{'expression'} || '';
 335
 336         $return              =  {
 337             supertype        => 'constraint',
 338             name             => $item{'constraint_name'}[0] || '',
 339             type             => $type,
 340             expression       => $type eq 'check' ? $expression : '',
 341             deferrable       => $item{'deferrable'},
 342             deferred         => $item{'deferred'},
 343             reference_table  => $desc->{'reference_table'},
 344             reference_fields => $desc->{'reference_fields'},
 345             match_type       => $desc->{'match_type'},
 346             on_delete_do     => $desc->{'on_delete_do'},
 347             on_update_do     => $desc->{'on_update_do'},
 348         }
 349     }
 350
 351 constraint_name : /constraint/i name_with_opt_quotes { $item[2] }
 352
 353 column_constraint_type : /not null/i { $return = { type => 'not_null' } }
 354     |
 355     /null/i
 356         { $return = { type => 'null' } }
 357     |
 358     /unique/i
 359         { $return = { type => 'unique' } }
 360     |
 361     /primary key/i
 362         { $return = { type => 'primary_key' } }
 363     |
 364     /check/i '(' /[^)]+/ ')'
 365         { $return = { type => 'check', expression => $item[3] } }
 366     |
 367     /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 368     {
 369         my ( $on_delete, $on_update );
 370         for my $action ( @{ $item[5] || [] } ) {
 371             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 372             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 373         }
 374
 375         $return              =  {
 376             type             => 'foreign_key',
 377             reference_table  => $item[2],
 378             reference_fields => $item[3][0],
 379             match_type       => $item[4][0],
 380             on_delete_do     => $on_delete,
 381             on_update_do     => $on_update,
 382         }
 383     }
 384
 385 table_name : name_with_opt_quotes
 386
 387 field_name : name_with_opt_quotes
 388
 389 name_with_opt_quotes : double_quote(?) NAME double_quote(?) { $item[2] }
 390
 391 double_quote: /"/
 392
 393 index_name : WORD
 394
 395 data_type : pg_data_type parens_value_list(?)
 396     {
 397         my $data_type = $item[1];
 398
 399         #
 400         # We can deduce some sizes from the data type's name.
 401         #
 402         $data_type->{'size'} ||= $item[2][0];
 403
 404         $return  = $data_type;
 405     }
 406
 407 pg_data_type :
 408     /(bigint|int8)/i
 409         {
 410             $return = {
 411                 type => 'integer',
 412                 size => 20,
 413             };
 414         }
 415     |
 416     /(smallint|int2)/i
 417         {
 418             $return = {
 419                 type => 'integer',
 420                 size => 5,
 421             };
 422         }
 423     |
 424     /(integer|int4?)/i # interval must come before this
 425         {
 426             $return = {
 427                 type => 'integer',
 428                 size => 10,
 429             };
 430         }
 431     |
 432     /(real|float4)/i
 433         {
 434             $return = {
 435                 type => 'real',
 436                 size => 10,
 437             };
 438         }
 439     |
 440     /(double precision|float8?)/i
 441         {
 442             $return = {
 443                 type => 'float',
 444                 size => 20,
 445             };
 446         }
 447     |
 448     /(bigserial|serial8)/i
 449         {
 450             $return = {
 451                 type              => 'integer',
 452                 size              => 20,
 453                 is_auto_increment => 1,
 454             };
 455         }
 456     |
 457     /serial4?/i
 458         {
 459             $return = {
 460                 type              => 'integer',
 461                 size              => 11,
 462                 is_auto_increment => 1,
 463             };
 464         }
 465     |
 466     /(bit varying|varbit)/i
 467         {
 468             $return = { type => 'varbit' };
 469         }
 470     |
 471     /character varying/i
 472         {
 473             $return = { type => 'varchar' };
 474         }
 475     |
 476     /char(acter)?/i
 477         {
 478             $return = { type => 'char' };
 479         }
 480     |
 481     /bool(ean)?/i
 482         {
 483             $return = { type => 'boolean' };
 484         }
 485     |
 486     /bytea/i
 487         {
 488             $return = { type => 'bytea' };
 489         }
 490     |
 491     /(timestamptz|timestamp)/i
 492         {
 493             $return = { type => 'timestamp' };
 494         }
 495     |
 496     /text/i
 497         {
 498             $return = {
 499                 type => 'text',
 500                 size => 64_000,
 501             };
 502         }
 503     |
 504     /(bit|box|cidr|circle|date|inet|interval|line|lseg|macaddr|money|numeric|decimal|path|point|polygon|timetz|time|varchar)/i
 505         {
 506             $return = { type => $item[1] };
 507         }
 508
 509 parens_value_list : '(' VALUE(s /,/) ')'
 510     { $item[2] }
 511
 512 parens_word_list : '(' WORD(s /,/) ')'
 513     { $item[2] }
 514
 515 field_size : '(' num_range ')' { $item{'num_range'} }
 516
 517 num_range : DIGITS ',' DIGITS
 518     { $return = $item[1].','.$item[3] }
 519     | DIGITS
 520     { $return = $item[1] }
 521
 522 table_constraint : comment(s?) constraint_name(?) table_constraint_type deferrable(?) deferred(?) comment(s?)
 523     {
 524         my $desc       = $item{'table_constraint_type'};
 525         my $type       = $desc->{'type'};
 526         my $fields     = $desc->{'fields'};
 527         my $expression = $desc->{'expression'};
 528         my @comments   = ( @{ $item[1] }, @{ $item[-1] } );
 529
 530         $return              =  {
 531             name             => $item{'constraint_name'}[0] || '',
 532             supertype        => 'constraint',
 533             type             => $type,
 534             fields           => $type ne 'check' ? $fields : [],
 535             expression       => $type eq 'check' ? $expression : '',
 536             deferrable       => $item{'deferrable'},
 537             deferred         => $item{'deferred'},
 538             reference_table  => $desc->{'reference_table'},
 539             reference_fields => $desc->{'reference_fields'},
 540             match_type       => $desc->{'match_type'}[0],
 541             on_delete_do     => $desc->{'on_delete_do'},
 542             on_update_do     => $desc->{'on_update_do'},
 543             comments         => [ @comments ],
 544         }
 545     }
 546
 547 table_constraint_type : /primary key/i '(' name_with_opt_quotes(s /,/) ')'
 548     {
 549         $return = {
 550             type   => 'primary_key',
 551             fields => $item[3],
 552         }
 553     }
 554     |
 555     /unique/i '(' name_with_opt_quotes(s /,/) ')'
 556     {
 557         $return    =  {
 558             type   => 'unique',
 559             fields => $item[3],
 560         }
 561     }
 562     |
 563     /check/i '(' /[^)]+/ ')'
 564     {
 565         $return        =  {
 566             type       => 'check',
 567             expression => $item[3],
 568         }
 569     }
 570     |
 571     /foreign key/i '(' name_with_opt_quotes(s /,/) ')' /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 572     {
 573         my ( $on_delete, $on_update );
 574         for my $action ( @{ $item[9] || [] } ) {
 575             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 576             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 577         }
 578
 579         $return              =  {
 580             supertype        => 'constraint',
 581             type             => 'foreign_key',
 582             fields           => $item[3],
 583             reference_table  => $item[6],
 584             reference_fields => $item[7][0],
 585             match_type       => $item[8][0],
 586             on_delete_do     => $on_delete || '',
 587             on_update_do     => $on_update || '',
 588         }
 589     }
 590
 591 deferrable : /not/i /deferrable/i
 592     {
 593         $return = ( $item[1] =~ /not/i ) ? 0 : 1;
 594     }
 595
 596 deferred : /initially/i /(deferred|immediate)/i { $item[2] }
 597
 598 match_type : /match full/i { 'match_full' }
 599     |
 600     /match partial/i { 'match_partial' }
 601
 602 key_action : key_delete
 603     |
 604     key_update
 605
 606 key_delete : /on delete/i key_mutation
 607     {
 608         $return = {
 609             type   => 'delete',
 610             action => $item[2],
 611         };
 612     }
 613
 614 key_update : /on update/i key_mutation
 615     {
 616         $return = {
 617             type   => 'update',
 618             action => $item[2],
 619         };
 620     }
 621
 622 key_mutation : /no action/i { $return = 'no_action' }
 623     |
 624     /restrict/i { $return = 'restrict' }
 625     |
 626     /cascade/i { $return = 'cascade' }
 627     |
 628     /set null/i { $return = 'set null' }
 629     |
 630     /set default/i { $return = 'set default' }
 631
 632 alter : alter_table table_name add_column field ';'
 633     {
 634         my $field_def = $item[4];
 635         $tables{ $item[2] }{'fields'}{ $field_def->{'name'} } = {
 636             %$field_def, order => $field_order++
 637         };
 638         1;
 639     }
 640
 641 alter : alter_table table_name ADD table_constraint ';'
 642     {
 643         my $table_name = $item[2];
 644         my $constraint = $item[4];
 645         push @{ $tables{ $table_name }{'constraints'} }, $constraint;
 646         1;
 647     }
 648
 649 alter : alter_table table_name drop_column NAME restrict_or_cascade(?) ';'
 650     {
 651         $tables{ $item[2] }{'fields'}{ $item[4] }{'drop'} = 1;
 652         1;
 653     }
 654
 655 alter : alter_table table_name alter_column NAME alter_default_val ';'
 656     {
 657         $tables{ $item[2] }{'fields'}{ $item[4] }{'default'} =
 658             $item[5]->{'value'};
 659         1;
 660     }
 661
 662 #
 663 # These will just parse for now but won't affect the structure. - ky
 664 #
 665 alter : alter_table table_name /rename/i /to/i NAME ';'
 666     { 1 }
 667
 668 alter : alter_table table_name alter_column NAME SET /statistics/i INTEGER ';'
 669     { 1 }
 670
 671 alter : alter_table table_name alter_column NAME SET /storage/i storage_type ';'
 672     { 1 }
 673
 674 alter : alter_table table_name rename_column NAME /to/i NAME ';'
 675     { 1 }
 676
 677 alter : alter_table table_name DROP /constraint/i NAME restrict_or_cascade ';'
 678     { 1 }
 679
 680 alter : alter_table table_name /owner/i /to/i NAME ';'
 681     { 1 }
 682
 683 storage_type : /(plain|external|extended|main)/i
 684
 685 alter_default_val : SET default_val
 686     {
 687         $return = { value => $item[2]->{'value'} }
 688     }
 689     | DROP DEFAULT
 690     {
 691         $return = { value => undef }
 692     }
 693
 694 #
 695 # This is a little tricky to get right, at least WRT to making the
 696 # tests pass.  The problem is that the constraints are stored just as
 697 # a list (no name access), and the tests expect the constraints in a
 698 # particular order.  I'm going to leave the rule but disable the code
 699 # for now. - ky
 700 #
 701 alter : alter_table table_name alter_column NAME alter_nullable ';'
 702     {
 703 #        my $table_name  = $item[2];
 704 #        my $field_name  = $item[4];
 705 #        my $is_nullable = $item[5]->{'is_nullable'};
 706 #
 707 #        $tables{ $table_name }{'fields'}{ $field_name }{'is_nullable'} =
 708 #            $is_nullable;
 709 #
 710 #        if ( $is_nullable ) {
 711 #            1;
 712 #            push @{ $tables{ $table_name }{'constraints'} }, {
 713 #                type   => 'not_null',
 714 #                fields => [ $field_name ],
 715 #            };
 716 #        }
 717 #        else {
 718 #            for my $i (
 719 #                0 .. $#{ $tables{ $table_name }{'constraints'} || [] }
 720 #            ) {
 721 #                my $c = $tables{ $table_name }{'constraints'}[ $i ] or next;
 722 #                my $fields = join( '', @{ $c->{'fields'} || [] } ) or next;
 723 #                if ( $c->{'type'} eq 'not_null' && $fields eq $field_name ) {
 724 #                    delete $tables{ $table_name }{'constraints'}[ $i ];
 725 #                    last;
 726 #                }
 727 #            }
 728 #        }
 729
 730         1;
 731     }
 732
 733 alter_nullable : SET not_null
 734     {
 735         $return = { is_nullable => 0 }
 736     }
 737     | DROP not_null
 738     {
 739         $return = { is_nullable => 1 }
 740     }
 741
 742 not_null : /not/i /null/i
 743
 744 add_column : ADD COLUMN(?)
 745
 746 alter_table : ALTER TABLE ONLY(?)
 747
 748 drop_column : DROP COLUMN(?)
 749
 750 alter_column : ALTER COLUMN(?)
 751
 752 rename_column : /rename/i COLUMN(?)
 753
 754 restrict_or_cascade : /restrict/i |
 755     /cascade/i
 756
 757 #
 758 # End basically useless stuff. - ky
 759 #
 760
 761 create_table : CREATE TABLE
 762
 763 create_index : CREATE /index/i
 764
 765 default_val  : DEFAULT /(\d+|'[^']*'|\w+\(.*?\))|\w+/
 766     {
 767         my $val =  defined $item[2] ? $item[2] : '';
 768         $val    =~ s/^'|'$//g;
 769         $return =  {
 770             supertype => 'constraint',
 771             type      => 'default',
 772             value     => $val,
 773         }
 774     }
 775     | /null/i
 776     {
 777         $return =  {
 778             supertype => 'constraint',
 779             type      => 'default',
 780             value     => 'NULL',
 781         }
 782     }
 783
 784 name_with_opt_paren : NAME parens_value_list(s?)
 785     { $item[2][0] ? "$item[1]($item[2][0][0])" : $item[1] }
 786
 787 unique : /unique/i { 1 }
 788
 789 key : /key/i | /index/i
 790
 791 table_option : /inherits/i '(' name_with_opt_quotes(s /,/) ')'
 792     {
 793         $return = { type => 'inherits', table_name => $item[3] }
 794     }
 795     |
 796     /with(out)? oids/i
 797     {
 798         $return = { type => $item[1] =~ /out/i ? 'without_oids' : 'with_oids' }
 799     }
 800
 801 ADD : /add/i
 802
 803 ALTER : /alter/i
 804
 805 CREATE : /create/i
 806
 807 ONLY : /only/i
 808
 809 DEFAULT : /default/i
 810
 811 DROP : /drop/i
 812
 813 COLUMN : /column/i
 814
 815 TABLE : /table/i
 816
 817 SEMICOLON : /\s*;\n?/
 818
 819 INTEGER : /\d+/
 820
 821 WORD : /\w+/
 822
 823 DIGITS : /\d+/
 824
 825 COMMA : ','
 826
 827 SET : /set/i
 828
 829 NAME    : "`" /\w+/ "`"
 830     { $item[2] }
 831     | /\w+/
 832     { $item[1] }
 833     | /[\$\w]+/
 834     { $item[1] }
 835
 836 VALUE   : /[-+]?\.?\d+(?:[eE]\d+)?/
 837     { $item[1] }
 838     | /'.*?'/   # XXX doesn't handle embedded quotes
 839     { $item[1] }
 840     | /null/i
 841     { 'NULL' }
 842
 843 !;
 844
 845 # -------------------------------------------------------------------
 846 sub parse {
 847     my ( $translator, $data ) = @_;
 848     $parser ||= Parse::RecDescent->new($GRAMMAR);
 849
 850     $::RD_TRACE  = $translator->trace ? 1 : undef;
 851     $DEBUG       = $translator->debug;
 852
 853     unless (defined $parser) {
 854         return $translator->error("Error instantiating Parse::RecDescent ".
 855             "instance: Bad grammer");
 856     }
 857
 858     my $result = $parser->startrule($data);
 859     die "Parse failed.\n" unless defined $result;
 860     warn Dumper($result) if $DEBUG;
 861
 862     my $schema = $translator->schema;
 863     my @tables = sort {
 864         $result->{ $a }->{'order'} <=> $result->{ $b }->{'order'}
 865     } keys %{ $result };
 866
 867     for my $table_name ( @tables ) {
 868         my $tdata =  $result->{ $table_name };
 869         my $table =  $schema->add_table(
 870             name  => $tdata->{'table_name'},
 871         ) or die "Couldn't create table '$table_name': " . $schema->error;
 872
 873         my @fields = sort {
 874             $tdata->{'fields'}->{ $a }->{'order'}
 875             <=>
 876             $tdata->{'fields'}->{ $b }->{'order'}
 877         } keys %{ $tdata->{'fields'} };
 878
 879         for my $fname ( @fields ) {
 880             my $fdata = $tdata->{'fields'}{ $fname };
 881             next if $fdata->{'drop'};
 882             my $field = $table->add_field(
 883                 name              => $fdata->{'name'},
 884                 data_type         => $fdata->{'data_type'},
 885                 size              => $fdata->{'size'},
 886                 default_value     => $fdata->{'default'},
 887                 is_auto_increment => $fdata->{'is_auto_increment'},
 888                 is_nullable       => $fdata->{'is_nullable'},
 889             ) or die $table->error;
 890
 891             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 892
 893             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 894                 next unless $cdata->{'type'} eq 'foreign_key';
 895                 $cdata->{'fields'} ||= [ $field->name ];
 896                 push @{ $tdata->{'constraints'} }, $cdata;
 897             }
 898         }
 899
 900         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 901             my $index  =  $table->add_index(
 902                 name   => $idata->{'name'},
 903                 type   => uc $idata->{'type'},
 904                 fields => $idata->{'fields'},
 905             ) or die $table->error;
 906         }
 907
 908         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 909             my $constraint       =  $table->add_constraint(
 910                 name             => $cdata->{'name'},
 911                 type             => $cdata->{'type'},
 912                 fields           => $cdata->{'fields'},
 913                 reference_table  => $cdata->{'reference_table'},
 914                 reference_fields => $cdata->{'reference_fields'},
 915                 match_type       => $cdata->{'match_type'} || '',
 916                 on_delete        => $cdata->{'on_delete_do'},
 917                 on_update        => $cdata->{'on_update_do'},
 918                 expression       => $cdata->{'expression'},
 919             ) or die "Can't add constraint of type '" .
 920                 $cdata->{'type'} .  "' to table '" . $table->name .
 921                 "': " . $table->error;
 922         }
 923     }
 924
 925     return 1;
 926 }
 927
 928 1;
 929
 930 # -------------------------------------------------------------------
 931 # Rescue the drowning and tie your shoestrings.
 932 # Henry David Thoreau
 933 # -------------------------------------------------------------------
 934
 935 =pod
 936
 937 =head1 AUTHORS
 938
 939 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>,
 940 Allen Day E<lt>allenday@ucla.eduE<gt>.
 941
 942 =head1 SEE ALSO
 943
 944 perl(1), Parse::RecDescent.
 945
 946 =cut