lib/SQL/Translator/Parser/PostgreSQL.pm

   1 package SQL::Translator::Parser::PostgreSQL;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: PostgreSQL.pm,v 1.27 2003-08-17 00:46:23 rossta Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>,
   7 #                    Allen Day <allenday@users.sourceforge.net>,
   8 #                    darren chamberlain <darren@cpan.org>,
   9 #                    Chris Mungall <cjm@fruitfly.org>
  10 #
  11 # This program is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU General Public License as
  13 # published by the Free Software Foundation; version 2.
  14 #
  15 # This program is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program; if not, write to the Free Software
  22 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  23 # 02111-1307  USA
  24 # -------------------------------------------------------------------
  25
  26 =head1 NAME
  27
  28 SQL::Translator::Parser::PostgreSQL - parser for PostgreSQL
  29
  30 =head1 SYNOPSIS
  31
  32   use SQL::Translator;
  33   use SQL::Translator::Parser::PostgreSQL;
  34
  35   my $translator = SQL::Translator->new;
  36   $translator->parser("SQL::Translator::Parser::PostgreSQL");
  37
  38 =head1 DESCRIPTION
  39
  40 The grammar was started from the MySQL parsers.  Here is the description
  41 from PostgreSQL:
  42
  43 Table:
  44 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createtable.html)
  45
  46   CREATE [ [ LOCAL ] { TEMPORARY | TEMP } ] TABLE table_name (
  47       { column_name data_type [ DEFAULT default_expr ]
  48          [ column_constraint [, ... ] ]
  49       | table_constraint }  [, ... ]
  50   )
  51   [ INHERITS ( parent_table [, ... ] ) ]
  52   [ WITH OIDS | WITHOUT OIDS ]
  53
  54   where column_constraint is:
  55
  56   [ CONSTRAINT constraint_name ]
  57   { NOT NULL | NULL | UNIQUE | PRIMARY KEY |
  58     CHECK (expression) |
  59     REFERENCES reftable [ ( refcolumn ) ] [ MATCH FULL | MATCH PARTIAL ]
  60       [ ON DELETE action ] [ ON UPDATE action ] }
  61   [ DEFERRABLE | NOT DEFERRABLE ]
  62   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  63
  64   and table_constraint is:
  65
  66   [ CONSTRAINT constraint_name ]
  67   { UNIQUE ( column_name [, ... ] ) |
  68     PRIMARY KEY ( column_name [, ... ] ) |
  69     CHECK ( expression ) |
  70     FOREIGN KEY ( column_name [, ... ] )
  71      REFERENCES reftable [ ( refcolumn [, ... ] ) ]
  72       [ MATCH FULL | MATCH PARTIAL ]
  73       [ ON DELETE action ] [ ON UPDATE action ] }
  74   [ DEFERRABLE | NOT DEFERRABLE ]
  75   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  76
  77 Index:
  78 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createindex.html)
  79
  80   CREATE [ UNIQUE ] INDEX index_name ON table
  81       [ USING acc_method ] ( column [ ops_name ] [, ...] )
  82       [ WHERE predicate ]
  83   CREATE [ UNIQUE ] INDEX index_name ON table
  84       [ USING acc_method ] ( func_name( column [, ... ]) [ ops_name ] )
  85       [ WHERE predicate ]
  86
  87 Alter table:
  88
  89   ALTER TABLE [ ONLY ] table [ * ]
  90       ADD [ COLUMN ] column type [ column_constraint [ ... ] ]
  91   ALTER TABLE [ ONLY ] table [ * ]
  92       ALTER [ COLUMN ] column { SET DEFAULT value | DROP DEFAULT }
  93   ALTER TABLE [ ONLY ] table [ * ]
  94       ALTER [ COLUMN ] column SET STATISTICS integer
  95   ALTER TABLE [ ONLY ] table [ * ]
  96       RENAME [ COLUMN ] column TO newcolumn
  97   ALTER TABLE table
  98       RENAME TO new_table
  99   ALTER TABLE table
 100       ADD table_constraint_definition
 101   ALTER TABLE [ ONLY ] table
 102           DROP CONSTRAINT constraint { RESTRICT | CASCADE }
 103   ALTER TABLE table
 104           OWNER TO new_owner
 105
 106 View table:
 107
 108     CREATE [ OR REPLACE ] VIEW view [ ( column name list ) ] AS SELECT query
 109
 110 =cut
 111
 112 use strict;
 113 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
 114 $VERSION = sprintf "%d.%02d", q$Revision: 1.27 $ =~ /(\d+)\.(\d+)/;
 115 $DEBUG   = 0 unless defined $DEBUG;
 116
 117 use Data::Dumper;
 118 use Parse::RecDescent;
 119 use Exporter;
 120 use base qw(Exporter);
 121
 122 @EXPORT_OK = qw(parse);
 123
 124 # Enable warnings within the Parse::RecDescent module.
 125 $::RD_ERRORS = 1; # Make sure the parser dies when it encounters an error
 126 $::RD_WARN   = 1; # Enable warnings. This will warn on unused rules &c.
 127 $::RD_HINT   = 1; # Give out hints to help fix problems.
 128
 129 my $parser; # should we do this?  There's no programmic way to
 130             # change the grammar, so I think this is safe.
 131
 132 $GRAMMAR = q!
 133
 134 { our ( %tables, $table_order ) }
 135
 136 #
 137 # The "eofile" rule makes the parser fail if any "statement" rule
 138 # fails.  Otherwise, the first successful match by a "statement"
 139 # won't cause the failure needed to know that the parse, as a whole,
 140 # failed. -ky
 141 #
 142 startrule : statement(s) eofile { \%tables }
 143
 144 eofile : /^\Z/
 145
 146 statement : create
 147   | comment
 148   | alter
 149   | grant
 150   | revoke
 151   | drop
 152   | insert
 153   | connect
 154   | update
 155   | set
 156   | <error>
 157
 158 connect : /^\s*\\\connect.*\n/
 159
 160 set : /set/i /[^;]*/ ';'
 161
 162 revoke : /revoke/i WORD(s /,/) /on/i TABLE(?) table_name /from/i name_with_opt_quotes(s /,/) ';'
 163     {
 164         my $table_name = $item{'table_name'};
 165         push @{ $tables{ $table_name }{'permissions'} }, {
 166             type       => 'revoke',
 167             actions    => $item[2],
 168             users      => $item[7],
 169         }
 170     }
 171
 172 grant : /grant/i WORD(s /,/) /on/i TABLE(?) table_name /to/i name_with_opt_quotes(s /,/) ';'
 173     {
 174         my $table_name = $item{'table_name'};
 175         push @{ $tables{ $table_name }{'permissions'} }, {
 176             type       => 'grant',
 177             actions    => $item[2],
 178             users      => $item[7],
 179         }
 180     }
 181
 182 drop : /drop/i /[^;]*/ ';'
 183
 184 insert : /insert/i /[^;]*/ ';'
 185
 186 update : /update/i /[^;]*/ ';'
 187
 188 #
 189 # Create table.
 190 #
 191 create : create_table table_name '(' create_definition(s /,/) ')' table_option(s?) ';'
 192     {
 193         my $table_name                       = $item{'table_name'};
 194         $tables{ $table_name }{'order'}      = ++$table_order;
 195         $tables{ $table_name }{'table_name'} = $table_name;
 196
 197         my $i = 1;
 198         my @constraints;
 199         for my $definition ( @{ $item[4] } ) {
 200             if ( $definition->{'type'} eq 'field' ) {
 201                 my $field_name = $definition->{'name'};
 202                 $tables{ $table_name }{'fields'}{ $field_name } =
 203                     { %$definition, order => $i };
 204                 $i++;
 205
 206                 for my $constraint ( @{ $definition->{'constraints'} || [] } ) {
 207                     $constraint->{'fields'} = [ $field_name ];
 208                     push @{ $tables{ $table_name }{'constraints'} },
 209                         $constraint;
 210                 }
 211             }
 212             elsif ( $definition->{'type'} eq 'constraint' ) {
 213                 $definition->{'type'} = $definition->{'constraint_type'};
 214                 # group FKs at the field level
 215 #                if ( $definition->{'type'} eq 'foreign_key' ) {
 216 #                    for my $fld ( @{ $definition->{'fields'} || [] } ) {
 217 #                        push @{
 218 #                            $tables{$table_name}{'fields'}{$fld}{'constraints'}
 219 #                        }, $definition;
 220 #                    }
 221 #                }
 222 #                else {
 223                     push @{ $tables{ $table_name }{'constraints'} },
 224                         $definition;
 225 #                }
 226             }
 227             else {
 228                 push @{ $tables{ $table_name }{'indices'} }, $definition;
 229             }
 230         }
 231
 232         for my $option ( @{ $item[6] } ) {
 233             $tables{ $table_name }{'table_options(s?)'}{ $option->{'type'} } =
 234                 $option;
 235         }
 236
 237         1;
 238     }
 239
 240 #
 241 # Create index.
 242 #
 243 create : /create/i unique(?) /(index|key)/i index_name /on/i table_name using_method(?) '(' field_name(s /,/) ')' where_predicate(?) ';'
 244     {
 245         push @{ $tables{ $item{'table_name'} }{'indices'} },
 246             {
 247                 name   => $item{'index_name'},
 248                 type   => $item{'unique'}[0] ? 'unique' : 'normal',
 249                 fields => $item[9],
 250                 method => $item{'using_method'}[0],
 251             }
 252         ;
 253     }
 254
 255 #
 256 # Create anything else (e.g., domain, function, etc.)
 257 #
 258 create : /create/i WORD /[^;]+/ ';'
 259
 260 using_method : /using/i WORD { $item[2] }
 261
 262 where_predicate : /where/i /[^;]+/
 263
 264 create_definition : field
 265     | table_constraint
 266     | <error>
 267
 268 comment : /^\s*(?:#|-{2}).*\n/
 269
 270 field : comment(s?) field_name data_type field_meta(s?) comment(s?)
 271     {
 272         my ( $default, @constraints, $is_pk );
 273         my $null = 1;
 274         for my $meta ( @{ $item[4] } ) {
 275             if ( $meta->{'type'} eq 'default' ) {
 276                 $default = $meta;
 277                 next;
 278             }
 279             elsif ( $meta->{'type'} eq 'not_null' ) {
 280                 $null = 0;
 281 #                next;
 282             }
 283             elsif ( $meta->{'type'} eq 'primary_key' ) {
 284                 $is_pk = 1;
 285             }
 286
 287             push @constraints, $meta if $meta->{'supertype'} eq 'constraint';
 288         }
 289
 290         my @comments = ( @{ $item[1] }, @{ $item[5] } );
 291
 292         $return = {
 293             type           => 'field',
 294             name           => $item{'field_name'},
 295             data_type      => $item{'data_type'}{'type'},
 296             size           => $item{'data_type'}{'size'},
 297             null           => $null,
 298             default        => $default->{'value'},
 299             constraints    => [ @constraints ],
 300             comments       => [ @comments ],
 301             is_primary_key => $is_pk || 0,
 302         }
 303     }
 304     | <error>
 305
 306 field_meta : default_val
 307     | column_constraint
 308
 309 column_constraint : constraint_name(?) column_constraint_type deferrable(?) deferred(?)
 310     {
 311         my $desc       = $item{'column_constraint_type'};
 312         my $type       = $desc->{'type'};
 313         my $fields     = $desc->{'fields'}     || [];
 314         my $expression = $desc->{'expression'} || '';
 315
 316         $return              =  {
 317             supertype        => 'constraint',
 318             name             => $item{'constraint_name'}[0] || '',
 319             type             => $type,
 320             expression       => $type eq 'check' ? $expression : '',
 321             deferrable       => $item{'deferrable'},
 322             deferred         => $item{'deferred'},
 323             reference_table  => $desc->{'reference_table'},
 324             reference_fields => $desc->{'reference_fields'},
 325             match_type       => $desc->{'match_type'},
 326             on_delete_do     => $desc->{'on_delete_do'},
 327             on_update_do     => $desc->{'on_update_do'},
 328         }
 329     }
 330
 331 constraint_name : /constraint/i name_with_opt_quotes { $item[2] }
 332
 333 column_constraint_type : /not null/i { $return = { type => 'not_null' } }
 334     |
 335     /null/i
 336         { $return = { type => 'null' } }
 337     |
 338     /unique/i
 339         { $return = { type => 'unique' } }
 340     |
 341     /primary key/i
 342         { $return = { type => 'primary_key' } }
 343     |
 344     /check/i '(' /[^)]+/ ')'
 345         { $return = { type => 'check', expression => $item[2] } }
 346     |
 347     /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 348     {
 349         my ( $on_delete, $on_update );
 350         for my $action ( @{ $item[5] || [] } ) {
 351             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 352             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 353         }
 354
 355         $return              =  {
 356             type             => 'foreign_key',
 357             reference_table  => $item[2],
 358             reference_fields => $item[3][0],
 359             match_type       => $item[4][0],
 360             on_delete_do     => $on_delete,
 361             on_update_do     => $on_update,
 362         }
 363     }
 364
 365 table_name : name_with_opt_quotes
 366
 367 field_name : name_with_opt_quotes
 368
 369 name_with_opt_quotes : double_quote(?) NAME double_quote(?) { $item[2] }
 370
 371 double_quote: /"/
 372
 373 index_name : WORD
 374
 375 data_type : pg_data_type parens_value_list(?)
 376     {
 377         my $data_type = $item[1];
 378
 379         #
 380         # We can deduce some sizes from the data type's name.
 381         #
 382         $data_type->{'size'} ||= $item[2][0];
 383
 384         $return  = $data_type;
 385     }
 386
 387 pg_data_type :
 388     /(bigint|int8)/i
 389         {
 390             $return = {
 391                 type => 'integer',
 392                 size => [8],
 393             };
 394         }
 395     |
 396     /(smallint|int2)/i
 397         {
 398             $return = {
 399                 type => 'integer',
 400                 size => [2],
 401             };
 402         }
 403     |
 404     /(integer|int4?)/i # interval must come before this
 405         {
 406             $return = {
 407                 type => 'integer',
 408                 size => [4],
 409             };
 410         }
 411     |
 412     /(real|float4)/i
 413         {
 414             $return = {
 415                 type => 'real',
 416                 size => [4],
 417             };
 418         }
 419     |
 420     /(double precision|float8?)/i
 421         {
 422             $return = {
 423                 type => 'float',
 424                 size => [8],
 425             };
 426         }
 427     |
 428     /(bigserial|serial8)/i
 429         {
 430             $return = {
 431                 type           => 'integer',
 432                 size           => [8],
 433                 auto_increment => 1,
 434             };
 435         }
 436     |
 437     /serial4?/i
 438         {
 439             $return = {
 440                 type           => 'integer',
 441                 size           => [4],
 442                 auto_increment => 1,
 443             };
 444         }
 445     |
 446     /(bit varying|varbit)/i
 447         {
 448             $return = { type => 'varbit' };
 449         }
 450     |
 451     /character varying/i
 452         {
 453             $return = { type => 'varchar' };
 454         }
 455     |
 456     /char(acter)?/i
 457         {
 458             $return = { type => 'char' };
 459         }
 460     |
 461     /bool(ean)?/i
 462         {
 463             $return = { type => 'boolean' };
 464         }
 465     |
 466     /bytea/i
 467         {
 468             $return = { type => 'bytea' };
 469         }
 470     |
 471     /(timestamptz|timestamp)/i
 472         {
 473             $return = { type => 'timestamp' };
 474         }
 475     |
 476     /(bit|box|cidr|circle|date|inet|interval|line|lseg|macaddr|money|numeric|decimal|path|point|polygon|text|timetz|time|varchar)/i
 477         {
 478             $return = { type => $item[1] };
 479         }
 480
 481 parens_value_list : '(' VALUE(s /,/) ')'
 482     { $item[2] }
 483
 484 parens_word_list : '(' WORD(s /,/) ')'
 485     { $item[2] }
 486
 487 field_size : '(' num_range ')' { $item{'num_range'} }
 488
 489 num_range : DIGITS ',' DIGITS
 490     { $return = $item[1].','.$item[3] }
 491     | DIGITS
 492     { $return = $item[1] }
 493
 494 table_constraint : comment(s?) constraint_name(?) table_constraint_type deferrable(?) deferred(?) comment(s?)
 495     {
 496         my $desc       = $item{'table_constraint_type'};
 497         my $type       = $desc->{'type'};
 498         my $fields     = $desc->{'fields'};
 499         my $expression = $desc->{'expression'};
 500         my @comments   = ( @{ $item[1] }, @{ $item[-1] } );
 501
 502         $return              =  {
 503             name             => $item{'constraint_name'}[0] || '',
 504             type             => 'constraint',
 505             constraint_type  => $type,
 506             fields           => $type ne 'check' ? $fields : [],
 507             expression       => $type eq 'check' ? $expression : '',
 508             deferrable       => $item{'deferrable'},
 509             deferred         => $item{'deferred'},
 510             reference_table  => $desc->{'reference_table'},
 511             reference_fields => $desc->{'reference_fields'},
 512             match_type       => $desc->{'match_type'}[0],
 513             on_delete_do     => $desc->{'on_delete_do'},
 514             on_update_do     => $desc->{'on_update_do'},
 515             comments         => [ @comments ],
 516         }
 517     }
 518
 519 table_constraint_type : /primary key/i '(' name_with_opt_quotes(s /,/) ')'
 520     {
 521         $return = {
 522             type   => 'primary_key',
 523             fields => $item[3],
 524         }
 525     }
 526     |
 527     /unique/i '(' name_with_opt_quotes(s /,/) ')'
 528     {
 529         $return    =  {
 530             type   => 'unique',
 531             fields => $item[3],
 532         }
 533     }
 534     |
 535     /check/i '(' /(.+)/ ')'
 536     {
 537         $return        =  {
 538             type       => 'check',
 539             expression => $item[3],
 540         }
 541     }
 542     |
 543     /foreign key/i '(' name_with_opt_quotes(s /,/) ')' /references/i table_name parens_word_list(?) match_type(?) key_action(s?)
 544     {
 545         my ( $on_delete, $on_update );
 546         for my $action ( @{ $item[9] || [] } ) {
 547             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 548             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 549         }
 550
 551         $return              =  {
 552             type             => 'foreign_key',
 553             fields           => $item[3],
 554             reference_table  => $item[6],
 555             reference_fields => $item[7][0],
 556             match_type       => $item[8][0],
 557             on_delete_do     => $on_delete || '',
 558             on_update_do     => $on_update || '',
 559         }
 560     }
 561
 562 deferrable : /not/i /deferrable/i
 563     {
 564         $return = ( $item[1] =~ /not/i ) ? 0 : 1;
 565     }
 566
 567 deferred : /initially/i /(deferred|immediate)/i { $item[2] }
 568
 569 match_type : /match full/i { 'match_full' }
 570     |
 571     /match partial/i { 'match_partial' }
 572
 573 key_action : key_delete
 574     |
 575     key_update
 576
 577 key_delete : /on delete/i key_mutation
 578     {
 579         $return => {
 580             type   => 'delete',
 581             action => $item[2],
 582         };
 583     }
 584
 585 key_update : /on update/i key_mutation
 586     {
 587         $return => {
 588             type   => 'update',
 589             action => $item[2],
 590         };
 591     }
 592
 593 key_mutation : /no action/i { $return = 'no_action' }
 594     |
 595     /restrict/i { $return = 'restrict' }
 596     |
 597     /cascade/i { $return = 'cascade' }
 598     |
 599     /set null/i { $return = 'set_null' }
 600     |
 601     /set default/i { $return = 'set_default' }
 602
 603 alter : alter_table table_name /add/i table_constraint ';'
 604     {
 605         my $table_name = $item[2];
 606         my $constraint = $item[4];
 607         $constraint->{'type'} = $constraint->{'constraint_type'};
 608         push @{ $tables{ $table_name }{'constraints'} }, $constraint;
 609     }
 610
 611 alter_table : /alter/i /table/i only(?)
 612
 613 only : /only/i
 614
 615 create_table : /create/i TABLE
 616
 617 create_index : /create/i /index/i
 618
 619 default_val  : /default/i /(\d+|'[^']*'|\w+\(.*?\))|\w+/
 620     {
 621         my $val =  defined $item[2] ? $item[2] : '';
 622         $val    =~ s/^'|'$//g;
 623         $return =  {
 624             supertype => 'constraint',
 625             type      => 'default',
 626             value     => $val,
 627         }
 628     }
 629     | /null/i
 630     {
 631         $return =  {
 632             supertype => 'constraint',
 633             type      => 'default',
 634             value     => 'NULL',
 635         }
 636     }
 637
 638 name_with_opt_paren : NAME parens_value_list(s?)
 639     { $item[2][0] ? "$item[1]($item[2][0][0])" : $item[1] }
 640
 641 unique : /unique/i { 1 }
 642
 643 key : /key/i | /index/i
 644
 645 table_option : /inherits/i '(' name_with_opt_quotes(s /,/) ')'
 646     {
 647         $return = { type => 'inherits', table_name => $item[3] }
 648     }
 649     |
 650     /with(out)? oids/i
 651     {
 652         $return = { type => $item[1] =~ /out/i ? 'without_oids' : 'with_oids' }
 653     }
 654
 655 TABLE : /table/i
 656
 657 SEMICOLON : /\s*;\n?/
 658
 659 WORD : /\w+/
 660
 661 DIGITS : /\d+/
 662
 663 COMMA : ','
 664
 665 NAME    : "`" /\w+/ "`"
 666     { $item[2] }
 667     | /\w+/
 668     { $item[1] }
 669     | /[\$\w]+/
 670     { $item[1] }
 671
 672 VALUE   : /[-+]?\.?\d+(?:[eE]\d+)?/
 673     { $item[1] }
 674     | /'.*?'/   # XXX doesn't handle embedded quotes
 675     { $item[1] }
 676     | /null/i
 677     { 'NULL' }
 678
 679 !;
 680
 681 # -------------------------------------------------------------------
 682 sub parse {
 683     my ( $translator, $data ) = @_;
 684     $parser ||= Parse::RecDescent->new($GRAMMAR);
 685
 686     $::RD_TRACE  = $translator->trace ? 1 : undef;
 687     $DEBUG       = $translator->debug;
 688
 689     unless (defined $parser) {
 690         return $translator->error("Error instantiating Parse::RecDescent ".
 691             "instance: Bad grammer");
 692     }
 693
 694     my $result = $parser->startrule($data);
 695     die "Parse failed.\n" unless defined $result;
 696     warn Dumper($result) if $DEBUG;
 697
 698     my $schema = $translator->schema;
 699     my @tables = sort {
 700         $result->{ $a }->{'order'} <=> $result->{ $b }->{'order'}
 701     } keys %{ $result };
 702
 703     for my $table_name ( @tables ) {
 704         my $tdata =  $result->{ $table_name };
 705         my $table =  $schema->add_table(
 706             name  => $tdata->{'table_name'},
 707         ) or die "Couldn't create table '$table_name': " . $schema->error;
 708
 709         my @fields = sort {
 710             $tdata->{'fields'}->{$a}->{'order'}
 711             <=>
 712             $tdata->{'fields'}->{$b}->{'order'}
 713         } keys %{ $tdata->{'fields'} };
 714
 715         for my $fname ( @fields ) {
 716             my $fdata = $tdata->{'fields'}{ $fname };
 717             my $field = $table->add_field(
 718                 name              => $fdata->{'name'},
 719                 data_type         => $fdata->{'data_type'},
 720                 size              => $fdata->{'size'},
 721                 default_value     => $fdata->{'default'},
 722                 is_auto_increment => $fdata->{'is_auto_inc'},
 723                 is_nullable       => $fdata->{'null'},
 724             ) or die $table->error;
 725
 726             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 727
 728             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 729                 next unless $cdata->{'type'} eq 'foreign_key';
 730                 $cdata->{'fields'} ||= [ $field->name ];
 731                 push @{ $tdata->{'constraints'} }, $cdata;
 732             }
 733         }
 734
 735         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 736             my $index  =  $table->add_index(
 737                 name   => $idata->{'name'},
 738                 type   => uc $idata->{'type'},
 739                 fields => $idata->{'fields'},
 740             ) or die $table->error;
 741         }
 742
 743         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 744             my $constraint       =  $table->add_constraint(
 745                 name             => $cdata->{'name'},
 746                 type             => $cdata->{'type'},
 747                 fields           => $cdata->{'fields'},
 748                 reference_table  => $cdata->{'reference_table'},
 749                 reference_fields => $cdata->{'reference_fields'},
 750                 match_type       => $cdata->{'match_type'} || '',
 751                 on_delete        => $cdata->{'on_delete_do'},
 752                 on_update        => $cdata->{'on_update_do'},
 753             ) or die $table->error;
 754         }
 755     }
 756
 757     return 1;
 758 }
 759
 760 1;
 761
 762 # -------------------------------------------------------------------
 763 # Rescue the drowning and tie your shoestrings.
 764 # Henry David Thoreau
 765 # -------------------------------------------------------------------
 766
 767 =pod
 768
 769 =head1 AUTHORS
 770
 771 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>,
 772 Allen Day <allenday@ucla.edu>.
 773
 774 =head1 SEE ALSO
 775
 776 perl(1), Parse::RecDescent.
 777
 778 =cut